Author Topic: Pipecom Browser for Filename$ (Read 8523 times)

bplus · « **on:** February 07, 2021, 08:04:56 pm »

Here is application to viewing BMP24 files that NOVARSEG started:

Code: QB64: [Select]

Option _Explicit
_Title "Pipecom Browser for BMP24 File Display" 'b+ testing one array system with pipecom
' Thanks to Spriggsy, Zak, for convincing me pipecom is better!
' Using Steve's fixed BMP24 loader
' Also thanks to Dav for 1 window for file and folder selection idea
' Also thanks to NOVARSEG who got me going on this for a better filename$ retriever
 
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare
 
Screen _NewImage(1280, 740, 32)
_Delay .25
_ScreenMove 65, 0 ' your screen might need different
 
ReDim myFile$, image&
ReDim As Long col, row, charW, charH
Color , &HFF000033
Cls
Do 'test our new function
    ScnState 0
    col = 16: row = 3: charW = 128: charH = 40
    myFile$ = GetFileName$(row, col, charW, charH)
    ScnState -1 ' <<<<<<<<<<<<<<<<<<<<<<<<<<< this is supposed to restore back color
    image& = loadBMP24&(myFile$)
    Color , &HFF000033
    Cls
    If image& <> 0 Then
        _Title myFile$ + " press any to get another BMP24 file image, esc to quit"
        _PutImage ((_Width - _Width(image&)) / 2, (_Height - _Height(image&)) / 2)-Step(_Width(image&), _Height(image&)), image&, 0
        Sleep
        _FreeImage image&
    End If
Loop Until _KeyDown(27)
 
Function loadBMP24& (Filename$) ' Steve's revised version without the extra handle and memory leak
    Dim As _Unsigned Long of, l, w, r, c
    Dim i As _Unsigned Integer
    Dim a As _MEM
    Dim As Long handle, h ' <<< edit as per NOVARSEG
    Dim tt As String * 4
    Dim t As String * 3
    Dim padding$
 
    If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function
    Print Filename$
    Open Filename$ For Binary As #1
    Get #1, 11, of
    Get #1, 15, l
    Get #1, , w
    Get #1, , h
    Get #1, , i
    Get #1, , i 'get I twice ???
    If i <> 24 Then Exit Function
    handle = _NewImage(w, h, 32)
    a = _MemImage(handle)
    If ((w * 3) Mod 4) <> 0 Then padding$ = Space$((4 - ((w * 3) Mod 4))) '’need padding pixels
    Seek #1, of + 1 'go to the offset where the data starts
    For r = h - 1 To 0 Step -1 'from the bottom to top
        For c = 0 To w - 1 'left to right
            Get #1, , t 'get the data sequentially
            tt = t + Chr$(255)
            _MemPut a, a.OFFSET + (w * r + c) * 4, tt
        Next c
        Get #1, , padding$ 'Get the padding at the end of the line
    Next r
    Close
    loadBMP24& = handle
    _MemFree a
End Function
 
Function GetFileName$ (LocateR, LocateC, CharWide, CharHigh) ' < careful Locate Row, Col NOT x, y
    'This Funtion needs:
    ' pipecom.h in same folder as QB64.exe
    ' This in main code section near top:
    ' Declare Library "pipecom"
    '    Function pipecom$ (cmd As String)
    ' End Declare
    ' sub  Split source$, delimiter$, arr$()
    ' function GetArrayItem$(x, y, w, h, arr$())
 
    ReDim As String d, s, dr
    ReDim As _Unsigned Long fc, bc
    fc = _DefaultColor: bc = _BackgroundColor ' save colors
    Getfolder:
    Color fc, bc: Cls
    d = pipecom("dir /n /o:gend") '/n files on right (40) /o = order g for group dirs first, e extension, name, date
    d = Left$(d, Len(d) - 1) ' always ends with delimiter
    ReDim dir(1 To 1) As String
    Split d, Chr$(10), dir()
    s = GetArrayItem$(LocateR, LocateC, CharWide, CharHigh, dir())
    If InStr(s, "<DIR>") Then 'isolate name
        dr = _Trim$(Mid$(s, InStr(s, "<DIR>") + 6))
        ChDir dr
        GoTo Getfolder
    ElseIf InStr(s, "AM") Or InStr(s, "PM") Then
        GetFileName$ = _Trim$(Mid$(s, 40))
        Color fc, bc: Cls
    ElseIf s = "" Then 'cancel, escape, bad line
        Color fc, bc: Cls ' will return empty string
    End If
