How to change the mouse cursor inside a program

[random1]

Hi all

I am making a simple shooter game and want to use a custom mouse pointer, "gunsight", then change
back to the to the windows default when the program is exited.  I tried searching but got nothing in the
results. 

Thanks in advance.

R1

[SMcNeill]

Wouldn't you just use_MOUSEHIDE to hide the cursor, and then draw what you want on the screen where it's normally at?

_MOUSEHIDE
CIRCLE (_MOUSEX, _MOUSEY), 10,_RGB(255,0,0)

[johnno56]

.. then I personally would add...
CIRCLE(_MOUSEX,_MOUSEY), 1, _RGB(255,0,0)  (maybe 2 instead of 1 for the centre of the sight)

[Petr]

Try:
        _MOUSESHOW "LINK" will display an upward pointing hand cursor used to denote hypertext
        _MOUSESHOW "TEXT" will display the I cursor often used in text entry areas
        _MOUSESHOW "CROSSHAIR" will display a crosshair cursor
        _MOUSESHOW "VERTICAL" will display vertical arrow cursor for movement
        _MOUSESHOW "HORIZONTAL" will display horizontal arrow cursor for movement
        _MOUSESHOW "TOPLEFT_BOTTOMRIGHT" will display bottom diagonal arrow cursor for movement
        _MOUSESHOW "TOPRIGHT_BOTTOMLEFT" will display bottom diagonal arrow cursor for movement
        _MOUSESHOW "DEFAULT" can be used after a mouse cursor statement above was previously used.

[johnno56]

This snippet is crude but seems to work.

Press LMB to change sights.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. _MOUSEHIDE
3.  
4. DIM red AS _UNSIGNED LONG
5.  
6. red = _RGB(255, 0, 0)
7.  
8. DO
9.     CLS
10.  
11.     DO WHILE _MOUSEINPUT: mX = _MOUSEX: mY = _MOUSEY: mB = _MOUSEBUTTON(1): LOOP
12.  
13.     CIRCLE (mX, mY), 20, red
14.     IF mB = 0 THEN
15.         CIRCLE (mX, mY), 2, red
16.     ELSE
17.         LINE (mX, mY - 5)-STEP(0, 10), red
18.         LINE (mX - 5, mY)-STEP(10, 0), red
19.     END IF
20.  
21.     _DISPLAY
22.     _LIMIT 60
23. LOOP UNTIL INKEY$ = CHR$(27)
24. _DELAY 1
25. SYSTEM
26.  

I am sure that anyone here can produce a far more superior sample of this code.

[OldMoses]

Utilizing mostly Steve's quality tooling; since the wheel has already been invented, I present a target reticle.

If you try to go full auto your barrel will seize. ;)

Code: QB64: [Select]

