Program code ScreenShot non QB64 program fullscreen *** SOLVED = [⊞] + [PrtSc]

[Richard]

I am trying to in a program take a ScreenShot of a Windows Screen (the QB64 program window is not visible).

I have tried Auto Hot Key which using ^J (CHR$(10)) as the hotkey for PrintScreen and this takes a screenshot when I manually use it (i.e. Ctrl J), but when I attempt to script it for program control - the external program does not seem to accept the ^J for the screenshot via the

SHELL _DONTWAIT "START /MAX MyExternalProgram.exe filename.ext"

_CLIPBOARD$ = CHR$(10)  ' Ctrl + J     .ahk file  ^-^-#{PrintScreen}   reduce screen elements a few times THEN take a ScreenShot

PRINT _CLIPBOARD$

_SCREENPRINT CHR$(22)  ' Ctrl + V paste from clipboard

_DELAY 5

Since it is not a QB64 program screen, I cannot use my program screenshot routine. Any way (program-wise) to get a ScreenShot?

[RhoSigma]

_SCREENIMAGE maybe ?

http://www.qb64.org/wiki/SCREENIMAGE

[SMcNeill]

_SCREENIMAGE

[Richard]

@RhoSigma
@Steve

Thanks for your replies.

Based on the Wiki example, I inserted the following Code fragment at the beginning of the program:-

desktop& = _SCREENIMAGE
MaxScreenx& = _WIDTH(desktop&)
MaxScreeny& = _HEIGHT(desktop&)
_FREEIMAGE desktop ' free image after measuring screen (it is not displayed)
SCREEN _NEWIMAGE(MaxScreenx&, MaxScreeny&, 32) ' program window is sized to fit
_SCREENMOVE 0, 0

PRINT "..."


then had my stuff calling my externalprogram

and then used my simple .BMP format screendump


open "A:\screen32.bmp" for binary as #1

... 56 byte header

FOR y% = 1799 TO 0 STEP -1
    FOR x% = 0 TO 3199

        c& = POINT(x%, y%)

        r$ = CHR$(_RED32(c&))
        g$ = CHR$(_GREEN32(c&))
        b$ = CHR$(_BLUE32(c&))
        a$ = CHR$(_ALPHA32(c&))       '       PUT #1, , a$ alpha field not saved in .bmp format used  so ONLY 3 bytes RGB used per pixel

        PUT #1, , r$
        PUT #1, , g$
        PUT #1, , b$
    NEXT
NEXT


CLOSE #1



Now the externalprogram is NOT FULLSCREEN and the .bmp file is all black with my "..." at top left hand corner. Its as if I cannot access anything outside of the QB64 program window.

Any further suggestions (hoping its something I omitted)?

[RhoSigma]

1. Run external program (guess it will output something into its own window/console on the desktop)
2. Catch the current desktop contents using _SCREENIMAGE
3. Do whatever you want with the image handle obtained from step 2. (save it, print it or whatever)
4. Free the desktop image handle using _FREEIMAGE

[Petr]

Hi. Source for image miss:

desktop& = _SCREENIMAGE
MaxScreenx& = _WIDTH(desktop&)
MaxScreeny& = _HEIGHT(desktop&)

SCREEN _NEWIMAGE(MaxScreenx&, MaxScreeny&, 32) ' program window is sized to fit
_SCREENMOVE 0, 0

PRINT "..."


then had my stuff calling my externalprogram

and then used my simple .BMP format screendump


open "A:\screen32.bmp" for binary as #1

... 56 byte header
_SOURCE  desktop&
FOR y% = 1799 TO 0 STEP -1
    FOR x% = 0 TO 3199

        c& = POINT(x%, y%)

        r$ = CHR$(_RED32(c&))
        g$ = CHR$(_GREEN32(c&))
        b$ = CHR$(_BLUE32(c&))
        a$ = CHR$(_ALPHA32(c&))       '       PUT #1, , a$ alpha field not saved in .bmp format used  so ONLY 3 bytes RGB used per pixel

        PUT #1, , r$
        PUT #1, , g$
        PUT #1, , b$
    NEXT
NEXT

_FREEIMAGE desktop& ' free image after measuring it (you do not need graphical mode SCREEN for work with images)
CLOSE #1

[SMcNeill]

I'm not really certain what you're trying to do with your example, Richard, so I thought I'd just go the route of giving you a working example to start from:

Code: QB64: [Select]