End Function
 
Sub Split (SplitMeString As String, delim As String, loadMeArray() As String)
    Dim curpos As Long, arrpos As Long, LD As Long, dpos As Long 'fix use the Lbound the array already has
    curpos = 1: arrpos = LBound(loadMeArray): LD = Len(delim)
    dpos = InStr(curpos, SplitMeString, delim)
    Do Until dpos = 0
        loadMeArray(arrpos) = Mid$(SplitMeString, curpos, dpos - curpos)
        arrpos = arrpos + 1
        If arrpos > UBound(loadMeArray) Then ReDim _Preserve loadMeArray(LBound(loadMeArray) To UBound(loadMeArray) + 1000) As String
        curpos = dpos + LD
        dpos = InStr(curpos, SplitMeString, delim)
    Loop
    loadMeArray(arrpos) = Mid$(SplitMeString, curpos)
    ReDim _Preserve loadMeArray(LBound(loadMeArray) To arrpos) As String 'get the ubound correct
End Sub
 
 
' Help: all this I hope is intuitive so Help window is provided
' "Mouse, mouse wheel, and arrow keys should work as expected for item selection."
' "Press spacebar to select a highlighted item or just click it."
' "Use number(s) + enter to select an array item by it's index number,"
' "backspace will remove last number pressed, delete will clear a number started.
' "Numbers started are shown in bottom right PgDn bar."
' "Enter will also select the highlighted item, if no number has been started."
' "Home starts you at lowest array index, End highlights then highest index."
' "Use PgUp and PgDn keys to flip through pages of array items."
'
' Escape to Cancel Return "" else Return the selected string from the array
Function GetArrayItem$ (LocateRoww, LocateColumn, BoxWidth, BoxHeight, Arr() As String)
    'Notes: locateRow, locateColumn for top right corner of selection box on screen in characters for LOCATE.
    'boxWidth and boxHeight are in character units, again for locate and print at correct places.
    'All displaying is restricted to inside the box, which has PgUP and PgDn as top and bottom lines in the display.
 
    ReDim As Long maxWidth, maxHeight, page, hlite, mx, my, locateRow, lastMX, lastMY, row, mb
    ReDim As Long lba, uba, choice, kh, index
    Dim clrStr As String, b As String
 
    'ScnState 0 ' use out side this function before and after
    locateRow = LocateRoww + 1 'fix a miscalc in coding
    maxWidth = BoxWidth '       number of characters in box
    maxHeight = BoxHeight - 2 ' number of lines displayed of array at one time = 1 page
    lba = LBound(arr)
    uba = UBound(arr)
    page = 0
    hlite = 0 '                 line in display ready for selection by spacebar or if no number is started, enter
    clrStr$ = Space$(maxWidth) 'clearing a display line
 
    GoSub update '              show the beginning of the array items for selection
    choice = -1719
    Do 'until get a selection or demand exit
 
        'handle the key stuff
        kh& = _KeyHit
        If kh& Then
            If kh& > 0 And kh& < 255 Then
                If InStr("0123456789", Chr$(kh&)) > 0 Then
                    b$ = b$ + Chr$(kh&): GoSub update
                ElseIf kh& = 13 Then 'enter pressed check if number is being entered?
                    If Len(b$) Then
                        If Val(b$) >= lba And Val(b$) <= uba Then 'we have number started
                            choice = Val(b$): Exit Do
                        Else 'clear b$ to show some response to enter
                            b$ = "": GoSub update 'clear the value that doesn't work
                        End If
                    Else
                        choice = hlite + page * maxHeight + lba 'must mean to select the highlighted item
                    End If
                ElseIf kh& = 27 Then
                    Exit Do 'escape clause offered to Cancel selection process
                ElseIf kh& = 32 Then
                    choice = hlite + page * maxHeight + lba 'best way to choose highlighted selection
                ElseIf kh& = 8 Then 'backspace to edit number
                    If Len(b$) Then b$ = Left$(b$, Len(b$) - 1): GoSub update
                End If
            Else
                Select Case kh& 'choosing sections of array to display and highlighted item
                    Case 21248 ' delete so clear b$
                        b$ = "": GoSub update
                    Case 20736 ' pg dn
                        If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
                    Case 18688 ' pg up
                        If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                    Case 18432 ' up
                        If hlite - 1 < 0 Then
                            If page > 0 Then
                                page = page - 1: hlite = maxHeight - 1: GoSub update
                            End If
                        Else
                            hlite = hlite - 1: GoSub update
                        End If
                    Case 20480 'down
                        If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                            If hlite + 1 > maxHeight - 1 Then
                                page = page + 1: hlite = 0: GoSub update
                            Else
                                hlite = hlite + 1: GoSub update
                            End If
                        End If
                    Case 18176 'home
                        page = 0: hlite = 0: GoSub update
                    Case 20224 ' end
                        page = Int((uba - lba) / maxHeight): hlite = maxHeight - 1: GoSub update
                End Select
            End If
        End If
 
        'handle the mouse stuff
        While _MouseInput
            If _MouseWheel = -1 Then 'up?
                If hlite - 1 < 0 Then
                    If page > 0 Then
                        page = page - 1: hlite = maxHeight - 1: GoSub update
                    End If
                Else
                    hlite = hlite - 1: GoSub update
                End If
            ElseIf _MouseWheel = 1 Then 'down?
                If (hlite + 1) + page * maxHeight + lba <= uba Then 'ok to move up
                    If hlite + 1 > maxHeight - 1 Then
                        page = page + 1: hlite = 0: GoSub update
                    Else
                        hlite = hlite + 1: GoSub update
                    End If
                End If
            End If
        Wend
        mx = Int((_MouseX - LocateColumn * 8) / 8) + 2: my = Int((_MouseY - locateRow * 16) / 16) + 2
        If _MouseButton(1) Then 'click contols or select array item
            'clear mouse clicks
            mb = _MouseButton(1)
            If mb Then 'clear it
                While mb 'OK!
                    If _MouseInput Then mb = _MouseButton(1)
                    _Limit 100
                Wend
            End If
 
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                choice = my + page * maxHeight + lba - 1 'select item clicked
            ElseIf mx >= 1 And mx <= maxWidth And my = 0 Then 'page up or exit
                If my = 0 And (mx <= maxWidth And mx >= maxWidth - 2) Then 'exit sign
                    Exit Do 'escape plan for mouse click top right corner of display box
                Else 'PgUp bar clicked
                    If (page - 1) * maxHeight + lba >= lba Then page = page - 1: GoSub update
                End If
            ElseIf mx >= 1 And mx <= maxWidth And my = maxHeight + 1 Then 'page down bar clicked
                If (page + 1) * maxHeight + lba <= uba Then page = page + 1: GoSub update
            End If
        Else '   mouse over highlighting, only if mouse has moved!
            If mx >= 1 And mx <= maxWidth And my >= 1 And my <= maxHeight Then
                If mx <> lastMX Or my <> lastMY Then
                    If my - 1 <> hlite And (my - 1 + page * maxHeight + lba <= uba) Then
                        hlite = my - 1
                        lastMX = mx: lastMY = my
                        GoSub update
                    End If
                End If
            End If
        End If
        _Limit 200
    Loop Until choice >= lba And choice <= uba
    If choice <> -1719 Then GetArrayItem$ = Arr(choice) 'set function and restore screen
    'ScnState -1 'restore
    Exit Function
 
    'display of array sections and controls on screen  ====================================================
    update:
 
    'fix hlite if it has dropped below last array item
    While hlite + page * maxHeight + lba > uba
        hlite = hlite - 1
    Wend
 
    'main display of array items at page * maxHeight (lines high)
    For row = 0 To maxHeight - 1
        If hlite = row Then Color _RGB(200, 200, 255), _RGB32(0, 0, 88) Else Color _RGB32(0, 0, 88), _RGB(200, 200, 255)
        Locate locateRow + row, LocateColumn: Print clrStr$;
        index = row + page * maxHeight + lba
        If index >= lba And index <= uba Then
            Locate locateRow + row, LocateColumn
            Print Left$(LTrim$(Str$(index)) + ") " + Arr(index), maxWidth);
        End If
    Next
 
    'make page up and down bars to click, print PgUp / PgDn if available
    Color _RGB32(200, 200, 255), _RGB32(0, 100, 50)
    Locate locateRow - 1, LocateColumn: Print Space$(maxWidth);
    If page <> 0 Then Locate locateRow - 1, LocateColumn: Print Left$(" Pg Up" + Space$(maxWidth), maxWidth);
    Locate locateRow + maxHeight, LocateColumn: Print Space$(maxWidth);
    If page <> Int(uba / maxHeight) Then
        Locate locateRow + maxHeight, LocateColumn: Print Left$(" Pg Dn" + Space$(maxWidth), maxWidth);
    End If
    'make exit sign for mouse click
    Color _RGB32(255, 255, 255), _RGB32(200, 100, 0)
    Locate locateRow - 1, LocateColumn + maxWidth - 3
    Print " X ";
 
    'if a number selection has been started show it's build = b$
    If Len(b$) Then
        Color _RGB(255, 255, 0), _RGB32(0, 0, 0)
        Locate locateRow + maxHeight, LocateColumn + maxWidth - Len(b$) - 1
        Print b$;
    End If
    _Display
    _Limit 100
    Return
