Upcoming feature (v1.5) - _MEMSOUND (Hi, Petr!)

[Petr]

I will return to the beginning of this thread with a few questions to @STxAxTIC

I implanted your frequency acquisition program. Finally. It seems to work perfectly. The only thing I need to clarify: The resulting frequency in your second example is given by the number of samples analyzed. It is so? Therefore, a small number of samples is sufficient to obtain low frequencies. In your example, these are pixels, my solution is _SNDGETPOS - 300 TO _SNDGETPOS + 300. This way I get 600 audio samples, that's enough to get low frequencies. But if I wanted a frequency of 20 KHz, I would need to analyze the whole second (44100 samples for precise detection). Am I getting it right, or am I completely out of it again?

Wait. What I'm writing is nonsense. After all, a high frequency can be interspersed several times, even in a small number of samples. So it will be possible to construct the frequency detection as an average in six hundred samples. This is an imperceptible moment to the ear (0.014 seconds) but is enough to detect the frequency. Then it can be argued that the average frequency in a 0.014 second sample has some value. This will be the right solution, right?

[Petr]

Hi. Here is a little work with _MEMSOUND, the movement of the stars in the background is the output of the implanted program from @STxAxTIC

[FellippeHeitor]

Whooooooa that's so cool!

[STxAxTIC]

@Petr  - this is just great!

I ran into a few - what I will call "windowing" problems with the frequency measurement code, so I will shortly dust off my latest copy and show where I left off. There is still something to fix - but we're *almost* there on a solution for reliably getting frequencies... I'll return to this as soon as I can.

[_vince]

This all sounds very interesting!   Could something like this be used to analyze a played pitch and see if it's in tune?  Like frequency 440 Hz is the note A.    I tune pianos on the side, wonder if it would be possible to make a piano tuning app in QB64?

- Dav

if you know the sampling frequency, ie

Code: QB64: [Select]

