Author Topic: eRATication (Read 10798 times)

bplus · « **on:** July 13, 2018, 11:18:30 pm »

Astroids inspired, though I did similar in SmallBASIC with plasma ray shooter.

Code: QB64: [Select]

_TITLE "eRATication by bplus 2018-07-13"
'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
 
' 2018-07-13 modified from Asteroids game
 
'screen dimensions
CONST xmax = 1200
CONST ymax = 700
 
DIM SHARED pi
pi = _PI
 
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 100, 20
RANDOMIZE TIMER
 
CONST nRats = 100
CONST nBullets = 1000
CONST bSpeed = 20
 
'r for rat prefix have x, y location, r for radius, h for heading, s for speed, k for kolor
DIM SHARED rx(nRats), ry(nRats), rr(nRats), rh(nRats), rs(nRats), rk(nRats) AS _UNSIGNED LONG
DIM SHARED shooterAngle, shooterX, shooterY, life, points
'b prefix for bullet, x, y, dx, dy, a for active
DIM SHARED bx(nBullets), by(nBullets), bdx(nBullets), bdy(nBullets), ba(nBullets)
points = 0
FOR i = 1 TO 100
    newRat i
NEXT
life = 1
shooterX = xmax / 2: shooterY = ymax / 2
rats = 5
shooterAngle = 0
WHILE life <= 3
    CLS
    FOR i = 1 TO life * rats 'the rats
        drawRat i
    NEXT
 
    '    _KEYDOWN WORKS NICE!!!!
    'use arrow keys to swing shooter, spacebar to fire
    IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
    IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
    IF _KEYDOWN(18432) OR _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 30)
    IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
    drawshooter xmax / 2, ymax / 2, shooterAngle
 
    'handle bullets
    FOR i = 0 TO nBullets
        IF ba(i) = 0 AND fire = 1 THEN 'have in active bullet index to use
            bx(i) = shooterX + 3 * bSpeed * COS(shooterAngle)
            by(i) = shooterY + 3 * bSpeed * SIN(shooterAngle)
            bdx(i) = bSpeed * COS(shooterAngle)
            bdy(i) = bSpeed * SIN(shooterAngle)
            ba(i) = 1
            fire = 0
        END IF
        IF ba(i) = 1 THEN 'new location
            bx(i) = bx(i) + bdx(i)
            by(i) = by(i) + bdy(i)
            IF bx(i) > 0 AND bx(i) < xmax AND by(i) > 0 AND by(i) < ymax THEN 'in bounds draw it
                'check for collision with rock
                FOR r = 1 TO rats * life
                    IF ((rx(r) - bx(i)) ^ 2 + (ry(r) - by(i)) ^ 2) ^ .5 < .75 * rr(r) THEN
                        FOR rad = 1 TO rr(r)
                            fcirc rx(r), ry(r), rad, _RGB32(255 - rad, 128 - rad, 0)
                            _DISPLAY
                        NEXT
                        points = points + life ^ life
                        _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
                        _DISPLAY
                        newRat r
                        ba(i) = 0
                    ELSE
                        fcirc bx(i), by(i), 2, _RGB32(255, 255, 0)
                    END IF
                NEXT
            ELSE
                ba(i) = 0
            END IF
        END IF
    NEXT
    _DISPLAY
    _LIMIT 30
WEND
_DELAY 5
 
SUB drawshooter (x, y, radianAngle) 'simple red iso triangle pointed towards radianAngle
    'calculate 3 points of triangle shooter
    x1 = x + 60 * COS(radianAngle) 'main point of shooter according to heading
    y1 = y + 60 * SIN(radianAngle)
    x2 = x + 30 * COS(radianAngle + _PI(2 / 3)) 'next two points are 120 degrees off main point in direction
    y2 = y + 30 * SIN(radianAngle + _PI(2 / 3))
    x3 = x + 30 * COS(radianAngle - _PI(2 / 3))
    y3 = y + 30 * SIN(radianAngle - _PI(2 / 3))
    fTri x, y, x1, y1, x2, y2, _RGB(255, 0, 0)
    fTri x, y, x1, y1, x3, y3, _RGB(255, 0, 0)
    ln x1, y1, x2, y2, _RGB32(255, 255, 128)
    ln x1, y1, x3, y3, _RGB32(255, 255, 128)
    ln x1, y1, x, y, _RGB32(255, 255, 128)
