Poke to screen 0 for speed

[bplus]

Ha! that's fast work. May I ask what is the object of game?

[PMACKAY]

the topic at the moment is to collect all diamonds, what out for getting blocked in by boulders, there are going to be some monsters that can chase and kill you, and get through the levels, i am not to sure what to do yet. just mucking about. i will do a level editor to go with this. but one thing first is getting this to work

[bplus]

Well you got the 2 dimensional array map array fast enough!

You are doing odd thing (to me) for polling key presses, _keydown is great for picking up which key or key combo was pressed.

IF _KEYDOWN(32) then print "You pressed space bar."

http://qb64.org/wiki/KEYDOWN

Of course, just because I think your method is odd or complicated doesn't mean it's wrong or won't work.

All these key press polling methods have problem of clearing the buffer to tell if a key was meant to be pressed once or many times in a row. Usually the QB64 assumes many times and it is hard to move one space at time with arrows.

[bplus]

I wonder why the CASE is not indenting here:

  [ You are not allowed to view this attachment ]  

[PMACKAY]

the keyboard is alway hard on the pc. think the interupt is the issue as it reads it so quick and fills the buffer. i have just fixed a few things on it now


i think the case is not indentting as i have more than one on a line

[FellippeHeitor]

I wonder why the CASE is not indenting here:

  [ You are not allowed to view this attachment ]

Excessive grouping is giving the IDE a hard time.

[PMACKAY]

select case and end select can be made to run as one line. just looks tight.

[PMACKAY]

time for bed for me

[bplus]

;)

I tried it with _KEYDOWN and clearing last _KEYDOWN so that one key press = one space moved

Code: QB64: [Select]

1. DEFINT A-Z: DIM screenmem%(22, 12)
2. WIDTH 20, 14: _FULLSCREEN
3. GOSUB readlev: GOSUB displaymap: GOSUB animate: score = 0
4. DO
5.  
6.     screenmem%(mx%, my%) = 1
7.     GOSUB animate
8.     screenmem%(mx%, my%) = 32
9.  
10.     IF _KEYDOWN(18432) THEN 'up
11.         IF screenmem%(mx%, my% - 1) = 32 OR screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1
12.         WHILE _KEYDOWN(18432): _LIMIT 200: WEND
13.     END IF
14.  
15.     IF _KEYDOWN(20480) THEN 'down
16.         IF screenmem%(mx%, my% + 1) = 32 OR screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1
17.         IF screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
18.         WHILE _KEYDOWN(20480): _LIMIT 200: WEND
19.     END IF
20.  
21.     IF _KEYDOWN(19200) THEN 'left
22.         IF screenmem%(mx% - 1, my%) = 32 OR screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1
23.         IF screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
24.         IF screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
25.         WHILE _KEYDOWN(19200): _LIMIT 200: WEND
26.     END IF
27.  
28.  
29.     IF _KEYDOWN(19712) THEN 'right
30.         IF screenmem%(mx% + 1, my%) = 32 OR screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1
31.         IF screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
32.         IF screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
33.         WHILE _KEYDOWN(19712): _LIMIT 200: WEND
34.     END IF
35.  
36.     _LIMIT 100
37. LOOP UNTIL _KEYDOWN(27) 'escape
38.  
39. END
40.  
41. animate:
42.  
43. FOR i = 1 TO 19
44.     FOR j = 11 TO 1 STEP -1
45.         IF screenmem%(i, j) = 79 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 79
46.         IF screenmem%(i, j) = 4 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 4
47.     NEXT j
48. NEXT i
49.  
50. displaymap:
51.  
52. FOR i = 1 TO 12
53.     FOR j = 1 TO 20
54.         b = screenmem%(j, i)
55.         COLOR 4
56.         SELECT CASE b
57.         CASE 79: COLOR 15: CASE 177: COLOR 4
58.         CASE 234: COLOR 2: CASE 235: COLOR 2
59.         CASE 176: COLOR 6: CASE 1: COLOR 14
60.         CASE 219: COLOR 4: CASE 4: COLOR 1
61.         END SELECT
62.         _PRINTSTRING (j, i), CHR$(b)
63.     NEXT j
64. NEXT i
65. COLOR 6: _PRINTSTRING (4, 13), "SCORE - " + STR$(score)
66. RETURN
67.  
68. readlev:
69.  
70. FOR i = 1 TO 12
71.     READ map$
72.     FOR j = 1 TO 20
73.         b$ = MID$(map$, j, 1)
74.         IF b$ = "B" THEN b = 177
75.         IF b$ = " " THEN b = 32
76.         IF b$ = "M" THEN b = 234
77.         IF b$ = "m" THEN b = 235
78.         IF b$ = "v" THEN b = 1: mx% = j: my% = i
79.         IF b$ = "O" THEN b = 79
80.         IF b$ = "." THEN b = 176
81.         IF b$ = "X" THEN b = 219
82.         IF b$ = "D" THEN b = 4
83.         screenmem%(j, i) = b
84.     NEXT j
85. NEXT i
86.  
87. RETURN
88.  
89. DATA "BBBBBBBBBBBBBBBBBBBB"
90. DATA "BOODBM       BODODOB"
91. DATA "B...BB... OO B.OOO.B"
92. DATA "B.BBB..O. .. B.....B"
93. DATA "B.....O.O       .O.B"
94. DATA "B.O.O.BDBvBBBBB ...X"
95. DATA "BO....BBB BODOB O..B"
96. DATA "B.......B BDODB .OOB"
97. DATA "B..O.O..B BBOBB ...B"
98. DATA "B.O.O.O.B ..... .O.B"
99. DATA "B.OD.DO.B   m   .ODB"
100. DATA "BBBBBBBBBBXBBBBBBBBB"
101.  
102.  