1. 'defdbl a-z
2.  
3. CONST sw = 1024
4. CONST sh = 600
5.  
6. DIM SHARED pi AS DOUBLE
7. 'pi = 2*asin(1)
8. pi = 4*ATN(1)
9.  
10. DECLARE SUB rfft(xx_r(), xx_i(), x_r(), n)
11.  
12. DIM x_r(sw-1), x_i(sw-1)
13. DIM xx_r(sw-1), xx_i(sw-1)
14. DIM t AS DOUBLE
15.  
16. FOR i=0 TO sw-1
17.         x_r(i) = 100*SIN(2*pi*(sw*2000/44000)*i/sw) + (100*RND - 50)
18. NEXT
19.  
20.  
21. 'screenres sw, sh, 32
22. SCREEN _NEWIMAGE(sw, sh, 32)
23.  
24. 'plot signal
25. PSET (0, sh/4 - x_r(0))
26. FOR i=0 TO sw-1
27.         LINE -(i, sh/4 - x_r(i)), _RGB(255,0,0)
28. NEXT
29. LINE (0, sh/4)-STEP(sw,0), _RGB(255,0,0),,&h5555
30.  
31. _PRINTSTRING (0, 0), "2000 Hz signal with RND noise sampled at 44 kHz in 1024 samples"
32.  
33.  
34. rfft xx_r(), xx_i(), x_r(), sw
35.  
36. 'plot its fft
37. PSET (0, 50+3*sh/4 - 0.005*SQR(xx_r(0)*xx_r(0) + xx_i(0)*xx_i(0)) ), _RGB(255,255,0)
38. FOR i=0 TO sw/2
39.         LINE -(i*2, 50+3*sh/4 - 0.005*SQR(xx_r(i)*xx_r(i) + xx_i(i)*xx_i(i)) ), _RGB(255,255,0)
40. NEXT
41. LINE (0, 50+3*sh/4)-STEP(sw,0), _RGB(255,255,0),,&h5555
42.  
43.  
44. 'find peak
45. DIM max AS DOUBLE, d AS DOUBLE
46. max = 0
47. m = 0
48. FOR i=0 TO sw/2
49.         d = 0.01*SQR(xx_r(i)*xx_r(i) + xx_i(i)*xx_i(i))
50.         IF d > max THEN
51.                 max = d
52.                 m = i
53.         END IF
54. NEXT
55.  
56. _PRINTSTRING (0, sh/2), "m_peak ="+STR$(m)
57. _PRINTSTRING (0, sh/2 + 16), "f_peak = m_peak * 44 kHz / 1024 samples = "+STR$(m*44000/1024)+" Hz"
58.  
59. 'apply frequency correction, only works for some signals
60. DIM c AS DOUBLE
61. DIM u_r AS DOUBLE, u_i AS DOUBLE
62. DIM v_r AS DOUBLE, v_i AS DOUBLE
63.  
64. u_r = xx_r(m - 1) - xx_r(m + 1)
65. u_i = xx_i(m - 1) - xx_i(m + 1)
66. v_r = 2*xx_r(m) - xx_r(m - 1) - xx_r(m + 1)
67. v_i = 2*xx_i(m) - xx_i(m - 1) - xx_i(m + 1)
68. c = (u_r*v_r + u_i*v_i)/(v_r*v_r + v_i*v_i)
69.  
70. _PRINTSTRING (0, sh/2 + 2*16), "f_corrected = "+STR$((m+c)*44000/1024)+" Hz"
71.  
72. SLEEP
73. SYSTEM
74.  
75.  
76. SUB rfft(xx_r(), xx_i(), x_r(), n)
77.         DIM w_r AS DOUBLE, w_i AS DOUBLE, wm_r AS DOUBLE, wm_i AS DOUBLE
78.         DIM u_r AS DOUBLE, u_i AS DOUBLE, v_r AS DOUBLE, v_i AS DOUBLE
79.  
80.         log2n = LOG(n/2)/LOG(2)
81.  
82.         FOR i=0 TO n/2 - 1
83.                 rev = 0
84.                 FOR j=0 TO log2n - 1
85.                         IF i AND (2^j) THEN rev = rev + (2^(log2n - 1 - j))
86.                 NEXT
87.  
88.                 xx_r(i) = x_r(2*rev)
89.                 xx_i(i) = x_r(2*rev + 1)
90.         NEXT
91.  
92.         FOR i=1 TO log2n
93.                 m = 2^i
94.                 wm_r = COS(-2*pi/m)
95.                 wm_i = SIN(-2*pi/m)
96.  
97.                 FOR j=0 TO n/2 - 1 STEP m
98.                         w_r = 1
99.                         w_i = 0
100.  
101.                         FOR k=0 TO m/2 - 1
102.                                 p = j + k
103.                                 q = p + (m \ 2)
104.  
105.                                 u_r = w_r*xx_r(q) - w_i*xx_i(q)
106.                                 u_i = w_r*xx_i(q) + w_i*xx_r(q)
107.                                 v_r = xx_r(p)
108.                                 v_i = xx_i(p)
109.  
110.                                 xx_r(p) = v_r + u_r
111.                                 xx_i(p) = v_i + u_i
112.                                 xx_r(q) = v_r - u_r
113.                                 xx_i(q) = v_i - u_i
114.  
115.                                 u_r = w_r
116.                                 u_i = w_i
117.                                 w_r = u_r*wm_r - u_i*wm_i
118.                                 w_i = u_r*wm_i + u_i*wm_r
119.                         NEXT
120.                 NEXT
121.         NEXT
122.  
123.         xx_r(n/2) = xx_r(0)
124.         xx_i(n/2) = xx_i(0)
125.  
126.         FOR i=1 TO n/2 - 1
127.                 xx_r(n/2 + i) = xx_r(n/2 - i)
128.                 xx_i(n/2 + i) = xx_i(n/2 - i)
129.         NEXT
130.  
131.         DIM xpr AS DOUBLE, xpi AS DOUBLE
132.         DIM xmr AS DOUBLE, xmi AS DOUBLE
133.  
134.         FOR i=0 TO n/2 - 1
135.                 xpr = (xx_r(i) + xx_r(n/2 + i)) / 2
136.                 xpi = (xx_i(i) + xx_i(n/2 + i)) / 2
137.  
138.                 xmr = (xx_r(i) - xx_r(n/2 + i)) / 2
139.                 xmi = (xx_i(i) - xx_i(n/2 + i)) / 2
140.  
141.                 xx_r(i) = xpr + xpi*COS(2*pi*i/n) - xmr*SIN(2*pi*i/n)
142.                 xx_i(i) = xmi - xpi*SIN(2*pi*i/n) - xmr*COS(2*pi*i/n)
143.         NEXT
144.  
145.         'symmetry, complex conj
146.         FOR i=0 TO n/2 - 1
147.                 xx_r(n/2 + i) = xx_r(n/2 - 1 - i)
148.                 xx_i(n/2 + i) =-xx_i(n/2 - 1 - i)
149.         NEXT
150. END SUB
151.  

