PRINT USING for non US numbers

[zaadstra]

Hi,

I wonder if it is possible to setup PRINT USING to display (large) numbers, separated with points instead of comma's.  This is common in EU and possibly other areas.

Wiki http://www.qb64.org/wiki/PRINT_USING says:
  ,.    Comma to left of decimal point, prints a comma every 3 used # digit places left of the decimal point.

This gives me 324,653,221.  if programmed with PRINT USING "##############,."; a  (and I don't need decimals here).
Stripping to PRINT USING "##############,"; a      (undocumented on wiki) makes it even better to  324,653,221

But PRINT USING "##############."; a    doesn't do the trick.

I like to see my number as 324.653.221 with PRINT USING and preferrably without coding that myself in a Function ;-)

Is this possible?

[OldMoses]

I'm not really familiar with PRINT USING templates. I've used them, but they usually devil me terribly. Maybe someone else knows more, but I think it's not generally possible. How would one tell the difference between 1,000,000.321 and 1.000.000.321? Is it a million and three decimal places or a tad over a billion? Sounds like a good way to get something wrong by orders of magnitude. Of course, if it's understood that one is only working with integers then I suppose it would be fine.

In the spirit of addressing the problem I offer the following...

Code: QB64: [Select]

1. SCREEN 0
2.  
3. DO
4.     CLS
5.     INPUT "enter a number for point conversion ", a##
6.     Point_Number a##
7.     PRINT "Space to continue"
8.     SLEEP
9. LOOP UNTIL _KEYDOWN(27)
10.  
11. SUB Point_Number (var AS _FLOAT)
12.  
13.     x$ = _TRIM$(STR$(var))
14.     full% = LEN(x$)
15.     dec_point% = INSTR(x$, ".")
16.     IF dec_point% = 0 THEN lngth% = full% ELSE lngth% = dec_point% - 1
17.     FOR x = 1 TO lngth%
18.         IF ((lngth% + 1 - x) / 3 = INT((lngth% + 1 - x) / 3)) AND x <> 1 THEN
19.             y$ = y$ + "."
20.         END IF
21.         y$ = y$ + MID$(x$, x, 1)
22.     NEXT x
23.     IF dec_point% <> 0 THEN y$ = y$ + MID$(x$, dec_point%)
24.     PRINT y$
25.  
26. END SUB
27.  

[luke]

Unfortunately PRINT USING is fairly American, and doesn't really know about internationalisation.

Likely you'll have to write a routine yourself (or even better, wait a few days and someone will likely come along with one for you).

[TempodiBasic]

Hi zaadstra
your homework is:
print an integer number using the point for dividing the thousand multiple at the place of the comma.
PRINT USING let format the output of the number but it divides the thousand multiple using the comma.

Here one of the thousand possible solutions

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM i1 AS INTEGER, i2 AS _INTEGER64
4.  
5. i1 = -23200
6. i2 = 12345678901
7. PRINT "   Input        Output"
8. PRINT i1, IntPrintUsing$(STR$(i1))
9. PRINT i2, IntPrintUsing$(STR$(i2))
10. END
11.  
12. FUNCTION IntPrintUsing$ (Toprint AS STRING)
13.     DIM in AS STRING, tmp AS STRING, index AS INTEGER, cont AS INTEGER
14.     Toprint = _TRIM$(Toprint)
15.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
16.     cont = 0: index = 0
17.     WHILE cont < LEN(in)
18.         IF index + 3 < LEN(in) THEN
19.             index = index + 3
20.         ELSE
21.             index = LEN(in) - index
22.         END IF
23.         cont = cont + 3
24.         IF index > 2 THEN tmp = "." + MID$(in, 1 + LEN(in) - index, 3) + tmp ELSE tmp = MID$(in, 1, index) + tmp
25.     WEND
26.     in = tmp
27.     IF INSTR(Toprint, "-") THEN in = "-" + in
28.     IntPrintUsing$ = in
29. END FUNCTION

this can be optimized to save time (for example storing in a variable the result of LEN(in) instead of calculating each time this same result)

Good Enjoying  with programming

[bplus]

Unfortunately PRINT USING is fairly American, and doesn't really know about internationalisation.

Likely you'll have to write a routine yourself (or even better, wait a few days and someone will likely come along with one for you).

Ha I was expecting @RhoSigma to come along ;-))  must be on Holidays.