End Function
 
Sub ScnState (restoreTF As Long) 'Thanks Steve McNeill  should we get a snap shot of screen?
    Static As _Unsigned Long defaultColor, backGroundColor
    Static As Long font, dest, source, row, col, autodisplay, mb, snap
    If restoreTF Then
        _Font font
        Color defaultColor, backGroundColor
        _Dest dest
        _Source source
 
        _KeyClear
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _PutImage , snap, dest
        _FreeImage snap
        _Display
        If autodisplay Then _AutoDisplay Else _Display
        Locate row, col
    Else
        snap = _NewImage(_Width, _Height, 32)
        _PutImage , 0, snap
        font = _Font: defaultColor = _DefaultColor: backGroundColor = _BackgroundColor
        dest = _Dest: source = _Source
        row = CsrLin: col = Pos(0): autodisplay = _AutoDisplay
        While _MouseInput: Wend 'clear mouse clicks
        mb = _MouseButton(1)
        If mb Then 'need this if line ?
            Do
                While _MouseInput: Wend
                mb = _MouseButton(1)
                _Limit 100
            Loop Until mb = 0
        End If
        _KeyClear
    End If
End Sub
 
 
 
 
 

You will need this in your QB64.exe Folder and a QB64 version dev 1.5 version.

EDIT: made h Long in LoadBMP24 Sub as per NOVARSEG