[Petr]

Thank you @_vince ! I try apply it to real audio signal and then give here my outputs.

[Petr]

@_vince Please look to my modification your code, if it is modfified correctly? Use some MP3 file.

I am not sure on row 101 in this source code, if can it be with _CONTINUE, if m = 0.

Thank you.

Code: QB64: [Select]

1. 'defdbl a-z
2.  
3. CONST sw = 1024
4. CONST sh = 600
5.  
6.  
7. '''
8. DIM Left AS _MEM
9. DIM L AS INTEGER
10. '''
11.  
12. DIM SHARED pi AS DOUBLE
13. 'pi = 2*asin(1)
14. pi = 4 * ATN(1)
15.  
16. DECLARE SUB rfft(xx_r(), xx_i(), x_r(), n)
17.  
18. DIM x_r(sw - 1), x_i(sw - 1)
19. DIM xx_r(sw - 1), xx_i(sw - 1)
20. DIM t AS DOUBLE
21.  
22. '''
23. AudioFile$ = "Track10.mp3"
24. S = _SNDOPEN(AudioFile$)
25. Left = _MEMSOUND(S, 1)
26. _SNDPLAY S
27. '''
28. SCREEN _NEWIMAGE(sw, sh, 32)
29.  
30.  
31. '''
32. DO UNTIL _SNDPLAYING(S) = 0
33.     i = 0: j = 0
34.     Position& = _SNDGETPOS(S) * _SNDRATE
35.     IF Position& > 1024 AND Position& < Left.SIZE - 1024 THEN 'current (actual playing) sound frame is in middle - in position Position&
36.         j& = Position& - 1022
37.         DO UNTIL i = 1024
38.  
39.             x_r(i) = 100 * (_MEMGET(Left, Left.OFFSET + j&, INTEGER) / 32767)
40.             i = i + 1
41.             j& = j& + 2
42.         LOOP
43.         test& = j& - Position&
44.  
45.     END IF
46.  
47.     'FOR i = 0 TO sw - 1
48.     'x_r(i) = 100 * SIN(2 * pi * (sw * 20000 / 44000) * i / sw) + (100 * RND - 50)
49.     'NEXT
50.  
51.     i = 0
52.     j = 0
53.     '''
54.  
55.  
56.  
57.     'screenres sw, sh, 32
58.     'SCREEN _NEWIMAGE(sw, sh, 32)
59.  
60.     'plot signal
61.     CLS
62.     PSET (0, sh / 4 - x_r(0))
63.     FOR i = 0 TO sw - 1
64.         LINE -(i, sh / 4 - x_r(i)), _RGB(255, 0, 0)
65.     NEXT
66.     LINE (0, sh / 4)-STEP(sw, 0), _RGB(255, 0, 0), , &H5555
67.  
68.     ' _PRINTSTRING (0, 0), "2000 Hz signal with RND noise sampled at 44 kHz in 1024 samples"
69.  
70.  
71.     rfft xx_r(), xx_i(), x_r(), sw
72.  
73.     'plot its fft
74.     PSET (0, 50 + 3 * sh / 4 - 0.005 * SQR(xx_r(0) * xx_r(0) + xx_i(0) * xx_i(0))), _RGB(255, 255, 0)
75.     FOR i = 0 TO sw / 2
76.         LINE -(i * 2, 50 + 3 * sh / 4 - 0.005 * SQR(xx_r(i) * xx_r(i) + xx_i(i) * xx_i(i))), _RGB(255, 255, 0)
77.     NEXT
78.     LINE (0, 50 + 3 * sh / 4)-STEP(sw, 0), _RGB(255, 255, 0), , &H5555
79.  
80.  
81.     'find peak
82.     DIM max AS DOUBLE, d AS DOUBLE
83.     max = 0
84.     m = 0
85.     FOR i = 0 TO sw / 2
86.         d = 0.01 * SQR(xx_r(i) * xx_r(i) + xx_i(i) * xx_i(i))
87.         IF d > max THEN
88.             max = d
89.             m = i
90.         END IF
91.     NEXT
92.  
93.     _PRINTSTRING (0, sh / 2), "m_peak =" + STR$(m)
94.     _PRINTSTRING (0, sh / 2 + 16), "f_peak = m_peak * 44 kHz / 1024 samples = " + STR$(m * 44000 / 1024) + " Hz"
95.  
96.     'apply frequency correction, only works for some signals
97.     DIM c AS DOUBLE
98.     DIM u_r AS DOUBLE, u_i AS DOUBLE
99.     DIM v_r AS DOUBLE, v_i AS DOUBLE
100.  
101.     IF m = 0 THEN _CONTINUE 'm = 1
102.     u_r = xx_r(m - 1) - xx_r(m + 1)
103.     u_i = xx_i(m - 1) - xx_i(m + 1)
104.     v_r = 2 * xx_r(m) - xx_r(m - 1) - xx_r(m + 1)
105.     v_i = 2 * xx_i(m) - xx_i(m - 1) - xx_i(m + 1)
106.     c = (u_r * v_r + u_i * v_i) / (v_r * v_r + v_i * v_i)
107.  
108.     _PRINTSTRING (0, sh / 2 + 2 * 16), "f_corrected = " + STR$((m + c) * 44000 / 1024) + " Hz"
109.  
110.     ' SLEEP
111.     PRINT test&
112.     _DISPLAY
113.     _LIMIT 20
114. LOOP
115.  
116. SYSTEM
117.  
118.  
119. SUB rfft (xx_r(), xx_i(), x_r(), n)
120.     DIM w_r AS DOUBLE, w_i AS DOUBLE, wm_r AS DOUBLE, wm_i AS DOUBLE
121.     DIM u_r AS DOUBLE, u_i AS DOUBLE, v_r AS DOUBLE, v_i AS DOUBLE
122.  
123.     log2n = LOG(n / 2) / LOG(2)
124.  
125.     FOR i = 0 TO n / 2 - 1
126.         rev = 0
127.         FOR j = 0 TO log2n - 1
128.             IF i AND (2 ^ j) THEN rev = rev + (2 ^ (log2n - 1 - j))
129.         NEXT
130.  
131.         xx_r(i) = x_r(2 * rev)
132.         xx_i(i) = x_r(2 * rev + 1)
133.     NEXT
134.  
135.     FOR i = 1 TO log2n
136.         m = 2 ^ i
137.         wm_r = COS(-2 * pi / m)
138.         wm_i = SIN(-2 * pi / m)
139.  
140.         FOR j = 0 TO n / 2 - 1 STEP m
141.             w_r = 1
142.             w_i = 0
143.  
144.             FOR k = 0 TO m / 2 - 1
145.                 p = j + k
146.                 q = p + (m \ 2)
147.  
148.                 u_r = w_r * xx_r(q) - w_i * xx_i(q)
149.                 u_i = w_r * xx_i(q) + w_i * xx_r(q)
150.                 v_r = xx_r(p)
151.                 v_i = xx_i(p)
152.  
153.                 xx_r(p) = v_r + u_r
154.                 xx_i(p) = v_i + u_i
155.                 xx_r(q) = v_r - u_r
156.                 xx_i(q) = v_i - u_i
157.  
158.                 u_r = w_r
159.                 u_i = w_i
160.                 w_r = u_r * wm_r - u_i * wm_i
161.                 w_i = u_r * wm_i + u_i * wm_r
162.             NEXT
163.         NEXT
164.     NEXT
165.  
166.     xx_r(n / 2) = xx_r(0)
167.     xx_i(n / 2) = xx_i(0)
168.  
169.     FOR i = 1 TO n / 2 - 1
170.         xx_r(n / 2 + i) = xx_r(n / 2 - i)
171.         xx_i(n / 2 + i) = xx_i(n / 2 - i)
172.     NEXT
173.  
174.     DIM xpr AS DOUBLE, xpi AS DOUBLE
175.     DIM xmr AS DOUBLE, xmi AS DOUBLE
176.  
177.     FOR i = 0 TO n / 2 - 1
178.         xpr = (xx_r(i) + xx_r(n / 2 + i)) / 2
179.         xpi = (xx_i(i) + xx_i(n / 2 + i)) / 2
180.  
181.         xmr = (xx_r(i) - xx_r(n / 2 + i)) / 2
182.         xmi = (xx_i(i) - xx_i(n / 2 + i)) / 2
183.  
184.         xx_r(i) = xpr + xpi * COS(2 * pi * i / n) - xmr * SIN(2 * pi * i / n)
185.         xx_i(i) = xmi - xpi * SIN(2 * pi * i / n) - xmr * COS(2 * pi * i / n)
186.     NEXT
187.  
188.     'symmetry, complex conj
189.     FOR i = 0 TO n / 2 - 1
190.         xx_r(n / 2 + i) = xx_r(n / 2 - 1 - i)
191.         xx_i(n / 2 + i) = -xx_i(n / 2 - 1 - i)
192.     NEXT
193. END SUB
194.  
195.  
196.  