END SUB
 
SUB drawRat (i)
    rx(i) = rx(i) + rs(i) * COS(rh(i) + RND * _PI(rand(-5, 5) / 10))
    ry(i) = ry(i) + rs(i) * SIN(rh(i) + RND * _PI(rand(-5, 5) / 10))
    'rat collides with shooter?
    IF ((rx(i) - shooterX) ^ 2 + (ry(i) - shooterY) ^ 2) ^ .5 < rr(i) + 20 THEN
        FOR rad = 1 TO 200
            fcirc shooterX, shooterY, rad, _RGB32(255 - rad, 255 - 2 * rad, 0)
            _DISPLAY
            _LIMIT 300
        NEXT
        life = life + 1
        IF life <= 3 THEN
            _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
        ELSE
            _TITLE "Rats Hit:" + STR$(points) + " THE END"
        END IF
        _DISPLAY
        newRat i
        EXIT SUB
    END IF
    IF rx(i) > 0 AND rx(i) < xmax AND ry(i) > 0 AND ry(i) < ymax THEN
        noseX = rx(i) + 2 * rr(i) * COS(rh(i))
        noseY = ry(i) + 2 * rr(i) * SIN(rh(i))
        neckX = rx(i) + .75 * rr(i) * COS(rh(i))
        neckY = ry(i) + .75 * rr(i) * SIN(rh(i))
        tailX = rx(i) + 2 * rr(i) * COS(rh(i) + _PI)
        tailY = ry(i) + 2 * rr(i) * SIN(rh(i) + _PI)
        earLX = rx(i) + rr(i) * COS(rh(i) - _PI(1 / 12))
        earLY = ry(i) + rr(i) * SIN(rh(i) - _PI(1 / 12))
        earRX = rx(i) + rr(i) * COS(rh(i) + _PI(1 / 12))
        earRY = ry(i) + rr(i) * SIN(rh(i) + _PI(1 / 12))
        fcirc rx(i), ry(i), .65 * rr(i), rk(i)
        fcirc neckX, neckY, rr(i) * .3, rk(i)
        fTri noseX, noseY, earLX, earLY, earRX, earRY, rk(i)
        fcirc earLX, earLY, rr(i) * .3, rk(i)
        fcirc earRX, earRY, rr(i) * .3, rk(i)
        wX = .5 * rr(i) * COS(rh(i) - _PI(11 / 18))
        wY = .5 * rr(i) * SIN(rh(i) - _PI(11 / 18))
        ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
        wX = .5 * rr(i) * COS(rh(i) - _PI(7 / 18))
        wY = .5 * rr(i) * SIN(rh(i) - _PI(7 / 18))
        ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
        ln rx(i), ry(i), tailX, tailY, rk(i)
    ELSE
        newRat i
    END IF
END SUB
 
SUB newRat (iRat)
    'bring rock in from one side, need to set heading according to side
    'RANDOMIZE TIMER + RND
    side = rand(1, 4)
    SELECT CASE side
        CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
        CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
        CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
        CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
    END SELECT
    'speed, angle, radius, gray coloring, spin, seed
    rs(iRat) = RND * 5 * life + 1
    rr(iRat) = RND * 55 + 15
    r = rand(60, 255)
    rk(iRat) = _RGB32(r, .9 * r, .8 * r)
END SUB
 
FUNCTION rand% (lo%, hi%)
    rand% = INT(RND * (hi% - lo% + 1)) + lo%
END FUNCTION
 
' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
SUB fTri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    PSET (0, 0), K
    _DEST 0
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
    _FREEIMAGE a& '<<< this is important!
END SUB
 
SUB ln (x1, y1, x2, y2, K AS _UNSIGNED LONG) 'box frame
    LINE (x1, y1)-(x2, y2), K
END SUB
 
'vince version
SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
    x0 = R
    y0 = 0
    e = 0
    DO WHILE y0 < x0
        IF e <= 0 THEN
            y0 = y0 + 1
            LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
            LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
            e = e + 2 * y0
        ELSE
            LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
            LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
            x0 = x0 - 1
            e = e - 2 * x0
        END IF
    LOOP
    LINE (x - R, y)-(x + R, y), C, BF
