Simple CreateProcess Win32 MSDN Example

[SpriggsySpriggs]

Based on the MSDN page for Creating Processes, here is a super simple way to demonstrate starting another application from QB64 using the Win32 API function set. The below code uses all functions used in the MSDN example. It is designed to be compiled as a console application and ran from CMD or PowerShell. You will pass it the name or full path of another executable to run as the argument.

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3.  
4. Type STARTUPINFO
5.     As Long cb
6.     $If 64BIT Then
7.         As Long padding
8.     $End If
9.     As _Offset lpReserved, lpDesktop, lpTitle
10.     As Long dwX, dwY, dwXSize, dwYSize, dwXCountChars, dwYCountChars, dwFillAttribute, dwFlags
11.     As Integer wShowWindow, cbReserved2
12.     $If 64BIT Then
13.         As Long padding2
14.     $End If
15.     As _Offset lpReserved2, hStdInput, hStdOutput, hStdError
16. End Type
17.  
18. Type PROCESS_INFORMATION
19.     As _Offset hProcess, hThread
20.     As Long dwProcessId
21.     $If 64BIT Then
22.         As Long padding
23.     $End If
24. End Type
25.  
26. Const INFINITE = 4294967295
27.  
28. Declare CustomType Library
29.     Function CreateProcess%% Alias "CreateProcessA" (ByVal lpApplicationName As _Offset, lpCommandLine As String, Byval lpProcessAttributes As _Offset, Byval lpThreadAttributes As _Offset, Byval bInheritHandles As Integer, Byval dwCreationFlags As Long, Byval lpEnvironment As _Offset, Byval lpCurrentDirectory As _Offset, Byval lpStartupInfor As _Offset, Byval lpProcessInformation As _Offset)
30.     Sub CloseHandle (ByVal hObject As _Offset)
31.     Sub WaitForSingleObject (ByVal hHandle As _Offset, Byval dwMilliseconds As Long)
32.     Sub printf (template As String, arg As String)
33.     Sub printf2 Alias "printf" (template As String, Byval dwArg As Long)
34.     Function GetLastError& ()
35.     Sub ZeroMemory Alias "SecureZeroMemory" (ByVal Destination As _Offset, Byval Length As _Offset)
36. End Declare
37.  
38. Dim As STARTUPINFO si
39. Dim As PROCESS_INFORMATION pi
40.  
41. ZeroMemory _Offset(si), Len(si)
42. ZeroMemory _Offset(pi), Len(pi)
43.  
44. si.cb = Len(si)
45.  
46. If _CommandCount <> 1 Then
47.     printf "Usage: %s [cmdline]" + Chr$(10) + Chr$(0), Command$(0)
48.     System
49. End If
50.  
51. If CreateProcess(0, Command$(1) + Chr$(0), 0, 0, 0, 0, 0, 0, _Offset(si), _Offset(pi)) = 0 Then
52.     printf2 "CreateProcess failed (%d)." + Chr$(10) + Chr$(0), GetLastError
53.     System
54. End If
55.  
56. WaitForSingleObject pi.hProcess, INFINITE
57.  
58. CloseHandle pi.hProcess
59. CloseHandle pi.hThread
60. System