1. TYPE v2
2.     x AS INTEGER
3.     y AS INTEGER
4. END TYPE
5.  
6. DIM hole(10000) AS v2
7.  
8.  
9. SCREEN _NEWIMAGE(600, 600, 32)
10.  
11. 'define reticle image
12. ret& = _NEWIMAGE(50, 50, 32)
13. _DEST ret&
14. CLS
15. _CLEARCOLOR _RGB32(0, 0, 0)
16. CIRCLE (24, 24), 20, &HFFFF0000
17. LINE (0, 24)-(49, 24), &HFFFF0000
18. LINE (24, 0)-(24, 49), &HFFFF0000
19. _DEST 0
20.  
21. _MOUSEHIDE
22. shoot = 0
23. DO
24.     ms = MBS
25.     IF ms AND 1 THEN
26.         IF ms AND 64 THEN _CONTINUE
27.         hole(shoot).x = _MOUSEX
28.         hole(shoot).y = _MOUSEY
29.         shoot = shoot + 1
30.     END IF
31.     CLS
32.     FOR x = 0 TO shoot
33.         FCirc hole(x).x, hole(x).y, 3, &HFFFF0000
34.     NEXT x
35.     _PUTIMAGE (_MOUSEX - 24, _MOUSEY - 24), ret&
36.     _DISPLAY
37.     _LIMIT 50
38. LOOP
39.  
40.  
41. FUNCTION MBS% 'Mouse Button Status  by Steve McNeill
42.     STATIC StartTimer AS _FLOAT
43.     STATIC ButtonDown AS INTEGER
44.     'STATIC ClickCount AS INTEGER
45.     CONST ClickLimit## = .2 'Less than 1/4 of a second to down, up a key to count as a CLICK.
46.     '                          Down longer counts as a HOLD event.
47.     SHARED Mouse_StartX, Mouse_StartY, Mouse_EndX, Mouse_EndY
48.     WHILE _MOUSEINPUT 'Remark out this block, if mouse main input/clear is going to be handled manually in main program.
49.         SELECT CASE SGN(_MOUSEWHEEL)
50.             CASE 1: MBS = MBS OR 512
51.             CASE -1: MBS = MBS OR 1024
52.         END SELECT
53.     WEND
54.  
55.     IF _MOUSEBUTTON(1) THEN MBS = MBS OR 1
56.     IF _MOUSEBUTTON(2) THEN MBS = MBS OR 2
57.     IF _MOUSEBUTTON(3) THEN MBS = MBS OR 4
58.  
59.     IF StartTimer = 0 THEN
60.         IF _MOUSEBUTTON(1) THEN 'If a button is pressed, start the timer to see what it does (click or hold)
61.             ButtonDown = 1: StartTimer = TIMER(0.01)
62.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
63.         ELSEIF _MOUSEBUTTON(2) THEN
64.             ButtonDown = 2: StartTimer = TIMER(0.01)
65.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
66.         ELSEIF _MOUSEBUTTON(3) THEN
67.             ButtonDown = 3: StartTimer = TIMER(0.01)
68.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
69.         END IF
70.     ELSE
71.         BD = ButtonDown MOD 3
72.         IF BD = 0 THEN BD = 3
73.         IF TIMER(0.01) - StartTimer <= ClickLimit THEN 'Button was down, then up, within time limit.  It's a click
74.             IF _MOUSEBUTTON(BD) = 0 THEN MBS = 4 * 2 ^ ButtonDown: ButtonDown = 0: StartTimer = 0
75.         ELSE
76.             IF _MOUSEBUTTON(BD) = 0 THEN 'hold event has now ended
77.                 MBS = 0: ButtonDown = 0: StartTimer = 0
78.                 Mouse_EndX = _MOUSEX: Mouse_EndY = _MOUSEY
79.             ELSE 'We've now started the hold event
80.                 MBS = MBS OR 32 * 2 ^ ButtonDown
81.             END IF
82.         END IF
83.     END IF
84. END FUNCTION 'MBS%
85.  
86. SUB FCirc (CX AS INTEGER, CY AS INTEGER, RR AS INTEGER, C AS _UNSIGNED LONG)
87.  
88.     'Steve's circle draw
89.     DIM R AS INTEGER, RError AS INTEGER
90.     DIM X AS INTEGER, Y AS INTEGER
91.     R = ABS(RR)
92.     RError = -R
93.     X = R
94.     Y = 0
95.     IF R = 0 THEN PSET (CX, CY), C: EXIT SUB
96.     LINE (CX - X, CY)-(CX + X, CY), C, BF
97.     WHILE X > Y
98.         RError = RError + Y * 2 + 1
99.         IF RError >= 0 THEN
100.             IF X <> Y + 1 THEN
101.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
102.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
103.             END IF
104.             X = X - 1
105.             RError = RError - X * 2
106.         END IF
107.         Y = Y + 1
108.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
109.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
110.     WEND
111.  
112. END SUB 'FCirc
113.  
114.  

[random1]

Hi all

Thanks for the replies but what I would really like to do is change my default cursor.  I attached a pic
of the game  that shows the stages of aiming and shooting a bug.  The _MOUSESHOW "CROSSHAIR"  comes close to what I want but kind of falls short graphic wise.  I thought there might be a simple way
to change the default cursor inside a program which would make things very simple.  My graphic does
not show up until the fire button is pressed.  What I want to achieve is the effect of looking through
a scope to zero in on the bugs.  Anyway, maybe the attached pic will help.