Hi zaadstra
your homework is:
print an integer number using the point for dividing the thousand multiple at the place of the comma.
PRINT USING let format the output of the number but it divides the thousand multiple using the comma.

Here one of the thousand possible solutions

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM i1 AS INTEGER, i2 AS _INTEGER64
4.  
5. i1 = -23200
6. i2 = 12345678901
7. PRINT "   Input        Output"
8. PRINT i1, IntPrintUsing$(STR$(i1))
9. PRINT i2, IntPrintUsing$(STR$(i2))
10. END
11.  
12. FUNCTION IntPrintUsing$ (Toprint AS STRING)
13.     DIM in AS STRING, tmp AS STRING, index AS INTEGER, cont AS INTEGER
14.     Toprint = _TRIM$(Toprint)
15.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
16.     cont = 0: index = 0
17.     WHILE cont < LEN(in)
18.         IF index + 3 < LEN(in) THEN
19.             index = index + 3
20.         ELSE
21.             index = LEN(in) - index
22.         END IF
23.         cont = cont + 3
24.         IF index > 2 THEN tmp = "." + MID$(in, 1 + LEN(in) - index, 3) + tmp ELSE tmp = MID$(in, 1, index) + tmp
25.     WEND
26.     in = tmp
27.     IF INSTR(Toprint, "-") THEN in = "-" + in
28.     IntPrintUsing$ = in
29. END FUNCTION

this can be optimized to save time (for example storing in a variable the result of LEN(in) instead of calculating each time this same result)

Good Enjoying  with programming

@TempodiBasic

Try more numbers for your Function:

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM test AS _INTEGER64
4.  
5. DO
6.     PRINT
7.     INPUT "Enter an Integer to convert > "; test
8.     PRINT IntPrintUsing$(STR$(test))
9. LOOP UNTIL test = 0
10.  
11. FUNCTION IntPrintUsing$ (Toprint AS STRING)
12.     DIM in AS STRING, tmp AS STRING, index AS INTEGER, cont AS INTEGER
13.     Toprint = _TRIM$(Toprint)
14.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
15.     cont = 0: index = 0
16.     WHILE cont < LEN(in)
17.         IF index + 3 < LEN(in) THEN
18.             index = index + 3
19.         ELSE
20.             index = LEN(in) - index
21.         END IF
22.         cont = cont + 3
23.         IF index > 2 THEN tmp = "." + MID$(in, 1 + LEN(in) - index, 3) + tmp ELSE tmp = MID$(in, 1, index) + tmp
24.     WEND
25.     in = tmp
26.     IF INSTR(Toprint, "-") THEN in = "-" + in
27.     IntPrintUsing$ = in
28. END FUNCTION
29.  
30.  

I am not liking how 999 and -999 are looking, how about you?

[TempodiBasic]

Hi Bplus
Thanks to find a bug to that function!
It didn't manage rightly the number with digits multiple of 3!

Now it seems that it works.

Give a try to this fix.

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM i1 AS INTEGER, i2 AS _INTEGER64, i3 AS _INTEGER64, i4 AS INTEGER, i5 AS _INTEGER64
4.  
5. i1 = -23200
6. i2 = 12345678901
7. i3 = 799444
8. i4 = -999
9. i5 = -111222333
10. PRINT "   Input        Output"
11. PRINT i1, IntPrintUsing$(STR$(i1))
12. PRINT i2, IntPrintUsing$(STR$(i2))
13. PRINT i3, IntPrintUsing$(STR$(i3))
14. PRINT i4, IntPrintUsing$(STR$(i4))
15. PRINT i5, IntPrintUsing$(STR$(i5))
16. END
17.  
18. FUNCTION IntPrintUsing$ (Toprint AS STRING)
19.     DIM in AS STRING, tmp AS STRING, index AS INTEGER, cont AS INTEGER
20.     Toprint = _TRIM$(Toprint)
21.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
22.     cont = 0: index = 0
23.     WHILE cont < LEN(in)
24.         IF index + 3 <= LEN(in) THEN
25.             index = index + 3
26.         ELSE
27.             index = LEN(in) - index
28.         END IF
29.         cont = cont + 3
30.         IF index > 2 THEN tmp = "." + MID$(in, 1 + LEN(in) - index, 3) + tmp ELSE tmp = MID$(in, 1, index) + tmp
31.     WEND
32.     IF LEN(in) - cont = 0 THEN tmp = RIGHT$(tmp, LEN(tmp) - INSTR(tmp, "."))
33.     in = tmp
34.     IF INSTR(Toprint, "-") THEN in = "-" + in
35.     IntPrintUsing$ = in
36. END FUNCTION

  [ You are not allowed to view this attachment ]  