I will have to think about how to get that diamond in bottom right corner without being buried in rocks!

[FellippeHeitor]

You seem to fail to grasp that _KEYDOWN will return -1 for as long as the key is held down. It doesn't need clearing (and isn't even affected by _KEYCLEAR).

The use of _KEYDOWN is awesome for games because it allows you to react to multiple keys at once.

Code: QB64: [Select]

1. x = 40
2. y = 12
3.  
4. DO
5.     IF _KEYDOWN(18432) THEN y = y - 1
6.     IF _KEYDOWN(20480) THEN y = y + 1
7.     IF _KEYDOWN(19200) THEN x = x - 1
8.     IF _KEYDOWN(19712) THEN x = x + 1
9.  
10.     IF y < 1 THEN y = 1
11.     IF y > 25 THEN y = 25
12.     IF x < 1 THEN x = 1
13.     IF x > 80 THEN x = 80
14.  
15.     CLS
16.     COLOR 7
17.     PRINT "You can go up/down/left/right but also diagonally"
18.     PRINT "if you hold more than one key at a time."
19.  
20.     COLOR 10
21.     _PRINTSTRING (x, y), CHR$(254)
22.     _DISPLAY
23.     _LIMIT 30
24. LOOP

Now if you want...

one key press = one space moved

...then you're better off sticking to old ways and using INKEY$ (or even _KEYHIT).

[bplus]

You seem to fail to grasp that _KEYDOWN will return -1 for as long as the key is held down. It doesn't need clearing (and isn't even affected by _KEYCLEAR).

The use of _KEYDOWN is awesome for games because it allows you to react to multiple keys at once.

Code: QB64: [Select]

1. x = 40
2. y = 12
3.  
4. DO
5.     IF _KEYDOWN(18432) THEN y = y - 1
6.     IF _KEYDOWN(20480) THEN y = y + 1
7.     IF _KEYDOWN(19200) THEN x = x - 1
8.     IF _KEYDOWN(19712) THEN x = x + 1
9.  
10.     IF y < 1 THEN y = 1
11.     IF y > 25 THEN y = 25
12.     IF x < 1 THEN x = 1
13.     IF x > 80 THEN x = 80
14.  
15.     CLS
16.     COLOR 7
17.     PRINT "You can go up/down/left/right but also diagonally"
18.     PRINT "if you hold more than one key at a time."
19.  
20.     COLOR 10
21.     _PRINTSTRING (x, y), CHR$(254)
22.     _DISPLAY
23.     _LIMIT 30
24. LOOP

Now if you want...

one key press = one space moved

...then you're better off sticking to old ways and using INKEY$ (or even _KEYHIT).