SpriggsySpriggs · « **Reply #1 on:** February 07, 2021, 08:06:18 pm »

@bplus It's cool that you were able to use my pipecom library to make something neat

bplus · « **Reply #2 on:** February 07, 2021, 08:08:47 pm »

Tell me you tried it already! ;-))

I just got done editing a thankyou to you. :)

SpriggsySpriggs · « **Reply #3 on:** February 07, 2021, 09:32:33 pm »

@bplus It works great! Super fast on my system. Good job on the UI

STxAxTIC · « **Reply #4 on:** February 07, 2021, 10:25:49 pm »

well this is nice!

NOVARSEG · « **Reply #5 on:** February 08, 2021, 02:53:57 am »

@bplus
got to get latest version.

Yes it is true Steve did fix the padding issue. Evidently some BMPs have a negative height value so you gotta change the

h in
Dim As _Unsigned Long of, l, w, h, r, c

to a LONG

I've never come across a negative height BMP though.. See my latest BMP viewer code that handles negative height BMPs

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

Dav · « **Reply #6 on:** February 08, 2021, 07:39:53 am »

Works great here! Fast too. I like it.

- Dav

bplus · « **Reply #7 on:** February 08, 2021, 12:16:12 pm »

Thanks for your feedback!

If someone could provide a Linux command that produces a Directory Listing that distinguishes Files from Folders and provides a Sample Output Directory, I could adapt this for Linux.

