Floyd–Steinberg dithering

[_vince]

implementation of https://en.wikipedia.org/wiki/Floyd%E2%80%93Steinberg_dithering

Code: QB64: [Select]

1. deflng a-z
2.  
3. img1 = _loadimage("img/zmago.jpg", 32)
4.  
5. w = _width(img1)
6. h = _height(img1)
7.  
8. img2 = _newimage(w, h, 32)
9. img3 = _newimage(w, h, 32)
10. img4 = _newimage(w, h, 32)
11.  
12. screen _newimage(w*2, h*2, 32)
13.  
14. dither_bw img1, img2, 0.1
15.  
16. dither img1, img3, 2
17. dither img1, img4, 4
18.  
19. _dest 0
20. _putimage (0, 0), img1
21. _putimage (w, 0), img2
22. _putimage (0, h), img3
23. _putimage (w, h), img4
24.  
25. do
26. loop until _keyhit=27
27. system
28.  
29. 'colour dither
30. 'source image, destination image, number of colours per channel
31. sub dither(img1, img2, num)
32.         w = _width(img1)
33.         h = _height(img1)
34.  
35.         _dest img2
36.         _source img2
37.  
38.         _putimage , img1
39.  
40.         for y=0 to h-1
41.         for x=0 to w-1
42.  
43.                 z = point(x, y)
44.  
45.                 r = (_red(z)*num\255)*255\num
46.                 g = (_green(z)*num\255)*255\num
47.                 b = (_blue(z)*num\255)*255\num
48.  
49.                 pset (x, y), _rgb(r, g, b)
50.  
51.                 qr = _red(z) - r
52.                 qg = _green(z) - g
53.                 qb = _blue(z) - b
54.  
55.                 r = _red(point(x + 1, y)) +   qr*7/16
56.                 g = _green(point(x + 1, y)) + qg*7/16
57.                 b = _blue(point(x + 1, y)) +  qb*7/16
58.                 pset (x + 1, y), _rgb(r, g, b)
59.  
60.                 r = _red(point(x - 1, y + 1)) +   qr*3/16
61.                 g = _green(point(x - 1, y + 1)) + qg*3/16
62.                 b = _blue(point(x - 1, y + 1)) +  qb*3/16
63.                 pset (x - 1, y + 1), _rgb(r, g, b)
64.  
65.                 r = _red(point(x, y + 1)) +   qr*5/16
66.                 g = _green(point(x, y + 1)) + qg*5/16
67.                 b = _blue(point(x, y + 1)) +  qb*5/16
68.                 pset (x, y + 1), _rgb(r, g, b)
69.  
70.                 r = _red(point(x + 1, y + 1)) +   qr*1/16
71.                 g = _green(point(x + 1, y + 1)) + qg*1/16
72.                 b = _blue(point(x + 1, y + 1)) +  qb*1/16
73.                 pset (x + 1, y + 1), _rgb(r, g, b)
74.         next
75.         next
76. end sub
77.  
78. 'black and white dither
79. 'source image, destination image, bw threshold percent
80. sub dither_bw(img1, img2, t as double)
81.         w = _width(img1)
82.         h = _height(img1)
83.  
84.         _dest img2
85.         _source img2
86.  
87.         _putimage , img1
88.  
89.         for y=0 to h-1
90.         for x=0 to w-1
91.  
92.                 z = point(x, y)
93.  
94.                 c = -((_red(z)+_green(z)+_blue(z))/3 > 255*t)*255
95.  
96.                 pset (x, y), _rgb(c, c, c)
97.  
98.                 qr = _red(z) - c
99.                 qg = _green(z) - c
100.                 qb = _blue(z) - c
101.  
102.                 r = _red(point(x + 1, y)) +   qr*7/16
103.                 g = _green(point(x + 1, y)) + qg*7/16
104.                 b = _blue(point(x + 1, y)) +  qb*7/16
105.                 pset (x + 1, y), _rgb(r, g, b)
106.  
107.                 r = _red(point(x - 1, y + 1)) +   qr*3/16
108.                 g = _green(point(x - 1, y + 1)) + qg*3/16
109.                 b = _blue(point(x - 1, y + 1)) +  qb*3/16
110.                 pset (x - 1, y + 1), _rgb(r, g, b)
111.  
112.                 r = _red(point(x, y + 1)) +   qr*5/16
113.                 g = _green(point(x, y + 1)) + qg*5/16
114.                 b = _blue(point(x, y + 1)) +  qb*5/16
115.                 pset (x, y + 1), _rgb(r, g, b)
116.  
117.                 r = _red(point(x + 1, y + 1)) +   qr*1/16
118.                 g = _green(point(x + 1, y + 1)) + qg*1/16
119.                 b = _blue(point(x + 1, y + 1)) +  qb*1/16
120.                 pset (x + 1, y + 1), _rgb(r, g, b)
121.         next
122.         next
123. end sub
124.  

[bplus]

Hi v,

This is very interesting. Can an image be so modified that it is recognizable with just the black dot pattern? or would the dot sizes have to be increased?

[RhoSigma]

Maybe some interresting reading for you to dive deeper into dithering: http://www.tannerhelland.com/4660/dithering-eleven-algorithms-source-code/

[_vince]

Maybe some interresting reading for you to dive deeper into dithering: http://www.tannerhelland.com/4660/dithering-eleven-algorithms-source-code/

I have added support for arbitrary error diffusion matrices so you can now use 9 out of those in the page.  Or try to invent your own error diffusion matrix.  Usage should be clear from the code. Screenshots shows each matrix for black&white, 2*3 colors, and 4*3 colors.

Code: QB64: [Select]