All the methods I have tried for polling keys have trouble with too much response with out some sort of delay or clearing of key buffer. The same goes for mouse.

[bplus]

To show you what I am talking about, here is a little mod to the demo:

Code: QB64: [Select]

1. x = 40
2. y = 12
3.  
4. DO
5.     IF _KEYDOWN(18432) THEN y = y - 1
6.     IF _KEYDOWN(20480) THEN y = y + 1
7.     IF _KEYDOWN(19200) THEN x = x - 1
8.     IF _KEYDOWN(19712) THEN x = x + 1
9.  
10.     IF y < 1 THEN y = 1
11.     IF y > 25 THEN y = 25
12.     IF x < 1 THEN x = 1
13.     IF x > 80 THEN x = 80
14.  
15.     CLS
16.     COLOR 7
17.     PRINT "You can go up/down/left/right but also diagonally"
18.     PRINT "if you hold more than one key at a time."
19.     PRINT
20.     PRINT "Now try to stop the moving dot inside the blue ( )"
21.  
22.     COLOR 9
23.     _PRINTSTRING (10, 6), "( )"
24.     _PRINTSTRING (30, 10), "( )"
25.     _PRINTSTRING (1, 12), "( )"
26.  
27.     COLOR 10
28.     _PRINTSTRING (x, y), CHR$(254)
29.     _DISPLAY
30.     _LIMIT 30
31. LOOP
32.  

It does work better with INKEY$

Code: QB64: [Select]

1.     k$ = INKEY$
2.     IF k$ = "u" THEN y = y - 1
3.     IF k$ = "d" THEN y = y + 1
4.     IF k$ = "l" THEN x = x - 1
5.     IF k$ = "r" THEN x = x + 1
6.  

[FellippeHeitor]

So there you have it, we agree. For cases where you need a single entry, INKEY$ or _KEYHIT.

_KEYDOWN has its own range of uses.

[SMcNeill]

Taking a look at your code, I have a few questions for you:

1) Why make keystate so hard to comprehend, when what it's doing is really very simple:

Code: QB64: [Select]

1. FOR k = 0 TO 127 '255
2.     keystate(k) = 1 'keystate(k) = -((k AND 128) = 0)
3. NEXT

The code you're using is running the formula from 0 to 255, and placing the value of 1 in the first 128 elements of the array (0 to 127), and then placing 0 in the next 128 elements.  It works, but it's some of the best code obfuscation I've seen in ages.  You can see how much simpler, and easier to read and understand, the changes I'd make are, above.

2) Same question with the DATA array.  Why read it as a single line for "B", "X", "V" and such, and then have to break it down with MID$ to get the numeric values you want from that data -- after running it through a value conversion routine? 

Isn't it much simpler to just change the DATA so that it represents what you're actually using?

Code: QB64: [Select]

1. DATA "±±±±±±±±±±±±±±±±±±±±"
2. DATA "±OO±ê       ±OOO±"
3. DATA "±°°°±±°°° OO ±°OOO°±"
4. DATA "±°±±±°°O° °° ±°°°°°±"
5. DATA "±°°°°°O°O       °O°±"
6. DATA "±°O°O°±±
   ±±±±± °°°Û"
7. DATA "±O°°°°±±± ±OO± O°°±"
8. DATA "±°°°°°°°± ±O± °OO±"
9. DATA "±°°O°O°°± ±±O±± °°°±"
10. DATA "±°O°O°O°± °°°°° °O°±"
11. DATA "±°O°O°±   ë   °O±"
12. DATA "±±±±±±±±±±Û±±±±±±±±±"
13.  

Note that the above doesn't display all pretty for me here on the forums, but it works just fine in QB64's IDE which supports the extended ASCII characters.

Also note, with the above, all we need to read that DATA and use it is the following little routine:

Code: QB64: [Select]

1. readlev:
2.  
3. FOR i = 1 TO 12
4.     READ map$
5.     FOR j = 1 TO 20
6.         b = ASC(map$, j)
7.         IF b = 1 THEN mx% = j: my% = i
8.         screenmem%(j, i) = b
9.     NEXT j
10. NEXT i
11.  
12. RETURN

Doesn't that seem a wee bit simpler?

Or, even better, I prefer to break the DATA down to the ASC values and store them independent as the following:

