« previous next »
Pages: [1]   Go Down

Author Topic: 3D Bouncing Balls (GL) - Historical Copy  (Read 4706 times)

0 Members and 1 Guest are viewing this topic.

Offline Qwerkey

  • Forum Resident
  • Posts: 755
    • View Profile
3D Bouncing Balls (GL) - Historical Copy
« on: July 15, 2018, 07:52:00 am »
This program simulates coloured balls moving and colliding.  It is a copy of my program which first appeared on [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there], and there is nothing changed or added.  It is copied here because [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] is now non-existent.

The 3D full perspective visualisation is enhanced by making the actual balls 3D shapes.  The 2D ball image is mapped via _MAPTRIANGLE to an actual spherical shape.  You will notice that this method has the effect of distorting the ball shape, especially at distances from the centre of the screen.  This arises because of the vanishing-point perspective used in _MAPTIANGLE(3D).

Esc to quit the program.

Richard

Code: QB64: [Select]
  1. ' 3D Bouncing Balls Using _MAPTRIANGLE by QWERKEY (Richard Notley) 21/04/18
  2.  
  3. ' Cyperium method for sphere image
  4.  
  5. CONST True = -1`, False = 0`
  6. _TITLE "3D Bouncing Balls"
  8.  
  9. CONST NoBalls%% = 10, Uscreen% = 1000, Vscreen% = 800, NoPhis%% = 16, NoAlphas%% = 6, XBright! = 0.5
  10. CONST Pi! = 4 * ATN(1), Rad1%% = 25, PerspDist% = 550, DeltaSepn! = 0.25 'small offset to stop balls sticking
  11. CONST Alpha! = Pi! / (2 * NoAlphas%%), Phi! = 2 * Pi! / NoPhis%%
  12. DIM BallStats!(NoBalls%% - 1, 9), ViewOrder%%(NoBalls%% - 1), Cyperium&(NoBalls%% - 1)
  13. DIM MapConv%(NoPhis%%, NoAlphas%%, 1, 2)
  14.  
  15. 'Conversion from 2D
  16. FOR N%% = 0 TO NoPhis%%
  17.     FOR M%% = 0 TO NoAlphas%%
  18.         MapConv%(N%%, M%%, 0, 0) = 128 + CINT(127 * SIN((Pi! / 2) - M%% * Alpha!) * COS(N%% * Phi!))
  19.         MapConv%(N%%, M%%, 0, 1) = 128 + CINT(127 * SIN((Pi! / 2) - M%% * Alpha!) * SIN(N%% * Phi!))
  20.         MapConv%(N%%, M%%, 1, 0) = CINT(Rad1%% * SIN((Pi! / 2) - M%% * Alpha!) * COS(N%% * Phi!))
  21.         MapConv%(N%%, M%%, 1, 1) = CINT(Rad1%% * SIN((Pi! / 2) - M%% * Alpha!) * SIN(N%% * Phi!))
  22.         MapConv%(N%%, M%%, 1, 2) = CINT(Rad1%% * COS((Pi! / 2) - M%% * Alpha!))
  23.     NEXT M%%
  24. NEXT N%%
  25.  
  26. 'Screen Background
  27. TempImage& = _NEWIMAGE(Uscreen%, Vscreen%, 32)
  28. _DEST TempImage&
  29. COLOR _RGB(255, 255, 255), _RGB(10, 60, 60)
  31. FOR UCol% = 0 TO Uscreen% - 1
  32.     FOR VCol% = 0 TO Vscreen% - 1
  33.         PSET (UCol%, VCol%), _RGB(100, INT(180 * UCol% / Uscreen%), INT(180 * VCol% / Vscreen%))
  34.     NEXT VCol%
  35. NEXT UCol%
  36. Background& = MakeHardware&(TempImage&)
  37.  
  38. 'Set array for depth order
  39. JumpStart%% = 1
  40. WHILE JumpStart%% <= NoBalls%%: JumpStart%% = JumpStart%% * 2: WEND
  41. FOR N%% = 0 TO NoBalls%% - 1
  42.     ViewOrder%%(N%%) = N%%
  43. NEXT N%%
  44.  
  45. ' Define characteristics of balls
  46. DATA 255,0,0
  47. DATA 219,80,0
  48. DATA 150,100,0
  49. DATA 138,117,0
  50. DATA 80,155,20
  51. DATA 0,255,0
  52. DATA 20,135,100
  53. DATA 0,105,150
  54. DATA 0,60,150
  55. DATA 0,0,255
  56. FOR N%% = 0 TO NoBalls%% - 1
  57.     'Ball mass
  58.     BallStats!(N%%, 0) = 0.1 + (0.8 * N%% / (NoBalls%% - 1))
  59.     IF BallStats!(N%%, 0) = 0 THEN BallStats!(N%%, 0) = 0.000001
  60.     'Ball colours (temporarily use (N%%,1,2,3)
  61.     FOR P%% = 1 TO 3
  62.         READ BallStats!(N%%, P%%)
  63.     NEXT P%%
  64.     TempImage& = _NEWIMAGE(256, 256, 32)
  65.     _DEST TempImage&
  66.     COLOR _RGB(BallStats!(N%%, 1), BallStats!(N%%, 2), BallStats!(N%%, 3)), _RGBA(0, 0, 0, 0)
  67.     'Image data goes from 1 to 255 (not 0 to 255)
  68.     FOR Z% = 128 TO 255
  69.         FOR X% = 1 TO 255
  70.             FOR Y% = 1 TO 255
  71.                 DeltaX% = X% - 127
  72.                 DeltaY% = Y% - 127
  73.                 DeltaZ% = Z% - 127
  74.                 Dist! = SQR((DeltaX% * DeltaX%) + (DeltaY% * DeltaY%) + (DeltaZ% * DeltaZ%))
  75.                 IF Dist! > 125 AND Dist! < 127 THEN PSET (X%, Y%), _RGB(CINT(Z% * BallStats!(N%%, 1) * (1 - (XBright! * X% / 255)) / 255), CINT(Z% * BallStats!(N%%, 2) * (1 - (XBright! * X% / 255)) / 255), CINT(Z% * BallStats!(N%%, 3) * (1 - (XBright! * X% / 255)) / 255))
  76.             NEXT
  77.         NEXT
  78.     NEXT
  79.     Cyperium&(N%%) = MakeHardware&(TempImage&)
  80.     'Ball positions/velocities
  81.     FOR P%% = 4 TO 6
  82.         BallStats!(N%%, P%%) = (0.5 - RND) * 1000
  83.     NEXT P%%
  84.     FOR P%% = 7 TO 9
  85.         Velocity! = 0.5 - RND
  86.         IF Velocity! < 0 THEN
  87.             Velocity! = Velocity! - 0.5
  88.         ELSE
  89.             Velocity! = Velocity! + 0.5
  90.         END IF
  91.         BallStats!(N%%, P%%) = Velocity! * 3
  92.     NEXT P%%
  93. NEXT N%%
  94.  
  95. 'Create screen
  96. SCREEN _NEWIMAGE(Uscreen%, Vscreen%, 32)
  99. _DISPLAYORDER _HARDWARE 'do not even render the software layer, just the hardware one.
  100.  
  101. 'Initialise axes and rotations
  102. ZRot! = (RND - 0.5) * 0.0011: YRot! = (RND - 0.5) * 0.0011: XRot! = (RND - 0.5) * 0.0011
  103. ZTime% = 15 + INT(47 * RND): YTime%% = 15 + INT(47 * RND): XTime% = 15 + INT(47 * RND)
  104. ZStart! = TIMER: YStart! = TIMER: XStart! = TIMER
  105. Zaxis! = 0: Yaxis! = 0: Xaxis! = 0
  106. Stereo` = True
  107.  
  108. WHILE Stereo`
  109.     _LIMIT 120 'Game Frames/Second Rate
  110.  
  111.     _PUTIMAGE (0, 0), Background&
  112.  
  113.     'Calculate moves
  114.     FOR N%% = 0 TO NoBalls%% - 1
  115.         FOR P%% = 1 TO 3
  116.             BallStats!(N%%, 3 + P%%) = BallStats!(N%%, 3 + P%%) + BallStats!(N%%, 6 + P%%)
  117.         NEXT P%%
  118.     NEXT N%%
  119.  
  120.     'Check for collsions
  121.     FOR N%% = 0 TO NoBalls%% - 2
  122.         FOR M%% = N%% + 1 TO NoBalls%% - 1
  123.             SepnSqd! = (BallStats!(N%%, 4) - BallStats!(M%%, 4)) * (BallStats!(N%%, 4) - BallStats!(M%%, 4)) + (BallStats!(N%%, 5) - BallStats!(M%%, 5)) * (BallStats!(N%%, 5) - BallStats!(M%%, 5)) + (BallStats!(N%%, 6) - BallStats!(M%%, 6)) * (BallStats!(N%%, 6) - BallStats!(M%%, 6))
  124.             IF SepnSqd! <= 4 * Rad1%% * Rad1%% THEN
  125.                 ' Set new velocities
  126.                 Multiplier! = 0: NDist! = 0: MDist! = 0
  127.                 FOR P%% = 1 TO 3
  128.                     Multiplier! = Multiplier! + (BallStats!(N%%, 6 + P%%) - BallStats!(M%%, 6 + P%%)) * (BallStats!(N%%, 3 + P%%) - BallStats!(M%%, 3 + P%%))
  129.                     NDist! = NDist! + BallStats!(N%%, 3 + P%%) * BallStats!(N%%, 3 + P%%)
  130.                     MDist! = MDist! + BallStats!(M%%, 3 + P%%) * BallStats!(M%%, 3 + P%%)
  131.                 NEXT P%%
  132.                 NDist! = SQR(NDist!)
  133.                 MDist! = SQR(MDist!)
  134.                 Multiplier! = 2 * Multiplier! / (SepnSqd! * (BallStats!(N%%, 0) + BallStats!(M%%, 0)))
  135.                 FOR P%% = 1 TO 3
  136.                     SepnVect! = BallStats!(N%%, 3 + P%%) - BallStats!(M%%, 3 + P%%)
  137.                     BallStats!(N%%, 6 + P%%) = BallStats!(N%%, 6 + P%%) - (Multiplier! * BallStats!(M%%, 0) * SepnVect!)
  138.                     BallStats!(M%%, 6 + P%%) = BallStats!(M%%, 6 + P%%) + (Multiplier! * BallStats!(N%%, 0) * SepnVect!)
  139.                     IF NDist! > MDist! THEN
  140.                         BallStats!(M%%, 3 + P%%) = BallStats!(M%%, 3 + P%%) - (DeltaSepn! * (BallStats!(N%%, 3 + P%%) - BallStats!(M%%, 3 + P%%)) / SQR(SepnSqd!))
  141.                     ELSE
  142.                         BallStats!(N%%, 3 + P%%) = BallStats!(N%%, 3 + P%%) + (DeltaSepn! * (BallStats!(N%%, 3 + P%%) - BallStats!(M%%, 3 + P%%)) / SQR(SepnSqd!))
  143.                     END IF
  144.                 NEXT P%%
  145.             END IF
  146.         NEXT M%%
  147.     NEXT N%%
  148.  
  149.     'Look for reflection off sides
  150.     FOR N%% = 0 TO NoBalls%% - 1
  151.         FOR P%% = 1 TO 3
  152.             IF BallStats!(N%%, 3 + P%%) > 500 - Rad1%% THEN
  153.                 BallStats!(N%%, 6 + P%%) = -BallStats!(N%%, 6 + P%%)
  154.                 IF BallStats!(N%%, 3 + P%%) + BallStats!(N%%, 6 + P%%) > 500 - Rad1%% THEN
  155.                     BallStats!(N%%, 3 + P%%) = BallStats!(N%%, 3 + P%%) - DeltaSepn!
  156.                 END IF
  157.             ELSEIF BallStats!(N%%, 3 + P%%) < -500 + Rad1%% THEN
  158.                 BallStats!(N%%, 6 + P%%) = -BallStats!(N%%, 6 + P%%)
  159.                 IF BallStats!(N%%, 3 + P%%) + BallStats!(N%%, 6 + P%%) < -500 + Rad1%% THEN
  160.                     BallStats!(N%%, 3 + P%%) = BallStats!(N%%, 3 + P%%) + DeltaSepn!
  161.                 END IF
  162.             END IF
  163.         NEXT P%%
  164.     NEXT N%%
  165.  
  166.     'Adjust for angle of rotation
  167.     FOR N%% = 0 TO NoBalls%% - 1
  168.         R2! = SQR(BallStats!(N%%, 4) * BallStats!(N%%, 4) + BallStats!(N%%, 5) * BallStats!(N%%, 5) + BallStats!(N%%, 6) * BallStats!(N%%, 6))
  169.         Theta2! = _ACOS(BallStats!(N%%, 6) / R2!)
  170.         Phi2! = _ATAN2(BallStats!(N%%, 5), BallStats!(N%%, 4)) + Zaxis!
  171.         BallStats!(N%%, 1) = R2! * SIN(Theta2!) * COS(Phi2!)
  172.         BallStats!(N%%, 2) = R2! * SIN(Theta2!) * SIN(Phi2!)
  173.         BallStats!(N%%, 3) = R2! * COS(Theta2!)
  174.         R2! = SQR(BallStats!(N%%, 1) * BallStats!(N%%, 1) + BallStats!(N%%, 2) * BallStats!(N%%, 2) + BallStats!(N%%, 3) * BallStats!(N%%, 3))
  175.         Theta2! = _ACOS(BallStats!(N%%, 1) / R2!)
  176.         Phi2! = _ATAN2(BallStats!(N%%, 3), BallStats!(N%%, 2)) + Xaxis!
  177.         BallStats!(N%%, 2) = R2! * SIN(Theta2!) * COS(Phi2!)
  178.         BallStats!(N%%, 3) = R2! * SIN(Theta2!) * SIN(Phi2!)
  179.         BallStats!(N%%, 1) = R2! * COS(Theta2!)
  180.         R2! = SQR(BallStats!(N%%, 1) * BallStats!(N%%, 1) + BallStats!(N%%, 2) * BallStats!(N%%, 2) + BallStats!(N%%, 3) * BallStats!(N%%, 3))
  181.         Theta2! = _ACOS(BallStats!(N%%, 2) / R2!)
  182.         Phi2! = _ATAN2(BallStats!(N%%, 1), BallStats!(N%%, 3)) + Yaxis!
  183.         BallStats!(N%%, 3) = CINT(R2! * SIN(Theta2!) * COS(Phi2!))
  184.         BallStats!(N%%, 1) = CINT(R2! * SIN(Theta2!) * SIN(Phi2!))
  185.         BallStats!(N%%, 2) = CINT(R2! * COS(Theta2!))
  186.     NEXT N%%
  187.  
  188.     'Change display order: furthest first
  189.     Jump%% = JumpStart%%
  190.     WHILE Jump%% > 1
  191.         Jump%% = (Jump%% - 1) \ 2
  192.         DoneHere` = False
  193.         WHILE NOT DoneHere`
  194.             DoneHere` = True
  195.             FOR Upper%% = 1 TO NoBalls%% - Jump%%
  196.                 Lower%% = Upper%% + Jump%%
  197.                 'BallStats! z-dim
  198.                 IF BallStats!(ViewOrder%%(Upper%% - 1), 3) > BallStats!(ViewOrder%%(Lower%% - 1), 3) THEN
  199.                     SWAP ViewOrder%%(Upper%% - 1), ViewOrder%%(Lower%% - 1)
  200.                     DoneHere` = False
  201.                 END IF
  202.             NEXT Upper%%
  203.         WEND
  204.     WEND
  205.  
  206.     'Display balls
  207.     FOR N1%% = NoBalls%% - 1 TO 0 STEP -1
  208.         P%% = ViewOrder%%(N1%%)
  209.         '_PUTIMAGE (BallStats!(P%%, 1) + 500, BallStats!(P%%, 2) + 400), Cyperium&(P%%)
  210.         'Ball views done with _MAPTRIANGLE 3D
  211.         FOR N%% = 0 TO NoPhis%% - 1
  212.             FOR M%% = 0 TO NoAlphas%% - 2
  213.                 Ax% = MapConv%(N%%, M%%, 1, 0) + BallStats!(P%%, 1)
  214.                 Ay% = MapConv%(N%%, M%%, 1, 1) + BallStats!(P%%, 2)
  215.                 Az% = MapConv%(N%%, M%%, 1, 2) + BallStats!(P%%, 3) - PerspDist%
  216.                 Bx% = MapConv%(N%%, M%% + 1, 1, 0) + BallStats!(P%%, 1)
  217.                 By% = MapConv%(N%%, M%% + 1, 1, 1) + BallStats!(P%%, 2)
  218.                 Bz% = MapConv%(N%%, M%% + 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%
  219.                 Cx% = MapConv%(N%% + 1, M%% + 1, 1, 0) + BallStats!(P%%, 1)
  220.                 Cy% = MapConv%(N%% + 1, M%% + 1, 1, 1) + BallStats!(P%%, 2)
  221.                 Cz% = MapConv%(N%% + 1, M%% + 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%
  222.                 _MAPTRIANGLE (MapConv%(N%%, M%%, 0, 0), MapConv%(N%%, M%%, 0, 1))-(MapConv%(N%%, M%% + 1, 0, 0), MapConv%(N%%, M%% + 1, 0, 1))-(MapConv%(N%% + 1, M%% + 1, 0, 0), MapConv%(N%% + 1, M%% + 1, 0, 1)), Cyperium&(P%%) TO(Ax%, Ay%, Az%)-(Bx%, By%, Bz%)-(Cx%, Cy%, Cz%)
  223.                 _MAPTRIANGLE (MapConv%(N%% + 1, M%% + 1, 0, 0), MapConv%(N%% + 1, M%% + 1, 0, 1))-(MapConv%(N%% + 1, M%%, 0, 0), MapConv%(N%% + 1, M%%, 0, 1))-(MapConv%(N%%, M%%, 0, 0), MapConv%(N%%, M%%, 0, 1)), Cyperium&(P%%) TO(Cx%, Cy%, Cz%)-(MapConv%(N%% + 1, M%%, 1, 0) + BallStats!(P%%, 1), MapConv%(N%% + 1, M%%, 1, 1) + BallStats!(P%%, 2), MapConv%(N%% + 1, M%%, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(Ax%, Ay%, Az%)
  224.                 '_MAPTRIANGLE (MapConv%(N%%, M%%, 0, 0), MapConv%(N%%, M%%, 0, 1))-(MapConv%(N%%, M%% + 1, 0, 0), MapConv%(N%%, M%% + 1, 0, 1))-(MapConv%(N%% + 1, M%% + 1, 0, 0), MapConv%(N%% + 1, M%% + 1, 0, 1)), Cyperium&(P%%) TO(MapConv%(N%%, M%%, 1, 0) + BallStats!(P%%, 1), MapConv%(N%%, M%%, 1, 1) + BallStats!(P%%, 2), MapConv%(N%%, M%%, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(MapConv%(N%%, M%% + 1, 1, 0) + BallStats!(P%%, 1), MapConv%(N%%, M%% + 1, 1, 1) + BallStats!(P%%, 2), MapConv%(N%%, M%% + 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(MapConv%(N%% + 1, M%% + 1, 1, 0) + BallStats!(P%%, 1), MapConv%(N%% + 1, M%% + 1, 1, 1) + BallStats!(P%%, 2), MapConv%(N%% + 1, M%% + 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%)
  225.                 '_MAPTRIANGLE (MapConv%(N%% + 1, M%% + 1, 0, 0), MapConv%(N%% + 1, M%% + 1, 0, 1))-(MapConv%(N%% + 1, M%%, 0, 0), MapConv%(N%% + 1, M%%, 0, 1))-(MapConv%(N%%, M%%, 0, 0), MapConv%(N%%, M%%, 0, 1)), Cyperium&(P%%) TO(MapConv%(N%% + 1, M%% + 1, 1, 0) + BallStats!(P%%, 1), MapConv%(N%% + 1, M%% + 1, 1, 1) + BallStats!(P%%, 2), MapConv%(N%% + 1, M%% + 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(MapConv%(N%% + 1, M%%, 1, 0) + BallStats!(P%%, 1), MapConv%(N%% + 1, M%%, 1, 1) + BallStats!(P%%, 2), MapConv%(N%% + 1, M%%, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(MapConv%(N%%, M%%, 1, 0) + BallStats!(P%%, 1), MapConv%(N%%, M%%, 1, 1) + BallStats!(P%%, 2), MapConv%(N%%, M%%, 1, 2) + BallStats!(P%%, 3) - PerspDist%)
  226.             NEXT M%%
  227.             _MAPTRIANGLE (MapConv%(N%%, NoAlphas%% - 1, 0, 0), MapConv%(N%%, NoAlphas%% - 1, 0, 1))-(128, 128)-(MapConv%(N%% + 1, NoAlphas%% - 1, 0, 0), MapConv%(N%% + 1, NoAlphas%% - 1, 0, 1)), Cyperium&(P%%) TO(Bx%, By%, Bz%)-(BallStats!(P%%, 1), BallStats!(P%%, 2), BallStats!(P%%, 3) + Rad1%% - PerspDist%)-(Cx%, Cy%, Cz%)
  228.             '_MAPTRIANGLE (MapConv%(N%%, NoAlphas%% - 1, 0, 0), MapConv%(N%%, NoAlphas%% - 1, 0, 1))-(128, 128)-(MapConv%(N%% + 1, NoAlphas%% - 1, 0, 0), MapConv%(N%% + 1, NoAlphas%% - 1, 0, 1)), Cyperium&(P%%) TO(MapConv%(N%%, NoAlphas%% - 1, 1, 0) + BallStats!(P%%, 1), MapConv%(N%%, NoAlphas%% - 1, 1, 1) + BallStats!(P%%, 2), MapConv%(N%%, NoAlphas%% - 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%)-(BallStats!(P%%, 1), BallStats!(P%%, 2), BallStats!(P%%, 3) + Rad1%% - PerspDist%)-(MapConv%(N%% + 1, NoAlphas%% - 1, 1, 0) + BallStats!(P%%, 1), MapConv%(N%% + 1, NoAlphas%% - 1, 1, 1) + BallStats!(P%%, 2), MapConv%(N%% + 1, NoAlphas%% - 1, 1, 2) + BallStats!(P%%, 3) - PerspDist%)
  229.         NEXT N%%
  230.     NEXT N1%%
  231.  
  232.     'rotate around z- axis
  233.     Zaxis! = Zaxis! + ZRot!
  234.     IF Zaxis! > Pi! THEN
  235.         Zaxis! = Zaxis! - 2 * Pi!
  236.     ELSEIF Zaxis! < -Pi! THEN
  237.         Zaxis! = Zaxis! + 2 * Pi!
  238.     END IF
  239.  
  240.     'rotate around y- axis
  241.     Yaxis! = Yaxis! + YRot!
  242.     IF Yaxis! > Pi! THEN
  243.         Yaxis! = Yaxis! - 2 * Pi!
  244.     ELSEIF Yaxis! < -Pi! THEN
  245.         Yaxis! = Yaxis! + 2 * Pi!
  246.     END IF
  247.  
  248.     'rotate around x- axis
  249.     Xaxis! = Xaxis! + XRot!
  250.     IF Xaxis! > Pi! THEN
  251.         Xaxis! = Xaxis! - 2 * Pi!
  252.     ELSEIF Xaxis! < -Pi! THEN
  253.         Xaxis! = Xaxis! + 2 * Pi!
  254.     END IF
  255.  
  256.     IF TIMER > ZStart! + ZTime% THEN
  257.         ZRot! = (RND - 0.5) * 0.0011
  258.         ZTime% = 15 + INT(47 * RND)
  259.         ZStart! = TIMER
  260.         RANDOMIZE (ZStart!)
  261.     END IF
  262.     IF TIMER > YStart! + YTime%% THEN
  263.         YRot! = (RND - 0.5) * 0.0011
  264.         YTime%% = 15 + INT(47 * RND)
  265.         YStart! = TIMER
  266.     END IF
  267.     IF TIMER > XStart! + XTime% THEN
  268.         XRot! = (RND - 0.5) * 0.0011
  269.         XTime% = 15 + INT(47 * RND)
  270.         XStart! = TIMER
  271.     END IF
  272.  
  273.     IF _KEYHIT = 27 THEN Stereo` = False 'Esc  to quit
  274.  
  275.     _DISPLAY
  276.  
  278.  
  280.  
  281. FUNCTION MakeHardware& (Imagename&)
  282.     MakeHardware& = _COPYIMAGE(Imagename&, 33)
  283.     _FREEIMAGE Imagename&
  285.  


« Last Edit: July 09, 2020, 07:47:01 am by Qwerkey »
Logged
Pages: [1]   Go Up
« previous next »