R1       

[johnno56]

I don't know if this helps... But I use an ancient game "Delta Force: Land Warrior". The weapons that use a "scope" can activate the scope using the Right Mouse Button then fire with the Left Mouse Button. Pressing the RMB again hides the scope.

Perhaps something similar. When you want to shoot, press the RMB to change your mouse pointer into a mouse pointer with sights. Shoot with LMB. Press RMB to restore to a normal mouse pointer.

Just a thought.  Is that closer to what you need?. If so, then its just a simple task, of producing a 'sited pointer' sprite.

[Petr]

Hi. You say that the cursor does not change until you press the fire button. This means that the error is in the logic of the mouse display (in your program). I'm adding a sample like to do this because I don't have a sprite image of a beetle, a rectangle is used instead. The rectangle (representing the beetle) measures 50 x 50 pixels. Its position is determined by the upper left corner:

Example 1 - using MOUSESHOW

Code: QB64: [Select]

1. 'example 1 using _MOUSESHOW
2. bug = _NEWIMAGE(50, 50, 32)
3. _DEST bug
4. LINE -(49, 49), _RGB32(127, 200, 99), BF
5. SCREEN _NEWIMAGE(800, 600, 32)
6.  
7. DO UNTIL _KEYHIT = 32
8.     _MOUSESHOW "Default"
9.     WHILE _MOUSEINPUT
10.     WEND
11.     MX = _MOUSEX
12.     MY = _MOUSEY
13.     LB = _MOUSEBUTTON(1)
14.  
15.     'placing bug middle to screen
16.     _PUTIMAGE (400 - 25, 300 - 25), bug
17.  
18.     IF MX > 400 - 25 AND MX < 400 + 25 THEN '     if mouseX is on bug X location
19.         IF MY > 300 - 25 AND MY < 300 + 25 THEN ' if mouseY is on bug Y location
20.             _MOUSESHOW "crosshair"
21.         END IF
22.     END IF
23. LOOP
24.  
25.  

Example 2 - use image as mouse cursor:

Code: QB64: [Select]

1. 'example 2 using image
2.  
3. CurrentScreen = _DEST
4.  
5. bug = _NEWIMAGE(50, 50, 32) '                create virtual image contains "bug" - quad
6. _DEST bug
7. LINE -(49, 49), _RGB32(127, 200, 99), BF
8.  
9.  
10.  
11. Cursor = _NEWIMAGE(50, 50, 32) '            create virtual image contains your cursor
12. _DEST Cursor
13. CLS
14. CIRCLE (25, 25), 22, _RGB32(255, 255, 255)
15. LINE (25, 0)-(25, 50), _RGB32(255, 255, 255)
16. LINE (0, 25)-(50, 25), _RGB32(255, 255, 255)
17. _CLEARCOLOR _RGB32(0, 0, 0)
18.  
19. _DEST CurrentScreen
20. SCREEN _NEWIMAGE(800, 600, 32)
21. CLS
22. 'placing bug middle to screen
23. _PUTIMAGE (400 - 25, 300 - 25), bug
24.  
25. 'save current screen content
26. Content = _COPYIMAGE(0)
27.  
28.  
29.  
30. DO UNTIL _KEYHIT = 32
31.  
32.     _PUTIMAGE , Content
33.  
34.     WHILE _MOUSEINPUT
35.     WEND
36.     MX = _MOUSEX
37.     MY = _MOUSEY
38.     LB = _MOUSEBUTTON(1)
39.     ShowCursor = 1
40.     IF MX > 400 AND MX < 400 + 25 THEN '     if mouseX is on bug X location
41.         IF MY > 300 AND MY < 300 + 25 THEN ' if mouseY is on bug Y location
42.             _PUTIMAGE (MX - 25, MY - 25), Cursor
43.             ShowCursor = 0 '                 comment this and show who real mouse cursor is
44.         END IF
45.     END IF
46.     IF ShowCursor THEN _MOUSESHOW "Default" ELSE _MOUSEHIDE
47.     _DISPLAY
48.     _LIMIT 30
49. LOOP
50.  
51.  