@johnno56 can you help with this?

Here simple Pipecom code to test commands to OS and Sample Output from Windows that I see all Files and Folders and can distingush Folders have <DIR> in label.

Code: [Select]

_Title "Quick Pipecom Demo" 'b+ 2021-02-08
Declare Library "pipecom"
    Function pipecom$ (cmd As String)
End Declare

Dim F As String 'tests with command line dir calls
' NOTE: these slants work \    these do not /
'F = pipecom("dir " + Chr$(34) + "C:\users\marka\desktop\QB64 work\000 work QB64" + Chr$(34) + " /b /A:D") ' Linux needs other switches
'F = pipecom("dir /b *.BAS") 'if you need just the filenames and not the rest of the output
'F = pipecom("dir /b /A:D") ' /b = bare list /A:D directories only

F = pipecom("dir ??? ") ' <<<<<<<<<<< Linux command goes between quotes here
Print F
_Clipboard$ = F


' Paste from ClipBoard
' Volume in drive C is Windows
' Volume Serial Number is 0EDF-FD28

' Directory of C:\Users\marka\Desktop\QB64 work\000 work QB64\000 Test\DIR$() replacement Spriggsy

'02/08/2021  12:14 PM    <DIR>          .
'02/08/2021  12:14 PM    <DIR>          ..
'10/26/2020  10:14 AM    <DIR>          pipecom.h bak
'02/07/2021  08:43 PM            14,491 Pipecom Browser mod 2 Better Array Select.bas
'02/06/2021  12:56 AM             1,015 Pipecom demo to replace Dir$() by Spriggsy.bas
'02/07/2021  08:54 PM             4,160 Pipecome Browser 1 Crude Keypress Select.bas
'02/08/2021  12:12 PM                 2 Quick Pipecom demo.bas
'01/19/2021  10:45 AM             2,548 Really simple pipe to clip by doppler.bas
'02/07/2021  12:00 PM             2,180 Shell dir to clipboard doppler.bas
'02/07/2021  08:35 PM         2,110,464 Pipecom Browser mod 2 Better Array Select.exe
'02/07/2021  08:53 PM         2,094,592 Pipecome Browser 1 Crude Keypress Select.exe
'02/08/2021  12:14 PM         2,080,256 Quick Pipecom demo.exe
'02/07/2021  11:59 AM         2,085,888 Really simple pipe to clip by doppler.exe
'02/07/2021  12:00 PM         2,087,424 Shell dir to clipboard doppler.exe
'              11 File(s)     10,483,020 bytes
'               3 Dir(s)  907,052,933,120 bytes free

Again put this into the same Folder as your QB64.exe

bplus · « **Reply #8 on:** February 08, 2021, 12:34:40 pm »

Quote from: NOVARSEG on February 08, 2021, 02:53:57 am

@bplus
got to get latest version.

Yes it is true Steve did fix the padding issue. Evidently some BMPs have a negative height value so you gotta change the

h in
Dim As _Unsigned Long of, l, w, h, r, c

to a LONG

I've never come across a negative height BMP though.. See my latest BMP viewer code that handles negative height BMPs

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