[Petr]

@_vince  gave us a treasure. By no means do I understand what the hell SUB rfft is doing, but he's doing it damn well and incredibly fast. I sat down and played with it. Now it seems to work the way I wanted. I just had to take the results of the  _Vince program and categorize them. Now I'm going to try to turn this treasure into a SUB so that I just insert the _MEM field and get back a number indicating the frequency.

You can try it. The program includes a graphics analyzer. (on left depth, then next frequencies by the highest on right side). It seems that sometimes when there is a long deep frequency, it does not register a high frequency (cymbals) but it is highly likely that it is my fault.

@_vince, thank you. This took me a long time.

Code: QB64: [Select]

1. 'defdbl a-z
2.  
3. CONST sw = 1024
4. CONST sh = 600
5.  
6.  
7. '''
8. DIM Left AS _MEM
9. DIM Right AS _MEM
10. DIM Analyzer(8) AS SINGLE
11. '''
12.  
13.  
14. DIM c AS DOUBLE
15. DIM u_r AS DOUBLE, u_i AS DOUBLE
16. DIM v_r AS DOUBLE, v_i AS DOUBLE
17.  
18.  
19. DIM SHARED pi AS DOUBLE
20. 'pi = 2*asin(1)
21. pi = 4 * ATN(1)
22.  
23. DECLARE SUB rfft(xx_r(), xx_i(), x_r(), n)
24.  
25. DIM x_r(sw - 1), x_i(sw - 1)
26. DIM xx_r(sw - 1), xx_i(sw - 1)
27. DIM t AS DOUBLE
28.  
29. '''
30. AudioFile$ = "01.mp3"
31. S = _SNDOPEN(AudioFile$)
32. Left = _MEMSOUND(S, 1)
33. Right = _MEMSOUND(S, 2)
34.  
35. '''
36. SCREEN _NEWIMAGE(sw, sh, 32)
37.  
38. TestT = TIMER
39. '''
40. _SNDPLAY S
41. DO UNTIL _SNDPLAYING(S) = 0
42.     i = 0: j = 0 '                                             reset previous values
43.     Position& = _SNDGETPOS(S) * _SNDRATE * 2 '                 *2, because sound data are in INTEGER format and INTEGER is always 2 byte long
44.     IF Position& > 1024 AND Position& < Left.SIZE - 1024 THEN 'current (actual playing) sound frame is in middle - in position Position&
45.         j& = Position& - 1022
46.         DO UNTIL i >= 1024
47.             x_r(i) = 100 * _MEMGET(Left, Left.OFFSET + j&, INTEGER) / 32767
48.             i = i + 1
49.             j& = j& + 2
50.         LOOP
51.         test& = j& - Position&
52.     END IF
53.  
54.     'FOR i = 0 TO sw - 1
55.     'x_r(i) = 100 * SIN(2 * pi * (sw * 20000 / 44000) * i / sw) + (100 * RND - 50)      '_Vince's signal generator in original source code
56.     'NEXT
57.  
58.     i = 0
59.     j& = 0
60.     '''
61.  
62.  
63.  
64.     'screenres sw, sh, 32
65.     'SCREEN _NEWIMAGE(sw, sh, 32)
66.  
67.     'plot signal
68.     CLS
69.     PSET (0, sh / 4 - x_r(0))
70.     FOR i = 0 TO sw - 1
71.         LINE -(i, sh / 4 - x_r(i)), _RGB(255, 0, 0)
72.     NEXT
73.     LINE (0, sh / 4)-STEP(sw, 0), _RGB(255, 0, 0), , &H5555
74.  
75.     ' _PRINTSTRING (0, 0), "2000 Hz signal with RND noise sampled at 44 kHz in 1024 samples"
76.  
77.  
78.     rfft xx_r(), xx_i(), x_r(), sw
79.  
80.     'plot its fft
81.     PSET (0, 50 + 3 * sh / 4 - 0.005 * SQR(xx_r(0) * xx_r(0) + xx_i(0) * xx_i(0))), _RGB(255, 255, 0)
82.     FOR i = 0 TO sw / 2
83.         LINE -(i * 2, 50 + 3 * sh / 4 - 0.005 * SQR(xx_r(i) * xx_r(i) + xx_i(i) * xx_i(i))), _RGB(255, 255, 0)
84.     NEXT
85.     LINE (0, 50 + 3 * sh / 4)-STEP(sw, 0), _RGB(255, 255, 0), , &H5555
86.  
87.  
88.     'find peak
89.     DIM max AS DOUBLE, d AS DOUBLE
90.     max = 0
91.     m = 0
92.     FOR i = 0 TO sw / 2
93.         d = 0.01 * SQR(xx_r(i) * xx_r(i) + xx_i(i) * xx_i(i))
94.         IF d > max THEN
95.             max = d
96.             m = i
97.         END IF
98.     NEXT
99.  
100.     _PRINTSTRING (0, sh / 2), "m_peak =" + STR$(m)
101.     _PRINTSTRING (0, sh / 2 + 16), "f_peak = m_peak * 44 kHz / 1024 samples = " + STR$(m * 44000 / 1024) + " Hz"
102.  
103.     'apply frequency correction, only works for some signals
104.     '   DIM c AS DOUBLE
105.     '  DIM u_r AS DOUBLE, u_i AS DOUBLE
106.     ' DIM v_r AS DOUBLE, v_i AS DOUBLE
107.  
108.     IF m = 0 THEN _CONTINUE
109.     u_r = xx_r(m - 1) - xx_r(m + 1)
110.     u_i = xx_i(m - 1) - xx_i(m + 1)
111.     v_r = 2 * xx_r(m) - xx_r(m - 1) - xx_r(m + 1)
112.     v_i = 2 * xx_i(m) - xx_i(m - 1) - xx_i(m + 1)
113.     c = (u_r * v_r + u_i * v_i) / (v_r * v_r + v_i * v_i)
114.  
115.     F = (m + c) * _SNDRATE / 1024 '                                                             1024 = number of samples
116.     _PRINTSTRING (0, sh / 2 + 2 * 16), "f_corrected = " + STR$(F) '(m + c) * 44000 / 1024) + " Hz"
117.  
118.  
119.     'If signal is contained in some range, add 30 pixels for Y coordinate (analyzer go up, its wroted as bottom - this value)
120.     SELECT CASE F
121.         CASE 20 TO 125: Analyzer(1) = Analyzer(1) + 30 'areas set by picture on google...
122.         CASE 126 TO 300: Analyzer(2) = Analyzer(2) + 30
123.         CASE 300 TO 500: Analyzer(3) = Analyzer(3) + 30
124.         CASE 500 TO 1000: Analyzer(4) = Analyzer(4) + 30
125.         CASE 1001 TO 2000: Analyzer(5) = Analyzer(5) + 30
126.         CASE 2001 TO 4000: Analyzer(6) = Analyzer(6) + 30
127.         CASE 4001 TO 8000: Analyzer(7) = Analyzer(7) + 30
128.         CASE IS > 8001: Analyzer(8) = Analyzer(8) + 30
129.     END SELECT
130.  
131.  
132.  
133.     'analyzer overflow control
134.     FOR analyze = 1 TO 8 '                                    analyze 8 spectrums
135.         IF Analyzer(analyze) > 150 THEN Analyzer(analyze) = 100
136.     NEXT
137.  
138.     'draw analyzer
139.     AnC = 0
140.     FOR AnalyzatorX = 600 TO 670 STEP 10
141.         AnC = AnC + 1
142.         FreqHeight = Analyzer(AnC) '                          Y coordinate for drawing frequency analyzer, maximal size is 150 pixels
143.         LINE (AnalyzatorX - 4, 400)-(AnalyzatorX + 4, 400 - FreqHeight), &HFFAD0000, BF
144.         IF Analyzer(AnC) > 0 THEN Analyzer(AnC) = Analyzer(AnC) - 1 ' always, if analyzer contains some higher position than bottom, give one pixel out
145.     NEXT
146.  
147.     PRINT Position&, _SNDGETPOS(S) * _SNDRATE
148.     PRINT TIMER - TestT: TestT = TIMER
149.     _DISPLAY
150.     _LIMIT 200
151. LOOP
152.  
153. SYSTEM
154.  
155.  
156. SUB rfft (xx_r(), xx_i(), x_r(), n)
157.     DIM w_r AS DOUBLE, w_i AS DOUBLE, wm_r AS DOUBLE, wm_i AS DOUBLE
158.     DIM u_r AS DOUBLE, u_i AS DOUBLE, v_r AS DOUBLE, v_i AS DOUBLE
159.  
160.     log2n = LOG(n / 2) / LOG(2)
161.  
162.     FOR i = 0 TO n / 2 - 1
163.         rev = 0
164.         FOR j = 0 TO log2n - 1
165.             IF i AND (2 ^ j) THEN rev = rev + (2 ^ (log2n - 1 - j))
166.         NEXT
167.  
168.         xx_r(i) = x_r(2 * rev)
169.         xx_i(i) = x_r(2 * rev + 1)
170.     NEXT
171.  
172.     FOR i = 1 TO log2n
173.         m = 2 ^ i
174.         wm_r = COS(-2 * pi / m)
175.         wm_i = SIN(-2 * pi / m)
176.  
177.         FOR j = 0 TO n / 2 - 1 STEP m
178.             w_r = 1
179.             w_i = 0
180.  
181.             FOR k = 0 TO m / 2 - 1
182.                 p = j + k
183.                 q = p + (m \ 2)
184.  
185.                 u_r = w_r * xx_r(q) - w_i * xx_i(q)
186.                 u_i = w_r * xx_i(q) + w_i * xx_r(q)
187.                 v_r = xx_r(p)
188.                 v_i = xx_i(p)
189.  
190.                 xx_r(p) = v_r + u_r
191.                 xx_i(p) = v_i + u_i
192.                 xx_r(q) = v_r - u_r
193.                 xx_i(q) = v_i - u_i
194.  
195.                 u_r = w_r
196.                 u_i = w_i
197.                 w_r = u_r * wm_r - u_i * wm_i
198.                 w_i = u_r * wm_i + u_i * wm_r
199.             NEXT
200.         NEXT
201.     NEXT
202.  
203.     xx_r(n / 2) = xx_r(0)
204.     xx_i(n / 2) = xx_i(0)
205.  
206.     FOR i = 1 TO n / 2 - 1
207.         xx_r(n / 2 + i) = xx_r(n / 2 - i)
208.         xx_i(n / 2 + i) = xx_i(n / 2 - i)
209.     NEXT
210.  
211.     DIM xpr AS DOUBLE, xpi AS DOUBLE
212.     DIM xmr AS DOUBLE, xmi AS DOUBLE
213.  
214.     FOR i = 0 TO n / 2 - 1
215.         xpr = (xx_r(i) + xx_r(n / 2 + i)) / 2
216.         xpi = (xx_i(i) + xx_i(n / 2 + i)) / 2
217.  
218.         xmr = (xx_r(i) - xx_r(n / 2 + i)) / 2
219.         xmi = (xx_i(i) - xx_i(n / 2 + i)) / 2
220.  
221.         xx_r(i) = xpr + xpi * COS(2 * pi * i / n) - xmr * SIN(2 * pi * i / n)
222.         xx_i(i) = xmi - xpi * SIN(2 * pi * i / n) - xmr * COS(2 * pi * i / n)
223.     NEXT
224.  
225.     'symmetry, complex conj
226.     FOR i = 0 TO n / 2 - 1
227.         xx_r(n / 2 + i) = xx_r(n / 2 - 1 - i)
228.         xx_i(n / 2 + i) = -xx_i(n / 2 - 1 - i)
229.     NEXT
230. END SUB
231.  