END SUB
 
 

bplus · « **Reply #1 on:** July 14, 2018, 07:23:21 am »

Code: QB64: [Select]

I ran your program (called it ratgame.bas) and defeated it by holding down UpArrow and Space and
let it run indefinitely and killed 100s of rats..
 
Erik.
 

Yeah, not exactly meant to be a game of skill... ;)

Life #1 easy peasy, 1 point per rat
Life #2 might work up a sweat, 4 points per rat
Life #3 Ha! 27 points per rat

bplus · « **Reply #2 on:** July 14, 2018, 07:33:17 am »

Yeah, so you CAN play this like a game of skill and try to kill one rat with one shot (or burst) PLUS you can just hose the rats off screen, very satisfying like popping bubble wrap. I won't judge which way you try. ;)

Petr · « **Reply #3 on:** July 14, 2018, 02:18:17 pm »

Nice work! :-D

bplus · « **Reply #4 on:** July 15, 2018, 09:01:48 am »

Thanks Petr, thanks to Erik's feedback, I hope to add a rat palette and track life/death of each rat so as to not delay action when one is hit. Perhaps if I just leave out poisoned cheese, no shooting would be necessary. ;D

Petr · « **Reply #5 on:** July 15, 2018, 09:06:20 am »

Bplus, I'll come to see TJP behind you and Erik.

bplus · « **Reply #6 on:** July 15, 2018, 02:37:56 pm »

Hi Petr,

I can keep you updated here.

Here is improvements suggested by Erik PLUS I made life #3 even harder to survive. ;D

Code: QB64: [Select]

_TITLE "eRATication no 2 by bplus 2018-07-15"
'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
 
' 2018-07-13 modified from Asteroids game
' 2018-07-15 eRATication 2
' color rats, eliminate jerks when kill rat,
' decrease rat size as life progresses
 
'screen dimensions
CONST xmax = 1200
CONST ymax = 700
 
DIM SHARED pi
pi = _PI
 
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 100, 20
RANDOMIZE TIMER
 
CONST nRats = 100
CONST nBullets = 1000
CONST bSpeed = 20
 
'r for rat prefix have x, y location, r for radius, h for heading, s for speed, k for kolor
DIM SHARED rx(nRats), ry(nRats), rr(nRats), rh(nRats), rs(nRats), rdead(nRats), rk(nRats) AS _UNSIGNED LONG
DIM SHARED shooterAngle, shooterX, shooterY, life, points, walk
'b prefix for bullet, x, y, dx, dy, a for active
DIM SHARED bx(nBullets), by(nBullets), bdx(nBullets), bdy(nBullets), ba(nBullets)
 
life = 1
rats = 5
points = 0
shooterAngle = 0
shooterX = xmax / 2
shooterY = ymax / 2
FOR i = 0 TO nRats - 1
    newRat i
NEXT
WHILE life <= 3
    CLS , _RGB32(188, 178, 168)
    walk = (walk + 1) MOD 2
    FOR i = 1 TO life * rats 'the rats
        drawRat i
    NEXT
 
    '    _KEYDOWN WORKS NICE!!!!
    'use arrow keys to swing shooter, spacebar to fire
    IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
    IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
    IF _KEYDOWN(18432) OR _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 30)
    IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
    drawshooter xmax / 2, ymax / 2, shooterAngle
 
    'handle bullets
    FOR i = 0 TO nBullets
        IF ba(i) = 0 AND fire = 1 THEN 'have in active bullet index to use
            bx(i) = shooterX + 3 * bSpeed * COS(shooterAngle)
            by(i) = shooterY + 3 * bSpeed * SIN(shooterAngle)
            bdx(i) = bSpeed * COS(shooterAngle)
            bdy(i) = bSpeed * SIN(shooterAngle)
            ba(i) = 1
            fire = 0
        END IF
        IF ba(i) = 1 THEN 'new location
            bx(i) = bx(i) + bdx(i)
            by(i) = by(i) + bdy(i)
            IF bx(i) > 0 AND bx(i) < xmax AND by(i) > 0 AND by(i) < ymax THEN 'in bounds draw it
                'check for collision with rock
                FOR r = 0 TO rats * life
                    IF ((rx(r) - bx(i)) ^ 2 + (ry(r) - by(i)) ^ 2) ^ .5 < .75 * rr(r) THEN
                        IF rdead(r) = 0 THEN
                            rdead(r) = 1
                            points = points + life ^ life
                            _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
                            ba(i) = 0
                        END IF
                    ELSE
                        fcirc bx(i), by(i), 2, _RGB32(30, 60, 80)
                    END IF
                NEXT
            ELSE
                ba(i) = 0
            END IF
        END IF
    NEXT
    _DISPLAY
    _LIMIT 30