1. _SCREENHIDE 'Hide our QB64 screen, so we don't grab a capture of it
2. DesktopImage = _SCREENIMAGE
3. QB64Screen = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
4. SCREEN QB64Screen 'set our screen
5. _SCREENSHOW 'Show our QB64 screen, so we can see what we're doing
6. _SCREENMOVE 0, 0 'move it to the top left of our desktop
7. _PUTIMAGE (_WIDTH, _HEIGHT)-(0, 0), DesktopImage 'place the screenimage onto our QB64 screen -- upside down
8.  
9. SaveBMP "UpsideDown.bmp", 0, 0, 0, _WIDTH, _HEIGHT 'Save it to the drive
10.  
11.  
12.  
13. SUB SaveBMP (filename$, image&, x1%, y1%, x2%, y2%)
14.     'Super special STEVE-Approved BMP Export routine for use with any QB64 graphic mode.
15.     IF x2% = _WIDTH(image&) THEN x2% = x2% - 1
16.     IF y2% = _HEIGHT(image&) THEN y2% = y2% - 1
17.  
18.     IF _PIXELSIZE(image&) = 0 THEN
19.         IF SaveTextAs256Color THEN
20.             tempimage& = TextScreenToImage256&(image&)
21.         ELSE
22.             tempimage& = TextScreenToImage32&(image&)
23.         END IF
24.         F = _FONT(image&)
25.         FW = _FONTWIDTH(F): FH = _FONTHEIGHT(F)
26.         SaveBMP filename$, tempimage&, x1% * FW, y1% * FH, x2% * FW, y2% * FH
27.         _FREEIMAGE tempimage&
28.         EXIT FUNCTION
29.     END IF
30.  
31.     TYPE BMPFormat
32.         ID AS STRING * 2
33.         Size AS LONG
34.         Blank AS LONG
35.         Offset AS LONG
36.         Hsize AS LONG
37.         PWidth AS LONG
38.         PDepth AS LONG
39.         Planes AS INTEGER
40.         BPP AS INTEGER
41.         Compression AS LONG
42.         ImageBytes AS LONG
43.         Xres AS LONG
44.         Yres AS LONG
45.         NumColors AS LONG
46.         SigColors AS LONG
47.     END TYPE
48.  
49.  
50.     DIM BMP AS BMPFormat
51.     DIM x AS LONG, y AS LONG
52.     DIM temp AS STRING, t AS STRING * 1
53.  
54.     DIM n AS _MEM, o AS _OFFSET, m AS _MEM
55.     m = _MEMIMAGE(image&)
56.  
57.     IF x1% > x2% THEN SWAP x1%, x2%
58.     IF y1% > y2% THEN SWAP y1%, y2%
59.     IF x2% = _WIDTH(imagehandle%) THEN x2% = _WIDTH(imagehandle%) - 1 'troubleshoot in case user does a common mistake for 0-width instead of 0 - (width-1) for fullscreen
60.     IF y2% = _HEIGHT(imagehandle%) THEN y2% = _HEIGHT(imagehandle%) - 1 'troubleshoot in case user does a common mistake for 0-width instead of 0 - (width-1) for fullscreen
61.  
62.     s& = _SOURCE
63.     _SOURCE image&
64.  
65.     BMP.PWidth = (x2% - x1%) + 1
66.     BMP.PDepth = (y2% - y1%) + 1
67.     BMP.ID = "BM"
68.     BMP.Blank = 0
69.     BMP.Hsize = 40
70.     BMP.Planes = 1
71.     BMP.Compression = 0
72.     BMP.Xres = 0
73.     BMP.Yres = 0
74.  
75.     BMP.SigColors = 0
76.  
77.     SELECT CASE _PIXELSIZE(image&)
78.         CASE 1
79.             temp = SPACE$(x2% - x1% + 1)
80.             OffsetBITS& = 54 + 1024 'add palette in 256 color modes
81.             BMP.BPP = 8
82.             IF BMP.PWidth MOD 4 THEN ZeroPAD$ = SPACE$(4 - (BMP.PWidth MOD 4))
83.             ImageSize& = (BMP.PWidth + LEN(ZeroPAD$)) * BMP.PDepth
84.             BMP.ImageBytes = ImageSize&
85.             BMP.NumColors = 256
86.             BMP.Size = ImageSize& + OffsetBITS&
87.             BMP.Offset = OffsetBITS&
88.         CASE 4
89.             temp = SPACE$(3)
90.             OffsetBITS& = 54 'no palette in 24/32 bit
91.             BMP.BPP = 24
92.             IF ((BMP.PWidth * 3) MOD 4) THEN ZeroPAD$ = SPACE$(4 - ((BMP.PWidth * 3) MOD 4))
93.             ImageSize& = (BMP.PWidth + LEN(ZeroPAD$)) * BMP.PDepth
94.             BMP.ImageBytes = ImageSize&
95.             BMP.NumColors = 0
96.             BMP.Size = ImageSize& * 3 + OffsetBITS&
97.             BMP.Offset = OffsetBITS&
98.     END SELECT
99.  
100.     F = FREEFILE
101.     n = _MEMNEW(BMP.Size)
102.     _MEMPUT n, n.OFFSET, BMP
103.     o = n.OFFSET + 54
104.     zp& = LEN(ZeroPAD$)
105.     $CHECKING:OFF
106.  
107.     IF BMP.BPP = 8 THEN 'Store the Palette for 256 color mode
108.         FOR c& = 0 TO 255 ' read BGR color settings from JPG image + 1 byte spacer(CHR$(0))
109.             cv& = _PALETTECOLOR(c&, image) ' color attribute to read.
110.             b$ = CHR$(_BLUE32(cv&)) + CHR$(_GREEN32(cv&)) + CHR$(_RED32(cv&)) + CHR$(0) 'spacer byte
111.             _MEMPUT n, o, b$
112.             o = o + 4
113.         NEXT
114.         y = y2% + 1
115.         w& = _WIDTH(image&)
116.         x = x2% - x1% + 1
117.         DO
118.             y = y - 1
119.             _MEMGET m, m.OFFSET + (w& * y + x1%), temp
120.             _MEMPUT n, o, temp
121.             o = o + x
122.             _MEMPUT n, o, ZeroPAD$
123.             o = o + zp&
124.         LOOP UNTIL y = y1%
125.     ELSE
126.         y = y2% + 1
127.         w& = _WIDTH(image&)
128.         DO
129.             y = y - 1: x = x1% - 1
130.             DO
131.                 x = x + 1
132.                 _MEMGET m, m.OFFSET + (w& * y + x) * 4, temp
133.                 _MEMPUT n, o, temp
134.                 o = o + 3
135.             LOOP UNTIL x = x2%
136.             _MEMPUT n, o, ZeroPAD$
137.             o = o + zp&
138.         LOOP UNTIL y = y1%
139.     END IF
140.     $CHECKING:ON
141.     _MEMFREE m
142.     OPEN filename$ FOR BINARY AS #F
143.     t1$ = SPACE$(BMP.Size)
144.     _MEMGET n, n.OFFSET, t1$
145.     PUT #F, , t1$
146.     _MEMFREE n
147.     CLOSE #F
148.     _SOURCE s&
149. END SUB
150.  
151.  