[SMcNeill]

Quick thought:

Shouldn’t _MEMSOUND have a mem.TYPE associate with it?

http://www.qb64.org/wiki/MEM

mem.TYPE is an OFFSET, so it’s always a minimum of 32-bits in size.  _MEMSOUND could easily just take the 17th bit as an identifier.

[FellippeHeitor]

It should. Thoughts?

[bplus]

Nice one! @Petr 

I nominate you to do the Wiki demo example for this :)

[Petr]

@bplus

I really appreciate this offer, do you mean the source code for the video above? Or a newer one that uses the _Vince solution to gain frequency? I'll probably get there on Sunday or Monday. Tomorrow my daughter celebrates her birthday, so there will be no time tomorrow. So I'll send you the source code, because I don't have access to the wiki myself, you'll be able to paste it there.

[bplus]

@bplus

I really appreciate this offer, do you mean the source code for the video above? Or a newer one that uses the _Vince solution to gain frequency? I'll probably get there on Sunday or Monday. Tomorrow my daughter celebrates her birthday, so there will be no time tomorrow. So I'll send you the source code, because I don't have access to the wiki myself, you'll be able to paste it there.

Oh I don't have access to Wiki either and I am sort of a generalist myself, but you seem expert in the arena of sound and all it's nuances. I think Wiki needs short and as little complicated as can get but still get the point of how to use the thing being demo'd, so _vince variation might go over the top in needs. You guys are already over my head so _vince thing might be just the thing, I don't know ;)

I could put demo in Infomatics Board if you say it's specially good.

[Petr]

I understand. Just write the simplest program possible. Something light for visualization with descriptions in English. Good! I'll prepare it here.
But I don't feel like a sound expert myself. I'm just interested.

[bplus]

I understand. Just write the simplest program possible. Something light for visualization with descriptions in English. Good! I'll prepare it here.
But I don't feel like a sound expert myself. I'm just interested.

Petr for Infomatics (the thing I have some permission for) simple is not so important than cool! If the thing with _vince stuff is way cooler than a simple demo then let's go for that. It would be cool to get something with _vince contributing too!

For Wiki, it is only MHO that simple is better by simple I mean short and sweet and by sweet I mean gets the point across elegantly, one very fine example of this is Wiki's Rotozoom. But I am not involved with Wiki project, so far everyone has been doing great by me for that! And thanks again to those who do contribute to that project.

I'm just interested.

Yes that can go a long way towards getting your head into the game and coming up with something clever.