formula to determine if point is inside a circle ?

[mynameispaul]

does someone have a formula that can determine if a point is within a circle if the circle's X Y and radius is known?
thanks

[FellippeHeitor]

Code: QB64: [Select]

1. 'Calculate the distance between two points.
2. FUNCTION dist! (x1!, y1!, x2!, y2!)
3.     dist! = _HYPOT((x2! - x1!), (y2! - y1!))
4. END FUNCTION

If dist!(x of circle center, y of circle center, x of your point, y of your point) is =< radius, your point is within the circle.

[FellippeHeitor]

Code: QB64: [Select]

1. TYPE vector
2.     x AS SINGLE
3.     y AS SINGLE
4.     r AS INTEGER
5. END TYPE
6.  
7. DIM circ AS vector
8. DIM pt AS vector
9.  
10. SCREEN _NEWIMAGE(600, 600, 32)
11.  
12. circ.x = _WIDTH / 2
13. circ.y = _HEIGHT / 2
14. circ.r = 100
15.  
16. DO
17.     WHILE _MOUSEINPUT: WEND
18.     pt.x = _MOUSEX
19.     pt.y = _MOUSEY
20.  
21.     CLS
22.     CIRCLE (circ.x, circ.y), circ.r, _RGB32(255)
23.  
24.     IF dist(circ.x, circ.y, pt.x, pt.y) <= circ.r THEN
25.         PAINT (circ.x, circ.y), _RGB32(0, 116, 0), _RGB32(255)
26.     END IF
27.  
28.     _DISPLAY
29.     _LIMIT 60
30. LOOP
31.  
32. 'Calculate the distance between two points.
33. FUNCTION dist! (x1!, y1!, x2!, y2!)
34.     dist! = _HYPOT((x2! - x1!), (y2! - y1!))
35. END FUNCTION
36.  

[qbkiller101]

we were just discussing it on the discord server, just before you asked,
anyways, heres the formula (returns true if inside circle):
((pointX-circleX)^2 + (pointY - circleY)^2 < r^2)
where pointx and y are x,y of the point, and circle x,y are the circle's center's x and y coords

[mynameispaul]

Thanks all.
Appreciate it.

[bplus]

Take Fellippe's

Code: QB64: [Select]

1. IF dist(circ.x, circ.y, pt.x, pt.y) <= circ.r THEN

 and make collision of 2 circles

Code: QB64: [Select]

1. IF dist(circ1.x, circ1.y, circ2.x, circ2.y) <= circ1.r + circ2.r THEN 'collision!

[carloscordeiro]

Good evening everyone,
Taking advantage of the post, not to open another, with a simple request for help.

As everyone knows, I am a simple qbasic apprentice.
I am having trouble associating a number in its quantities.
Example:
a (1) = 2
a (2) = 3
a (3) = 5
a (4) = 7
a (5) = 11
a (6) = 13
a (7) = 17
a (8) = 19
a (9) = 23
a1 (a (1)) = 1250
a1 (a (2)) = 1262
a1 (a (3)) = 1245
a1 (a (4)) = 1212
a1 (a (5)) = 1266
a1 (a (6)) = 1282
a1 (a (7)) = 1238
a1 (a (8)) = 1248
a1 (a (9)) = 1245

When I order in quantities 1282 is the first that corresponds to the number 13. The problem is that I am not able to associate 1282 with 13.
Follows small code and image.

DIM a(1 TO 9) AS LONG
DIM a1(500) AS _INTEGER64
'-----------------------------------
a(1) = 2
a(2) = 3
a(3) = 5
a(4) = 7
a(5) = 11
a(6) = 13
a(7) = 17
a(8) = 19
a(9) = 23
'-----------------------------------
a1(a(1)) = 1250
a1(a(2)) = 1262
a1(a(3)) = 1245
a1(a(4)) = 1212
a1(a(5)) = 1266
a1(a(6)) = 1282
a1(a(7)) = 1238
a1(a(8)) = 1248
a1(a(9)) = 1245
'-----------------------------------
v = 2

FOR b = 1 TO 9
    LOCATE v, 2: PRINT a(b); "="; a1(a(b))
    v = v + 1
NEXT b

FOR b = 1 TO 9
    FOR i = 1 TO 8
        IF a1(a(i)) > a1(a(i + 1)) THEN
            SWAP a1(a(i)), a1(a(i + 1))
        END IF
    NEXT i
NEXT b
v = 2
FOR b = 9 TO 1 STEP -1
    LOCATE v, 20: PRINT a(b); "="; a1(a(b))
    v = v + 1
NEXT b

Carlos

[carloscordeiro]

Bplus Didn't you wake up funny today to help me with this?

After SWAP it loses association.
I didn't mention your name, because sometimes I'm ashamed to ask you directly. considering that you and steve already help me a lot in this forum.

[Cobalt]

Wasn't there another post on this topic sometime last year?  Or am I just having deja vu?

[carloscordeiro]

Not with me

I'm taking advantage of the post, not to open another with a simple code
Did you understand what I'm up to?

I want to put in order by bigger numbers, and the associated numbers follow the order

Before the SWAP command the lines are associated, after the SWAP it keeps the larger numbers, however it disassociates.

[bplus]

Bplus Didn't you wake up funny today to help me with this?

After SWAP it loses association.
I didn't mention your name, because sometimes I'm ashamed to ask you directly. considering that you and steve already help me a lot in this forum.

I'm sorry Carlos I haven't a clue what you are up to here.

Also if you have your own question unrelated to discussion or code, it is perfectly fine and courteous to start a new post so don't worry about starting a new topic please. Or you are free to PM me. :)