1. deflng a-z
2.  
3. img1 = _loadimage("img/zmago.jpg", 32)
4.  
5. w = _width(img1)
6. h = _height(img1)
7.  
8. img2 = _newimage(w, h, 32)
9. img3 = _newimage(w, h, 32)
10. img4 = _newimage(w, h, 32)
11.  
12. img5 = _newimage(w, h, 32)
13. img6 = _newimage(w, h, 32)
14. img7 = _newimage(w, h, 32)
15.  
16. img8 = _newimage(w, h, 32)
17. img9 = _newimage(w, h, 32)
18. img10 = _newimage(w, h, 32)
19.  
20. screen _newimage(w*3, h*3, 32)
21.  
22. redim h(2, 1) as single
23. h(0,0)=0:h(1,0)=-1:h(2,0)=7/16
24. h(0,1)=3/16:h(1,1)=5/16:h(2,1)=1/16
25.  
26. dither_bw img1, img2, 0.1, h()
27. dither img1, img3, 2, h()
28. dither img1, img4, 4, h()
29.  
30. redim h(4, 2) as single
31. h(0,0)=0:h(1,0)=0:h(2,0)=-1:h(3,0)=7/48:h(4,0)=5/48
32. h(0,1)=3/48:h(1,1)=5/48:h(2,1)=7/48:h(3,1)=5/48:h(4,1)=3/48
33. h(0,2)=1/48:h(1,2)=3/48:h(2,2)=5/48:h(3,2)=3/48:h(4,2)=1/48
34.  
35. dither_bw img1, img5, 0.1, h()
36. dither img1, img6, 2, h()
37. dither img1, img7, 4, h()
38.  
39. redim h(3, 2) as single
40. h(0,0)=0:h(1,0)=-1:h(2,0)=1/8:h(3,0)=1/8
41. h(0,1)=1/8:h(1,1)=1/8:h(2,1)=1/8:h(3,1)=0
42. h(0,2)=0:h(1,2)=1/8:h(2,2)=0:h(3,2)=0
43.  
44. dither_bw img1, img8, 0.1, h()
45. dither img1, img9, 2, h()
46. dither img1, img10, 4, h()
47.  
48. _dest 0
49. _putimage (0, 0), img2
50. _putimage (w, 0), img3
51. _putimage (2*w, 0), img4
52. _printstring (0,0),"Floyd-Steinberg"
53.  
54. _putimage (0, h), img5
55. _putimage (w, h), img6
56. _putimage (2*w, h), img7
57. _printstring (0,h),"Jarvis, Judice, and Ninke"
58.  
59. _putimage (0, 2*h), img8
60. _putimage (w, 2*h), img9
61. _putimage (2*w, 2*h), img10
62. _printstring (0,2*h),"Atkinson"
63.  
64.  
65. do
66. loop until _keyhit=27
67. system
68.  
69. 'colour dither
70. 'source image, destination image, number of colours per channel, diffusion matrix
71. sub dither(img1, img2, num, h() as single)
72.         w = _width(img1)
73.         h = _height(img1)
74.  
75.         _dest img2
76.         _source img2
77.  
78.         _putimage , img1
79.  
80.         for y=0 to h-1
81.         for x=0 to w-1
82.  
83.                 z = point(x, y)
84.  
85.                 r = (_red(z)*num\255)*255\num
86.                 g = (_green(z)*num\255)*255\num
87.                 b = (_blue(z)*num\255)*255\num
88.  
89.                 pset (x, y), _rgb(r, g, b)
90.  
91.                 qr = _red(z) - r
92.                 qg = _green(z) - g
93.                 qb = _blue(z) - b
94.  
95.                 conv_ed img2, x, y, h(), qr, qg, qb
96.         next
97.         next
98. end sub
99.  
100. 'black and white dither
101. 'source image, destination image, bw threshold percent, diffusion matrix
102. sub dither_bw(img1, img2, t as double, h() as single)
103.         w = _width(img1)
104.         h = _height(img1)
105.  
106.         _dest img2
107.         _source img2
108.  
109.         _putimage , img1
110.  
111.         for y=0 to h-1
112.         for x=0 to w-1
113.  
114.                 z = point(x, y)
115.  
116.                 c = -((_red(z)+_green(z)+_blue(z))/3 > 255*t)*255
117.  
118.                 pset (x, y), _rgb(c, c, c)
119.  
120.                 qr = _red(z) - c
121.                 qg = _green(z) - c
122.                 qb = _blue(z) - c
123.  
124.                 conv_ed img2, x, y, h(), qr, qg, qb
125.         next
126.         next
127. end sub
128.  
129. sub conv_ed(img, x0, y0, h() as single, qr, qg, qb)
130.         for y=0 to ubound(h,2)
131.         for x=0 to ubound(h,1)
132.                 if h(x,y)=-1 then
133.                         xx = x
134.                         yy = y
135.                 end if
136.         next
137.         next
138.  
139.         _source img
140.         _dest img
141.  
142.         for y=0 to ubound(h,2)
143.         for x=0 to ubound(h,1)
144.                 if h(x,y)<>-1 and h(x,y)<>0 then
145.                         r = _red(point(x0-xx+x, y0-yy+y)) + qr*h(x,y)
146.                         g = _green(point(x0-xx+x, y0-yy+y)) + qg*h(x,y)
147.                         b = _blue(point(x0-xx+x, y0-yy+y)) + qb*h(x,y)
148.  
149.                         pset (x0-xx+x, y0-yy+y), _rgb(r, g, b)
150.                 end if
151.         next
152.         next
153. end sub
154.  

[_vince]

FYI, here are the non-dithered downsampled versions of the image.