WEND
_DELAY 5 'so don't start printing spaces in the editor
 
SUB drawshooter (x, y, radianAngle) 'simple red iso triangle pointed towards radianAngle
    'calculate 3 points of triangle shooter
    x1 = x + 60 * COS(radianAngle) 'main point of shooter according to heading
    y1 = y + 60 * SIN(radianAngle)
    x2 = x + 30 * COS(radianAngle + _PI(2 / 3)) 'next two points are 120 degrees off main point in direction
    y2 = y + 30 * SIN(radianAngle + _PI(2 / 3))
    x3 = x + 30 * COS(radianAngle - _PI(2 / 3))
    y3 = y + 30 * SIN(radianAngle - _PI(2 / 3))
    fTri x, y, x1, y1, x2, y2, _RGB(255, 0, 0)
    fTri x, y, x1, y1, x3, y3, _RGB(255, 0, 0)
    ln x1, y1, x2, y2, _RGB32(255, 255, 128)
    ln x1, y1, x3, y3, _RGB32(255, 255, 128)
    ln x1, y1, x, y, _RGB32(255, 255, 128)
END SUB
 
SUB drawRat (i)
    IF rdead(i) = 0 THEN 'if rat not dead move it
        rx(i) = rx(i) + rs(i) * COS(rh(i)) + rand(-.1 * rr(i), .1 * rr(i))
        ry(i) = ry(i) + rs(i) * SIN(rh(i)) + rand(-.1 * rr(i), .1 * rr(i))
    END IF
 
    'rat collides with shooter?
    IF ((rx(i) - shooterX) ^ 2 + (ry(i) - shooterY) ^ 2) ^ .5 < rr(i) + 20 THEN
        FOR rad = 1 TO 350
            fcirc shooterX, shooterY, rad, _RGB32(255 - .25 * rad, 128 - .125 * rad, 0)
            _DISPLAY
            _LIMIT 300
        NEXT
        life = life + 1
        'new set o rats
        FOR i = 0 TO nRats - 1
            newRat i
        NEXT
        IF life <= 3 THEN
            _TITLE "Rats Hit:" + STR$(points) + "   Life #" + STR$(life)
        ELSE
            _TITLE "Rats Hit:" + STR$(points) + " THE END"
            _DELAY 5 'so don't start printing spaces in the editor
            END
        END IF
        _DISPLAY
        EXIT SUB
    END IF
 
    IF rx(i) > 0 AND rx(i) < xmax AND ry(i) > 0 AND ry(i) < ymax THEN 'inbounds
        IF rdead(i) THEN 'show the burn out until reaches rat radius
            rdead(i) = rdead(i) + 2
            IF rdead(i) < rr(i) THEN
                fcirc rx(i), ry(i), rr(i) - rdead(i), _RGB32(255 - rdead(i), 128 - rdead(i), 0)
                _DISPLAY
            ELSE
                newRat i
            END IF
        ELSE
            noseX = rx(i) + 2 * rr(i) * COS(rh(i))
            noseY = ry(i) + 2 * rr(i) * SIN(rh(i))
            neckX = rx(i) + .75 * rr(i) * COS(rh(i))
            neckY = ry(i) + .75 * rr(i) * SIN(rh(i))
            tailX = rx(i) + 2 * rr(i) * COS(rh(i) + _PI)
            tailY = ry(i) + 2 * rr(i) * SIN(rh(i) + _PI)
            earLX = rx(i) + rr(i) * COS(rh(i) - _PI(1 / 12))
            earLY = ry(i) + rr(i) * SIN(rh(i) - _PI(1 / 12))
            earRX = rx(i) + rr(i) * COS(rh(i) + _PI(1 / 12))
            earRY = ry(i) + rr(i) * SIN(rh(i) + _PI(1 / 12))
            fcirc rx(i), ry(i), .65 * rr(i), rk(i)
            fcirc neckX, neckY, rr(i) * .3, rk(i)
            fTri noseX, noseY, earLX, earLY, earRX, earRY, rk(i)
            fcirc earLX, earLY, rr(i) * .3, rk(i)
            fcirc earRX, earRY, rr(i) * .3, rk(i)
            wX = .5 * rr(i) * COS(rh(i) - _PI(11 / 18))
            wY = .5 * rr(i) * SIN(rh(i) - _PI(11 / 18))
            ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
            wX = .5 * rr(i) * COS(rh(i) - _PI(7 / 18))
            wY = .5 * rr(i) * SIN(rh(i) - _PI(7 / 18))
            ln noseX + wX, noseY + wY, noseX - wX, noseY - wY, rk(i)
            ln rx(i), ry(i), tailX, tailY, rk(i)
        END IF
    ELSE 'out of bounds
        newRat i
    END IF