And also if it is more a question than something in particular you are doing in code it should be started under Discussion board.

So see, if you had started your own discussion I would feel free to pester you with questions like what the heck are you trying to do? Fortunately mynameispaul seemed finished and topic did seem done so...

I see a() is first 1 to 9 primes and then a1() array you assign the first 9 prime indexes in 1200's, why would anybody do that? ;-))  so a1(2) = 1250   a1(3) = 1262 and so on...

And then you do some crazy thing with swapping, why would anybody do that? ;-))

And so my friend as I said, I have no idea what you are up to. :)



Update:

I want to put in order by bigger numbers, and the associated numbers follow the order

Before the SWAP command the lines are associated, after the SWAP it keeps the larger numbers, however it disassociates.

OK got it!

Code: QB64: [Select]

1. REDIM a(0 TO 1, 1 TO 9)
2.  
3. 'load a() with primes in 0 index and 1200's in  index 1, now the prime number is bonded to the 1200 number
4. a(0, 1) = 2
5. a(0, 2) = 3
6. a(0, 3) = 5
7. a(0, 4) = 7
8. a(0, 5) = 11
9. a(0, 6) = 13
10. a(0, 7) = 17
11. a(0, 8) = 19
12. a(0, 9) = 23
13.  
14. a(1, 1) = 1250
15. a(1, 2) = 1262
16. a(1, 3) = 1245
17. a(1, 4) = 1212
18. a(1, 5) = 1266
19. a(1, 6) = 1282
20. a(1, 7) = 1238
21. a(1, 8) = 1248
22. a(1, 9) = 1245
23.  
24. ' now sort a() according to index 1 not 0
25.  
26. FOR i = 1 TO 8
27.     FOR j = i + 1 TO 9
28.         IF a(1, i) > a(1, j) THEN
29.             SWAP a(0, i), a(0, j) ' when swap a 1200 number swap primes of same index
30.             SWAP a(1, i), a(1, j)
31.         END IF
32.     NEXT
33. NEXT
34.  
35. FOR i = 1 TO 9
36.     PRINT a(0, i), a(1, i)
37. NEXT
38.  

[Petr]

Hi Carloscodeiro. You say you're an apprentice. So first learn to open new topics where we can focus on you. How does mynameispaul come to this when his thread, which he apparently follows, must solves your problem? Would you like that? It is impolite.

Your problem is here:

Code: QB64: [Select]

1. DIM a (1 AŽ 9) AS LONG
2. DIM a1 (500) AS _INTEGER64
3. '--------------------------------- -
4. a (1) = 2
5. a (2) = 3
6. a (3) = 5
7. a (4) = 7
8. a (5) = 11
9. a (6) = 13
10. a (7) = 17
11. a (8) = 19
12. a (9) = 23
13. '-----------------------------------
14. a1 (a (1)) = 1250
15. a1 (a (2)) = 1262
16. a1 (a (3)) = 1245
17. a1 (a (4)) = 1212
18. a1 (a (5)) = 1266
19. a1 (a (6)) = 1282
20. a1 (a ( 7)) = 1238
21. a1 (a (8)) = 1248
22. a1 (a (9)) = 1245
23.  

  a1 (a(1)) ----- is the same as a1 (2) because a(1) is 2.

easy work:

For S = 1 to 9
SWAP A1(s), A(s)   'this replace values between A1 and A arrays.
NEXT S

[Petr]

mynameispaul: Copyed from CIRCLE help + modified to function:

Code: QB64: [Select]

1.  
2. 'original source code
3. SCREEN 12
4. PRINT "Use mouse, then press Esc for function test..."
5. r& = 200 'radius    change circle size and position here
6. cx& = 320 'center x horizontal
7. cy& = 240 'center y vertical
8.  
9. DO
10.     i = _MOUSEINPUT
11.     x& = _MOUSEX
12.     y& = _MOUSEY
13.     xy& = ((x& - cx&) ^ 2) + ((y& - cy&) ^ 2) 'Pythagorean theorem
14.     IF r& ^ 2 >= xy& THEN CIRCLE (cx&, cy&), r&, 10 ELSE CIRCLE (cx&, cy&), r&, 12
15. LOOP UNTIL INKEY$ = CHR$(27) 'escape key exit
16.  
17. 'modified to function:
18. _KEYCLEAR
19. DO UNTIL _KEYHIT = 27
20.     WHILE _MOUSEINPUT: WEND
21.     x& = _MOUSEX
22.     y& = _MOUSEY
23.     'cx&, cy&, r& are the same as is begin
24.     LOCATE 2
25.     IF INCIRCLE(x&, y&, r&, cx&, cy&) THEN PRINT "Point is in circle    " ELSE PRINT "Point is not in circle"
26. LOOP
27.  
28.  
29. FUNCTION INCIRCLE (x&, y&, r&, cx&, cy&)
30.     xy& = ((x& - cx&) ^ 2) + ((y& - cy&) ^ 2) 'Pythagorean theorem
31.     IF r& ^ 2 >= xy& THEN INCIRCLE = 1 ELSE INCIRCLE = 0
32. END FUNCTION
33.  
34.  

[carloscordeiro]

I apologize amynameispaul and everyone who understood this. I had no bad intention of reopening the topic and I also had no intention of being rude.

Bplus, you left me more relaxed. When I need to open topics, I will no longer be embarrassed by my learner questions.

In my mind, in asking a question directly to you Bplus, I thought I was belittling others in the forum.

Petr, you are right I was rude, but as I mentioned, it was not my intention.

I will try your suggestion for SWAP A1 (s), A (s) If it does not solve I will open a topic explaining better.

This ear tug is another learning experience for me.