Basic question about window size

[ZapJackson]

Hi there!  I just learned about QB64 yesterday because I'm doing this goofy roguelike project:  https://twitter.com/zapjackson/status/1015367087508746240

I have an embarrassingly basic question -- I've been working in QuickBASIC in DOSBox at 2x scaling, and while the screen size of QB64 is really great for coding, I really need the finished product to run in a larger window.

Is there some trick I'm missing to scale the window up when it's in the default 80x24 text screen, or to make it gracefully user-resizable?  I'd love to release this thing when it's done, but it's too small to be comfortable to play on modern monitors.

Zack

[FellippeHeitor]

Hi there and welcome to the forum!

Just add this to the beginning of your program:

Code: QB64: [Select]

1. $RESIZE:STRETCH

You can also replace stretch with SMOOTH for some antialiasing.

[FellippeHeitor]

If you want an alternative resolution (any size really), you can:

Code: QB64: [Select]

1. myScreen& = _NEWIMAGE(width, height, mode)
2. SCREEN myScreen&

With mode being any legacy graphic mode (7, 13...) or even 256 (for 8bit color mode) or 32 for 32bit color mode.

We also have easy _RGB32 mixing available:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2. COLOR _RGB33(255, 0, 0)
3. PRINT "This is bright red"
4.  

[FellippeHeitor]

_NEWIMAGE can also create any-sized screen 0, except you don't give width and height in pixels, but in characters.

[ZapJackson]

Thanks so much, this is great!

[dukeofthebump]

Hey everyone, hopefully it's okay for me to bump this thread, but my problem pertains to the exact subject being discussed and I can't find an answer anywhere.

I'm making a text mode game and I'm having the same issue ZapJackson is - I'm actually using his source code to help with my project (thank you for sharing it, by the way) and he ended up just using the $RESIZE metacommand, which is fine, but I'd really like to be able to manipulate the size of the window in the program and I'm stuck. I know how to do this in graphical screen modes, and I know how to change the number of text columns with WIDTH, but I'd really like to be able to actually resize the window and I'm at a loss. I'd like the game to start in a larger window so the player doesn't have to resize it every time they start playing, and my eventual goal is to have a menu with different windowed/fullscreen options they can set. Basically I want to have the program perform the action of the player resizing the window, but with a specific resolution and without needing to use the mouse.

In the wiki it says "To automatically run in Qbasic fullscreen, use another Screen mode before using SCREEN 0." I don't want it to start fullscreen, but I thought it might work the same way with a window, so I tried this at the beginning of the program:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1280, 800, 32)
2. SLEEP
3. SCREEN 0
4.  

It launches in a 1280x800 window, but after I press a key and it changes to screen 0 it goes right back to the default size. If anyone has any ideas I'd be very appreciative.

Edit: also, in the wiki entry for _FONT it says: "NOTE: SCREEN 0 can only use one font type and style per viewed SCREEN page. Font size may also affect the window size."

So I assume this means I can change the font size and the window will automatically scale to adapt to it, but I have no idea how to do this. :( I know it would be possible if I load a custom TTF, but is there a way to change the size of the default font 16?

[FellippeHeitor]

SCREEN _NEWIMAGE(80, 25, 0)

The command above will create a screen identical to SCREEN 0: 80 columns by 25 rows in text mode (0). Just change the number of columns/rows you desire.

Welcome to the forum, dukeofthebump.

[luke]

Text and graphics screens are treated very similarly:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(20, 30, 0)

That'll give you a text mode screen that is 20 characters wide and 30 characters high. Things to note:
 - Measurements are in characters, not in pixels.
 - Like graphics commands (but unlike LOCATE) the order of arguments is the X coordinate (columns) first then the Y coordinate (rows).
 - Because character cells aren't squares, _NEWIMAGE(50, 50, 0) doesn't produce a square window. You can use the _FONTHEIGHT and _FONTWIDTH commands to convert pixel measurements to character cell measurements, so

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800 / _FONTWIDTH, 800 / _FONTHEIGHT, 0)

will give you a window that is square (though beware the optical illusion where width & height are perceived differently - check with a ruler if in doubt).

That passage from the wiki sounds misleading and probably needs to be edited.

[dukeofthebump]

Thanks so much for the quick response!

The problem is, I want to increase the size of the window but also scale the contents of the window, as if the user had resized it themselves. That is, I don't want a window with more characters, I want the characters to be larger.