[RhoSigma]

Ha I was expecting @RhoSigma to come along ;-))  must be on Holidays.

Funny thing, I was just about releasing a bigger update to my IndexFormat() function before the year's end, when this topic popped up, which made me rethink things before the release. So still give me a day or two to finish things and you'll not only able to flip the comma/dot notation, but also to exchange the $ currency sign. Also a feature request on GitHub asks for the ability to group hex/bin/oct outputs, which can be achieved with the new IndexFormat() function too, so stay tuned....

[TempodiBasic]

Waiting the sooner RhoSigma developments
Here another way to do the same work of the first : just use the point instead of comma for thousands multiple on printing on the screen an integer digit.

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM i1 AS INTEGER, i2 AS _INTEGER64, i3 AS _INTEGER64, i4 AS INTEGER, i5 AS _INTEGER64, i6 AS _INTEGER64
4.  
5. i1 = -23200
6. i2 = 12345678901
7. i3 = 799444
8. i4 = -999
9. i5 = -11122233
10. i6 = -111222333
11. PRINT "   Input        Output   "
12. PRINT i1, IntPrintUsing$(STR$(i1))
13. PRINT i2, IntPrintUsing$(STR$(i2))
14. PRINT i3, IntPrintUsing$(STR$(i3))
15. PRINT i4, IntPrintUsing$(STR$(i4))
16. PRINT i5, IntPrintUsing$(STR$(i5))
17. PRINT i6, IntPrintUsing$(STR$(i6))
18. PRINT "----Input--------Output---"
19. PRINT i1, IntPrintUsing2$(STR$(i1))
20. PRINT i2, IntPrintUsing2$(STR$(i2))
21. PRINT i3, IntPrintUsing2$(STR$(i3))
22. PRINT i4, IntPrintUsing2$(STR$(i4))
23. PRINT i5, IntPrintUsing2$(STR$(i5))
24. PRINT i6, IntPrintUsing2$(STR$(i6))
25. END
26.  
27. FUNCTION IntPrintUsing$ (Toprint AS STRING)
28.     DIM in AS STRING, tmp AS STRING, index AS INTEGER, cont AS INTEGER
29.     Toprint = _TRIM$(Toprint)
30.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
31.     cont = 0: index = 0
32.     WHILE cont < LEN(in)
33.         IF index + 3 <= LEN(in) THEN
34.             index = index + 3
35.         ELSE
36.             index = LEN(in) - index
37.         END IF
38.         cont = cont + 3
39.         IF index > 2 THEN tmp = "." + MID$(in, 1 + LEN(in) - index, 3) + tmp ELSE tmp = MID$(in, 1, index) + tmp
40.     WEND
41.     IF LEN(in) - cont = 0 THEN tmp = RIGHT$(tmp, LEN(tmp) - INSTR(tmp, "."))
42.     in = tmp
43.     IF INSTR(Toprint, "-") THEN in = "-" + in
44.     IntPrintUsing$ = in
45. END FUNCTION
46.  
47. FUNCTION IntPrintUsing2$ (Toprint AS STRING)
48.     DIM l AS INTEGER, in AS STRING, Tmp AS STRING, Start AS INTEGER, cont AS INTEGER
49.     Toprint = _TRIM$(Toprint)
50.     IF INSTR(Toprint, "-") THEN in = MID$(Toprint, INSTR(Toprint, "-") + 1, LEN(Toprint) - INSTR(Toprint, "-")) ELSE in = Toprint
51.     l = LEN(in)
52.     IF l MOD 3 = 0 THEN
53.         Start = 3
54.         cont = 1
55.     ELSE
56.         Start = l MOD 3
57.         cont = 0
58.     END IF
59.     Tmp = MID$(in, 1, Start)
60.  
61.     WHILE cont < l - Start
62.         cont = cont + 3
63.         Tmp = Tmp + "." + MID$(in, cont, 3)
64.     WEND
65.     IF INSTR(Toprint, "-") THEN Tmp = "-" + Tmp
66.     IntPrintUsing2$ = Tmp
67. END FUNCTION