Code: QB64: [Select]

1. DATA 177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177
2. DATA 177,79,79,4,177,234,32,32,32,32,32,32,32,177,79,4,79,4,79,177
3. DATA 177,176,176,176,177,177,176,176,176,32,79,79,32,177,176,79,79,79,176,177
4. DATA 177,176,177,177,177,176,176,79,176,32,176,176,32,177,176,176,176,176,176,177
5. DATA 177,176,176,176,176,176,79,176,79,32,32,32,32,32,32,32,176,79,176,177
6. DATA 177,176,79,176,79,176,177,4,177,1,177,177,177,177,177,32,176,176,176,219
7. DATA 177,79,176,176,176,176,177,177,177,32,177,79,4,79,177,32,79,176,176,177
8. DATA 177,176,176,176,176,176,176,176,177,32,177,4,79,4,177,32,176,79,79,177
9. DATA 177,176,176,79,176,79,176,176,177,32,177,177,79,177,177,32,176,176,176,177
10. DATA 177,176,79,176,79,176,79,176,177,32,176,176,176,176,176,32,176,79,176,177
11. DATA 177,176,79,4,176,4,79,176,177,32,32,32,235,32,32,32,176,79,4,177
12. DATA 177,177,177,177,177,177,177,177,177,177,219,177,177,177,177,177,177,177,177,177

And, with the DATA stored as we actually need it, all we have to do is the following to use it in our program:

Code: QB64: [Select]

1. readlev:
2.  
3. FOR i = 1 TO 12
4.     FOR j = 1 TO 20
5.         READ screenmem(j, i)
6.         IF screenmem(j, i) = 1 THEN mx% = j: my% = i
7.     NEXT j
8. NEXT i
9.  
10. RETURN

It doesn't get any simpler -- or faster -- than that!  ;)

My overall changes to your last set of code that you shared would end up looking like the following:

Code: QB64: [Select]