It'll probably be easier to get with visual examples:

This is the basic screen mode 0 with no changes

This is that same window, stretched to approximately double-sized by the player

This is what I get when I try to double the screen size with SCREEN _NEWIMAGE(80, 50, 0). The window's bigger, but it's not actually scaling anything.

I'd like the look of example #2 without the player needing to physically resize the window with the mouse.

[FellippeHeitor]

This is a rather convoluted solution, but it works. I hope the comments in the code are clear enough (feel free to ask anything if they happen to not be). This approach will also slow down execution quite a bit:

Code: QB64: [Select]

1. 'setup screen sizes
2. originalW = 640
3. originalH = 400
4. desiredW = 1280
5. 'desired height is automatically calculated below
6.  
7. 'create canvases
8. smallerScreen = _NEWIMAGE(originalW, originalH, 256)
9. bigScreen = _NEWIMAGE(desiredW, (originalH * desiredW) / originalW, 32)
10. SCREEN bigScreen
11. _DEST smallerScreen
12.  
13. 'setup an update timer
14. updateTimer = _FREETIMER
15. ON TIMER(updateTimer, .03) updateScreen
16. TIMER(updateTimer) ON
17.  
18. '-----------------------------------------------------------------
19. 'your actual program starts here
20. PRINT "hello world"
21. PRINT "active screen:"; _WIDTH(smallerScreen); "x"; _HEIGHT(smallerScreen)
22. PRINT "visible screen:"; _WIDTH(bigScreen); "x"; _HEIGHT(bigScreen)
23.  
24. DO
25.     _LIMIT 30
26. LOOP UNTIL _KEYHIT
27.  
28. '-----------------------------------------------------------------
29. 'update the screen by stretching the working canvas to fit the visible window area:
30. SUB updateScreen
31.     SHARED smallerScreen, bigScreen
32.     _PUTIMAGE , smallerScreen, bigScreen
33.     _DISPLAY
34. END SUB

[dukeofthebump]

I didn't realize this would be such an involved process, and I really appreciate you taking the time to work this out. I thought I was just missing something obvious, but I guess I was over-estimating the flexibility of text mode. I tried your solution and it works perfectly, and at least so far I'm not noticing much of a speed hit, but that might change as the game gets more complex. It might be better in the long run to just build it from the ground up with graphical mode in mind, and fake text mode with a bitmapped font and limited palette.

Thanks again!

[SMcNeill]

I sn't this just a simple case of adding $RESIZE to the top of the code?

[dukeofthebump]

I sn't this just a simple case of adding $RESIZE to the top of the code?

That lets the player resize the window with the mouse, but I need to be able to do it within the program itself.

[SMcNeill]

I sn't this just a simple case of adding $RESIZE to the top of the code?

That lets the player resize the window with the mouse, but I need to be able to do it within the program itself.

Would a simple routine like the one below work for you?

Code: QB64: [Select]

1. _FONT _LOADFONT("cour.ttf", 16, "monospace")
2. ScaleScreen 0 'initialize the font settings
3.  
4. PRINT "Hello World"
5. SLEEP
6.  
7. ScaleScreen 50
8. SLEEP
9. ScaleScreen 200
10. SLEEP
11. ScaleScreen 150
12. SLEEP
13.  
14.  
15.  
16.  
17.  
18. SUB ScaleScreen (percent AS INTEGER)
19.     STATIC FontSize(4 TO 100), RanOnce
20.     IF NOT RanOnce THEN
21.         RanOnce = -1
22.         FOR i = 4 TO 100
23.             _LIMIT 25
24.             F = _LOADFONT("cour.ttf", i, "monospace")
25.             FontSize(i) = _FONTWIDTH(F) 'make and keep an array of font sizes so we don't have to keep loading them over and over
26.             _FREEFONT F
27.         NEXT
28.     END IF
29.     IF percent = 0 THEN EXIT SUB
30.     h = _FONTWIDTH
31.     desiredscale = (percent / 100) * h
32.     FOR i = 5 TO 100
33.         IF FontSize(i) > desiredscale THEN EXIT FOR
34.     NEXT
35.     Ftemp = _FONT
36.     F = _LOADFONT("cour.ttf", i - 1, "monospace")
37.     _FONT F
38.     IF Ftemp <> 16 THEN _FREEFONT Ftemp
39. END SUB
40.