Windows drives

[SMcNeill]

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DECLARE LIBRARY
4.     FUNCTION GetLogicalDrives&
5.     'drives that exist are stored in bit position from 0 to 31.   Bit 0 = Drive A, Bit 1 = Drive B, Bit 2 = Drive C, ect
6.     FUNCTION GetLogicalDriveStringsA& (BYVAL nBufferLength AS LONG, lpBuffer AS STRING)
7.     FUNCTION GetDriveTypeA& (nDrive AS STRING)
8. END DECLARE
9.  
10. 'Drive types will be one of the following:
11. CONST DRIVE_UNKNOWN = 0
12. CONST DRIVE_ABSENT = 1
13. CONST DRIVE_REMOVABLE = 2
14. CONST DRIVE_FIXED = 3
15. CONST DRIVE_REMOTE = 4
16. CONST DRIVE_CDROM = 5
17. CONST DRIVE_RAMDISK = 6
18.  
19.  
20. PRINT "Drives detected:"
21.  
22. FOR i = 0 TO 25 'get all the drives as a bit value array
23.     IF _READBIT(GetLogicalDrives, i) THEN PRINT CHR$(65 + i)
24. NEXT
25.  
26. 'Get all the drives in a string
27. strSave$ = STRING$(255, 0)
28. ret& = GetLogicalDriveStringsA(255, strSave$)
29. PRINT strSave$
30.  
31. 'Get the drive type for drive C:\ as an example
32. GDT = GetDriveTypeA("C:\")
33. SELECT CASE GDT
34.     CASE 2
35.         PRINT "Removable"
36.     CASE 3
37.         PRINT "Drive Fixed"
38.     CASE 4
39.         PRINT "Remote"
40.     CASE 5
41.         PRINT "Cd-Rom"
42.     CASE 6
43.         PRINT "Ram disk"
44.     CASE ELSE
45.         PRINT "Unrecognized"
46. END SELECT
47.  
48.  
49.  

Get a list of the available drives on your machine, and some info on what type they are.

[SpriggsySpriggs]

Oh yeah I did this same thing with a post a while back when that one guy asked about seeing how much space is left on a drive

[bplus]

Oh that looks like it would be handy, I'll be watching for feedback from testers.

Looks good on my system. Didn't even know I had a D: drive or name of my CD drive. Tried SD card and detected as G and removable.

D: drive is that mine or Windows?

[Dav]

It works for me.  Nice to see _READBIT used too - another keyword I need to get to know.

Someone put my version up in the wiki a few years ago, but yours is more complete and should replace it.

- Dav

[SpriggsySpriggs]

Yeah, this is what I did a few months back for Richard.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST DRIVE_UNKNOWN = 0
4. CONST DRIVE_NO_ROOT_DIR = 1
5. CONST DRIVE_REMOVABLE = 2
6. CONST DRIVE_FIXED = 3
7. CONST DRIVE_REMOTE = 4
8. CONST DRIVE_CDROM = 5
9. CONST DRIVE_RAMDISK = 6
10.  
11. DECLARE DYNAMIC LIBRARY "Kernel32"
12.     FUNCTION GetDiskFreeSpace% ALIAS GetDiskFreeSpaceExA (lpDirectoryName AS STRING, BYVAL lpFreeBytesAvailableToCaller AS _OFFSET, BYVAL lpTotalNumberOfBytes AS _OFFSET, BYVAL lpTotalNumberOfFreeBytes AS _OFFSET)
13.     FUNCTION GetDriveType~& ALIAS GetDriveTypeA (lpRootPathName AS STRING)
14. END DECLARE
15.  
16. DIM totalFreeBytesOnDisk AS _UNSIGNED _INTEGER64
17.  
18. IF GetDiskFreeSpace("L:\", 0, 0, _OFFSET(totalFreeBytesOnDisk)) THEN
19.     SELECT CASE totalFreeBytesOnDisk
20.         CASE IS < 1024
21.             PRINT USING "    ####, B Available"; totalFreeBytesOnDisk,
22.         CASE IS < (1024 ^ 2) AND totalFreeBytesOnDisk >= 1024
23.             PRINT USING "####,.## KB Available"; (totalFreeBytesOnDisk / 1024)
24.         CASE IS < (1024 ^ 3) AND totalFreeBytesOnDisk >= (1024 ^ 2)
25.             PRINT USING "####,.## MB Available"; (totalFreeBytesOnDisk / (1024 ^ 2))
26.         CASE IS < (1024 ^ 4) AND totalFreeBytesOnDisk >= (1024 ^ 3)
27.             PRINT USING "####,.## GB Available"; (totalFreeBytesOnDisk / (1024 ^ 3))
28.         CASE IS < (1024 ^ 5) AND totalFreeBytesOnDisk >= (1024 ^ 4)
29.             PRINT USING "####,.## TB Available"; (totalFreeBytesOnDisk / (1024 ^ 4))
30.     END SELECT
31. END IF
32.  
33. SELECT CASE GetDriveType("L:\")
34.     CASE DRIVE_UNKNOWN
35.         PRINT "Unkown drive type"
36.     CASE DRIVE_NO_ROOT_DIR
37.         PRINT "Invalid path"
38.     CASE DRIVE_REMOVABLE
39.         PRINT "Removable media"
40.     CASE DRIVE_FIXED
41.         PRINT "Fixed media"
42.     CASE DRIVE_REMOTE
43.         PRINT "Network media"
44.     CASE DRIVE_CDROM
45.         PRINT "CD-ROM drive"
46.     CASE DRIVE_RAMDISK
47.         PRINT "RAM disk"
48. END SELECT

I guess I didn't get the drive letter on this one but I made it so you could input the drive letter and get the info for it

[bplus]

What is "No Root Dir", something linked to Internet or cloud?

[SpriggsySpriggs]

Not sure. I'd have to read the MSDN again

[euklides]

Well, well, well.
Not really true...
So an usb hard drive  (an also an usb3 ssd external drive) is detected as ""Fixed media"...
The very good answer is "Removal hard disk".

I have the solution of this in Visual Basic Excel, but not in QB64 !!!