END SUB
 
SUB newRat (iRat)
    'bring rock in from one side, need to set heading according to side
    'RANDOMIZE TIMER + RND
    side = rand(1, 4)
    SELECT CASE side
        CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
        CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
        CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
        CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
    END SELECT
    'speed, angle, radius, gray coloring, spin, seed
    rs(iRat) = RND * 5 * life + 1
    rr(iRat) = RND * 60 / life + 10
    rdead(iRat) = 0
    rk(iRat) = ratKolor~&
END SUB
 
FUNCTION ratKolor~& ()
    r% = INT(RND * 140)
    g% = rand(INT(.5 * r%), INT(.8 * r%))
    b% = rand(INT(.5 * g%), INT(.8 * g%))
    ratKolor~& = _RGB32(r%, g%, b%)
END FUNCTION
 
FUNCTION rand% (lo%, hi%)
    rand% = INT(RND * (hi% - lo% + 1)) + lo%
END FUNCTION
 
' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
SUB fTri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    PSET (0, 0), K
    _DEST 0
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
    _FREEIMAGE a& '<<< this is important!
END SUB
 
SUB ln (x1, y1, x2, y2, K AS _UNSIGNED LONG) 'box frame
    LINE (x1, y1)-(x2, y2), K
END SUB
 
'vince version
SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
    x0 = R
    y0 = 0
    e = 0
    DO WHILE y0 < x0
        IF e <= 0 THEN
            y0 = y0 + 1
            LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
            LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
            e = e + 2 * y0
        ELSE
            LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
            LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
            x0 = x0 - 1
            e = e - 2 * x0
        END IF
    LOOP
    LINE (x - R, y)-(x + R, y), C, BF
END SUB
 
 

bplus · « **Reply #7 on:** July 15, 2018, 02:53:05 pm »

better gun action with arrows keys:

Code: QB64: [Select]

    '    _KEYDOWN WORKS NICE!!!!
    'use arrow keys to swing shooter, spacebar to fire
    IF _KEYDOWN(19200) THEN shooterAngle = shooterAngle - _PI(1 / 60)
    IF _KEYDOWN(19712) THEN shooterAngle = shooterAngle + _PI(1 / 60)
    IF _KEYDOWN(18432) THEN shooterAngle = shooterAngle - _PI(1 / 20)
    IF _KEYDOWN(20480) THEN shooterAngle = shooterAngle + _PI(1 / 20)
    IF _KEYDOWN(32) THEN fire = 1 ELSE fire = 0
    drawshooter xmax / 2, ymax / 2, shooterAngle
 

fast and slow swing both ways.

Petr · « **Reply #8 on:** July 15, 2018, 05:36:58 pm »

Nice! Strategy if i spin to right, is reliable, but small mice i have to shoot straight, they are monsters :-D

johnno56 · « **Reply #9 on:** July 15, 2018, 05:46:25 pm »

Oh. You noticed THAT too? Those sneaky little mongrels! You shoot at them with a hail of bullets, but NO, they're small enough to avoid getting hit and then "stab you in the back" when you least expect it!

B+. You have a mean streak within you. Clever but mean! lol

J

Ashish · « **Reply #10 on:** July 16, 2018, 03:55:18 am »

Nice game, bplus! Here's my highscore in the attachment.