OK edited the original post, thanks

NOVARSEG · « **Reply #9 on:** February 08, 2021, 06:01:08 pm »

@bplus
Did you actually try it with -h?

If it works, a normal BMP image (with positive h) will be upside down.

Dim padding$
h = 0 - h ' *** add this line ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

bplus · « **Reply #10 on:** February 08, 2021, 06:52:38 pm »

Quote from: NOVARSEG on February 08, 2021, 06:01:08 pm

@bplus
Did you actually try it with -h?

If it works, a normal BMP image (with positive h) will be upside down.

Dim padding$
h = 0 - h ' *** add this line ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

I changed the type of h to Long and tested the pictures I had and ran fine.

Now if h is a negative number it will work, I assume. I need an BMP24 file with h <0 pic to test that situation..

NOVARSEG · « **Reply #11 on:** February 08, 2021, 07:05:50 pm »

Quote

Now if h is a negative number it will work, I assume. I need an BMP24 file with h <0 pic to test that situation.

.

Don't need an actual -h BMP to test

Dim padding$
h = 0 - h ' *** add this line. For testing only ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

If the code works then a BMP with +h will display upside down

with commented
' h = 0 - h

A BMP with actual -h will now display properly

****
for one thing

handle = _NewImage(w, h, 32)

can't have a negative h

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

bplus · « **Reply #12 on:** February 08, 2021, 09:40:24 pm »

Quote from: NOVARSEG on February 08, 2021, 07:05:50 pm

.

Don't need an actual -h BMP to test

Dim padding$
h = 0 - h ' *** add this line. For testing only ***
If Right$(UCase$(Filename$), 4) <> ".BMP" Then Exit Function

If the code works then a BMP with +h will display upside down

with commented
' h = 0 - h

A BMP with actual -h will now display properly

****
for one thing

handle = _NewImage(w, h, 32)

can't have a negative h

https://www.qb64.org/forum/index.php?topic=3602.30#lastPost

I'm not messing around with all that if it is enough to make h long. The point of this thread is to test Pipecom and filename retriever code, I just happened to use BMP24 files because it was recent and you @NOVARSEG asked about mouse input app for you code.

I will be glad to test a -h BMP24 file if one were provided with this app as it is. :)

SMcNeill · « **Reply #13 on:** February 08, 2021, 09:47:04 pm »

If you do get a -h file, just read it as usual and then _PUTIMAGE it from bottom to top to your screen.

NOVARSEG · « **Reply #14 on:** February 08, 2021, 10:35:44 pm »

@bplus

That will be a fair test of the code

I will make a -h BMP convertor. It will take a +h BMP and then convert it into a -h BMP

https://www.mozilla.org/en-US/security/advisories/mfsa2012-61/

here is an interesting one. MS paint evidently crashes with -h BMPs
https://groups.google.com/g/microsoft.public.win32.programmer.gdi/c/8CnUgn-gzD0/m/FS8rzRXq9DgJ

OK i tried engine3.bmp in MSPAINT and it worked .

News:

Author Topic: Pipecom Browser for Filename$ (Read 8523 times)

bplus

Pipecom Browser for Filename$

SpriggsySpriggs

Re: Pipecom Browser for Filename$

bplus

Re: Pipecom Browser for Filename$

SpriggsySpriggs

Re: Pipecom Browser for Filename$

STxAxTIC

Re: Pipecom Browser for Filename$

NOVARSEG

Re: Pipecom Browser for Filename$

Dav

Re: Pipecom Browser for Filename$

bplus

Re: Pipecom Browser for Filename$

bplus

Re: Pipecom Browser for Filename$

NOVARSEG

Re: Pipecom Browser for Filename$

bplus

Re: Pipecom Browser for Filename$

NOVARSEG

Re: Pipecom Browser for Filename$

bplus

Re: Pipecom Browser for Filename$

SMcNeill

Re: Pipecom Browser for Filename$

NOVARSEG

Re: Pipecom Browser for Filename$