1. DEFINT A-Z
2. DIM screenmem%(22, 12), kbd(255), keystate(255)
3.  
4. 'Why complicate the following with hard to understand math, when a much simpler method exists which is way easier to understand?
5.  
6. FOR k = 0 TO 127 '255
7.     keystate(k) = 1 'keystate(k) = -((k AND 128) = 0)
8. NEXT
9.  
10. WIDTH 20, 14: _FULLSCREEN
11.  
12.  
13. GOSUB readlev
14. score = 0
15. GOSUB displaymap
16. GOSUB animate
17. DO
18.  
19.     screenmem%(mx%, my%) = 1
20.     k = INP(&H60): kbd(k AND 127) = keystate(k)
21.     xv = kbd(77) - kbd(75)
22.     yv = kbd(80) - kbd(72)
23.     GOSUB animate
24.     screenmem%(mx%, my%) = 32
25.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 32 THEN mx% = mx% - 1
26.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 32 THEN mx% = mx% + 1
27.     IF yv = -1 AND screenmem%(mx%, my% - 1) = 32 THEN my% = my% - 1
28.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 32 THEN my% = my% + 1
29.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 176 THEN mx% = mx% - 1: GOTO skp
30.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 176 THEN mx% = mx% + 1: GOTO skp
31.     IF yv = -1 AND screenmem%(mx%, my% - 1) = 176 THEN my% = my% - 1: GOTO skp
32.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 176 THEN my% = my% + 1: GOTO skp
33.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 79 AND screenmem%(mx% - 2, my%) = 32 THEN screenmem%(mx% - 2, my%) = 79: screenmem%(mx% - 1, my%) = 32: mx% = mx% - 1
34.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 79 AND screenmem%(mx% + 2, my%) = 32 THEN screenmem%(mx% + 2, my%) = 79: screenmem%(mx% + 1, my%) = 32: mx% = mx% + 1
35.     IF xv = -1 AND screenmem%(mx% - 1, my%) = 4 THEN mx% = mx% - 1: score = score + 1
36.     IF xv = 1 AND screenmem%(mx% + 1, my%) = 4 THEN mx% = mx% + 1: score = score + 1
37.     IF yv = 1 AND screenmem%(mx%, my% + 1) = 4 THEN my% = my% + 1: score = score + 1
38.     skp:
39.     _DELAY 0.10
40.  
41. LOOP UNTIL kbd(1) 'escape key exits
42.  
43. SYSTEM
44.  
45.  
46.  
47.  
48.  
49. animate:
50.  
51. FOR i = 1 TO 19
52.     FOR j = 11 TO 1 STEP -1
53.         IF screenmem%(i, j) = 79 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 79
54.         IF screenmem%(i, j) = 4 AND screenmem%(i, j + 1) = 32 THEN screenmem%(i, j) = 32: screenmem%(i, j + 1) = 4
55.     NEXT j
56. NEXT i
57.  
58. displaymap:
59.  
60. FOR i = 1 TO 12
61.     FOR j = 1 TO 20
62.         b = screenmem%(j, i)
63.         SELECT CASE b
64.             CASE 79: COLOR 15
65.             CASE 177: COLOR 4
66.             CASE 234: COLOR 2
67.             CASE 235: COLOR 2
68.             CASE 176: COLOR 6
69.             CASE 1: COLOR 14
70.             CASE 219: COLOR 4
71.             CASE 4: COLOR 1
72.         END SELECT
73.         _PRINTSTRING (j, i), CHR$(b)
74.     NEXT j
75. NEXT i
76. COLOR 6: _PRINTSTRING (4, 13), "SCORE - " + STR$(score)
77. RETURN
78.  
79. readlev:
80.  
81. FOR i = 1 TO 12
82.     FOR j = 1 TO 20
83.         READ screenmem(j, i)
84.         IF screenmem(j, i) = 1 THEN mx% = j: my% = i
85.     NEXT j
86. NEXT i
87.  
88. RETURN
89.  
90.  
91.  
92. DATA 177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177,177
93. DATA 177,79,79,4,177,234,32,32,32,32,32,32,32,177,79,4,79,4,79,177
94. DATA 177,176,176,176,177,177,176,176,176,32,79,79,32,177,176,79,79,79,176,177
95. DATA 177,176,177,177,177,176,176,79,176,32,176,176,32,177,176,176,176,176,176,177
96. DATA 177,176,176,176,176,176,79,176,79,32,32,32,32,32,32,32,176,79,176,177
97. DATA 177,176,79,176,79,176,177,4,177,1,177,177,177,177,177,32,176,176,176,219
98. DATA 177,79,176,176,176,176,177,177,177,32,177,79,4,79,177,32,79,176,176,177
99. DATA 177,176,176,176,176,176,176,176,177,32,177,4,79,4,177,32,176,79,79,177
100. DATA 177,176,176,79,176,79,176,176,177,32,177,177,79,177,177,32,176,176,176,177
101. DATA 177,176,79,176,79,176,79,176,177,32,176,176,176,176,176,32,176,79,176,177
102. DATA 177,176,79,4,176,4,79,176,177,32,32,32,235,32,32,32,176,79,4,177
103. DATA 177,177,177,177,177,177,177,177,177,177,219,177,177,177,177,177,177,177,177,177
104.  
105. 'The above DATA statements correspond directly to the ASCII values of each spot on the grid below
106. 'DATA "±±±±±±±±±±±±±±±±±±±±"
107. 'DATA "±OO±ê       ±OOO±"
108. 'DATA "±°°°±±°°° OO ±°OOO°±"
109. 'DATA "±°±±±°°O° °° ±°°°°°±"
110. 'DATA "±°°°°°O°O       °O°±"
111. 'DATA "±°O°O°±±
     ±±±±± °°°Û"
112. 'DATA "±O°°°°±±± ±OO± O°°±"
113. 'DATA "±°°°°°°°± ±O± °OO±"
114. 'DATA "±°°O°O°°± ±±O±± °°°±"
115. 'DATA "±°O°O°O°± °°°°° °O°±"
116. 'DATA "±°O°O°±   ë   °O±"
117. 'DATA "±±±±±±±±±±Û±±±±±±±±±"
118.  

[PMACKAY]

thank you for your tips. i found the keyboard routine over the net somewhere. i auctaully need the key left and right if pressed with space bar (space bar + left or space bar + right) to grab the diamond two spaces over so as to take a diamond without the rock in center falling in...


......O......
..D.v.......   so if spacebar pressed and direction will grab diamond without moving