Base64 Encoding/Decoding with Windows, Mac, and Linux

[SpriggsySpriggs]

Below is code that uses the WinAPI Crypt32 DLL to encode and decode strings (which is also now in my API collection). Also, there is code for using the built-in base64 command from Mac and Linux which will use my pipecom library attached below. I have some code in the $IF block that uses a built-in certutil command in Windows with my pipecom library should you wish to use that rather than WinAPI (you shouldn't). I know that as soon as I post this code someone will either link or post code written entirely in QB64 that encodes and decodes text using the base64 algorithm. I am aware there is a way to do that. I also do not care. This is just to show another way.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. DIM encode AS STRING
4. encode = encodeBase64("My name is Inigo Montoya")
5.  
6. PRINT encode
7.  
8. DIM decode AS STRING
9. decode = decodeBase64(encode)
10.  
11. PRINT decode
12. $IF WIN THEN
13.     'DECLARE LIBRARY ".\pipecom"
14.     '    FUNCTION pipecom$ (cmd AS STRING)
15.     'END DECLARE
16.     'FUNCTION encodeBase64$ (encode AS STRING)
17.     '    DIM encoded AS STRING
18.     '    DIM encodefile AS INTEGER
19.     '    encodefile = FREEFILE
20.     '    OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
21.     '    PRINT #encodefile, encode
22.     '    CLOSE #encodefile
23.     '    encoded = pipecom("certutil -encode 3nc0deb64 3nc0dedb64 && type 3nc0dedb64 && del 3nc0dedb64 && del 3nc0deb64")
24.     '    encoded = MID$(encoded, INSTR(encoded, "-----BEGIN CERTIFICATE-----") + LEN("-----BEGIN CERTIFICATE-----") + 1)
25.     '    encoded = MID$(encoded, 1, INSTR(encoded, "-----END CERTIFICATE-----") - 2)
26.     '    encodeBase64 = encoded
27.     'END FUNCTION
28.  
29.     'FUNCTION decodeBase64$ (decode AS STRING)
30.     '    DIM decoded AS STRING
31.     '    DIM decodefile AS INTEGER
32.     '    decodefile = FREEFILE
33.     '    OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
34.     '    PRINT #decodefile, decode
35.     '    CLOSE #decodefile
36.     '    decoded = pipecom("certutil -decode d3c0deb64 d3c0dedb64 && type d3c0dedb64 && del d3c0deb64 && del d3c0dedb64")
37.     '    decoded = MID$(decoded, _INSTRREV(decoded, "successfully.") + 1 + LEN("successfully."))
38.     '    decoded = MID$(decoded, 1, LEN(decoded) - 1)
39.     '    decodeBase64 = decoded
40.     'END FUNCTION
41.  
42.     DECLARE DYNAMIC LIBRARY "Crypt32"
43.         FUNCTION CryptBinaryToString%% ALIAS CryptBinaryToStringA (BYVAL pbBinary AS _OFFSET, BYVAL cbBinary AS LONG, BYVAL dwFlags AS LONG, BYVAL pszString AS _OFFSET, BYVAL pcchString AS _OFFSET)
44.         FUNCTION CryptStringToBinary%% ALIAS CryptStringToBinaryA (BYVAL pszString AS _OFFSET, BYVAL cchString AS LONG, BYVAL dwFlags AS LONG, BYVAL pbBinary AS _OFFSET, BYVAL pcbBinary AS _OFFSET, BYVAL pdwSkip AS _OFFSET, BYVAL pdwFlags AS _OFFSET)
45.     END DECLARE
46.  
47.     FUNCTION encodeBase64$ (encode AS STRING)
48.         CONST CRYPT_STRING_NOCRLF = &H40000000
49.         CONST CRYPT_STRING_BASE64 = &H00000001
50.  
51.         DIM a AS _BYTE
52.         DIM lengthencode AS LONG
53.         DIM encoded AS STRING
54.         DIM lengthencoded AS LONG
55.  
56.         encode = encode + CHR$(0)
57.         lengthencode = LEN(encode)
58.  
59.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, 0, _OFFSET(lengthencoded))
60.         'Calculate buffer length
61.         IF a <> 0 THEN
62.             encoded = SPACE$(lengthencoded)
63.         ELSE
64.             encodeBase64 = ""
65.             EXIT FUNCTION
66.         END IF
67.         a = CryptBinaryToString(_OFFSET(encode), lengthencode, CRYPT_STRING_BASE64 OR CRYPT_STRING_NOCRLF, _OFFSET(encoded), _OFFSET(lengthencoded))
68.         'Acual conversion
69.         IF a <> 0 THEN
70.             encodeBase64 = encoded
71.         ELSE
72.             encodeBase64 = ""
73.         END IF
74.     END FUNCTION
75.  
76.     FUNCTION decodeBase64$ (decode AS STRING)
77.         CONST CRYPT_STRING_BASE64_ANY = &H00000006
78.  
79.         DIM a AS _BYTE
80.         DIM lengthdecode AS LONG
81.         DIM decoded AS STRING
82.         DIM lengthdecoded AS LONG
83.  
84.         decode = decode + CHR$(0)
85.         lengthdecode = LEN(decode) - 1
86.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, 0, _OFFSET(lengthdecoded), 0, 0)
87.         'Calculate buffer length
88.         IF a <> 0 THEN
89.             decoded = SPACE$(lengthdecoded)
90.         ELSE
91.             decodeBase64 = ""
92.             EXIT FUNCTION
93.         END IF
94.         a = CryptStringToBinary(_OFFSET(decode), lengthdecode, CRYPT_STRING_BASE64_ANY, _OFFSET(decoded), _OFFSET(lengthdecoded), 0, 0)
95.         'Actual conversion
96.         IF a <> 0 THEN
97.             decodeBase64 = decoded
98.         ELSE
99.             decodeBase64 = ""
100.         END IF
101.     END FUNCTION
102. $ELSE
103.     DECLARE LIBRARY "./pipecom"
104.     FUNCTION pipecom$ (cmd AS STRING)
105.     END DECLARE
106.  
107.     FUNCTION encodeBase64$ (encode AS STRING)
108.     DIM encoded AS STRING
109.     DIM encodefile AS INTEGER
110.     encodefile = FREEFILE
111.     OPEN "3nc0deb64" FOR OUTPUT AS #encodefile
112.     PRINT #encodefile, encode
113.     CLOSE #encodefile
114.     encoded = pipecom("base64 3nc0deb64")
115.     KILL "3nc0deb64"
116.     encodeBase64 = MID$(encoded, 1, LEN(encoded) - 1)
117.     END FUNCTION
118.  
119.     FUNCTION decodeBase64$ (decode AS STRING)
120.     DIM decoded AS STRING
121.     DIM decodefile AS INTEGER
122.     decodefile = FREEFILE
123.     OPEN "d3c0deb64" FOR OUTPUT AS #decodefile
124.     PRINT #decodefile, decode
125.     CLOSE #decodefile
126.     decoded = pipecom("base64 -d d3c0deb64")
127.     KILL "d3c0deb64"
128.     decodeBase64 = decoded
129.     END FUNCTION
130. $END IF