[random1]

Petr

My mistake, when the LMB is pressed the sight graphic is drawn centered at the tip of the mouse pointer.
A custom cursor would make it as simple as pie.   I have used Pcopy in a loop to move an object or
graphic around which is maybe what I will do as a quick fix. 

_MOUSESHOW "CROSSHAIR" is very close to what I need, if only there was a _MOUSESHOW "Gunscope" option. 

Thanks to everyone.

R1

[OldMoses]

Here's something that updates the reticle idea with some scope magnification. I'll leave any gory animations to more capable hands than mine.

Note: game.png is the picture that random1 posted earlier, or substitute one of your own.

Edit: With a few tweaks I added a mousewheel scope power zoom.

Code: QB64: [Select]

1. TYPE v2
2.     x AS INTEGER
3.     y AS INTEGER
4. END TYPE
5.  
6. DIM hole(10000) AS v2
7. DIM SHARED msk&
8. DIM SHARED magfac
9.  
10. game& = _LOADIMAGE("game.png", 32)
11. SCREEN _NEWIMAGE(_WIDTH(game&), _HEIGHT(game&), 32)
12. DO: LOOP UNTIL _SCREENEXISTS
13. _SCREENMOVE 5, 5
14.  
15. ret& = _NEWIMAGE(150, 150, 32)
16. _DEST ret&
17. CLS
18. _CLEARCOLOR _RGB32(0, 0, 0)
19. CIRCLE (74, 74), 74, &HFFFF0000
20. CIRCLE (74, 74), 73, &HFFFF0000
21. CIRCLE (74, 74), 72, &HFFFF0000
22. LINE (0, 74)-(149, 74), &HFFFF0000
23. LINE (55, 75)-(95, 75), &HFFFF0000
24. LINE (75, 55)-(75, 95), &HFFFF0000
25. LINE (74, 0)-(74, 149), &HFFFF0000
26. _DEST 0
27.  
28. msk& = _NEWIMAGE(150, 150, 32)
29. _DEST msk&
30. COLOR , _RGB32(255, 0, 255)
31. CLS
32. FCirc 74, 74, 74, _RGB32(0, 0, 0)
33. _PUTIMAGE , ret&
34. _DEST 0
35.  
36. _MOUSEHIDE
37. shoot = 0
38. magfac = 3
39. DO
40.     ms = MBS
41.     IF ms AND 1 THEN
42.         IF ms AND 64 THEN _CONTINUE
43.         hole(shoot).x = _MOUSEX
44.         hole(shoot).y = _MOUSEY
45.         shoot = shoot + 1
46.     END IF
47.     IF ms AND 512 THEN magfac = magfac - 1 - (magfac = 1)
48.     IF ms AND 1024 THEN magfac = magfac + 1
49.  
50.     gamec& = _COPYIMAGE(game&)
51.     _PUTIMAGE , gamec&
52.     _FREEIMAGE gamec&
53.     FOR x = 0 TO shoot
54.         FCirc hole(x).x, hole(x).y, 3, &HFFFF0000
55.     NEXT x
56.     Magnify
57.     _DISPLAY
58.     _LIMIT 50
59. LOOP UNTIL _KEYDOWN(27)
60. END
61.  
62.  
63. SUB Magnify
64.  
65.     cpy& = _COPYIMAGE(game&, 32)
66.     mag& = _NEWIMAGE(150, 150, 32)
67.     _PUTIMAGE (0, 0)-(149, 149), cpy&, mag&, (_MOUSEX - (75 / magfac), _MOUSEY - (75 / magfac))-(_MOUSEX + (75 / magfac), _MOUSEY + (75 / magfac)), _SMOOTH
68.     _DEST mag&
69.     _CLEARCOLOR _RGB32(0, 0, 0), msk&
70.     _PUTIMAGE , msk&, mag&
71.     _CLEARCOLOR _RGB32(255, 0, 255), mag&
72.     _PUTIMAGE (_MOUSEX - 74, _MOUSEY - 74), mag&, 0
73.     _FREEIMAGE cpy&
74.     _FREEIMAGE mag&
75.  
76. END SUB 'Magnify
77.  
78.  
79. FUNCTION MBS% 'Mouse Button Status  by Steve McNeill
80.     STATIC StartTimer AS _FLOAT
81.     STATIC ButtonDown AS INTEGER
82.     'STATIC ClickCount AS INTEGER
83.     CONST ClickLimit## = .2 'Less than 1/4 of a second to down, up a key to count as a CLICK.
84.     '                          Down longer counts as a HOLD event.
85.     SHARED Mouse_StartX, Mouse_StartY, Mouse_EndX, Mouse_EndY
86.     WHILE _MOUSEINPUT 'Remark out this block, if mouse main input/clear is going to be handled manually in main program.
87.         SELECT CASE SGN(_MOUSEWHEEL)
88.             CASE 1: MBS = MBS OR 512
89.             CASE -1: MBS = MBS OR 1024
90.         END SELECT
91.     WEND
92.  
93.     IF _MOUSEBUTTON(1) THEN MBS = MBS OR 1
94.     IF _MOUSEBUTTON(2) THEN MBS = MBS OR 2
95.     IF _MOUSEBUTTON(3) THEN MBS = MBS OR 4
96.  
97.     IF StartTimer = 0 THEN
98.         IF _MOUSEBUTTON(1) THEN 'If a button is pressed, start the timer to see what it does (click or hold)
99.             ButtonDown = 1: StartTimer = TIMER(0.01)
100.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
101.         ELSEIF _MOUSEBUTTON(2) THEN
102.             ButtonDown = 2: StartTimer = TIMER(0.01)
103.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
104.         ELSEIF _MOUSEBUTTON(3) THEN
105.             ButtonDown = 3: StartTimer = TIMER(0.01)
106.             Mouse_StartX = _MOUSEX: Mouse_StartY = _MOUSEY
107.         END IF
108.     ELSE
109.         BD = ButtonDown MOD 3
110.         IF BD = 0 THEN BD = 3
111.         IF TIMER(0.01) - StartTimer <= ClickLimit THEN 'Button was down, then up, within time limit.  It's a click
112.             IF _MOUSEBUTTON(BD) = 0 THEN MBS = 4 * 2 ^ ButtonDown: ButtonDown = 0: StartTimer = 0
113.         ELSE
114.             IF _MOUSEBUTTON(BD) = 0 THEN 'hold event has now ended
115.                 MBS = 0: ButtonDown = 0: StartTimer = 0
116.                 Mouse_EndX = _MOUSEX: Mouse_EndY = _MOUSEY
117.             ELSE 'We've now started the hold event
118.                 MBS = MBS OR 32 * 2 ^ ButtonDown
119.             END IF
120.         END IF
121.     END IF
122. END FUNCTION 'MBS%
123.  
124. SUB FCirc (CX AS INTEGER, CY AS INTEGER, RR AS INTEGER, C AS _UNSIGNED LONG)
125.  
126.     'Steve's circle draw
127.     DIM R AS INTEGER, RError AS INTEGER
128.     DIM X AS INTEGER, Y AS INTEGER
129.     R = ABS(RR)
130.     RError = -R
131.     X = R
132.     Y = 0
133.     IF R = 0 THEN PSET (CX, CY), C: EXIT SUB
134.     LINE (CX - X, CY)-(CX + X, CY), C, BF
135.     WHILE X > Y
136.         RError = RError + Y * 2 + 1
137.         IF RError >= 0 THEN
138.             IF X <> Y + 1 THEN
139.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
140.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
141.             END IF
142.             X = X - 1
143.             RError = RError - X * 2
144.         END IF
145.         Y = Y + 1
146.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
147.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
148.     WEND
149.  
150. END SUB 'FCirc
151.  

[jack]

you may be able to use a custom cursor using Windows API, perhaps  SpriggsySpriggs could help
here's example code in Pete's favorite language https://www.freebasic.net/forum/viewtopic.php?p=189138#p189138
perhaps someone could adapt that to QB64