bplus · « **Reply #11 on:** July 16, 2018, 09:04:53 am »

Thanks guys! your comments have me smiling and laughing.

Erik has done some interesting mods at TJP, slowing the bullet speed but doubling the bullets. He also has overridden the max life # of 3 to 10 input at the beginning of the game. He also is tracking high score adding a comma delimited score. Is he optimistic or what? ;) PLUS he is storing high scores to file using _STARTDIR$ keyword for current directory.

So up to 10 lives! ? He allows.

Let's take a closer look at how a new rat is started, Johnno you might get some ideas about taking the edge off my cruel streak. ;)

Code: QB64: [Select]

SUB newRat (iRat)
    'bring rock in from one side, need to set heading according to side
    'RANDOMIZE TIMER + RND
    side = rand(1, 4)
    SELECT CASE side
        CASE 1: rx(iRat) = 0: ry(iRat) = RND * ymax: rh(iRat) = 3 * pi / 2 + RND * pi
        CASE 2: rx(iRat) = xmax: ry(iRat) = RND * ymax: rh(iRat) = pi / 2 + RND * pi
        CASE 3: rx(iRat) = RND * xmax: ry(iRat) = 0: rh(iRat) = RND * pi
        CASE 4: rx(iRat) = RND * xmax: ry(iRat) = ymax: rh(iRat) = pi + RND * pi
    END SELECT
    'speed, angle, radius, gray coloring, spin, seed
    rs(iRat) = RND * 5 * life + 1    '<<<<<<<<<<<<<<<<<<<<<< rat speed is set here and adjusted according to life #
    rr(iRat) = RND * 60 / life + 10 ' <<<<<<<<<<<<<<<<<<<<<< rat radius or size of rat is set here and also adjusted according to life #
    rdead(iRat) = 0
    rk(iRat) = ratKolor~&
END SUB
 

With a range of life from 1 to 10 as Erik has it, rat speeds will vary from 1 to 6 in life #1 and 1 to 51 in life #10. 51!!!! Yikes!
With a range of life from 1 to 10 as Erik has it, rat radii will vary from 10 to 70 in life #1 and 10 to 16 in life #10

And the number of rats is 5 * life so start with 5 in life #1 and could go as high as 50 in life # 10.

I think if you really want to get into point systems if you are taking trouble to store High scores:
1. You should make a table for High Scores depending on the life # you choose to play.
2. You might start getting deductions for wasteful use of bullets ie skill starts to be factored into score.

Oh BTW if you are in life #10 and kill a rat that is worth 10 ^ 10 points! No wonder Erik starts to need a comma delimited score!

FellippeHeitor · « **Reply #12 on:** July 16, 2018, 11:03:21 am »

Very fun to play, bplus!

You may consider using the main canvas to show score/lives as the title bar doesn't update as reliably on Linux/macOS (if you intend to support those platforms as well).

bplus · « **Reply #13 on:** July 16, 2018, 11:58:40 pm »

Hi Fellippe, Thanks for feedback with Linux.

Cobalt · « **Reply #14 on:** July 17, 2018, 10:19:57 am »

very interesting game Bplus. I give it a B+!

One thing I noticed(least in the first version at top of the thread) is that you only hit the rats in the arse area, and the shot continues on after the hit.

A slight improvement to would be to have the explosions happen as part of the main loop so there is not that slight pause every time you make a kill, that may just be my old laptop causing it though. basically you have a explosion routine that is called each loop that makes the explosion grow a step. That way the explosions happen but the game doesn't pause, and it could even have multiple kills happening at once. kind of how my first (and only 100% completed) BASIC game , Space Dodger and the Giant Killer Space Hamsters, ran. a game lost to Geocities I'm afraid.

News:

Author Topic: eRATication (Read 10798 times)

bplus

eRATication

bplus

Re: eRATication

bplus

Re: eRATication

Petr

Re: eRATication

bplus

Re: eRATication

Petr

Re: eRATication

bplus

Re: eRATication

bplus

Re: eRATication

Petr

Re: eRATication

johnno56

Re: eRATication

Ashish

Re: eRATication

bplus

Re: eRATication

FellippeHeitor

Re: eRATication

bplus

Re: eRATication

Cobalt

Re: eRATication