[Dav]

Cool. You're really on a roll with the API stuff.  I appreciate your efforts. 

- Dav

[SpriggsySpriggs]

Cool. You're really on a roll with the API stuff.  I appreciate your efforts. 

- Dav

@Dav Thanks! Yeah, when I get itchin' on a particular subject I've been checking to see if WinAPI has something for it and if Mac and Linux have an alternative. I'm trying to make my API collection contain a balance of Windows & Mac/Linux.

[Petr]

Nice and useful thing, SpriggsySpriggs. I want to ask you - I don't know exactly how to describe it - is there any way to use API calls to pull dialogs, which use scrollbars and check boxes from Windows? Is it possible to create a sliding window using windows libraries? There are already ways to call the open / save dialog in the wiki, as well as how to call the message box. I think this would also be very useful.

[SpriggsySpriggs]

@Petr I'm not sure what you mean by sliding windows but as for the dialogs with check boxes; that is only available in Windows Vista using the WinAPI :(

[Dav]

I have some API code that mcaulkins made that goes into that area.  Had radio buttons, scroll bar, edit box I think.  I'll try to dig it up.

- Dav

[SpriggsySpriggs]

I have some API code that mcaulkins made that goes into that area.  Had radio buttons, scroll bar, edit box I think.  I'll try to dig it up.