Thanks to try
Maybe it is possible to extend the function to Single and Double numbers...

[bplus]

@TempodiBasic  Ah yes the fix looks good but I like the idea of your 2nd approach, specially for real numbers AKA floats AKA having digits to the right of decimal or is it comma now hahaha!

ie do it the American way with PRINT USING then swap . for , and vice versa but save place of decimal first and do commas to dots then at place of decimal put the comma.

[zaadstra]

Hi guys,

Thanks for all the thinking and even solutions!  I'd never thought a question like this would generate so many solutions :-)

A I noticed the American bias (also in character sets I have to do quite some tricks),  this normally isn't a problem. I was just hoping that in a 'next' version of QB64 the print using options will be added for the 3 digit groups and the decimal comma,  or only the 3 digit groups (like ,. and . in print using).
Print Using indeed has it's quirks but when it is tamed then it solves quite some formatting stuff for you.

Meanwhile, I had written my own function for this,  and funny enough, again another approach like all pieces of code above are different:
To simulate Print using with it's column formatting, I added a column width with parameter 'printlen' and have the number aligned to the right.

Code: QB64: [Select]

1. PRINT #99, "Matched  :"; PrintNiceRightAlign$(totalbytes1, 16); PrintNiceRightAlign$(totalbytes2, 16)
2.  
3. FUNCTION PrintNiceRightAlign$ (printnu&&, printlen)
4.    ' Parameters: number to print, total character length to be filled
5.    x$ = LTRIM$(STR$(printnu&&))
6.    printnu$ = ""
7.  
8.    FOR i = LEN(x$) TO 1 STEP -1
9.       printnu$ = printnu$ + MID$(x$, LEN(x$) - i + 1, 1)
10.       IF ((i - 1) MOD 3 = 0) AND i <> 1 THEN printnu$ = printnu$ + "."
11.    NEXT
12.  
13.    PrintNiceRightAlign$ = RIGHT$(SPACE$(printlen) + printnu$, printlen)
14. END FUNCTION
15.  
16. Output:
17. Matched  :   4.574.562.555   4.574.562.555
18.  

[Mad Axeman]

A I noticed the American bias

It's not just in the USA that a comma separator is used. We use it here in the UK too. Just out of interest, what country are you in?

[bplus]

Code: QB64: [Select]

1. SCREEN 0
2. CLS
3. DIM test AS _INTEGER64
4.  
5. DO
6.     PRINT
7.     INPUT "Enter an Integer to convert > "; test
8.     PRINT PrintNiceRightAlign$(test, 20)
9. LOOP UNTIL test = 0
10.  
11.  
12. FUNCTION PrintNiceRightAlign$ (printnu&&, printlen)
13.     ' Parameters: number to print, total character length to be filled
14.     x$ = LTRIM$(STR$(printnu&&))
15.     printnu$ = ""
16.  
17.     FOR i = LEN(x$) TO 1 STEP -1
18.         printnu$ = printnu$ + MID$(x$, LEN(x$) - i + 1, 1)
19.         IF ((i - 1) MOD 3 = 0) AND i <> 1 THEN printnu$ = printnu$ + "."
20.     NEXT
21.  
22.     PrintNiceRightAlign$ = RIGHT$(SPACE$(printlen) + printnu$, printlen)
23. END FUNCTION
24.  
25.  
26.  

Tested and I think fails on neg numbers:
  [ You are not allowed to view this attachment ]  

But is true you don't need $ for string constants or other suffix for other constants.

[zaadstra]

It's not just in the USA that a comma separator is used. We use it here in the UK too. Just out of interest, what country are you in?

I'm in The Netherlands.  (hi neigbour!)

Now out of curiosity, which regions are using what, I did some reading: https://en.wikipedia.org/wiki/Decimal_separator
We seem to owe our system to the Romans :-)
I'm not sure if there is a relation to the use of the imperial system of weights and measures in a country.

[zaadstra]

Tested and I think fails on neg numbers:
  [ You are not allowed to view this attachment ]  

But is true you don't need $ for string constants or other suffix for other constants.

That is very much possible!  But as my byte counter only produce positive numbers, I have no issue with that.

[bplus]

EDIT: oops wrong post