I hope the comments show what we're doing at each step of our code, but if you have any questions about anything, feel free to ask.  With this, you should end up with an "UpsideDown.bmp" file inside your QB64 folder, which looks like your desktop turned upside down and backwards.  :)

[Richard]

@ Steve

MANY THANKS

Your program met my requirements "to capture the whole screen as I see it (eg Windows File Explorer, etc) - effectively a Windows 10 Print Screen.

In case you are interested - just to give you an example of what I wanted to achieve:-

Call an "externalprogram" (in this case MSedge.exe) and let it do its thing with a file as listed just below AND then let the QB64 program take a complete screenshot (saved as upsidedown.bmp). SO the very minor modifications to your program is the addition as below

_DELAY 5
SHELL _DONTWAIT "START /MAX msedge.exe A:\Download_NTFS_Reader_for_DOS_-_MajorGeeks.mhtml"
_DELAY 5

Note: the computer was "off-line" when running the program

The .bmp file was converted to a .png file and is below and represents exactly ALL that I see on my display.

WARNING It has been reported by some that stuff from the above website is suspicious

Now to work out how to make it right way round before saving

Thanks again Steve!

[SMcNeill]

It’s my PUTIMAGE that is reversing the image for us, by putting it from bottom right to top left.  Just reverse the order in that command to do it proper.

_PUTIMAGE (0, 0)-(_WIDTH, _HEIGHT), DesktopImage

Though, it sounds like all you need is to change the imagehandle in the SaveBMP command.

SaveBMP “MyFile.bmp”, DesktopImage, 0, 0, _WIDTH, _HEIGHT

[Richard]

@ Steve

Thanks again

I will try it out again tonite - it is sunrise now (I am going to bed)

@ Petr
@ RhoSigma

Thanks for your replies - will also check out tonite.
https://www.qb64.org/forum/index.php?topic=2276.75#lastPost