- Dav

@Dav Excited to see it!

[Dav]

I also want to dig up something he made that sends a program to the system tray area of the task bar.  Looking for them now...

- Dav

[Petr]

Perfect. I'm also looking forward :)

[Dav]

Here's the GUI he made that makes buttons, scroll bar and edit area using API.   It uses an .h file to get WindowProc.  Still looking for the system tray code.  Maybe @Pete would have some snippets like these too - they came off the old qbasic forum.  This is old code by the way, QB64 has come a long way since.

- Dav

Save as win.h

ptrszint FUNC_WINDOWPROC(ptrszint*_FUNC_WINDOWPROC_OFFSET_HWND,uint32*_FUNC_WINDOWPROC_ULONG_UMSG,uptrszint*_FUNC_WINDOWPROC_UOFFSET_WPARAM,ptrszint*_FUNC_WINDOWPROC_OFFSET_LPARAM);

LRESULT CALLBACK WindowProc(HWND hwnd, UINT uMsg, WPARAM wParam, LPARAM lParam) {
 return FUNC_WINDOWPROC((ptrszint *) (& hwnd), & uMsg, & wParam, (ptrszint *) (& lParam));
}

void * GetWindowProc() {
 return (void *) WindowProc;

QB64 Code....

Code: QB64: [Select]

1. 'DEFSTR A-Z
2.  
3. ' public domain, michael calkins
4. ' revision 2012 09 12
5. ' very much experimental. I am a noob at GUI stuff, and might be doing multiple things wrong or in unideal ways.
6. ' rough translation of:
7. ' http://www.network54.com/Forum/613583/message/1347419042/
8. ' with a few liberties taken.
9.  
10. ' not only might I be doing things wrong, but I am also not doublechecking the function declarations, type definitions, and constant values. They could be wrong.
11.  
12. $CONSOLE
13. _DEST _CONSOLE
14. $SCREENHIDE
15.  
16. ' get more constants from winuser.h as needed.
17.  
18. CONST IDC_ARROW = &H7F00
19. CONST COLOR_WINDOW = 5
20.  
21. CONST WS_OVERLAPPED = 0
22. CONST WS_CHILD = &H40000000
23. CONST WS_VISIBLE = &H10000000
24. CONST WS_MAXIMIZE = &H01000000
25. CONST WS_CAPTION = &H00C00000
26. CONST WS_VSCROLL = &H00200000
27. CONST WS_HSCROLL = &H00100000
28. CONST WS_SYSMENU = &H00080000
29. CONST WS_THICKFRAME = &H00040000
30. CONST WS_TABSTOP = &H00010000
31. CONST WS_MINIMIZEBOX = &H00020000
32. CONST WS_MAXIMIZEBOX = &H00010000
33. CONST WS_OVERLAPPEDWINDOW = WS_OVERLAPPED OR WS_CAPTION OR WS_SYSMENU OR WS_THICKFRAME OR WS_MINIMIZEBOX OR WS_MAXIMIZEBOX
34.  
35. CONST CW_USEDEFAULT = &H80000000&
36.  
37. CONST BS_PUSHBUTTON = 0
38. CONST BS_AUTOCHECKBOX = 3
39. CONST BS_GROUPBOX = 7
40. CONST BS_AUTORADIOBUTTON = 9
41. CONST BS_TEXT = 0
42.  
43. CONST BN_CLICKED = 0
44.  
45. CONST BM_GETCHECK = &HF0
46.  
47. CONST ES_LEFT = 0
48. CONST ES_MULTILINE = 4
49. CONST ES_AUTOVSCROLL = &H0040
50. CONST ES_AUTOHSCROLL = &H0080
51. CONST ES_WANTRETURN = &H1000
52.  
53. CONST WM_DESTROY = 2
54. CONST WM_GETTEXT = &H000D
55. CONST WM_CLOSE = &H0010
56. CONST WM_COMMAND = &H0111
57.  
58. CONST SW_SHOWDEFAULT = &HA
59.  
60. DECLARE LIBRARY "win"
61.     FUNCTION GetWindowProc%& ()
62. END DECLARE
63.  
64. DECLARE DYNAMIC LIBRARY "user32"
65.     FUNCTION SendMessageA%& (BYVAL hWnd%&, BYVAL Msg~&, BYVAL wParam~%&, BYVAL lParam%&)
66.     FUNCTION DefWindowProcA%& (BYVAL hWnd%&, BYVAL Msg~&, BYVAL wParam~%&, BYVAL lParam%&)
67.     SUB PostQuitMessage (BYVAL nExitCode&)
68.     FUNCTION LoadCursorW%& (BYVAL hInstance%&, BYVAL lpCursorName%&)
69.     FUNCTION RegisterClassA~% (BYVAL lpWndClass%&)
70.     FUNCTION CreateWindowExA%& (BYVAL dwExStyle~&, BYVAL lpClassName%&, BYVAL lpWindowName%&, BYVAL dwStyle~&, BYVAL x&, BYVAL y&, BYVAL nWidth&, BYVAL nHeight&, BYVAL hWndParent%&, BYVAL hMenu%&, BYVAL hInstance%&, BYVAL lpParam%&)
71.     FUNCTION ShowWindow& (BYVAL hWnd%&, BYVAL nCmdShow&)
72.     FUNCTION UpdateWindow& (BYVAL hWnd%&)
73.     FUNCTION GetMessageA& (BYVAL lpMsg%&, BYVAL hWnd%&, BYVAL wMsgFilterMin~&, BYVAL wMsgFilterMax~&)
74.     FUNCTION TranslateMessage& (BYVAL lpMsg%&)
75.     FUNCTION DispatchMessageA%& (BYVAL lpmsg%&)
76. END DECLARE
77.  
78. DECLARE DYNAMIC LIBRARY "kernel32"
79.     FUNCTION GetModuleHandleW%& (BYVAL lpModuleName%&)
80.     FUNCTION GetLastError~& ()
81. END DECLARE
82.  
83. TYPE POINT
84.     x AS LONG
85.     y AS LONG
86. END TYPE
87.  
88. TYPE MSG
89.     hwnd AS _OFFSET
90.     message AS _UNSIGNED LONG
91.     wParam AS _UNSIGNED _OFFSET 'unsigned pointer sized integer
92.     lParam AS _OFFSET 'pointer sized integer
93.     time AS _UNSIGNED LONG
94.     pt AS POINT
95. END TYPE
96.  
97. TYPE WNDCLASSA
98.     style AS _UNSIGNED LONG
99.     lpfnWndProc AS _OFFSET
100.     cbClsExtra AS LONG
101.     cbWndExtra AS LONG
102.     hInstance AS _OFFSET
103.     hIcon AS _OFFSET
104.     hCursor AS _OFFSET
105.     hbrBackground AS _OFFSET
106.     lpszMenuName AS _OFFSET
107.     lpszClassName AS _OFFSET
108. END TYPE
109.  
110. DIM SHARED hi AS _OFFSET
111. DIM SHARED bRet AS LONG
112. DIM SHARED hw AS _OFFSET
113. DIM SHARED hwb0 AS _OFFSET
114. DIM SHARED hwb1 AS _OFFSET
115. DIM SHARED hwcb AS _OFFSET
116. DIM SHARED hwgb AS _OFFSET
117. DIM SHARED hwr0 AS _OFFSET
118. DIM SHARED hwr1 AS _OFFSET
119. DIM SHARED hwe AS _OFFSET
120. DIM SHARED wc AS WNDCLASSA
121. DIM SHARED msg AS MSG
122. DIM SHARED at AS _UNSIGNED INTEGER
123.  
124. DIM SHARED buf AS STRING * 4096
125.  
126. DIM SHARED discardb AS LONG
127. DIM SHARED discardp AS _OFFSET
128. DIM SHARED t0 AS STRING
129. DIM SHARED t1 AS STRING
130.  
131. DIM SHARED MainClassName AS STRING * 5
132. MainClassName = "main" + CHR$(0)
133. DIM SHARED crlf AS STRING * 2
134. crlf = MKI$(&HA0D)
135.  
136. hi = GetModuleHandleW(0)
137.  
138. wc.style = 0
139. wc.lpfnWndProc = GetWindowProc
140. wc.cbClsExtra = 0
141. wc.cbWndExtra = 0
142. wc.hInstance = hi
143. wc.hIcon = 0
144. wc.hCursor = LoadCursorW(0, IDC_ARROW)
145. wc.hbrBackground = COLOR_WINDOW + 1
146. wc.lpszMenuName = 0
147. wc.lpszClassName = _OFFSET(MainClassName)
148.  
149. at = RegisterClassA(_OFFSET(wc)): IF 0 = at THEN SYSTEM
150.  
151. t1 = "title" + CHR$(0)
152. hw = CreateWindowExA(0, at AND &HFFFF~&, _OFFSET(t1), WS_HSCROLL OR WS_OVERLAPPEDWINDOW OR WS_VSCROLL, CW_USEDEFAULT, CW_USEDEFAULT, CW_USEDEFAULT, CW_USEDEFAULT, 0, 0, hi, 0): IF 0 = hw THEN SYSTEM
153. t0 = "BUTTON" + CHR$(0)
154. t1 = "Button 0" + CHR$(0)
155. hwb0 = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR BS_PUSHBUTTON OR BS_TEXT, 10, 10, 150, 40, hw, 0, hi, 0): IF 0 = hw THEN SYSTEM
156. t1 = "Button 1" + CHR$(0)
157. hwb1 = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR BS_PUSHBUTTON OR BS_TEXT, 10, 60, 150, 40, hw, 0, hi, 0): IF 0 = hwb0 THEN SYSTEM
158. t1 = "Chk box" + CHR$(0)
159. hwcb = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR BS_AUTOCHECKBOX OR BS_TEXT, 10, 110, 150, 40, hw, 0, hi, 0): IF 0 = hwb1 THEN SYSTEM
160. t1 = "Group box" + CHR$(0)
161. hwgb = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_VISIBLE OR WS_CHILD OR BS_GROUPBOX OR BS_TEXT, 10, 160, 400, 80, hw, 0, hi, 0): IF 0 = hwgb THEN SYSTEM
162. t1 = "Radio 0" + CHR$(0)
163. hwr0 = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR BS_AUTORADIOBUTTON OR BS_TEXT, 10, 30, 150, 30, hwgb, 0, hi, 0): IF 0 = hwr0 THEN SYSTEM
164. t1 = "Radio 1" + CHR$(0)
165. hwr1 = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR BS_AUTORADIOBUTTON OR BS_TEXT, 210, 30, 150, 30, hwgb, 0, hi, 0): IF 0 = hwr1 THEN SYSTEM
166. t0 = "EDIT" + CHR$(0)
167. t1 = "This is a" + crlf + "multiline edit control." + crlf + "Click in me and type." + crlf + "It should scroll automatically in both directions, but there aren't any scroll bars." + crlf + "Close the window to see the text printed to the console." + CHR$(0)
168. hwe = CreateWindowExA(0, _OFFSET(t0), _OFFSET(t1), WS_TABSTOP OR WS_VISIBLE OR WS_CHILD OR ES_AUTOHSCROLL OR ES_AUTOVSCROLL OR ES_LEFT OR ES_MULTILINE OR ES_WANTRETURN, 10, 300, 400, 200, hw, 0, hi, 0): IF 0 = hwe THEN SYSTEM
169.  
170. discardb = ShowWindow(hw, SW_SHOWDEFAULT)
171. discardb = UpdateWindow(hw)
172. DO
173.     bRet = GetMessageA(_OFFSET(msg), 0, 0, 0)
174.     SELECT CASE bRet
175.         CASE 0, -1: EXIT DO
176.     END SELECT
177.     discardb = TranslateMessage(_OFFSET(msg))
178.     discardp = DispatchMessageA(_OFFSET(msg))
179. LOOP
180.  
181. _DELAY .5
182. ' Hopefully the user is running this console program from the command prompt.
183. ' If not, the half second delay should remind them.
184. ' I think that Sleep is okay here, because I assume we shouldn't be getting any more messages.
185. ' We're out of the message loop anyway...
186. SYSTEM
187.  
188. FUNCTION WindowProc%& (hWnd AS _OFFSET, uMsg AS _UNSIGNED LONG, wParam AS _UNSIGNED _OFFSET, lParam AS _OFFSET)
189.  
190.     SELECT CASE uMsg
191.  
192.         CASE WM_CLOSE
193.  
194.             discardp = SendMessageA(hwe, WM_GETTEXT, LEN(buf), _OFFSET(buf))
195.             PRINT: PRINT "First part of the edit control text:": PRINT
196.             PRINT buf: PRINT
197.             PRINT "Radio 0: 0x"; HEX$(SendMessageA(hwr0, BM_GETCHECK, 0, 0))
198.             PRINT "Radio 1: 0x"; HEX$(SendMessageA(hwr1, BM_GETCHECK, 0, 0))
199.  
200.             WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam): EXIT FUNCTION
201.  
202.         CASE WM_DESTROY
203.  
204.             PostQuitMessage 0
205.             WindowProc = 0: EXIT FUNCTION
206.  
207.         CASE WM_COMMAND
208.  
209.             IF wParam \ &H10000 = BN_CLICKED THEN
210.                 SELECT CASE lParam
211.                     CASE hwb0: PRINT "Button 0 pressed"
212.                     CASE hwb1: PRINT "Button 1 pressed"
213.                     CASE hwcb: PRINT "Check box pressed"
214.  
215.                         ' The following two lines are useless, because the Group Box is getting the message, not us.
216.                     CASE hwr0: PRINT "Radio 0 pressed"
217.                     CASE hwr1: PRINT "Radio 1 pressed"
218.                 END SELECT
219.                 WindowProc = 0: EXIT FUNCTION
220.             ELSE
221.                 WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam): EXIT FUNCTION
222.             END IF
223.  
224.         CASE ELSE
225.  
226.             WindowProc = DefWindowProcA(hWnd, uMsg, wParam, lParam): EXIT FUNCTION
227.     END SELECT
228.  
229. END FUNCTION
230.  

[SpriggsySpriggs]

@Dav You might want to modify the message so that the code you are pasting for the win.h is set for C++ or something that way it doesn't fail compilation. Since RETURN is capitalized it fails. The code seems to work in 32 but not in 64. WOW. It's amazing! I've been trying to get that to work forever but I just never could figure out how to make it work!

[Dav]

Corrected it.  Thanks.

- Dav

[Dav]

Michael is very knowledgable programmer. I saved most of the API things he's posted over the years.

EDIT: sorry for the extra post comment  - meant to add this the above one.

- Dav

[Petr]

Perfect work!, Dav, bug in C code! Add } to the end! Thank you for sharing!

[FellippeHeitor]

And a pointer to a qb64 function being passed to the API! That's very valuable!