b+ Asteroids makeover

[bplus]

Update: I did review Asteroids videos and I found someone with restored Atari 1979 or 80's Arcade Game and he went over the entire machine including trivia on coin boxes and outer detailing. Importantly he showed controls and instructions for them off original machine.

No reverse thrusters nor stop, there are 5 buttons. For left hand, two gun spinners left and right located as you would expect. 2 buttons for the right hand, thrust and fire (left to right) and in the middle and lower is Hyperspace jumper for better or worse position, to be used when crash is imminent.

Oh and a cool effect with thruster, it sets ship in motion of where the gun is pointing and drifts that way for awhile but eventually slows to stop unless more pumping of thruster meanwhile while moving/drifting you can spin your gun/ship in any direction to shoot. Which reminds me of action/adventure movies when the hero is sliding across floor or down a zip line with guns blazing in both directions taking out all the baddies.

Anyway, tried to duplicate that set of controls in the Thruster tester code, OK.
Keys A, S are left and right spinners, K =thrust, L =Fire thrust reads direction of guns at moment and sends ship that way for about 100+ pixels coming to stop unless thruster is pumped (then you basically start going out one border and in the opposite side so fast you don't have time to aim at anything.) Spacebar = Hyperspace jump (down from left and right hand buttons/keys and in middle just like controls on arcade machine.

I had difficulties one after the other when installing this set of controls into m8 for version m9 with rocks, aliens and live bullets... getting the guns to spin the right speed fast but also pinpoint shoot. Hit the thruster twice and you are crashed into border rock waiting to be released to screen. And Hyperspace only worked once or twice for some unknown reason I haven't figured out yet.

There is a question of pumping the key or laying on the key for spinning and firing. If you want to lay on the key then you need _KEYDOWN that can do several keys at once. If you want to pump keys for limited burst you need inkey or _KEYHIT...  anyway the Hyperspace problem had me baffled why I couldn't jump again and again if I wanted. I could jump once per life and maybe if waited long enough (for what?) jump again didn't matter if _KEYHIT, INKEY$ or _KEYDOWN it would only jump once. ??? a head scratcher!

[SierraKen]

B+, let's see the code, maybe I can find the problem. If it's not a flow problem, then it could be a variable that doesn't change how you need it to. I've noticed in the past that sometimes inkey$ will hold onto its past string amount, which is why I often say a$ = "" after it doesn't need it anymore.

[bplus]

Here I've fixed up thrust code for k key, everything is working just right here, now, since last post.

You can pump thrust k key while spin and fire all at once. I think this duplicates the cool effect Asteroids has.

Code: QB64: [Select]

1. _TITLE "Astroids a s spacebarn k l controls" 'b+ 2020-11-04
2. CONST xmax = 1024, ymax = 700, pi = _PI
3. SCREEN _NEWIMAGE(xmax, ymax, 32)
4. _SCREENMOVE 100, 10
5.  
6. ' a turn left
7. ' s turn right
8. ' spacebarn  "hyperspace" worm hole  bug out and show up somewhere else
9. ' k thrust  just a burst in direction you are pointed
10. ' l fire! owwha, owha, owha...
11.  
12.  
13. TYPE shipType
14.     x AS SINGLE
15.     y AS SINGLE
16.     live AS LONG
17.     speed AS SINGLE
18.     thrustAngle AS SINGLE
19.     angle AS SINGLE '   rotated position usu gun left or right (mouse button), maybe up press w or down press z
20.     thrust AS LONG ' use thruster as a count down, reset at each thrust change
21. END TYPE
22.  
23. DIM SHARED ship AS shipType
24. ship.x = xmax / 2: ship.y = ymax / 2: ship.angle = 0: ship.speed = 3.5
25. WHILE _KEYDOWN(27) = 0
26.     CLS
27.     PRINT ship.thrust
28.  
29.     ' Instruments Panel
30.  
31.     'a left spin
32.     IF _KEYDOWN(97) THEN ship.angle = ship.angle - pi / 48
33.  
34.     's right spin
35.     IF _KEYDOWN(115) THEN ship.angle = ship.angle + pi / 48
36.  
37.     'l is Fire!
38.     IF _KEYDOWN(108) THEN
39.         t = TIMER(.001)
40.         IF lastt = 0 OR t - lastt < .1 THEN fire = 1: SOUND 4088, .1
41.     END IF
42.     kh& = _KEYHIT
43.     SELECT CASE kh&
44.         CASE 107 'thrust  k key
45.             ship.thrustAngle = ship.angle: ship.thrust = 120
46.         CASE 32 ' space = hyperspace jump
47.             ship.x = (xmax - 200) * RND + 100: ship.y = (ymax - 200) * RND + 100: ship.thrust = 0
48.     END SELECT
49.  
50.     drawship
51.     _DISPLAY
52.     _LIMIT 60 ' same as Asteroids Game
53. WEND
54.  
55. SUB drawship 'simple red iso triangle pointed towards radianAngle
56.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, x3 AS LONG, y3 AS LONG
57.     DIM x4 AS LONG, y4 AS LONG, x5 AS LONG, y5 AS LONG
58.     IF ship.thrust > 0 THEN
59.         'relocate ship position
60.         ship.x = ship.x + ship.speed * COS(ship.thrustAngle)
61.         ship.y = ship.y + ship.speed * SIN(ship.thrustAngle)
62.         'jump borders
63.         IF ship.x < 0 THEN ship.x = xmax - ABS(ship.x)
64.         IF ship.x > xmax THEN ship.x = ship.x - xmax
65.         IF ship.y < 0 THEN ship.y = ymax - ABS(ship.y)
66.         IF ship.y > ymax THEN ship.y = ship.y - ymax
67.         'burn out flame as thruster dies out
68.         x4 = ship.x + .5 * ship.thrust * COS(ship.angle - 17 / 18 * pi)
69.         y4 = ship.y + .5 * ship.thrust * SIN(ship.angle - 17 / 18 * pi)
70.         x5 = ship.x + .5 * ship.thrust * COS(ship.angle - 19 / 18 * pi)
71.         y5 = ship.y + .5 * ship.thrust * SIN(ship.angle - 19 / 18 * pi)
72.         ftri ship.x, ship.y, x4, y4, x5, y5, &H99FFFF88
73.         ship.thrust = ship.thrust - 1
74.     END IF
75.     'draw ship dead or alive thrust or not, calculate 3 points of triangle ship
76.     fcirc ship.x, ship.y, 30, &H05FFFFFF
77.     x1 = ship.x + 30 * COS(ship.angle) ' front point
78.     y1 = ship.y + 30 * SIN(ship.angle) '
79.     x2 = ship.x + 30 * COS(ship.angle + .6666 * pi) ' wing
80.     y2 = ship.y + 30 * SIN(ship.angle + .6666 * pi)
81.     x3 = ship.x + 30 * COS(ship.angle - .6666 * pi) ' other wing
82.     y3 = ship.y + 30 * SIN(ship.angle - .6666 * pi)
83.     ftri ship.x, ship.y, x1, y1, x2, y2, _RGB32(80, 120, 80, 80)
84.     ftri ship.x, ship.y, x1, y1, x3, y3, _RGB32(60, 100, 60, 80)
85.     LINE (x1, y1)-(ship.x, ship.y), _RGB32(255, 255, 128)
86.     LINE (x1, y1)-(x2, y2), _RGB32(255, 180, 40)
87.     LINE (x1, y1)-(x3, y3), _RGB32(255, 180, 40)
88. END SUB
89.  
90. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
91.     DIM D AS LONG
92.     STATIC a&
93.     D = _DEST
94.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
95.     _DEST a&
96.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
97.     PSET (0, 0), K
98.     _BLEND a& '<<<< new 2019-12-16 fix
99.     _DEST D
100.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
101. END SUB
102.  
103. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version
104.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
105.     x0 = R: y0 = 0: e = 0
106.     DO WHILE y0 < x0
107.         IF e <= 0 THEN
108.             y0 = y0 + 1
109.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
110.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
111.             e = e + 2 * y0
112.         ELSE
113.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
114.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
115.             x0 = x0 - 1: e = e - 2 * x0
116.         END IF
117.     LOOP
118.     LINE (x - R, y)-(x + R, y), C, BF
119. END SUB
120.  
121.  

[bplus]

@SierraKen

Here is defective Hyperspace jump, I'm afraid I've messed up the code worse trying different things ie slowed way down?
But here is state of affairs as of quitting in frustration last night:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "b+ Asteroids m9 AS-Space-KL " 'started 2018-07-13"
3. RANDOMIZE TIMER
4.  
5. '                                            New Controls
6. ' key a = turn left
7. ' key s = turn right
8. '          spacebar =  "hyperspace" show up somewhere else  better or worse use when collision is imminent
9. ' key k = thrust  just a burst in direction you are pointed but doesn't last
10. ' key l = fire! owwha, owha, owha...
11.  
12. '=================================================================================================================
13.  
14. ' 2020-10-27 remove the alternate subs and get down below 200 LOC almost there now! new shooter action font and background
15. ' 2020-10-28 another makeover explosions and split asteroids
16. ' 2020-10-29 fix baby rock management, break between lives
17. ' 2020-10-29 fix left/right gun, fix explosions over many frames to eliminate pause in action, speed up 60 fps
18. ' 2020-10-30 m3 SierraKen's idea to angle shooter with mousewheel also finish WASD options, more rocks, points system
19. ' points:
20. ' The higher the speed the better    speed range .5 to 2.5, diff = 2 * 50 = 100          s - .5 * 50
21. ' DELETE The lower the color the better   color range 10 to 60, diff =      50 * 2 = 100  50 - (c - 10) * 2
22. ' The smaller the size the better  size range 10 to 100, diff = 90 * 1.1111 = 100  90 - (sz -10) * 1.1111
23. '        ((speed - .5) * 50 + (90 - (r - 10)) * 1.1111) / 2 = 100 best score per hit
24. ' 2020-10-30 increase level of difficulty, fix double lives lost, add an ending after all lives spent.
25. ' 2020-10-31 M4 They are Here - the aliens have accepted my invitaion for war games don't get caught in their beam.
26. ' rework ending and variable LONG suffix. Aliens on the attack 100 points before or after transformed into the Bolder of Death.
27. ' 2020-11-01 M5 FX Moving through space, Oh yeah, more aliens!
28. ' 2020-11-01 M6 add play again and save high game , continuous shoot
29. ' 2020-11-01 M7 fix hits count when hit alien ship or Bolder of Death. Fix lights on aliens ship. I want to see collsions with ship.
30. ' Ken recommends removing text in middle of screen, yeah, distracting. Makeover ship as with mouse x, y it's center. Add Splash screen.
31. ' Show mouse in between lives so can be in screen center when press key to start next run.
32.  
33. ' 2020-11-03 watching videos on Asteroids, I found a view and description of the control panel, it is:
34. ' 2 buttons on left and lower button in middle and 2 buttons on right level with 2 on left
35. ' 2 buttons on left are left and right turns they will be Keys A and S
36. ' the middle will be spacebar for Hypespace or these days we might call it worm hole, jump to another location better or worse!
37. ' 2 buttons on right K and L: K will be a thruster of sorts you evetually come to a stop L is the fire button
38. ' So let's try that. I am impressed by hitting thruster and shooting all around as you dift in direction gun was pionted when hit thruster.
39. ' Lighten rocks change points without rock color
40.  
41. '================================================================================================================
42.  
43. '    NOTE: !!!!!!!!!!!!!!!   When there is a pause in action, just hit = enter,  as in enter a new life!
44.  
45. '================================================================================================================
46.  
47. CONST xmax = 1200, ymax = 700, pi = _PI, polyAngle = _PI / 6, nRocks = 300, nBullets = 2000, bSpeed = 15
48.  
49. TYPE alienType
50.     x AS SINGLE
51.     y AS SINGLE
52.     dx AS SINGLE
53.     dy AS SINGLE
54.     ls AS LONG ' lights offset
55.     c AS _UNSIGNED LONG ' color
56.     live AS LONG
57.     attackFrame AS LONG
58.     fireX AS SINGLE
59.     fireY AS SINGLE
60.     transform AS LONG
61. END TYPE
62.  
63. TYPE particle
64.     x AS SINGLE
65.     y AS SINGLE
66.     dx AS SINGLE
67.     dy AS SINGLE
68.     size AS SINGLE
69.     kolor AS _UNSIGNED LONG
70. END TYPE
71.  
72. TYPE bullet
73.     x AS SINGLE
74.     y AS SINGLE
75.     dx AS SINGLE
76.     dy AS SINGLE
77.     live AS LONG
78. END TYPE
79.  
80. TYPE shipType
81.     x AS SINGLE
82.     y AS SINGLE
83.     live AS LONG
84.     speed AS SINGLE
85.     thrustAngle AS SINGLE
86.     angle AS SINGLE '   rotated position usu gun left or right (mouse button), maybe up press w or down press z
87.     thruster AS LONG ' 1 forward, 2 reverse, 3 left , 4 right 0 none for drawing
88. END TYPE
89.  
90. TYPE rock
91.     x AS SINGLE
92.     y AS SINGLE
93.     r AS LONG '            radius
94.     ra AS SINGLE '         rotation position   a = a + spin
95.     heading AS SINGLE '    heading from which dx, dy are calc with speed
96.     speed AS SINGLE '      speed
97.     spin AS SINGLE '       rotation direction and amount
98.     seed AS LONG '         for drawing rocks with RND USING
99.     c AS LONG '            color   rgb(c, c, c)
100.     live AS LONG '         need this to track rocks still active like bullets
101.     explodeFrame AS LONG ' after a rock is hit by bullet, it explodes and in more than one frame
102. END TYPE
103.  
104. REDIM SHARED aliens(1 TO 5) AS alienType
105. DIM SHARED dots(2000) AS particle
106. DIM SHARED b(nBullets) AS bullet
107. DIM SHARED ship AS shipType
108. DIM SHARED r(nRocks) AS rock
109. DIM SHARED lives AS LONG
110. DIM SHARED points AS LONG
111. DIM SHARED rocks AS LONG 'rocks is the minimum number of parent rocks to have on screen  automatic replace when hit or out of bounds
112.  
113. DIM HS AS LONG, fnt AS LONG, fnt2 AS LONG ' file LOAD handles
114. DIM i AS LONG, bullets AS LONG, fire AS LONG ' index and bullets
115. DIM r AS LONG, newRockN AS LONG, maxBabyRocks AS LONG, br AS LONG, hits AS LONG ' rock stuff
116. DIM ai AS LONG, alienN AS LONG ' alien index and number
117. DIM hs$, s$, k$, t, lastt 'high score, general string and times for bullets
118.  
119. SCREEN _NEWIMAGE(xmax, ymax, 32)
120. _SCREENMOVE 100, 20
121. _FULLSCREEN
122.  
123. fnt = _LOADFONT("ARLRDBD.ttf", 16, "MONOSPACE")
124. fnt2 = _LOADFONT("ARLRDBD.ttf", 40, "MONOSPACE")
125. _FONT fnt2
126. COLOR &HFF00FFFF, &H00000000
127.  
128. IF _FILEEXISTS("Asteroids High Score.txt") THEN
129.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
130.     INPUT #1, HS
131.     CLOSE #1
132. END IF
133. hs$ = "High Score:" + STR$(HS)
134.  
135. 'a little splash screen
136. rocks = 7: alienN = 3
137. FOR i = 1 TO nRocks
138.     newRock i
139.     IF i > rocks THEN r(i).live = 0
140. NEXT
141. FOR i = 1 TO alienN
142.     newAlien i
143. NEXT
144. i = 0
145. DO
146.     drawStars 0
147.     i = i + 1
148.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
149.     FOR r = 1 TO nRocks
150.         IF r(r).live THEN drawRock r
151.     NEXT
152.     FOR i = 1 TO alienN
153.         drawAliens i
154.     NEXT
155.     _FONT fnt2
156.     s$ = "Asteroids AS-Space-KL"
157.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 60), s$
158.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(hs$)) / 2, 140), hs$
159.     s$ = "A = Left spin"
160.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 220), s$
161.     s$ = "S = Right Spin"
162.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 300), s$
163.     s$ = "Space = Hyper jump"
164.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 380), s$
165.     s$ = "K = Thrust"
166.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 460), s$
167.     s$ = "L = Fire!"
168.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 540), s$
169.     _FONT fnt
170.     IF _KEYDOWN(27) THEN SYSTEM
171.     k$ = INKEY$
172.  
173.     _DISPLAY
174.     _LIMIT 60
175. LOOP UNTIL LEN(k$)
176.  
177. _MOUSEHIDE
178. restart:
179. IF _FILEEXISTS("Asteroids High Score.txt") THEN
180.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
181.     INPUT #1, HS
182.     CLOSE #1
183. END IF
184. hs$ = "  High Score:" + STR$(HS)
185. lives = 10: alienN = 1: rocks = 1: ' always active rocks
186. points = 0: hits = 0: bullets = 0
187. WHILE lives > 0 AND _KEYDOWN(27) = 0 ' init start restart
188.     REDIM aliens(1 TO alienN) AS alienType
189.     FOR ai = 1 TO alienN
190.         newAlien ai
191.     NEXT
192.     FOR i = 1 TO nRocks 'reset rocks mainly clear baby rocks
193.         newRock (i)
194.         IF i > rocks THEN r(i).live = 0
195.     NEXT
196.     ship.x = xmax / 2 'avoids explosions top left corner at start, dang still get some!
197.     ship.y = ymax / 2
198.     ship.angle = 0
199.     ship.thrustAngle = 0
200.     ship.speed = 0
201.     ship.live = 1
202.     _MOUSEHIDE
203.     WHILE ship.live AND _KEYDOWN(27) = 0
204.         k$ = INKEY$
205.         'draw everything then process bullets
206.         drawStars 1
207.  
208.         FOR ai = 1 TO alienN
209.             drawAliens ai
210.         NEXT
211.         FOR i = 1 TO nRocks
212.             IF r(i).live THEN drawRock i ' while drawing rocks the ship could be blown up
213.             IF ((r(i).x - ship.x) ^ 2 + (r(i).y - ship.y) ^ 2) ^ .5 < r(i).r + 30 THEN 'rock collides with ship?
214.                 FOR br = 1 TO 200 STEP 5
215.                     CIRCLE ((ship.x + r(i).x) / 2, (ship.y + r(i).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
216.                 NEXT
217.                 drawRock i
218.                 drawship
219.                 ship.live = 0
220.                 IF i <= rocks THEN newRock i ELSE r(i).live = 0
221.             END IF
222.         NEXT
223.         FOR i = 1 TO nRocks 'smoke up the place with rock debris fields still flying out from hit frames ago
224.             IF r(i).explodeFrame THEN
225.                 r(i).explodeFrame = r(i).explodeFrame + 1
226.                 IF r(i).explodeFrame > .25 * r(i).r THEN
227.                     r(i).explodeFrame = 0
228.                     IF i <= rocks THEN newRock i ' now replace the rock
229.                 ELSE
230.                     explode r(i).x, r(i).y, r(i).r, r(i).explodeFrame
231.                 END IF
232.             END IF
233.         NEXT
234.         IF ship.live THEN
235.             FOR ai = 1 TO alienN
236.                 IF SQR((aliens(ai).x - ship.x) ^ 2 + (aliens(ai).y - ship.y) ^ 2) < 60 THEN 'aliens and ship collisde boom boom
237.                     FOR br = 1 TO 200 STEP 5
238.                         CIRCLE ((ship.x + aliens(ai).x) / 2, (ship.y + aliens(ai).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
239.                     NEXT
240.                     drawship
241.                     ship.live = 0
242.                     _CONTINUE
243.                 ELSE
244.                     drawship
245.                 END IF
246.             NEXT
247.  
248.             ' ship update
249.             ship.thruster = 0 ' reset
250.  
251.  
252.             IF _KEYDOWN(ASC("a")) THEN ship.angle = ship.angle - pi / 90: ship.thruster = 4
253.             IF _KEYDOWN(ASC("s")) THEN ship.angle = ship.angle + pi / 90: ship.thruster = 3
254.             IF k$ = "k" THEN ship.speed = ship.speed + 3: ship.thrustAngle = ship.angle: ship.thruster = 1
255.             IF k$ = "l" THEN 'l =fire
256.                 fire = 0
257.                 t = TIMER(.01)
258.                 IF lastt = 0 OR t - lastt > .1 THEN fire = 1: lastt = t
259.             END IF
260.             IF k$ = " " THEN 'hyperspace
261.                 ship.x = (xmax - 200) * RND + 100: ship.y = (ymax - 200) * RND + 100: ship.speed = 0
262.             END IF
263.  
264.             'locate ship
265.             ship.x = ship.x + ship.speed * COS(ship.thrustAngle)
266.             ship.y = ship.y + ship.speed * SIN(ship.thrustAngle)
267.             ship.speed = ship.speed - .02
268.             IF ship.speed < 0 THEN ship.speed = 0
269.  
270.  
271.             IF ship.x < 0 THEN ship.x = xmax - ABS(ship.x)
272.             IF ship.x > xmax THEN ship.x = ship.x - xmax
273.             IF ship.y < 0 THEN ship.y = ymax - ABS(ship.y)
274.             IF ship.y > ymax THEN ship.y = ship.y - ymax
275.  
276.  
277.             FOR i = 0 TO nBullets 'handle bullets
278.                 IF b(i).live = 0 AND fire = 1 THEN 'have inactive bullet to use
279.                     b(i).x = ship.x + bSpeed * COS(ship.angle)
280.                     b(i).y = ship.y + bSpeed * SIN(ship.angle)
281.                     b(i).dx = bSpeed * COS(ship.angle)
282.                     b(i).dy = bSpeed * SIN(ship.angle)
283.                     b(i).live = -1
284.                     bullets = bullets + 1
285.                     fire = 0
286.                 END IF
287.                 IF b(i).live THEN 'new location
288.                     b(i).x = b(i).x + b(i).dx
289.                     b(i).y = b(i).y + b(i).dy
290.                     IF b(i).x > 0 AND b(i).x < xmax AND b(i).y > 0 AND b(i).y < ymax THEN 'in bounds draw it
291.  
292.                         'bullet hit aliens?
293.                         FOR ai = 1 TO alienN
294.                             IF SQR((aliens(ai).x - b(i).x) ^ 2 + (aliens(ai).y - b(i).y) ^ 2) < 30 THEN
295.                                 FOR br = 1 TO 120
296.                                     CIRCLE (aliens(ai).x, aliens(ai).y), br / 3, plasma~&(0)
297.                                 NEXT
298.                                 _DISPLAY
299.                                 _DELAY .05
300.                                 hits = hits + 1
301.                                 points = points + 100
302.                                 aliens(ai).live = 0
303.                                 newAlien ai
304.                                 b(i).live = 0
305.                                 _CONTINUE
306.                             END IF
307.                         NEXT
308.                         FOR r = 1 TO nRocks 'check for collision with rock
309.                             IF r(r).live THEN
310.                                 IF SQR((r(r).x - b(i).x) ^ 2 + (r(r).y - b(i).y) ^ 2) < r(r).r THEN 'its a hit!
311.                                     r(r).explodeFrame = 1 'linger with explosion
312.                                     r(r).live = 0
313.                                     hits = hits + 1
314.                                     points = points + ((r(r).speed - .5) * 50 + (90 - (r(r).r - 10)) * 1.1111) / 2
315.                                     IF r(r).r > 30 THEN '       split rock  into ? new ones
316.                                         maxBabyRocks = INT((r(r).r - 10) / 10)
317.                                         maxBabyRocks = irnd&(2, maxBabyRocks) ' pick a number of baby Rocks
318.                                         FOR br = 1 TO maxBabyRocks
319.                                             '                        new rock
320.                                             newRockN = freeRock& '                          get inactive rock number
321.                                             newRock newRockN '                              new identity and activate
322.                                             r(newRockN).r = (r(r).r - 10) / maxBabyRocks '  split in equal parts minus 20% mass
323.                                             r(newRockN).x = r(r).x + irnd&(-30, 30) '       thrown from parent
324.                                             r(newRockN).y = r(r).y + irnd&(-30, 30)
325.                                             r(newRockN).c = r(r).c '                   same color as parent
326.                                             r(newRockN).heading = rrnd(ship.angle - .75 * pi, ship.angle + .75 * pi)
327.                                         NEXT
328.                                     END IF ' big enough to split
329.                                     b(i).live = 0 'kill bullet
330.                                 END IF ' hit rock
331.                             END IF 'rock is there
332.                         NEXT ' rock
333.                         IF b(i).live THEN fcirc b(i).x, b(i).y, 3, _RGB32(255, 255, 0) 'draws bullet
334.                     ELSE
335.                         b(i).live = 0 'out of bounds
336.                     END IF ' bullet is in bounds
337.                 END IF ' bullet live
338.             NEXT ' bullet
339.         END IF ' if ship still live
340.         _DISPLAY
341.         IF ship.live = 0 THEN
342.             lives = lives - 1
343.             IF lives MOD 4 = 0 THEN rocks = rocks + 1
344.             IF lives MOD 4 = 2 THEN alienN = alienN + 1
345.             s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
346.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
347.             _FONT fnt2
348.             s$ = STR$(points) + hs$
349.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
350.             _FONT fnt
351.             s$ = "Press Enter to enter your next life"
352.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
353.             _DISPLAY
354.             _MOUSESHOW
355.             WHILE _KEYDOWN(13) = 0: WEND 'wait for enter key
356.         ELSE
357.             _LIMIT 30 ' if ship dies let's rest and regroup  before restart next life
358.         END IF
359.     WEND
360.     _DISPLAY
361. WEND
362. IF points > HS THEN
363.     OPEN "Asteroids High Score.txt" FOR OUTPUT AS #1
364.     PRINT #1, points
365.     CLOSE #1
366. END IF
367. ship.x = -200: ship.y = -200 'get it out of the way
368. i = 0
369. DO
370.     drawStars 0
371.     i = i + 1
372.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
373.     FOR r = 1 TO nRocks
374.         IF r(r).live THEN drawRock r
375.     NEXT
376.     s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
377.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
378.     _FONT fnt2
379.     s$ = STR$(points)
380.     IF points > HS THEN s$ = s$ + " a New Record!" ELSE s$ = STR$(points) + hs$
381.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
382.     _FONT fnt
383.     s$ = "Press q to quit, p or a to Play Again..."
384.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
385.     IF _KEYDOWN(ASC("a")) OR _KEYDOWN(ASC("p")) THEN GOTO restart
386.     _DISPLAY
387.     _LIMIT 60
388. LOOP UNTIL _KEYDOWN(ASC("q"))
389. SYSTEM
390.  
391. SUB drawStars (moving)
392.     TYPE starType
393.         x AS SINGLE
394.         y AS SINGLE
395.         size AS SINGLE
396.         c AS INTEGER
397.     END TYPE
398.     STATIC beenHere, stars(600) AS starType, cy AS LONG
399.     DIM i AS LONG
400.     IF beenHere = 0 THEN 'static part
401.         FOR i = 0 TO 200
402.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = 0
403.             stars(i).c = irnd&(80, 140)
404.         NEXT
405.         FOR i = 0 TO 200
406.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = .3
407.             stars(i).c = irnd&(80, 140)
408.         NEXT
409.  
410.         FOR i = 1 TO 140
411.             stars(i + 400).x = RND * xmax: stars(i + 400).y = RND * ymax: stars(i + 100).size = .6
412.             stars(i).c = irnd&(110, 170)
413.         NEXT
414.         FOR i = 1 TO 50
415.             stars(i + 540).x = RND * xmax: stars(i + 540).y = RND * ymax: stars(i + 170).size = 1.2
416.             stars(i).c = irnd&(140, 200)
417.         NEXT
418.         FOR i = 1 TO 10
419.             stars(i + 590).x = RND * xmax: stars(i + 590).y = RND * ymax: stars(i + 195).size = 2.4
420.             stars(i).c = irnd&(170, 235)
421.         NEXT
422.         cy = ymax / 2
423.         beenHere = 1
424.     END IF
425.     FOR i = 0 TO cy
426.         LINE (0, i)-(xmax, i), _RGB32(0, 0, .1 * i + 4)
427.         LINE (0, ymax - i)-(xmax, ymax - i), _RGB(0, 0, .1 * i + 4)
428.     NEXT
429.     FOR i = 0 TO 200
430.         IF moving THEN
431.             stars(i).x = stars(i).x + .2 * stars(i).size ^ stars(i).size
432.             IF stars(i).x > xmax THEN stars(i).x = -1 * RND * 20
433.         END IF
434.         fcirc stars(i).x, stars(i).y, stars(i).size, _RGB32(stars(i).c - 10, stars(i).c, stars(i).c + 10)
435.     NEXT
436. END SUB
437.  
438. SUB newAlien (i AS LONG)
439.     DIM side AS LONG, heading
440.     RANDOMIZE TIMER * RND 'to avoid making twins
441.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
442.     aliens(i).fireX = irnd(10, xmax - 10)
443.     aliens(i).fireY = irnd(10, ymax - 10)
444.     aliens(i).attackFrame = irnd(30, 400) ' EDIT a tweak to survive a little long before getting murdered with low lives over and over...
445.     SELECT CASE side
446.         CASE 1
447.             aliens(i).x = -10
448.             aliens(i).y = rrnd(20, ymax - 20)
449.         CASE 2
450.             aliens(i).x = xmax + 10
451.             aliens(i).y = rrnd(20, ymax - 20)
452.         CASE 3
453.             aliens(i).x = rrnd(20, xmax - 20)
454.             aliens(i).y = -10
455.         CASE 4
456.             aliens(i).x = rrnd(20, xmax - 20)
457.             aliens(i).y = ymax + 10
458.     END SELECT
459.     heading = _ATAN2(aliens(i).fireY - aliens(i).y, aliens(i).fireX - aliens(i).x)
460.     aliens(i).dx = .5 * COS(heading)
461.     aliens(i).dy = .5 * SIN(heading)
462.     aliens(i).live = 0
463.     aliens(i).transform = 0
464.     aliens(i).c = _RGB32(irnd(128, 255), irnd(0, 255), irnd(0, 255))
465. END SUB
466.  
467. FUNCTION plasma~& (new AS LONG)
468.     STATIC r, g, b, cnt, beenHere
469.     IF beenHere = 0 OR new THEN
470.         r = RND: g = RND: b = RND: beenHere = 1: cnt = 0
471.     END IF
472.     cnt = cnt + .2
473.     plasma~& = _RGB32(127 + 127 * SIN(r * cnt), 127 + 127 * SIN(g * cnt), 127 + 127 * SIN(b * cnt))
474. END FUNCTION
475.  
476. SUB drawAliens (i AS LONG) 'shipType
477.     DIM light AS LONG, heading, r AS LONG, g AS LONG, b AS LONG
478.     IF aliens(i).live THEN
479.         IF aliens(i).transform = 0 THEN
480.             r = _RED32(aliens(i).c): g = _GREEN32(aliens(i).c): b = _BLUE32(aliens(i).c)
481.             fellipse aliens(i).x, aliens(i).y, 6, 15, _RGB32(r, g - 120, b - 100)
482.             fellipse aliens(i).x, aliens(i).y, 18, 11, _RGB32(r, g - 60, b - 50)
483.             fellipse aliens(i).x, aliens(i).y, 30, 7, _RGB32(r, g, b)
484.             FOR light = 0 TO 5
485.                 fcirc aliens(i).x - 30 + 11 * light + aliens(i).ls, aliens(i).y, 1, _RGB32(aliens(i).ls * 50, aliens(i).ls * 50, aliens(i).ls * 50)
486.             NEXT
487.             aliens(i).ls = aliens(i).ls + 1
488.             IF aliens(i).ls > 5 THEN aliens(i).ls = 0
489.         ELSE
490.             drawBall aliens(i).x, aliens(i).y, 30, aliens(i).c
491.         END IF
492.         'time to shoot?
493.         aliens(i).x = aliens(i).x + aliens(i).dx
494.         aliens(i).y = aliens(i).y + aliens(i).dy
495.         IF SQR((aliens(i).fireX - aliens(i).x) ^ 2 + (aliens(i).fireY - aliens(i).y) ^ 2) < 5 THEN 'transform into the bolder of death
496.             aliens(i).transform = 1
497.             heading = _ATAN2(ship.y - aliens(i).y, ship.x - aliens(i).x)
498.             aliens(i).dx = 2.5 * COS(heading)
499.             aliens(i).dy = 2.5 * SIN(heading)
500.         END IF
501.         IF aliens(i).x < -10 OR aliens(i).x > xmax + 10 THEN
502.             IF aliens(i).y < -10 OR aliens(i).y > ymax + 10 THEN '  out of bounds goodbye bolder of death!
503.                 aliens(i).live = 0 'man we dodged a bullet here!!!!
504.                 newAlien i 'reset the trap
505.             END IF
506.         END IF
507.     ELSE
508.         IF aliens(i).attackFrame THEN
509.             aliens(i).attackFrame = aliens(i).attackFrame - 1
510.             IF aliens(i).attackFrame = 0 THEN
511.                 aliens(i).live = 1
512.             END IF
513.         END IF
514.     END IF
515. END SUB
516.  
517. FUNCTION freeRock&
518.     DIM i AS LONG
519.     FOR i = rocks + 1 TO nRocks ' look for inactive rock number
520.         IF r(i).live = 0 AND r(i).explodeFrame = 0 THEN freeRock& = i: EXIT FUNCTION
521.     NEXT
522. END FUNCTION
523.  
524. SUB explode (x AS LONG, y AS LONG, r AS LONG, frm AS LONG)
525.     DIM maxParticles AS LONG, i AS LONG, rounds AS LONG, loopCount AS LONG
526.     maxParticles = r * 4
527.     FOR i = 1 TO r
528.         NewDot i, x, y, r
529.     NEXT
530.     rounds = r
531.     FOR loopCount = 0 TO frm
532.         IF _KEYDOWN(27) THEN END
533.         FOR i = 1 TO rounds
534.             dots(i).x = dots(i).x + dots(i).dx
535.             dots(i).y = dots(i).y + dots(i).dy
536.             fcirc dots(i).x, dots(i).y, dots(i).size, dots(i).kolor
537.         NEXT
538.         IF rounds < maxParticles THEN
539.             FOR i = 1 TO r
540.                 NewDot (rounds + i), x, y, r
541.             NEXT
542.             rounds = rounds + r
543.         END IF
544.     NEXT
545. END SUB
546.  
547. SUB NewDot (i AS LONG, x AS LONG, y AS LONG, r AS LONG)
548.     DIM angle, rd
549.     angle = pi * 2 * RND
550.     rd = RND * 30
551.     dots(i).x = x + rd * COS(angle)
552.     dots(i).y = y + rd * SIN(angle)
553.     dots(i).size = RND * r * .05
554.     rd = RND 'STxAxTIC recommended for rounder spreads
555.     dots(i).dx = rd * 10 * (10 - 2 * dots(i).size) * COS(angle)
556.     dots(i).dy = rd * 10 * (10 - 2 * dots(i).size) * SIN(angle)
557.     rd = 20 + RND * 70
558.     dots(i).kolor = _RGBA32(rd, rd, rd, 80)
559. END SUB
560.  
561. SUB drawship 'simple red iso triangle pointed towards radianAngle
562.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, x3 AS LONG, y3 AS LONG
563.     DIM x4 AS LONG, y4 AS LONG, x5 AS LONG, y5 AS LONG, x6 AS LONG, y6 AS LONG
564.     DIM x7 AS LONG, y7 AS LONG
565.  
566.  
567.     'calculate 3 points of triangle ship
568.     fcirc ship.x, ship.y, 30, &H05FFFFFF
569.     x1 = ship.x + 30 * COS(ship.angle) ' front point
570.     y1 = ship.y + 30 * SIN(ship.angle) '
571.     x2 = ship.x + 30 * COS(ship.angle + .6666 * pi) ' wing
572.     y2 = ship.y + 30 * SIN(ship.angle + .6666 * pi)
573.     x3 = ship.x + 30 * COS(ship.angle - .6666 * pi) ' other wing
574.     y3 = ship.y + 30 * SIN(ship.angle - .6666 * pi)
575.     ftri ship.x, ship.y, x1, y1, x2, y2, _RGB32(80, 120, 80, 80)
576.     ftri ship.x, ship.y, x1, y1, x3, y3, _RGB32(60, 100, 60, 80)
577.     LINE (x1, y1)-(ship.x, ship.y), _RGB32(255, 255, 128)
578.     LINE (x1, y1)-(x2, y2), _RGB32(180, 180, 120)
579.     LINE (x1, y1)-(x3, y3), _RGB32(180, 180, 120)
580.  
581.     SELECT CASE ship.thruster
582.         CASE 1 'forward apex = ship.x, ship,y  direction = ship.angle + pi
583.             x4 = ship.x + 25 * COS(ship.angle - 17 / 18 * pi)
584.             y4 = ship.y + 25 * SIN(ship.angle - 17 / 18 * pi)
585.             x5 = ship.x + 25 * COS(ship.angle - 19 / 18 * pi)
586.             y5 = ship.y + 25 * SIN(ship.angle - 19 / 18 * pi)
587.             ftri ship.x, ship.y, x4, y4, x5, y5, &H99FFFF88
588.         CASE 2 'reverse apex = x1, y1
589.             x6 = x2 + 25 * COS(ship.angle + 1 / 18 * pi)
590.             y6 = y2 + 25 * SIN(ship.angle + 1 / 18 * pi)
591.             x7 = x2 + 25 * COS(ship.angle - 1 / 18 * pi)
592.             y7 = y2 + 25 * SIN(ship.angle - 1 / 18 * pi)
593.             ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
594.  
595.             x6 = x3 + 25 * COS(ship.angle + 1 / 18 * pi)
596.             y6 = y3 + 25 * SIN(ship.angle + 1 / 18 * pi)
597.             x7 = x3 + 25 * COS(ship.angle - 1 / 18 * pi)
598.             y7 = y3 + 25 * SIN(ship.angle - 1 / 18 * pi)
599.             ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
600.         CASE 3 'left apex = x2, y2
601.             x6 = x3 + 25 * COS(ship.angle - 17 / 18 * pi)
602.             y6 = y3 + 25 * SIN(ship.angle - 17 / 18 * pi)
603.             x7 = x3 + 25 * COS(ship.angle - 19 / 18 * pi)
604.             y7 = y3 + 25 * SIN(ship.angle - 19 / 18 * pi)
605.             ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
606.  
607.             'x6 = x2 + 25 * COS(ship.angle + 1 / 18 * pi)
608.             'y6 = y2 + 25 * SIN(ship.angle + 1 / 18 * pi)
609.             'x7 = x2 + 25 * COS(ship.angle - 1 / 18 * pi)
610.             'y7 = y2 + 25 * SIN(ship.angle - 1 / 18 * pi)
611.             'ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
612.         CASE 4 'right
613.             x6 = x2 + 25 * COS(ship.angle - 17 / 18 * pi)
614.             y6 = y2 + 25 * SIN(ship.angle - 17 / 18 * pi)
615.             x7 = x2 + 25 * COS(ship.angle - 19 / 18 * pi)
616.             y7 = y2 + 25 * SIN(ship.angle - 19 / 18 * pi)
617.             ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
618.  
619.             'x6 = x3 + 25 * COS(ship.angle + 1 / 18 * pi)
620.             'y6 = y3 + 25 * SIN(ship.angle + 1 / 18 * pi)
621.             'x7 = x3 + 25 * COS(ship.angle - 1 / 18 * pi)
622.             'y7 = y3 + 25 * SIN(ship.angle - 1 / 18 * pi)
623.             'ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
624.     END SELECT
625. END SUB
626.  
627. SUB drawRock (iRock)
628.     RANDOMIZE USING r(iRock).seed 'this prevents having to save a particular sequence of random number
629.     DIM dx, dy, j AS LONG, rRad AS SINGLE, leg AS SINGLE, x0 AS LONG, y0 AS LONG, rc AS LONG, c~&, x1 AS LONG, y1 AS LONG, xoff, yoff, i AS LONG
630.     DIM x2 AS LONG, y2 AS LONG
631.     dx = r(iRock).speed * COS(r(iRock).heading)
632.     dy = r(iRock).speed * SIN(r(iRock).heading) 'update location
633.     r(iRock).ra = r(iRock).ra + r(iRock).spin
634.     IF r(iRock).x + dx + r(iRock).r < 0 OR r(iRock).x + dx - r(iRock).r > xmax OR r(iRock).y + dy + r(iRock).r < 0 OR r(iRock).y + dy - r(iRock).r > ymax THEN
635.         IF iRock <= rocks THEN newRock iRock ELSE r(iRock).live = 0
636.         EXIT SUB ' reassigned get out of here
637.     ELSE
638.         r(iRock).x = r(iRock).x + dx
639.         r(iRock).y = r(iRock).y + dy
640.     END IF
641.     FOR j = 10 TO 3 STEP -1 '                  rock drawing (see demo program where developed code)
642.         rRad = .1 * j * r(iRock).r
643.         leg = rRad * (RND * .7 + .3)
644.         x0 = r(iRock).x + leg * COS(r(iRock).ra)
645.         y0 = r(iRock).y + leg * SIN(r(iRock).ra)
646.         rc = r(iRock).c + 30 * RND - 15
647.         c~& = _RGB32(rc + 5, rc - 10, rc + 5)
648.         x1 = x0
649.         y1 = y0
650.         xoff = RND * 20 - 10 + r(iRock).x
651.         yoff = RND * 20 - 10 + r(iRock).y
652.         FOR i = 1 TO 12
653.             leg = rRad * (RND * .35 + .65)
654.             IF i = 12 THEN
655.                 x2 = x0: y2 = y0
656.             ELSE
657.                 x2 = xoff + leg * COS(i * polyAngle + r(iRock).ra)
658.                 y2 = yoff + leg * SIN(i * polyAngle + r(iRock).ra)
659.             END IF
660.             ftri r(iRock).x, r(iRock).y, x1, y1, x2, y2, c~&
661.             x1 = x2: y1 = y2
662.         NEXT
663.     NEXT
664. END SUB
665.  
666. SUB newRock (iRock)
667.     DIM side AS LONG
668.     RANDOMIZE TIMER * RND 'to avoid making twins
669.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
670.     SELECT CASE side
671.         CASE 1
672.             r(iRock).x = -100
673.             r(iRock).y = rrnd(20, ymax - 20)
674.             r(iRock).heading = 3 * pi / 2 + RND * pi
675.         CASE 2
676.             r(iRock).x = xmax + 100
677.             r(iRock).y = rrnd(20, ymax - 20)
678.             r(iRock).heading = pi / 2 + RND * pi
679.         CASE 3
680.             r(iRock).x = rrnd(20, xmax - 20)
681.             r(iRock).y = -100
682.             r(iRock).heading = RND * pi
683.         CASE 4
684.             r(iRock).x = rrnd(20, xmax - 20)
685.             r(iRock).y = ymax + 100
686.             r(iRock).heading = pi + RND * pi
687.     END SELECT
688.     r(iRock).speed = rrnd(.5, 2.5) 'speed, rotation angle, radius, gray coloring, spin, seed, hit for explosion
689.     r(iRock).ra = RND * 2 * pi
690.     r(iRock).r = irnd&(30, 100)
691.     r(iRock).c = irnd&(60, 110) ' Ken request increase in rock color
692.     r(iRock).spin = rrnd(-pi / 20, pi / 20)
693.     r(iRock).seed = INT(RND * 64000) - 32000
694.     r(iRock).explodeFrame = 0
695.     r(iRock).live = 1
696. END SUB
697.  
698. FUNCTION irnd& (n1, n2) 'return an integer between 2 numbers
699.     DIM l%, h%
700.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
701.     irnd& = INT(RND * (h% - l% + 1)) + l%
702. END FUNCTION
703.  
704. FUNCTION rrnd (n1, n2) ' return number (expecting reals =_single, double, _float depending on default / define setup)
705.     rrnd = (n2 - n1) * RND + n1
706. END FUNCTION
707.  
708. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
709.     DIM red AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
710.     red = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
711.     FOR rr = r TO 0 STEP -1
712.         f = 1 - rr / r
713.         fcirc x, y, rr, _RGB32(red * f, grn * f, blu * f)
714.     NEXT
715. END SUB
716.  
717. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
718.     IF xr = 0 OR yr = 0 THEN EXIT SUB
719.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
720.     DIM x AS LONG, y AS LONG
721.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
722.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
723.     DO WHILE y < yr
724.         y = y + 1
725.         x = SQR((h2w2 - y * y * w2) \ h2)
726.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
727.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
728.     LOOP
729. END SUB
730.  
731. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
732.     DIM D AS LONG
733.     STATIC a&
734.     D = _DEST
735.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
736.     _DEST a&
737.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
738.     PSET (0, 0), K
739.     _BLEND a& '<<<< new 2019-12-16 fix
740.     _DEST D
741.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
742. END SUB
743.  
744. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version
745.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
746.     x0 = R: y0 = 0: e = 0
747.     DO WHILE y0 < x0
748.         IF e <= 0 THEN
749.             y0 = y0 + 1
750.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
751.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
752.             e = e + 2 * y0
753.         ELSE
754.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
755.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
756.             x0 = x0 - 1: e = e - 2 * x0
757.         END IF
758.     LOOP
759.     LINE (x - R, y)-(x + R, y), C, BF
760. END SUB
761.  

Don't knock yourself out with this, I am going to reinstall latest thrust changes I just posted (where ship.speed is constant).

But if you or anyone can solve the mysterious disappearance of Hyperdrive spacebar  after the first use, I probably would be grateful or disgusted by my blunder ha, ha! But live and learn!

[SierraKen]

Here you go B+. :) You will hate me when I tell you how I fixed it. It's something you guys have told me not to use more than once in an entire program but it works. I added RANDOMIZE TIMER right before the RND lines. I also changed the INKEY$ to KEYHIT since it seemed to work better, but you can try INKEY$ again if you want. What I found out was that it was actually working every time with KEYHIT (and possibly INKEY$) but it was just going to the same location you started at. For example, if I moved and used it, it went back to where it was before, almost every time. So that meant it was a randomize problem so RANDOMIZE TIMER does the trick. :) For some reason it needed to randomize the timer again probably since it also uses RND in other locations in your program. Oh, as I experimented with different things I also removed XMAX and YMAX and just used your values of it instead to make it easier on the program. That probably doesn't do anything though but I left it there.

Here is the code. It's where I added the '------------------- line, but you know where I'm talking about.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "b+ Asteroids m9 AS-Space-KL " 'started 2018-07-13"
3. RANDOMIZE TIMER
4.  
5. '                                            New Controls
6. ' key a = turn left
7. ' key s = turn right
8. '          spacebar =  "hyperspace" show up somewhere else  better or worse use when collision is imminent
9. ' key k = thrust  just a burst in direction you are pointed but doesn't last
10. ' key l = fire! owwha, owha, owha...
11.  
12. '=================================================================================================================
13.  
14. ' 2020-10-27 remove the alternate subs and get down below 200 LOC almost there now! new shooter action font and background
15. ' 2020-10-28 another makeover explosions and split asteroids
16. ' 2020-10-29 fix baby rock management, break between lives
17. ' 2020-10-29 fix left/right gun, fix explosions over many frames to eliminate pause in action, speed up 60 fps
18. ' 2020-10-30 m3 SierraKen's idea to angle shooter with mousewheel also finish WASD options, more rocks, points system
19. ' points:
20. ' The higher the speed the better    speed range .5 to 2.5, diff = 2 * 50 = 100          s - .5 * 50
21. ' DELETE The lower the color the better   color range 10 to 60, diff =      50 * 2 = 100  50 - (c - 10) * 2
22. ' The smaller the size the better  size range 10 to 100, diff = 90 * 1.1111 = 100  90 - (sz -10) * 1.1111
23. '        ((speed - .5) * 50 + (90 - (r - 10)) * 1.1111) / 2 = 100 best score per hit
24. ' 2020-10-30 increase level of difficulty, fix double lives lost, add an ending after all lives spent.
25. ' 2020-10-31 M4 They are Here - the aliens have accepted my invitaion for war games don't get caught in their beam.
26. ' rework ending and variable LONG suffix. Aliens on the attack 100 points before or after transformed into the Bolder of Death.
27. ' 2020-11-01 M5 FX Moving through space, Oh yeah, more aliens!
28. ' 2020-11-01 M6 add play again and save high game , continuous shoot
29. ' 2020-11-01 M7 fix hits count when hit alien ship or Bolder of Death. Fix lights on aliens ship. I want to see collsions with ship.
30. ' Ken recommends removing text in middle of screen, yeah, distracting. Makeover ship as with mouse x, y it's center. Add Splash screen.
31. ' Show mouse in between lives so can be in screen center when press key to start next run.
32.  
33. ' 2020-11-03 watching videos on Asteroids, I found a view and description of the control panel, it is:
34. ' 2 buttons on left and lower button in middle and 2 buttons on right level with 2 on left
35. ' 2 buttons on left are left and right turns they will be Keys A and S
36. ' the middle will be spacebar for Hypespace or these days we might call it worm hole, jump to another location better or worse!
37. ' 2 buttons on right K and L: K will be a thruster of sorts you evetually come to a stop L is the fire button
38. ' So let's try that. I am impressed by hitting thruster and shooting all around as you dift in direction gun was pionted when hit thruster.
39. ' Lighten rocks change points without rock color
40.  
41. '================================================================================================================
42.  
43. '    NOTE: !!!!!!!!!!!!!!!   When there is a pause in action, just hit = enter,  as in enter a new life!
44.  
45. '================================================================================================================
46.  
47. CONST xmax = 1200, ymax = 700, pi = _PI, polyAngle = _PI / 6, nRocks = 300, nBullets = 2000, bSpeed = 15
48.  
49. TYPE alienType
50.     x AS SINGLE
51.     y AS SINGLE
52.     dx AS SINGLE
53.     dy AS SINGLE
54.     ls AS LONG ' lights offset
55.     c AS _UNSIGNED LONG ' color
56.     live AS LONG
57.     attackFrame AS LONG
58.     fireX AS SINGLE
59.     fireY AS SINGLE
60.     transform AS LONG
61. END TYPE
62.  
63. TYPE particle
64.     x AS SINGLE
65.     y AS SINGLE
66.     dx AS SINGLE
67.     dy AS SINGLE
68.     size AS SINGLE
69.     kolor AS _UNSIGNED LONG
70. END TYPE
71.  
72. TYPE bullet
73.     x AS SINGLE
74.     y AS SINGLE
75.     dx AS SINGLE
76.     dy AS SINGLE
77.     live AS LONG
78. END TYPE
79.  
80. TYPE shipType
81.     x AS SINGLE
82.     y AS SINGLE
83.     live AS LONG
84.     speed AS SINGLE
85.     thrustAngle AS SINGLE
86.     angle AS SINGLE '   rotated position usu gun left or right (mouse button), maybe up press w or down press z
87.     thruster AS LONG ' 1 forward, 2 reverse, 3 left , 4 right 0 none for drawing
88. END TYPE
89.  
90. TYPE rock
91.     x AS SINGLE
92.     y AS SINGLE
93.     r AS LONG '            radius
94.     ra AS SINGLE '         rotation position   a = a + spin
95.     heading AS SINGLE '    heading from which dx, dy are calc with speed
96.     speed AS SINGLE '      speed
97.     spin AS SINGLE '       rotation direction and amount
98.     seed AS LONG '         for drawing rocks with RND USING
99.     c AS LONG '            color   rgb(c, c, c)
100.     live AS LONG '         need this to track rocks still active like bullets
101.     explodeFrame AS LONG ' after a rock is hit by bullet, it explodes and in more than one frame
102. END TYPE
103.  
104. REDIM SHARED aliens(1 TO 5) AS alienType
105. DIM SHARED dots(2000) AS particle
106. DIM SHARED b(nBullets) AS bullet
107. DIM SHARED ship AS shipType
108. DIM SHARED r(nRocks) AS rock
109. DIM SHARED lives AS LONG
110. DIM SHARED points AS LONG
111. DIM SHARED rocks AS LONG 'rocks is the minimum number of parent rocks to have on screen  automatic replace when hit or out of bounds
112.  
113. DIM HS AS LONG, fnt AS LONG, fnt2 AS LONG ' file LOAD handles
114. DIM i AS LONG, bullets AS LONG, fire AS LONG ' index and bullets
115. DIM r AS LONG, newRockN AS LONG, maxBabyRocks AS LONG, br AS LONG, hits AS LONG ' rock stuff
116. DIM ai AS LONG, alienN AS LONG ' alien index and number
117. DIM hs$, s$, k$, t, lastt 'high score, general string and times for bullets
118.  
119. SCREEN _NEWIMAGE(xmax, ymax, 32)
120. _SCREENMOVE 100, 20
121. _FULLSCREEN
122.  
123. fnt = _LOADFONT("ARLRDBD.ttf", 16, "MONOSPACE")
124. fnt2 = _LOADFONT("ARLRDBD.ttf", 40, "MONOSPACE")
125. _FONT fnt2
126. COLOR &HFF00FFFF, &H00000000
127.  
128. IF _FILEEXISTS("Asteroids High Score.txt") THEN
129.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
130.     INPUT #1, HS
131.     CLOSE #1
132. END IF
133. hs$ = "High Score:" + STR$(HS)
134.  
135. 'a little splash screen
136. rocks = 7: alienN = 3
137. FOR i = 1 TO nRocks
138.     newRock i
139.     IF i > rocks THEN r(i).live = 0
140. NEXT
141. FOR i = 1 TO alienN
142.     newAlien i
143. NEXT
144. i = 0
145. DO
146.     drawStars 0
147.     i = i + 1
148.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
149.     FOR r = 1 TO nRocks
150.         IF r(r).live THEN drawRock r
151.     NEXT
152.     FOR i = 1 TO alienN
153.         drawAliens i
154.     NEXT
155.     _FONT fnt2
156.     s$ = "Asteroids AS-Space-KL"
157.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 60), s$
158.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(hs$)) / 2, 140), hs$
159.     s$ = "A = Left spin"
160.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 220), s$
161.     s$ = "S = Right Spin"
162.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 300), s$
163.     s$ = "Space = Hyper jump"
164.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 380), s$
165.     s$ = "K = Thrust"
166.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 460), s$
167.     s$ = "L = Fire!"
168.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 540), s$
169.     _FONT fnt
170.     IF _KEYDOWN(27) THEN SYSTEM
171.     k$ = INKEY$
172.  
173.     _DISPLAY
174.     _LIMIT 60
175. LOOP UNTIL LEN(k$)
176.  
177. _MOUSEHIDE
178. restart:
179. IF _FILEEXISTS("Asteroids High Score.txt") THEN
180.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
181.     INPUT #1, HS
182.     CLOSE #1
183. END IF
184. hs$ = "  High Score:" + STR$(HS)
185. lives = 10: alienN = 1: rocks = 1: ' always active rocks
186. points = 0: hits = 0: bullets = 0
187. WHILE lives > 0 AND _KEYDOWN(27) = 0 ' init start restart
188.     REDIM aliens(1 TO alienN) AS alienType
189.     FOR ai = 1 TO alienN
190.         newAlien ai
191.     NEXT
192.     FOR i = 1 TO nRocks 'reset rocks mainly clear baby rocks
193.         newRock (i)
194.         IF i > rocks THEN r(i).live = 0
195.     NEXT
196.     ship.x = xmax / 2 'avoids explosions top left corner at start, dang still get some!
197.     ship.y = ymax / 2
198.     ship.angle = 0
199.     ship.thrustAngle = 0
200.     ship.speed = 0
201.     ship.live = 1
202.     _MOUSEHIDE
203.     WHILE ship.live AND _KEYDOWN(27) = 0
204.  
205.         'draw everything then process bullets
206.         drawStars 1
207.  
208.         FOR ai = 1 TO alienN
209.             drawAliens ai
210.         NEXT
211.         FOR i = 1 TO nRocks
212.             IF r(i).live THEN drawRock i ' while drawing rocks the ship could be blown up
213.             IF ((r(i).x - ship.x) ^ 2 + (r(i).y - ship.y) ^ 2) ^ .5 < r(i).r + 30 THEN 'rock collides with ship?
214.                 FOR br = 1 TO 200 STEP 5
215.                     CIRCLE ((ship.x + r(i).x) / 2, (ship.y + r(i).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
216.                 NEXT
217.                 drawRock i
218.                 drawship
219.                 ship.live = 0
220.                 IF i <= rocks THEN newRock i ELSE r(i).live = 0
221.             END IF
222.         NEXT
223.         FOR i = 1 TO nRocks 'smoke up the place with rock debris fields still flying out from hit frames ago
224.             IF r(i).explodeFrame THEN
225.                 r(i).explodeFrame = r(i).explodeFrame + 1
226.                 IF r(i).explodeFrame > .25 * r(i).r THEN
227.                     r(i).explodeFrame = 0
228.                     IF i <= rocks THEN newRock i ' now replace the rock
229.                 ELSE
230.                     explode r(i).x, r(i).y, r(i).r, r(i).explodeFrame
231.                 END IF
232.             END IF
233.         NEXT
234.         IF ship.live THEN
235.             FOR ai = 1 TO alienN
236.                 IF SQR((aliens(ai).x - ship.x) ^ 2 + (aliens(ai).y - ship.y) ^ 2) < 60 THEN 'aliens and ship collisde boom boom
237.                     FOR br = 1 TO 200 STEP 5
238.                         CIRCLE ((ship.x + aliens(ai).x) / 2, (ship.y + aliens(ai).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
239.                     NEXT
240.                     drawship
241.                     ship.live = 0
242.                     _CONTINUE
243.                 ELSE
244.                     drawship
245.                 END IF
246.             NEXT
247.  
248.             ' ship update
249.             ship.thruster = 0 ' reset
250.  
251.             k$ = INKEY$
252.             IF _KEYDOWN(ASC("a")) THEN ship.angle = ship.angle - pi / 90: ship.thruster = 4
253.             IF _KEYDOWN(ASC("s")) THEN ship.angle = ship.angle + pi / 90: ship.thruster = 3
254.             IF k$ = "k" THEN ship.speed = ship.speed + 3: ship.thrustAngle = ship.angle: ship.thruster = 1
255.             IF k$ = "l" THEN 'l =fire
256.                 fire = 0
257.                 t = TIMER(.01)
258.                 IF lastt = 0 OR t - lastt > .1 THEN fire = 1: lastt = t
259.             END IF
260.             IF _KEYHIT = 32 THEN 'hyperspace
261.                 RANDOMIZE TIMER
262.                 ship.x = (1000 * RND) + 100: ship.y = (500 * RND) + 100: ship.speed = 0
263.             END IF
264.  
265.             '-----------------------------------------------
266.             'locate ship
267.             ship.x = ship.x + ship.speed * COS(ship.thrustAngle)
268.             ship.y = ship.y + ship.speed * SIN(ship.thrustAngle)
269.             ship.speed = ship.speed - .02
270.             IF ship.speed < 0 THEN ship.speed = 0
271.             IF ship.x < 0 THEN ship.x = xmax - ABS(ship.x)
272.             IF ship.x > xmax THEN ship.x = ship.x - xmax
273.             IF ship.y < 0 THEN ship.y = ymax - ABS(ship.y)
274.             IF ship.y > ymax THEN ship.y = ship.y - ymax
275.  
276.  
277.             FOR i = 0 TO nBullets 'handle bullets
278.                 IF b(i).live = 0 AND fire = 1 THEN 'have inactive bullet to use
279.                     b(i).x = ship.x + bSpeed * COS(ship.angle)
280.                     b(i).y = ship.y + bSpeed * SIN(ship.angle)
281.                     b(i).dx = bSpeed * COS(ship.angle)
282.                     b(i).dy = bSpeed * SIN(ship.angle)
283.                     b(i).live = -1
284.                     bullets = bullets + 1
285.                     fire = 0
286.                 END IF
287.                 IF b(i).live THEN 'new location
288.                     b(i).x = b(i).x + b(i).dx
289.                     b(i).y = b(i).y + b(i).dy
290.                     IF b(i).x > 0 AND b(i).x < xmax AND b(i).y > 0 AND b(i).y < ymax THEN 'in bounds draw it
291.  
292.                         'bullet hit aliens?
293.                         FOR ai = 1 TO alienN
294.                             IF SQR((aliens(ai).x - b(i).x) ^ 2 + (aliens(ai).y - b(i).y) ^ 2) < 30 THEN
295.                                 FOR br = 1 TO 120
296.                                     CIRCLE (aliens(ai).x, aliens(ai).y), br / 3, plasma~&(0)
297.                                 NEXT
298.                                 _DISPLAY
299.                                 _DELAY .05
300.                                 hits = hits + 1
301.                                 points = points + 100
302.                                 aliens(ai).live = 0
303.                                 newAlien ai
304.                                 b(i).live = 0
305.                                 _CONTINUE
306.                             END IF
307.                         NEXT
308.                         FOR r = 1 TO nRocks 'check for collision with rock
309.                             IF r(r).live THEN
310.                                 IF SQR((r(r).x - b(i).x) ^ 2 + (r(r).y - b(i).y) ^ 2) < r(r).r THEN 'its a hit!
311.                                     r(r).explodeFrame = 1 'linger with explosion
312.                                     r(r).live = 0
313.                                     hits = hits + 1
314.                                     points = points + ((r(r).speed - .5) * 50 + (90 - (r(r).r - 10)) * 1.1111) / 2
315.                                     IF r(r).r > 30 THEN '       split rock  into ? new ones
316.                                         maxBabyRocks = INT((r(r).r - 10) / 10)
317.                                         maxBabyRocks = irnd&(2, maxBabyRocks) ' pick a number of baby Rocks
318.                                         FOR br = 1 TO maxBabyRocks
319.                                             '                        new rock
320.                                             newRockN = freeRock& '                          get inactive rock number
321.                                             newRock newRockN '                              new identity and activate
322.                                             r(newRockN).r = (r(r).r - 10) / maxBabyRocks '  split in equal parts minus 20% mass
323.                                             r(newRockN).x = r(r).x + irnd&(-30, 30) '       thrown from parent
324.                                             r(newRockN).y = r(r).y + irnd&(-30, 30)
325.                                             r(newRockN).c = r(r).c '                   same color as parent
326.                                             r(newRockN).heading = rrnd(ship.angle - .75 * pi, ship.angle + .75 * pi)
327.                                         NEXT
328.                                     END IF ' big enough to split
329.                                     b(i).live = 0 'kill bullet
330.                                 END IF ' hit rock
331.                             END IF 'rock is there
332.                         NEXT ' rock
333.                         IF b(i).live THEN fcirc b(i).x, b(i).y, 3, _RGB32(255, 255, 0) 'draws bullet
334.                     ELSE
335.                         b(i).live = 0 'out of bounds
336.                     END IF ' bullet is in bounds
337.                 END IF ' bullet live
338.             NEXT ' bullet
339.         END IF ' if ship still live
340.         _DISPLAY
341.         IF ship.live = 0 THEN
342.             lives = lives - 1
343.             IF lives MOD 4 = 0 THEN rocks = rocks + 1
344.             IF lives MOD 4 = 2 THEN alienN = alienN + 1
345.             s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
346.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
347.             _FONT fnt2
348.             s$ = STR$(points) + hs$
349.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
350.             _FONT fnt
351.             s$ = "Press Enter to enter your next life"
352.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
353.             _DISPLAY
354.             _MOUSESHOW
355.             WHILE _KEYDOWN(13) = 0: WEND 'wait for enter key
356.         ELSE
357.             _LIMIT 30 ' if ship dies let's rest and regroup  before restart next life
358.         END IF
359.     WEND
360.     _DISPLAY
361. WEND
362. IF points > HS THEN
363.     OPEN "Asteroids High Score.txt" FOR OUTPUT AS #1
364.     PRINT #1, points
365.     CLOSE #1
366. END IF
367. ship.x = -200: ship.y = -200 'get it out of the way
368. i = 0
369. DO
370.     drawStars 0
371.     i = i + 1
372.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
373.     FOR r = 1 TO nRocks
374.         IF r(r).live THEN drawRock r
375.     NEXT
376.     s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
377.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
378.     _FONT fnt2
379.     s$ = STR$(points)
380.     IF points > HS THEN s$ = s$ + " a New Record!" ELSE s$ = STR$(points) + hs$
381.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
382.     _FONT fnt
383.     s$ = "Press q to quit, p or a to Play Again..."
384.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
385.     IF _KEYDOWN(ASC("a")) OR _KEYDOWN(ASC("p")) THEN GOTO restart
386.     _DISPLAY
387.     _LIMIT 60
388. LOOP UNTIL _KEYDOWN(ASC("q"))
389. SYSTEM
390.  
391. SUB drawStars (moving)
392.     TYPE starType
393.         x AS SINGLE
394.         y AS SINGLE
395.         size AS SINGLE
396.         c AS INTEGER
397.     END TYPE
398.     STATIC beenHere, stars(600) AS starType, cy AS LONG
399.     DIM i AS LONG
400.     IF beenHere = 0 THEN 'static part
401.         FOR i = 0 TO 200
402.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = 0
403.             stars(i).c = irnd&(80, 140)
404.         NEXT
405.         FOR i = 0 TO 200
406.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = .3
407.             stars(i).c = irnd&(80, 140)
408.         NEXT
409.  
410.         FOR i = 1 TO 140
411.             stars(i + 400).x = RND * xmax: stars(i + 400).y = RND * ymax: stars(i + 100).size = .6
412.             stars(i).c = irnd&(110, 170)
413.         NEXT
414.         FOR i = 1 TO 50
415.             stars(i + 540).x = RND * xmax: stars(i + 540).y = RND * ymax: stars(i + 170).size = 1.2
416.             stars(i).c = irnd&(140, 200)
417.         NEXT
418.         FOR i = 1 TO 10
419.             stars(i + 590).x = RND * xmax: stars(i + 590).y = RND * ymax: stars(i + 195).size = 2.4
420.             stars(i).c = irnd&(170, 235)
421.         NEXT
422.         cy = ymax / 2
423.         beenHere = 1
424.     END IF
425.     FOR i = 0 TO cy
426.         LINE (0, i)-(xmax, i), _RGB32(0, 0, .1 * i + 4)
427.         LINE (0, ymax - i)-(xmax, ymax - i), _RGB(0, 0, .1 * i + 4)
428.     NEXT
429.     FOR i = 0 TO 200
430.         IF moving THEN
431.             stars(i).x = stars(i).x + .2 * stars(i).size ^ stars(i).size
432.             IF stars(i).x > xmax THEN stars(i).x = -1 * RND * 20
433.         END IF
434.         fcirc stars(i).x, stars(i).y, stars(i).size, _RGB32(stars(i).c - 10, stars(i).c, stars(i).c + 10)
435.     NEXT
436. END SUB
437.  
438. SUB newAlien (i AS LONG)
439.     DIM side AS LONG, heading
440.     RANDOMIZE TIMER * RND 'to avoid making twins
441.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
442.     aliens(i).fireX = irnd(10, xmax - 10)
443.     aliens(i).fireY = irnd(10, ymax - 10)
444.     aliens(i).attackFrame = irnd(30, 400) ' EDIT a tweak to survive a little long before getting murdered with low lives over and over...
445.     SELECT CASE side
446.         CASE 1
447.             aliens(i).x = -10
448.             aliens(i).y = rrnd(20, ymax - 20)
449.         CASE 2
450.             aliens(i).x = xmax + 10
451.             aliens(i).y = rrnd(20, ymax - 20)
452.         CASE 3
453.             aliens(i).x = rrnd(20, xmax - 20)
454.             aliens(i).y = -10
455.         CASE 4
456.             aliens(i).x = rrnd(20, xmax - 20)
457.             aliens(i).y = ymax + 10
458.     END SELECT
459.     heading = _ATAN2(aliens(i).fireY - aliens(i).y, aliens(i).fireX - aliens(i).x)
460.     aliens(i).dx = .5 * COS(heading)
461.     aliens(i).dy = .5 * SIN(heading)
462.     aliens(i).live = 0
463.     aliens(i).transform = 0
464.     aliens(i).c = _RGB32(irnd(128, 255), irnd(0, 255), irnd(0, 255))
465. END SUB
466.  
467. FUNCTION plasma~& (new AS LONG)
468.     STATIC r, g, b, cnt, beenHere
469.     IF beenHere = 0 OR new THEN
470.         r = RND: g = RND: b = RND: beenHere = 1: cnt = 0
471.     END IF
472.     cnt = cnt + .2
473.     plasma~& = _RGB32(127 + 127 * SIN(r * cnt), 127 + 127 * SIN(g * cnt), 127 + 127 * SIN(b * cnt))
474. END FUNCTION
475.  
476. SUB drawAliens (i AS LONG) 'shipType
477.     DIM light AS LONG, heading, r AS LONG, g AS LONG, b AS LONG
478.     IF aliens(i).live THEN
479.         IF aliens(i).transform = 0 THEN
480.             r = _RED32(aliens(i).c): g = _GREEN32(aliens(i).c): b = _BLUE32(aliens(i).c)
481.             fellipse aliens(i).x, aliens(i).y, 6, 15, _RGB32(r, g - 120, b - 100)
482.             fellipse aliens(i).x, aliens(i).y, 18, 11, _RGB32(r, g - 60, b - 50)
483.             fellipse aliens(i).x, aliens(i).y, 30, 7, _RGB32(r, g, b)
484.             FOR light = 0 TO 5
485.                 fcirc aliens(i).x - 30 + 11 * light + aliens(i).ls, aliens(i).y, 1, _RGB32(aliens(i).ls * 50, aliens(i).ls * 50, aliens(i).ls * 50)
486.             NEXT
487.             aliens(i).ls = aliens(i).ls + 1
488.             IF aliens(i).ls > 5 THEN aliens(i).ls = 0
489.         ELSE
490.             drawBall aliens(i).x, aliens(i).y, 30, aliens(i).c
491.         END IF
492.         'time to shoot?
493.         aliens(i).x = aliens(i).x + aliens(i).dx
494.         aliens(i).y = aliens(i).y + aliens(i).dy
495.         IF SQR((aliens(i).fireX - aliens(i).x) ^ 2 + (aliens(i).fireY - aliens(i).y) ^ 2) < 5 THEN 'transform into the bolder of death
496.             aliens(i).transform = 1
497.             heading = _ATAN2(ship.y - aliens(i).y, ship.x - aliens(i).x)
498.             aliens(i).dx = 2.5 * COS(heading)
499.             aliens(i).dy = 2.5 * SIN(heading)
500.         END IF
501.         IF aliens(i).x < -10 OR aliens(i).x > xmax + 10 THEN
502.             IF aliens(i).y < -10 OR aliens(i).y > ymax + 10 THEN '  out of bounds goodbye bolder of death!
503.                 aliens(i).live = 0 'man we dodged a bullet here!!!!
504.                 newAlien i 'reset the trap
505.             END IF
506.         END IF
507.     ELSE
508.         IF aliens(i).attackFrame THEN
509.             aliens(i).attackFrame = aliens(i).attackFrame - 1
510.             IF aliens(i).attackFrame = 0 THEN
511.                 aliens(i).live = 1
512.             END IF
513.         END IF
514.     END IF
515. END SUB
516.  
517. FUNCTION freeRock&
518.     DIM i AS LONG
519.     FOR i = rocks + 1 TO nRocks ' look for inactive rock number
520.         IF r(i).live = 0 AND r(i).explodeFrame = 0 THEN freeRock& = i: EXIT FUNCTION
521.     NEXT
522. END FUNCTION
523.  
524. SUB explode (x AS LONG, y AS LONG, r AS LONG, frm AS LONG)
525.     DIM maxParticles AS LONG, i AS LONG, rounds AS LONG, loopCount AS LONG
526.     maxParticles = r * 4
527.     FOR i = 1 TO r
528.         NewDot i, x, y, r
529.     NEXT
530.     rounds = r
531.     FOR loopCount = 0 TO frm
532.         IF _KEYDOWN(27) THEN END
533.         FOR i = 1 TO rounds
534.             dots(i).x = dots(i).x + dots(i).dx
535.             dots(i).y = dots(i).y + dots(i).dy
536.             fcirc dots(i).x, dots(i).y, dots(i).size, dots(i).kolor
537.         NEXT
538.         IF rounds < maxParticles THEN
539.             FOR i = 1 TO r
540.                 NewDot (rounds + i), x, y, r
541.             NEXT
542.             rounds = rounds + r
543.         END IF
544.     NEXT
545. END SUB
546.  
547. SUB NewDot (i AS LONG, x AS LONG, y AS LONG, r AS LONG)
548.     DIM angle, rd
549.     angle = pi * 2 * RND
550.     rd = RND * 30
551.     dots(i).x = x + rd * COS(angle)
552.     dots(i).y = y + rd * SIN(angle)
553.     dots(i).size = RND * r * .05
554.     rd = RND 'STxAxTIC recommended for rounder spreads
555.     dots(i).dx = rd * 10 * (10 - 2 * dots(i).size) * COS(angle)
556.     dots(i).dy = rd * 10 * (10 - 2 * dots(i).size) * SIN(angle)
557.     rd = 20 + RND * 70
558.     dots(i).kolor = _RGBA32(rd, rd, rd, 80)
559. END SUB
560.  
561. SUB drawship 'simple red iso triangle pointed towards radianAngle
562.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, x3 AS LONG, y3 AS LONG
563.     DIM x4 AS LONG, y4 AS LONG, x5 AS LONG, y5 AS LONG, x6 AS LONG, y6 AS LONG
564.     DIM x7 AS LONG, y7 AS LONG
565.  
566.  
567.     'calculate 3 points of triangle ship
568.     fcirc ship.x, ship.y, 30, &H05FFFFFF
569.     x1 = ship.x + 30 * COS(ship.angle) ' front point
570.     y1 = ship.y + 30 * SIN(ship.angle) '
571.     x2 = ship.x + 30 * COS(ship.angle + .6666 * pi) ' wing
572.     y2 = ship.y + 30 * SIN(ship.angle + .6666 * pi)
573.     x3 = ship.x + 30 * COS(ship.angle - .6666 * pi) ' other wing
574.     y3 = ship.y + 30 * SIN(ship.angle - .6666 * pi)
575.     ftri ship.x, ship.y, x1, y1, x2, y2, _RGB32(80, 120, 80, 80)
576.     ftri ship.x, ship.y, x1, y1, x3, y3, _RGB32(60, 100, 60, 80)
577.     LINE (x1, y1)-(ship.x, ship.y), _RGB32(255, 255, 128)
578.     LINE (x1, y1)-(x2, y2), _RGB32(180, 180, 120)
579.     LINE (x1, y1)-(x3, y3), _RGB32(180, 180, 120)
580.  
581.     SELECT CASE ship.thruster
582.         CASE 1 'forward apex = ship.x, ship,y  direction = ship.angle + pi
583.             x4 = ship.x + 25 * COS(ship.angle - 17 / 18 * pi)
584.             y4 = ship.y + 25 * SIN(ship.angle - 17 / 18 * pi)
585.             x5 = ship.x + 25 * COS(ship.angle - 19 / 18 * pi)
586.             y5 = ship.y + 25 * SIN(ship.angle - 19 / 18 * pi)
587.             ftri ship.x, ship.y, x4, y4, x5, y5, &H99FFFF88
588.         CASE 2 'reverse apex = x1, y1
589.             x6 = x2 + 25 * COS(ship.angle + 1 / 18 * pi)
590.             y6 = y2 + 25 * SIN(ship.angle + 1 / 18 * pi)
591.             x7 = x2 + 25 * COS(ship.angle - 1 / 18 * pi)
592.             y7 = y2 + 25 * SIN(ship.angle - 1 / 18 * pi)
593.             ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
594.  
595.             x6 = x3 + 25 * COS(ship.angle + 1 / 18 * pi)
596.             y6 = y3 + 25 * SIN(ship.angle + 1 / 18 * pi)
597.             x7 = x3 + 25 * COS(ship.angle - 1 / 18 * pi)
598.             y7 = y3 + 25 * SIN(ship.angle - 1 / 18 * pi)
599.             ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
600.         CASE 3 'left apex = x2, y2
601.             x6 = x3 + 25 * COS(ship.angle - 17 / 18 * pi)
602.             y6 = y3 + 25 * SIN(ship.angle - 17 / 18 * pi)
603.             x7 = x3 + 25 * COS(ship.angle - 19 / 18 * pi)
604.             y7 = y3 + 25 * SIN(ship.angle - 19 / 18 * pi)
605.             ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
606.  
607.             'x6 = x2 + 25 * COS(ship.angle + 1 / 18 * pi)
608.             'y6 = y2 + 25 * SIN(ship.angle + 1 / 18 * pi)
609.             'x7 = x2 + 25 * COS(ship.angle - 1 / 18 * pi)
610.             'y7 = y2 + 25 * SIN(ship.angle - 1 / 18 * pi)
611.             'ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
612.         CASE 4 'right
613.             x6 = x2 + 25 * COS(ship.angle - 17 / 18 * pi)
614.             y6 = y2 + 25 * SIN(ship.angle - 17 / 18 * pi)
615.             x7 = x2 + 25 * COS(ship.angle - 19 / 18 * pi)
616.             y7 = y2 + 25 * SIN(ship.angle - 19 / 18 * pi)
617.             ftri x2, y2, x6, y6, x7, y7, &H99FFFF88
618.  
619.             'x6 = x3 + 25 * COS(ship.angle + 1 / 18 * pi)
620.             'y6 = y3 + 25 * SIN(ship.angle + 1 / 18 * pi)
621.             'x7 = x3 + 25 * COS(ship.angle - 1 / 18 * pi)
622.             'y7 = y3 + 25 * SIN(ship.angle - 1 / 18 * pi)
623.             'ftri x3, y3, x6, y6, x7, y7, &H99FFFF88
624.     END SELECT
625. END SUB
626.  
627. SUB drawRock (iRock)
628.     RANDOMIZE USING r(iRock).seed 'this prevents having to save a particular sequence of random number
629.     DIM dx, dy, j AS LONG, rRad AS SINGLE, leg AS SINGLE, x0 AS LONG, y0 AS LONG, rc AS LONG, c~&, x1 AS LONG, y1 AS LONG, xoff, yoff, i AS LONG
630.     DIM x2 AS LONG, y2 AS LONG
631.     dx = r(iRock).speed * COS(r(iRock).heading)
632.     dy = r(iRock).speed * SIN(r(iRock).heading) 'update location
633.     r(iRock).ra = r(iRock).ra + r(iRock).spin
634.     IF r(iRock).x + dx + r(iRock).r < 0 OR r(iRock).x + dx - r(iRock).r > xmax OR r(iRock).y + dy + r(iRock).r < 0 OR r(iRock).y + dy - r(iRock).r > ymax THEN
635.         IF iRock <= rocks THEN newRock iRock ELSE r(iRock).live = 0
636.         EXIT SUB ' reassigned get out of here
637.     ELSE
638.         r(iRock).x = r(iRock).x + dx
639.         r(iRock).y = r(iRock).y + dy
640.     END IF
641.     FOR j = 10 TO 3 STEP -1 '                  rock drawing (see demo program where developed code)
642.         rRad = .1 * j * r(iRock).r
643.         leg = rRad * (RND * .7 + .3)
644.         x0 = r(iRock).x + leg * COS(r(iRock).ra)
645.         y0 = r(iRock).y + leg * SIN(r(iRock).ra)
646.         rc = r(iRock).c + 30 * RND - 15
647.         c~& = _RGB32(rc + 5, rc - 10, rc + 5)
648.         x1 = x0
649.         y1 = y0
650.         xoff = RND * 20 - 10 + r(iRock).x
651.         yoff = RND * 20 - 10 + r(iRock).y
652.         FOR i = 1 TO 12
653.             leg = rRad * (RND * .35 + .65)
654.             IF i = 12 THEN
655.                 x2 = x0: y2 = y0
656.             ELSE
657.                 x2 = xoff + leg * COS(i * polyAngle + r(iRock).ra)
658.                 y2 = yoff + leg * SIN(i * polyAngle + r(iRock).ra)
659.             END IF
660.             ftri r(iRock).x, r(iRock).y, x1, y1, x2, y2, c~&
661.             x1 = x2: y1 = y2
662.         NEXT
663.     NEXT
664. END SUB
665.  
666. SUB newRock (iRock)
667.     DIM side AS LONG
668.     RANDOMIZE TIMER * RND 'to avoid making twins
669.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
670.     SELECT CASE side
671.         CASE 1
672.             r(iRock).x = -100
673.             r(iRock).y = rrnd(20, ymax - 20)
674.             r(iRock).heading = 3 * pi / 2 + RND * pi
675.         CASE 2
676.             r(iRock).x = xmax + 100
677.             r(iRock).y = rrnd(20, ymax - 20)
678.             r(iRock).heading = pi / 2 + RND * pi
679.         CASE 3
680.             r(iRock).x = rrnd(20, xmax - 20)
681.             r(iRock).y = -100
682.             r(iRock).heading = RND * pi
683.         CASE 4
684.             r(iRock).x = rrnd(20, xmax - 20)
685.             r(iRock).y = ymax + 100
686.             r(iRock).heading = pi + RND * pi
687.     END SELECT
688.     r(iRock).speed = rrnd(.5, 2.5) 'speed, rotation angle, radius, gray coloring, spin, seed, hit for explosion
689.     r(iRock).ra = RND * 2 * pi
690.     r(iRock).r = irnd&(30, 100)
691.     r(iRock).c = irnd&(60, 110) ' Ken request increase in rock color
692.     r(iRock).spin = rrnd(-pi / 20, pi / 20)
693.     r(iRock).seed = INT(RND * 64000) - 32000
694.     r(iRock).explodeFrame = 0
695.     r(iRock).live = 1
696. END SUB
697.  
698. FUNCTION irnd& (n1, n2) 'return an integer between 2 numbers
699.     DIM l%, h%
700.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
701.     irnd& = INT(RND * (h% - l% + 1)) + l%
702. END FUNCTION
703.  
704. FUNCTION rrnd (n1, n2) ' return number (expecting reals =_single, double, _float depending on default / define setup)
705.     rrnd = (n2 - n1) * RND + n1
706. END FUNCTION
707.  
708. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
709.     DIM red AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
710.     red = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
711.     FOR rr = r TO 0 STEP -1
712.         f = 1 - rr / r
713.         fcirc x, y, rr, _RGB32(red * f, grn * f, blu * f)
714.     NEXT
715. END SUB
716.  
717. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
718.     IF xr = 0 OR yr = 0 THEN EXIT SUB
719.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
720.     DIM x AS LONG, y AS LONG
721.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
722.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
723.     DO WHILE y < yr
724.         y = y + 1
725.         x = SQR((h2w2 - y * y * w2) \ h2)
726.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
727.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
728.     LOOP
729. END SUB
730.  
731. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
732.     DIM D AS LONG
733.     STATIC a&
734.     D = _DEST
735.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
736.     _DEST a&
737.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
738.     PSET (0, 0), K
739.     _BLEND a& '<<<< new 2019-12-16 fix
740.     _DEST D
741.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
742. END SUB
743.  
744. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version
745.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
746.     x0 = R: y0 = 0: e = 0
747.     DO WHILE y0 < x0
748.         IF e <= 0 THEN
749.             y0 = y0 + 1
750.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
751.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
752.             e = e + 2 * y0
753.         ELSE
754.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
755.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
756.             x0 = x0 - 1: e = e - 2 * x0
757.         END IF
758.     LOOP
759.     LINE (x - R, y)-(x + R, y), C, BF
760. END SUB
761.  

[bplus]

Here you go B+. :) You will hate me when I tell you how I fixed it. It's something you guys have told me not to use more than once in an entire program but it works. I added RANDOMIZE TIMER right before the RND lines. I also changed the INKEY$ to KEYHIT since it seemed to work better, but you can try INKEY$ again if you want. What I found out was that it was actually working every time with KEYHIT (and possibly INKEY$) but it was just going to the same location you started at. For example, if I moved and used it, it went back to where it was before, almost every time. So that meant it was a randomize problem so RANDOMIZE TIMER does the trick. :) For some reason it needed to randomize the timer again probably since it also uses RND in other locations in your program. Oh, as I experimented with different things I also removed XMAX and YMAX and just used your values of it instead to make it easier on the program. That probably doesn't do anything though but I left it there.

@SierraKen

Brilliant! Thankyou, thankyou, thankyou!

I know exactly why you have to RANDOMIZE TIMER because I use RANDOMIZE USING with a seed number to redraw rocks over and over. It is a clever way to save a bunch of random data without saving it, just use same seed number in the same sequence of code. I got caught by that once before.

Yep, so there is at least one occasion when RANDOMIZE TIMER before using RND makes sense.

So you have saved me allot grief today when I install the rest of the controls, one shining gold star for you!

[johnno56]

Suggestion: If the overall "field of view" were larger than the screen image then a 'mini-map' could be added. Resolution of the mini-map could be linked to player health. eg: Full health will show all large and small rocks and ufo's. Poor health only large objects.

Just a thought...

J

[bplus]

Thanks @johnno56

I will put your idea on back burner while I try to get Asteroids playing the way I think it should. It may be a proper pilot that we might be waiting for. :)

[SierraKen]

You're welcome B+, glad I could help. :)

[bplus]

OK here is M9 with the new Thrust control and engine installed, this is working nice! Hyperspace jump handy and you can thrust through one border and come out the other side. Just shoot like a maniac!

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "b+ Asteroids m9 AS-Space-KL " 'started 2018-07-13
3. '2020 - Oct and Nov: Special thanks to SierraKen who has been helpful with suggestions, ideas and fixes.
4. RANDOMIZE TIMER
5.  
6. ' Far far away in a universe where Newton's 1st Law of Motion is not obeyed...    ;-))
7.  
8.  
9. '                                            New Controls
10. ' key a = turn left
11. ' key s = turn right
12. '          spacebar =  "hyperspace" show up somewhere else  better or worse use when collision is imminent
13. ' key k = thrust  just a burst in direction you are pointed but doesn't last
14. ' key l = fire! owwha, owha, owha...
15.  
16. '=================================================================================================================
17.  
18. ' 2020-10-27 remove the alternate subs and get down below 200 LOC almost there now! new shooter action font and background
19. ' 2020-10-28 another makeover explosions and split asteroids
20. ' 2020-10-29 fix baby rock management, break between lives
21. ' 2020-10-29 fix left/right gun, fix explosions over many frames to eliminate pause in action, speed up 60 fps
22. ' 2020-10-30 m3 SierraKen's idea to angle shooter with mousewheel also finish WASD options, more rocks, points system
23. ' points:
24. ' The higher the speed the better    speed range .5 to 2.5, diff = 2 * 50 = 100          s - .5 * 50
25. ' DELETE The lower the color the better   color range 10 to 60, diff =      50 * 2 = 100  50 - (c - 10) * 2
26. ' The smaller the size the better  size range 10 to 100, diff = 90 * 1.1111 = 100  90 - (sz -10) * 1.1111
27. '        ((speed - .5) * 50 + (90 - (r - 10)) * 1.1111) / 2 = 100 best score per hit
28. ' 2020-10-30 increase level of difficulty, fix double lives lost, add an ending after all lives spent.
29. ' 2020-10-31 M4 They are Here - the aliens have accepted my invitaion for war games don't get caught in their beam.
30. ' rework ending and variable LONG suffix. Aliens on the attack 100 points before or after transformed into the Bolder of Death.
31. ' 2020-11-01 M5 FX Moving through space, Oh yeah, more aliens!
32. ' 2020-11-01 M6 add play again and save high game , continuous shoot
33. ' 2020-11-01 M7 fix hits count when hit alien ship or Bolder of Death. Fix lights on aliens ship. I want to see collsions with ship.
34. ' Ken recommends removing text in middle of screen, yeah, distracting. Makeover ship as with mouse x, y it's center. Add Splash screen.
35. ' Show mouse in between lives so can be in screen center when press key to start next run.
36.  
37. ' 2020-11-03 M9 watching videos on Asteroids, I found a view and description of the control panel, it is:
38. ' 2 buttons on left and lower button in middle and 2 buttons on right level with 2 on left.
39. ' 2 buttons on left are left and right turns they will be Keys A and S
40. ' The middle will be spacebar for Hypespace or these days we might call it worm hole, jump to another location better or worse!
41. ' 2 buttons on right K and L: K will be a thruster of sorts you eventually come to a stop (not what Newton would like) L is the fire button.
42. ' So let's try that. I am impressed by hitting thruster and shooting all around as you dift in direction gun was pointed when hit thruster.
43. ' Lighten rocks and change points, based now only on size and speed of Asteroids.
44. ' 2020-11-04 M9 Install new update to thrust control. Thanks to SierraKen for finding out what happened to Hyperspace jump when press
45. ' spacebar a 2nd time in a life. Oh also Boulders of Death are now more like smooth colored spheres. Ahhhh Fixed the crashing at the borders
46. ' now fly out one side and come back in on the other! This is getting good! Adding some sound effects.
47.  
48. '================================================================================================================
49.  
50. '    NOTE: !!!!!!!!!!!!!!!   When there is a pause in action, just press enter,  as in enter a new life!
51.  
52. '================================================================================================================
53.  
54. CONST xmax = 1200, ymax = 700, pi = _PI, polyAngle = _PI / 6, nRocks = 300, nBullets = 2000, bSpeed = 15
55.  
56. TYPE alienType
57.     x AS SINGLE
58.     y AS SINGLE
59.     dx AS SINGLE
60.     dy AS SINGLE
61.     ls AS LONG ' lights offset and gray scale
62.     c AS _UNSIGNED LONG ' color
63.     live AS LONG
64.     attackFrame AS LONG
65.     fireX AS SINGLE
66.     fireY AS SINGLE
67.     transform AS LONG
68. END TYPE
69.  
70. TYPE particle
71.     x AS SINGLE
72.     y AS SINGLE
73.     dx AS SINGLE
74.     dy AS SINGLE
75.     size AS SINGLE
76.     kolor AS _UNSIGNED LONG
77. END TYPE
78.  
79. TYPE bullet
80.     x AS SINGLE
81.     y AS SINGLE
82.     dx AS SINGLE
83.     dy AS SINGLE
84.     live AS LONG
85. END TYPE
86.  
87. TYPE shipType
88.     x AS SINGLE
89.     y AS SINGLE
90.     live AS LONG
91.     speed AS SINGLE '       just a constant now when Thrust is applied
92.     thrustAngle AS SINGLE ' ship/gun angle at moment Thrust is pressed
93.     angle AS SINGLE '       rotated position ship/gun now A or S keypress or hold down
94.     thrust AS LONG '        this now tracks how many frames ship will move at speed and thrustAngle
95. END TYPE
96.  
97. TYPE rock
98.     x AS SINGLE
99.     y AS SINGLE
100.     r AS LONG '            radius
101.     ra AS SINGLE '         rotation position   a = a + spin
102.     heading AS SINGLE '    heading from which dx, dy are calc with speed
103.     speed AS SINGLE '      speed
104.     spin AS SINGLE '       rotation direction and amount
105.     seed AS LONG '         for drawing rocks with RND USING
106.     c AS LONG '            color   rgb(c, c, c)
107.     live AS LONG '         need this to track rocks still active like bullets
108.     explodeFrame AS LONG ' after a rock is hit by bullet, it explodes and in more than one frame
109. END TYPE
110.  
111. REDIM SHARED aliens(1 TO 5) AS alienType
112. DIM SHARED dots(2000) AS particle ' explosions
113. DIM SHARED b(nBullets) AS bullet
114. DIM SHARED ship AS shipType
115. DIM SHARED r(nRocks) AS rock
116. DIM SHARED lives AS LONG
117. DIM SHARED points AS LONG
118. DIM SHARED rocks AS LONG 'rocks is the minimum number of parent rocks to have on screen  automatic replace when hit or out of bounds
119.  
120. DIM HS AS LONG, fnt AS LONG, fnt2 AS LONG ' file LOAD handles
121. DIM i AS LONG, bullets AS LONG, fire AS LONG ' index and bullets
122. DIM r AS LONG, newRockN AS LONG, maxBabyRocks AS LONG, br AS LONG, hits AS LONG ' rock stuff
123. DIM ai AS LONG, alienN AS LONG ' alien index and number
124. DIM kh AS LONG 'key hit for ship thruster k or hyperspace jump spacebar
125. DIM hs$, s$, k$, t, lastt 'high score, general string and times for bullets
126. ship.speed = 3.5 'this would be a constant but ship has to declared as Ship Type first
127.  
128. SCREEN _NEWIMAGE(xmax, ymax, 32)
129. _SCREENMOVE 100, 20
130. _FULLSCREEN
131.  
132. fnt = _LOADFONT("ARLRDBD.ttf", 16, "MONOSPACE")
133. fnt2 = _LOADFONT("ARLRDBD.ttf", 40, "MONOSPACE")
134. _FONT fnt2
135. COLOR &HFF00FFFF, &H00000000
136.  
137. IF _FILEEXISTS("Asteroids High Score.txt") THEN
138.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
139.     INPUT #1, HS
140.     CLOSE #1
141. END IF
142. hs$ = "High Score:" + STR$(HS)
143.  
144. 'a little splash screen
145. rocks = 7: alienN = 3
146. FOR i = 1 TO nRocks
147.     newRock i
148.     IF i > rocks THEN r(i).live = 0
149. NEXT
150. FOR i = 1 TO alienN
151.     newAlien i
152. NEXT
153. i = 0
154. DO
155.     drawStars 0
156.     i = i + 1
157.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
158.     FOR r = 1 TO nRocks
159.         IF r(r).live THEN drawRock r
160.     NEXT
161.     FOR i = 1 TO alienN
162.         drawAliens i
163.     NEXT
164.     _FONT fnt2
165.     s$ = "Asteroids AS-Space-KL"
166.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 60), s$
167.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(hs$)) / 2, 140), hs$
168.     s$ = "A = Left spin"
169.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 220), s$
170.     s$ = "S = Right Spin"
171.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 300), s$
172.     s$ = "Space = Hyper jump"
173.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 380), s$
174.     s$ = "K = Thrust"
175.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 460), s$
176.     s$ = "L = Fire!"
177.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 540), s$
178.     _FONT fnt
179.     IF _KEYDOWN(27) THEN SYSTEM
180.     k$ = INKEY$
181.     _DISPLAY
182.     _LIMIT 60
183. LOOP UNTIL LEN(k$)
184.  
185. _MOUSEHIDE
186. restart:
187. IF _FILEEXISTS("Asteroids High Score.txt") THEN
188.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
189.     INPUT #1, HS
190.     CLOSE #1
191. END IF
192. hs$ = "  High Score:" + STR$(HS)
193. lives = 10: alienN = 1: rocks = 1: ' always active rocks
194. points = 0: hits = 0: bullets = 0
195. WHILE lives > 0 AND _KEYDOWN(27) = 0 ' init start restart
196.     REDIM aliens(1 TO alienN) AS alienType
197.     FOR ai = 1 TO alienN
198.         newAlien ai
199.     NEXT
200.     FOR i = 1 TO nRocks 'reset rocks mainly clear baby rocks
201.         newRock (i)
202.         IF i > rocks THEN r(i).live = 0
203.     NEXT
204.     ship.x = xmax / 2 'avoids explosions top left corner at start, dang still get some!
205.     ship.y = ymax / 2
206.     ship.angle = 0
207.     ship.thrustAngle = 0
208.     ship.thrust = 0
209.     ship.live = 1
210.     WHILE ship.live AND _KEYDOWN(27) = 0
211.         k$ = INKEY$
212.         'draw everything then process bullets
213.         drawStars 1
214.         FOR ai = 1 TO alienN
215.             drawAliens ai
216.         NEXT
217.         FOR i = 1 TO nRocks
218.             IF r(i).live THEN 'make sure if we crash into a ship it is a live rock, not one sitting on side waiting to be called up
219.                 drawRock i ' while drawing rocks the ship could be blown up
220.                 IF ((r(i).x - ship.x) ^ 2 + (r(i).y - ship.y) ^ 2) ^ .5 < r(i).r + 30 THEN 'rock collides with ship?
221.                     FOR br = 1 TO 200 STEP 5
222.                         CIRCLE ((ship.x + r(i).x) / 2, (ship.y + r(i).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
223.                     NEXT
224.                     drawRock i
225.                     drawship
226.                     ship.live = 0
227.                     IF i <= rocks THEN newRock i ELSE r(i).live = 0
228.                 END IF
229.             END IF
230.         NEXT
231.         FOR i = 1 TO nRocks 'smoke up the place with rock debris fields still flying out from hit frames ago
232.             IF r(i).explodeFrame THEN
233.                 r(i).explodeFrame = r(i).explodeFrame + 1
234.                 IF r(i).explodeFrame > .25 * r(i).r THEN
235.                     r(i).explodeFrame = 0
236.                     IF i <= rocks THEN newRock i ' now replace the rock
237.                 ELSE
238.                     explode r(i).x, r(i).y, r(i).r, r(i).explodeFrame
239.                 END IF
240.             END IF
241.         NEXT
242.         IF ship.live THEN
243.             FOR ai = 1 TO alienN
244.                 IF SQR((aliens(ai).x - ship.x) ^ 2 + (aliens(ai).y - ship.y) ^ 2) < 60 THEN 'aliens and ship collisde boom boom
245.                     FOR br = 1 TO 200 STEP 5
246.                         CIRCLE ((ship.x + aliens(ai).x) / 2, (ship.y + aliens(ai).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
247.                     NEXT
248.                     drawship
249.                     ship.live = 0
250.                     _CONTINUE
251.                 ELSE
252.                     drawship
253.                 END IF
254.             NEXT
255.  
256.             '                                                                   ship controls update
257.             'a left spin
258.             IF _KEYDOWN(97) THEN ship.angle = ship.angle - pi / 48
259.  
260.             's right spin
261.             IF _KEYDOWN(115) THEN ship.angle = ship.angle + pi / 48
262.  
263.             'l is Fire!
264.             fire = 0
265.             IF _KEYDOWN(108) THEN
266.                 t = TIMER(.01)
267.                 IF lastt = 0 OR t - lastt > .1 THEN fire = 1: SOUND 2088, .03: lastt = t
268.             END IF
269.             kh = _KEYHIT
270.             SELECT CASE kh
271.                 CASE 107 'thrust  k key
272.                     SOUND 488, 2
273.                     ship.thrustAngle = ship.angle: ship.thrust = 120
274.                 CASE 32 ' space = hyperspace jump
275.                     RANDOMIZE TIMER
276.                     ship.x = (xmax - 300) * RND + 150: ship.y = (ymax - 300) * RND + 150: ship.thrust = 0
277.             END SELECT
278.  
279.             '                                                                   locate ship
280.             IF ship.thrust > 0 THEN
281.                 'relocate ship position
282.                 ship.x = ship.x + ship.speed * COS(ship.thrustAngle)
283.                 ship.y = ship.y + ship.speed * SIN(ship.thrustAngle)
284.             END IF
285.             '                                                                    jump borders
286.             IF ship.x < 0 THEN ship.x = xmax - ABS(ship.x)
287.             IF ship.x > xmax THEN ship.x = ship.x - xmax
288.             IF ship.y < 0 THEN ship.y = ymax - ABS(ship.y)
289.             IF ship.y > ymax THEN ship.y = ship.y - ymax
290.  
291.  
292.             FOR i = 0 TO nBullets '                                               handle bullets
293.                 IF b(i).live = 0 AND fire = 1 THEN 'have inactive bullet to use
294.                     b(i).x = ship.x + bSpeed * COS(ship.angle)
295.                     b(i).y = ship.y + bSpeed * SIN(ship.angle)
296.                     b(i).dx = bSpeed * COS(ship.angle)
297.                     b(i).dy = bSpeed * SIN(ship.angle)
298.                     b(i).live = -1
299.                     bullets = bullets + 1
300.                     fire = 0
301.                 END IF
302.                 IF b(i).live THEN 'new location
303.                     b(i).x = b(i).x + b(i).dx
304.                     b(i).y = b(i).y + b(i).dy
305.                     IF b(i).x > 0 AND b(i).x < xmax AND b(i).y > 0 AND b(i).y < ymax THEN 'in bounds draw it
306.  
307.                         'bullet hit aliens?
308.                         FOR ai = 1 TO alienN
309.                             IF SQR((aliens(ai).x - b(i).x) ^ 2 + (aliens(ai).y - b(i).y) ^ 2) < 30 THEN
310.                                 FOR br = 1 TO 120
311.                                     CIRCLE (aliens(ai).x, aliens(ai).y), br / 3, plasma~&(0)
312.                                 NEXT
313.                                 _DISPLAY
314.                                 _DELAY .05
315.                                 hits = hits + 1
316.                                 points = points + 100
317.                                 aliens(ai).live = 0
318.                                 newAlien ai
319.                                 b(i).live = 0
320.                                 _CONTINUE
321.                             END IF
322.                         NEXT
323.                         FOR r = 1 TO nRocks 'check for collision with rock
324.                             IF r(r).live THEN
325.                                 IF SQR((r(r).x - b(i).x) ^ 2 + (r(r).y - b(i).y) ^ 2) < r(r).r THEN 'its a hit!
326.                                     r(r).explodeFrame = 1 'linger with explosion
327.                                     r(r).live = 0
328.                                     hits = hits + 1
329.                                     points = points + ((r(r).speed - .5) * 50 + (90 - (r(r).r - 10)) * 1.1111) / 2
330.                                     IF r(r).r > 30 THEN '       split rock  into ? new ones
331.                                         maxBabyRocks = INT((r(r).r - 10) / 10)
332.                                         maxBabyRocks = irnd&(2, maxBabyRocks) ' pick a number of baby Rocks
333.                                         FOR br = 1 TO maxBabyRocks
334.                                             '                        new rock
335.                                             newRockN = freeRock& '                          get inactive rock number
336.                                             newRock newRockN '                              new identity and activate
337.                                             r(newRockN).r = (r(r).r - 10) / maxBabyRocks '  split in equal parts minus 20% mass
338.                                             r(newRockN).x = r(r).x + irnd&(-30, 30) '       thrown from parent
339.                                             r(newRockN).y = r(r).y + irnd&(-30, 30)
340.                                             r(newRockN).c = r(r).c '                   same color as parent
341.                                             r(newRockN).heading = rrnd(ship.angle - .75 * pi, ship.angle + .75 * pi)
342.                                         NEXT
343.                                     END IF ' big enough to split
344.                                     b(i).live = 0 'kill bullet
345.                                 END IF ' hit rock
346.                             END IF 'rock is there
347.                         NEXT ' rock
348.                         IF b(i).live THEN fcirc b(i).x, b(i).y, 3, _RGB32(255, 255, 0) 'draws bullet
349.                     ELSE
350.                         b(i).live = 0 'out of bounds
351.                     END IF ' bullet is in bounds
352.                 END IF ' bullet live
353.             NEXT ' bullet
354.         END IF ' if ship still live
355.         _DISPLAY
356.         IF ship.live = 0 THEN
357.             lives = lives - 1
358.             IF lives MOD 4 = 0 THEN rocks = rocks + 1
359.             IF lives MOD 4 = 2 THEN alienN = alienN + 1
360.             s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
361.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
362.             _FONT fnt2
363.             s$ = STR$(points) + hs$
364.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
365.             _FONT fnt
366.             s$ = "Press Enter to enter your next life"
367.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
368.             _DISPLAY
369.             WHILE _KEYDOWN(13) = 0: WEND 'wait for enter key
370.         ELSE
371.             _LIMIT 60 ' if ship dies let's rest and regroup  before restart next life
372.         END IF
373.     WEND
374.     _DISPLAY
375. WEND
376. IF points > HS THEN
377.     OPEN "Asteroids High Score.txt" FOR OUTPUT AS #1
378.     PRINT #1, points
379.     CLOSE #1
380. END IF
381. ship.x = -200: ship.y = -200 'get it out of the way
382. i = 0
383. DO
384.     drawStars 0
385.     i = i + 1
386.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
387.     FOR r = 1 TO nRocks
388.         IF r(r).live THEN drawRock r
389.     NEXT
390.     s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
391.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
392.     _FONT fnt2
393.     s$ = STR$(points)
394.     IF points > HS THEN s$ = s$ + " a New Record!" ELSE s$ = STR$(points) + hs$
395.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
396.     _FONT fnt
397.     s$ = "Press q to quit, p or a to Play Again..."
398.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
399.     IF _KEYDOWN(ASC("a")) OR _KEYDOWN(ASC("p")) THEN GOTO restart
400.     _DISPLAY
401.     _LIMIT 60
402. LOOP UNTIL _KEYDOWN(ASC("q"))
403. SYSTEM
404.  
405. SUB drawStars (moving)
406.     TYPE starType
407.         x AS SINGLE
408.         y AS SINGLE
409.         size AS SINGLE
410.         c AS INTEGER
411.     END TYPE
412.     STATIC beenHere, stars(600) AS starType, cy AS LONG
413.     DIM i AS LONG
414.     IF beenHere = 0 THEN 'static part
415.         FOR i = 0 TO 200
416.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = 0
417.             stars(i).c = irnd&(80, 140)
418.         NEXT
419.         FOR i = 0 TO 200
420.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = .3
421.             stars(i).c = irnd&(80, 140)
422.         NEXT
423.  
424.         FOR i = 1 TO 140
425.             stars(i + 400).x = RND * xmax: stars(i + 400).y = RND * ymax: stars(i + 100).size = .6
426.             stars(i).c = irnd&(110, 170)
427.         NEXT
428.         FOR i = 1 TO 50
429.             stars(i + 540).x = RND * xmax: stars(i + 540).y = RND * ymax: stars(i + 170).size = 1.2
430.             stars(i).c = irnd&(140, 200)
431.         NEXT
432.         FOR i = 1 TO 10
433.             stars(i + 590).x = RND * xmax: stars(i + 590).y = RND * ymax: stars(i + 195).size = 2.4
434.             stars(i).c = irnd&(170, 235)
435.         NEXT
436.         cy = ymax / 2
437.         beenHere = 1
438.     END IF
439.     FOR i = 0 TO cy
440.         LINE (0, i)-(xmax, i), _RGB32(0, 0, .1 * i + 4)
441.         LINE (0, ymax - i)-(xmax, ymax - i), _RGB(0, 0, .1 * i + 4)
442.     NEXT
443.     FOR i = 0 TO 200
444.         IF moving THEN
445.             stars(i).x = stars(i).x + .2 * stars(i).size ^ stars(i).size
446.             IF stars(i).x > xmax THEN stars(i).x = -1 * RND * 20
447.         END IF
448.         fcirc stars(i).x, stars(i).y, stars(i).size, _RGB32(stars(i).c - 10, stars(i).c, stars(i).c + 10)
449.     NEXT
450. END SUB
451.  
452. SUB newAlien (i AS LONG)
453.     DIM side AS LONG, heading
454.     RANDOMIZE TIMER * RND 'to avoid making twins
455.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
456.     aliens(i).fireX = irnd(10, xmax - 10)
457.     aliens(i).fireY = irnd(10, ymax - 10)
458.     aliens(i).attackFrame = irnd(30, 400) ' EDIT a tweak to survive a little long before getting murdered with low lives over and over...
459.     SELECT CASE side
460.         CASE 1
461.             aliens(i).x = -10
462.             aliens(i).y = rrnd(20, ymax - 20)
463.         CASE 2
464.             aliens(i).x = xmax + 10
465.             aliens(i).y = rrnd(20, ymax - 20)
466.         CASE 3
467.             aliens(i).x = rrnd(20, xmax - 20)
468.             aliens(i).y = -10
469.         CASE 4
470.             aliens(i).x = rrnd(20, xmax - 20)
471.             aliens(i).y = ymax + 10
472.     END SELECT
473.     heading = _ATAN2(aliens(i).fireY - aliens(i).y, aliens(i).fireX - aliens(i).x)
474.     aliens(i).dx = .5 * COS(heading)
475.     aliens(i).dy = .5 * SIN(heading)
476.     aliens(i).live = 0
477.     aliens(i).transform = 0
478.     aliens(i).c = _RGB32(irnd(128, 255), irnd(0, 255), irnd(0, 255))
479. END SUB
480.  
481. FUNCTION plasma~& (new AS LONG)
482.     STATIC r, g, b, cnt, beenHere
483.     IF beenHere = 0 OR new THEN
484.         r = RND: g = RND: b = RND: beenHere = 1: cnt = 0
485.     END IF
486.     cnt = cnt + .2
487.     plasma~& = _RGB32(127 + 127 * SIN(r * cnt), 127 + 127 * SIN(g * cnt), 127 + 127 * SIN(b * cnt))
488. END FUNCTION
489.  
490. SUB drawAliens (i AS LONG) 'shipType
491.     DIM light AS LONG, heading, r AS LONG, g AS LONG, b AS LONG
492.     IF aliens(i).live THEN
493.         SOUND 6000 + i * 200, .03
494.         IF aliens(i).transform = 0 THEN
495.             r = _RED32(aliens(i).c): g = _GREEN32(aliens(i).c): b = _BLUE32(aliens(i).c)
496.             fellipse aliens(i).x, aliens(i).y, 6, 15, _RGB32(r, g - 120, b - 100)
497.             fellipse aliens(i).x, aliens(i).y, 18, 11, _RGB32(r, g - 60, b - 50)
498.             fellipse aliens(i).x, aliens(i).y, 30, 7, _RGB32(r, g, b)
499.             FOR light = 0 TO 5
500.                 fcirc aliens(i).x - 30 + 11 * light + aliens(i).ls, aliens(i).y, 1, _RGB32(aliens(i).ls * 50, aliens(i).ls * 50, aliens(i).ls * 50)
501.             NEXT
502.             aliens(i).ls = aliens(i).ls + 1
503.             IF aliens(i).ls > 5 THEN aliens(i).ls = 0
504.         ELSE
505.             drawBall aliens(i).x, aliens(i).y, 30, aliens(i).c
506.         END IF
507.         'time to shoot?
508.         aliens(i).x = aliens(i).x + aliens(i).dx
509.         aliens(i).y = aliens(i).y + aliens(i).dy
510.         IF SQR((aliens(i).fireX - aliens(i).x) ^ 2 + (aliens(i).fireY - aliens(i).y) ^ 2) < 5 THEN 'transform into the bolder of death
511.             aliens(i).transform = 1
512.             heading = _ATAN2(ship.y - aliens(i).y, ship.x - aliens(i).x)
513.             aliens(i).dx = 2.5 * COS(heading)
514.             aliens(i).dy = 2.5 * SIN(heading)
515.         END IF
516.         IF aliens(i).x < -10 OR aliens(i).x > xmax + 10 THEN
517.             IF aliens(i).y < -10 OR aliens(i).y > ymax + 10 THEN '  out of bounds goodbye bolder of death!
518.                 aliens(i).live = 0 'man we dodged a bullet here!!!!
519.                 newAlien i 'reset the trap
520.             END IF
521.         END IF
522.     ELSE
523.         IF aliens(i).attackFrame THEN
524.             aliens(i).attackFrame = aliens(i).attackFrame - 1
525.             IF aliens(i).attackFrame = 0 THEN
526.                 aliens(i).live = 1
527.             END IF
528.         END IF
529.     END IF
530. END SUB
531.  
532. FUNCTION freeRock&
533.     DIM i AS LONG
534.     FOR i = rocks + 1 TO nRocks ' look for inactive rock number
535.         IF r(i).live = 0 AND r(i).explodeFrame = 0 THEN freeRock& = i: EXIT FUNCTION
536.     NEXT
537. END FUNCTION
538.  
539. SUB explode (x AS LONG, y AS LONG, r AS LONG, frm AS LONG)
540.     DIM maxParticles AS LONG, i AS LONG, rounds AS LONG, loopCount AS LONG
541.     maxParticles = r * 4
542.     FOR i = 1 TO r
543.         NewDot i, x, y, r
544.     NEXT
545.     rounds = r
546.     FOR loopCount = 0 TO frm
547.         IF _KEYDOWN(27) THEN END
548.         FOR i = 1 TO rounds
549.             dots(i).x = dots(i).x + dots(i).dx
550.             dots(i).y = dots(i).y + dots(i).dy
551.             fcirc dots(i).x, dots(i).y, dots(i).size, dots(i).kolor
552.         NEXT
553.         IF rounds < maxParticles THEN
554.             FOR i = 1 TO r
555.                 NewDot (rounds + i), x, y, r
556.             NEXT
557.             rounds = rounds + r
558.         END IF
559.     NEXT
560. END SUB
561.  
562. SUB NewDot (i AS LONG, x AS LONG, y AS LONG, r AS LONG)
563.     DIM angle, rd
564.     angle = pi * 2 * RND
565.     rd = RND * 30
566.     dots(i).x = x + rd * COS(angle)
567.     dots(i).y = y + rd * SIN(angle)
568.     dots(i).size = RND * r * .05
569.     rd = RND 'STxAxTIC recommended for rounder spreads
570.     dots(i).dx = rd * 10 * (10 - 2 * dots(i).size) * COS(angle)
571.     dots(i).dy = rd * 10 * (10 - 2 * dots(i).size) * SIN(angle)
572.     rd = 20 + RND * 70
573.     dots(i).kolor = _RGBA32(rd, rd, rd, 80)
574. END SUB
575.  
576. SUB drawship 'simple red iso triangle pointed towards radianAngle
577.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, x3 AS LONG, y3 AS LONG
578.     DIM x4 AS LONG, y4 AS LONG, x5 AS LONG, y5 AS LONG
579.     IF ship.thrust > 0 THEN
580.         'burn out flame as thruster dies out
581.         x4 = ship.x + .5 * ship.thrust * COS(ship.angle - 17 / 18 * pi)
582.         y4 = ship.y + .5 * ship.thrust * SIN(ship.angle - 17 / 18 * pi)
583.         x5 = ship.x + .5 * ship.thrust * COS(ship.angle - 19 / 18 * pi)
584.         y5 = ship.y + .5 * ship.thrust * SIN(ship.angle - 19 / 18 * pi)
585.         ftri ship.x, ship.y, x4, y4, x5, y5, &H99FFFF88
586.         ship.thrust = ship.thrust - 1
587.     END IF
588.     'draw ship dead or alive thrust or not, calculate 3 points of triangle ship
589.     fcirc ship.x, ship.y, 30, &H05FFFFFF
590.     x1 = ship.x + 30 * COS(ship.angle) ' front point
591.     y1 = ship.y + 30 * SIN(ship.angle) '
592.     x2 = ship.x + 30 * COS(ship.angle + .6666 * pi) ' wing
593.     y2 = ship.y + 30 * SIN(ship.angle + .6666 * pi)
594.     x3 = ship.x + 30 * COS(ship.angle - .6666 * pi) ' other wing
595.     y3 = ship.y + 30 * SIN(ship.angle - .6666 * pi)
596.     ftri ship.x, ship.y, x1, y1, x2, y2, _RGB32(80, 120, 80, 80)
597.     ftri ship.x, ship.y, x1, y1, x3, y3, _RGB32(60, 100, 60, 80)
598.     LINE (x1, y1)-(ship.x, ship.y), _RGB32(255, 255, 128)
599.     LINE (x1, y1)-(x2, y2), _RGB32(255, 180, 40)
600.     LINE (x1, y1)-(x3, y3), _RGB32(255, 180, 40)
601. END SUB
602.  
603. SUB drawRock (iRock)
604.     RANDOMIZE USING r(iRock).seed 'this prevents having to save a particular sequence of random number
605.     DIM dx, dy, j AS LONG, rRad AS SINGLE, leg AS SINGLE, x0 AS LONG, y0 AS LONG, rc AS LONG, c~&, x1 AS LONG, y1 AS LONG, xoff, yoff, i AS LONG
606.     DIM x2 AS LONG, y2 AS LONG
607.     dx = r(iRock).speed * COS(r(iRock).heading)
608.     dy = r(iRock).speed * SIN(r(iRock).heading) 'update location
609.     r(iRock).ra = r(iRock).ra + r(iRock).spin
610.     IF r(iRock).x + dx + r(iRock).r < 0 OR r(iRock).x + dx - r(iRock).r > xmax OR r(iRock).y + dy + r(iRock).r < 0 OR r(iRock).y + dy - r(iRock).r > ymax THEN
611.         IF iRock <= rocks THEN newRock iRock ELSE r(iRock).live = 0
612.         EXIT SUB ' reassigned get out of here
613.     ELSE
614.         r(iRock).x = r(iRock).x + dx
615.         r(iRock).y = r(iRock).y + dy
616.     END IF
617.     FOR j = 10 TO 3 STEP -1 '                  rock drawing (see demo program where developed code)
618.         rRad = .1 * j * r(iRock).r
619.         leg = rRad * (RND * .7 + .3)
620.         x0 = r(iRock).x + leg * COS(r(iRock).ra)
621.         y0 = r(iRock).y + leg * SIN(r(iRock).ra)
622.         rc = r(iRock).c + 30 * RND - 15
623.         c~& = _RGB32(rc + 5, rc - 10, rc + 5)
624.         x1 = x0
625.         y1 = y0
626.         xoff = RND * 20 - 10 + r(iRock).x
627.         yoff = RND * 20 - 10 + r(iRock).y
628.         FOR i = 1 TO 12
629.             leg = rRad * (RND * .35 + .65)
630.             IF i = 12 THEN
631.                 x2 = x0: y2 = y0
632.             ELSE
633.                 x2 = xoff + leg * COS(i * polyAngle + r(iRock).ra)
634.                 y2 = yoff + leg * SIN(i * polyAngle + r(iRock).ra)
635.             END IF
636.             ftri r(iRock).x, r(iRock).y, x1, y1, x2, y2, c~&
637.             x1 = x2: y1 = y2
638.         NEXT
639.     NEXT
640. END SUB
641.  
642. SUB newRock (iRock)
643.     DIM side AS LONG
644.     RANDOMIZE TIMER * RND 'to avoid making twins
645.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
646.     SELECT CASE side
647.         CASE 1
648.             r(iRock).x = -100
649.             r(iRock).y = rrnd(20, ymax - 20)
650.             r(iRock).heading = 3 * pi / 2 + RND * pi
651.         CASE 2
652.             r(iRock).x = xmax + 100
653.             r(iRock).y = rrnd(20, ymax - 20)
654.             r(iRock).heading = pi / 2 + RND * pi
655.         CASE 3
656.             r(iRock).x = rrnd(20, xmax - 20)
657.             r(iRock).y = -100
658.             r(iRock).heading = RND * pi
659.         CASE 4
660.             r(iRock).x = rrnd(20, xmax - 20)
661.             r(iRock).y = ymax + 100
662.             r(iRock).heading = pi + RND * pi
663.     END SELECT
664.     r(iRock).speed = rrnd(.5, 2.5) 'speed, rotation angle, radius, gray coloring, spin, seed, hit for explosion
665.     r(iRock).ra = RND * 2 * pi
666.     r(iRock).r = irnd&(30, 100)
667.     r(iRock).c = irnd&(60, 110) ' Ken request increase in rock color
668.     r(iRock).spin = rrnd(-pi / 20, pi / 20)
669.     r(iRock).seed = INT(RND * 64000) - 32000
670.     r(iRock).explodeFrame = 0
671.     r(iRock).live = 1
672. END SUB
673.  
674. FUNCTION irnd& (n1, n2) 'return an integer between 2 numbers
675.     DIM l%, h%
676.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
677.     irnd& = INT(RND * (h% - l% + 1)) + l%
678. END FUNCTION
679.  
680. FUNCTION rrnd (n1, n2) ' return number (expecting reals =_single, double, _float depending on default / define setup)
681.     rrnd = (n2 - n1) * RND + n1
682. END FUNCTION
683.  
684. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
685.     DIM red AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
686.     red = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
687.     FOR rr = r TO 0 STEP -1
688.         f = 1 - rr / r
689.         fcirc x, y, rr, _RGB32(red * f, grn * f, blu * f)
690.     NEXT
691. END SUB
692.  
693. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
694.     IF xr = 0 OR yr = 0 THEN EXIT SUB
695.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
696.     DIM x AS LONG, y AS LONG
697.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
698.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
699.     DO WHILE y < yr
700.         y = y + 1
701.         x = SQR((h2w2 - y * y * w2) \ h2)
702.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
703.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
704.     LOOP
705. END SUB
706.  
707. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
708.     DIM D AS LONG
709.     STATIC a&
710.     D = _DEST
711.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
712.     _DEST a&
713.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
714.     PSET (0, 0), K
715.     _BLEND a& '<<<< new 2019-12-16 fix
716.     _DEST D
717.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
718. END SUB
719.  
720. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version
721.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
722.     x0 = R: y0 = 0: e = 0
723.     DO WHILE y0 < x0
724.         IF e <= 0 THEN
725.             y0 = y0 + 1
726.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
727.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
728.             e = e + 2 * y0
729.         ELSE
730.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
731.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
732.             x0 = x0 - 1: e = e - 2 * x0
733.         END IF
734.     LOOP
735.     LINE (x - R, y)-(x + R, y), C, BF
736. END SUB
737.  

If you have Windows, I don't think you even need the Font file in the zip in the Original Post.

Hey 2nd time out with M9 and this!
 

[SierraKen]

Awesome job! I like the new sounds. I didn't know the SOUND command could have such a high frequency and low time on them. I have one suggestion though if you want to keep working on this. Use the player's score to either speed things up or add asteroids and saucers to them. For example, every 5,000 the speed could increase by a certain amount or another asteroid or saucer is added on the screen. But that's all I will say because this is really good!

[bplus]

My last post from late last night is missing. Come to think the forum became inaccessible just after but the post was made?

Anyway I had new high score over 84,000.

I have one suggestion though if you want to keep working on this. Use the player's score to either speed things up or add asteroids and saucers to them.

Every other new life does get harder adding one more parent rock or alien to the game. I think I did slow down the speeds and lowered number of rocks from the mouse shooter versions so people can get use to the A&S turns and K&L thrust and fire buttons.

Number of rocks are started after first main loop handling lives, rocks are reset just before entering the main life loop you can increase them back to 5 or 6 to start and they will increase from there with lives left.

Under newRock and newAlien speeds are set by random number between an upper and lower bound, points for hitting rocks are based on speed and size so try to keep... oh I better set the range as variables that you can adjust or can be adjusted in game code because points are based on max/min speeds.

[Dav]

Good work!  Fun.  I did change the keys to fit my laptop keyboard layout more comfortably (L/R arrows for control, UP for thrust, space for fire, enter for hyperspace).  After that, it's an enjoyable play here.  I'm going to see how high a score I can get now.  My wife is gone this morning, so I can play away!

EDIT:  How about adding a current score & high score display during game play?  I stuck in a LOCATE 1, 32: PRINT points; " / "; HS; before the _DISPLAY call at the bottom of the IF ship.live area, and before the _DISPLAY call after the ufo explodes.  It doesn't seem to slow anything down here, and adds a visual goal to reach.  I also put in a pause game key here for taking a break.

Game is getting fun to waste time with, and it doesn't cost me .25 cents to play. Thanks.

- Dav 

[SierraKen]

Thanks B+, I might tinker around with it later today. Really cool game! Hopefully the final version of this game goes into the Games section of the forum.

[bplus]

M10 mods based on latest comments, have it both ways: arrows or AS and K. Fire is continuous why beat the keyboard up? A little score board in top left corner, I've been wondering about rocks being hit PUS score for round PLUS lives update. Constants added for tinkering with speeds and sizes.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "b+QB64 Asteroids M10" 'started 2018-07-13
3. '2020 - Oct and Nov: Special thanks to SierraKen who has been helpful with suggestions, ideas and fixes.
4. RANDOMIZE TIMER
5.  
6. ' Far far away in a universe where Newton's 1st Law of Motion is not obeyed...    ;-))
7.  
8.  
9. '                                            New Controls
10. ' key a or left arrow = turn left
11. ' key s or right arrow = turn right
12. ' enter or spacebar =  "hyperspace" show up somewhere else  better or worse use when collision is imminent
13. ' key k or up arrow = thrust  just a burst in direction you are pointed but doesn't last
14. ' fire! owwha, owha, owha...  is now continuous
15.  
16. '=================================================================================================================
17.  
18. ' 2020-10-27 remove the alternate subs and get down below 200 LOC almost there now! new shooter action font and background
19. ' 2020-10-28 another makeover explosions and split asteroids
20. ' 2020-10-29 fix baby rock management, break between lives
21. ' 2020-10-29 fix left/right gun, fix explosions over many frames to eliminate pause in action, speed up 60 fps
22. ' 2020-10-30 m3 SierraKen's idea to angle shooter with mousewheel also finish WASD options, more rocks, points system
23. ' points:
24. ' The higher the speed the better    speed range .5 to 2.5, diff = 2 * 50 = 100          s - .5 * 50
25. ' DELETE The lower the color the better   color range 10 to 60, diff =      50 * 2 = 100  50 - (c - 10) * 2
26. ' The smaller the size the better  size range 10 to 100, diff = 90 * 1.1111 = 100  90 - (sz -10) * 1.1111
27. '        ((speed - .5) * 50 + (90 - (r - 10)) * 1.1111) / 2 = 100 best score per hit
28. ' 2020-10-30 increase level of difficulty, fix double lives lost, add an ending after all lives spent.
29. ' 2020-10-31 M4 They are Here - the aliens have accepted my invitaion for war games don't get caught in their beam.
30. ' rework ending and variable LONG suffix. Aliens on the attack 100 points before or after transformed into the Bolder of Death.
31. ' 2020-11-01 M5 FX Moving through space, Oh yeah, more aliens!
32. ' 2020-11-01 M6 add play again and save high game , continuous shoot
33. ' 2020-11-01 M7 fix hits count when hit alien ship or Bolder of Death. Fix lights on aliens ship. I want to see collsions with ship.
34. ' Ken recommends removing text in middle of screen, yeah, distracting. Makeover ship as with mouse x, y it's center. Add Splash screen.
35. ' Show mouse in between lives so can be in screen center when press key to start next run.
36.  
37. ' 2020-11-03 M9 watching videos on Asteroids, I found a view and description of the control panel, it is:
38. ' 2 buttons on left and lower button in middle and 2 buttons on right level with 2 on left.
39. ' 2 buttons on left are left and right turns they will be Keys A and S
40. ' The middle will be spacebar for Hypespace or these days we might call it worm hole, jump to another location better or worse!
41. ' 2 buttons on right K and L: K will be a thruster of sorts you eventually come to a stop (not what Newton would like) L is the fire button.
42. ' So let's try that. I am impressed by hitting thruster and shooting all around as you dift in direction gun was pointed when hit thruster.
43. ' Lighten rocks and change points, based now only on size and speed of Asteroids.
44. ' 2020-11-04 M9 Install new update to thrust control. Thanks to SierraKen for finding out what happened to Hyperspace jump when press
45. ' spacebar a 2nd time in a life. Oh also Boulders of Death are now more like smooth colored spheres. Ahhhh Fixed the crashing at the borders
46. ' now fly out one side and come back in on the other! This is getting good! Adding some sound effects.
47. ' 2020-11-05 M10 set some constants for starting game so can just change them to level of play desired.
48. ' speed points =  50 * (rockSpeed - minRockSpeed)/rockSpeedRange > fastest rock gets 50 points
49. ' size points = 50 * (rockSizeRange - (rockSize - minRockSize))/rockSizeRange  > smallest rock gets 50 points
50. ' points = points +  50 * ( (rockSpeed - minRockSpeed)/rockSpeedRange +  (rockSizeRange - (rockSize - minRockSize))/rockSizeRange )
51. ' Dav's comments: Add arrow keys for left right turns and up for thrust, continuous fire now! A little score board in top left corner.
52. ' Dav I am keeping spacebar for Hyperspace but also Enter, don't need fire button now.
53. ' Try the A for left and the right arrow for right turns.
54.  
55. '================================================================================================================
56.  
57. '    NOTE: !!!!!!!!!!!!!!!   When there is a pause in action, just press enter,  as in enter a new life!
58.  
59. '================================================================================================================
60.  
61. CONST xmax = 1200, ymax = 700, pi = _PI, polyAngle = _PI / 6, nRocks = 300, nBullets = 2000, bSpeed = 15
62. CONST startRocks = 2, minRockSpeed = 0.5000, maxRockSpeed = 2.5000, minRockSize = 10, maxRockSize = 100
63. CONST rockSpeedRange = maxRockSpeed - minRockSpeed, rockSizeRange = maxRockSize - minRockSize
64. CONST alienSpeed = rockSpeedRange / 2 + minRockSpeed ' average rock speed
65.  
66. TYPE alienType
67.     x AS SINGLE
68.     y AS SINGLE
69.     dx AS SINGLE
70.     dy AS SINGLE
71.     ls AS LONG ' lights offset and gray scale
72.     c AS _UNSIGNED LONG ' color
73.     live AS LONG
74.     attackFrame AS LONG
75.     fireX AS SINGLE
76.     fireY AS SINGLE
77.     transform AS LONG
78. END TYPE
79.  
80. TYPE particle
81.     x AS SINGLE
82.     y AS SINGLE
83.     dx AS SINGLE
84.     dy AS SINGLE
85.     size AS SINGLE
86.     kolor AS _UNSIGNED LONG
87. END TYPE
88.  
89. TYPE bullet
90.     x AS SINGLE
91.     y AS SINGLE
92.     dx AS SINGLE
93.     dy AS SINGLE
94.     live AS LONG
95. END TYPE
96.  
97. TYPE shipType
98.     x AS SINGLE
99.     y AS SINGLE
100.     live AS LONG
101.     speed AS SINGLE '       just a constant now when Thrust is applied
102.     thrustAngle AS SINGLE ' ship/gun angle at moment Thrust is pressed
103.     angle AS SINGLE '       rotated position ship/gun now A or S keypress or hold down
104.     thrust AS LONG '        this now tracks how many frames ship will move at speed and thrustAngle
105. END TYPE
106.  
107. TYPE rock
108.     x AS SINGLE
109.     y AS SINGLE
110.     r AS LONG '            radius
111.     ra AS SINGLE '         rotation position   a = a + spin
112.     heading AS SINGLE '    heading from which dx, dy are calc with speed
113.     speed AS SINGLE '      speed
114.     spin AS SINGLE '       rotation direction and amount
115.     seed AS LONG '         for drawing rocks with RND USING
116.     c AS LONG '            color   rgb(c, c, c)
117.     live AS LONG '         need this to track rocks still active like bullets
118.     explodeFrame AS LONG ' after a rock is hit by bullet, it explodes and in more than one frame
119. END TYPE
120.  
121. REDIM SHARED aliens(1 TO 5) AS alienType
122. DIM SHARED dots(2000) AS particle ' explosions
123. DIM SHARED b(nBullets) AS bullet
124. DIM SHARED ship AS shipType
125. DIM SHARED r(nRocks) AS rock
126. DIM SHARED lives AS LONG
127. DIM SHARED points AS LONG
128. DIM SHARED rocks AS LONG 'rocks is the minimum number of parent rocks to have on screen  automatic replace when hit or out of bounds
129.  
130. DIM HS AS LONG, fnt AS LONG, fnt2 AS LONG ' file LOAD handles
131. DIM i AS LONG, bullets AS LONG, fire AS LONG ' index and bullets
132. DIM r AS LONG, newRockN AS LONG, maxBabyRocks AS LONG, br AS LONG, hits AS LONG ' rock stuff
133. DIM ai AS LONG, alienN AS LONG ' alien index and number
134. DIM kh AS LONG 'key hit for ship thrust k or up arrow or hyperspace jump spacebar
135. DIM hs$, s$, k$, t, lastt 'high score, general string and times for bullets
136. DIM rockPoints AS LONG, roundPoints AS LONG ' various points scores
137. ship.speed = 3.5 'this would be a constant but ship has to declared as Ship Type first, Hyperspace jump
138.  
139. SCREEN _NEWIMAGE(xmax, ymax, 32)
140. _SCREENMOVE 100, 20
141. _FULLSCREEN
142.  
143. fnt = _LOADFONT("ARLRDBD.ttf", 16, "MONOSPACE")
144. fnt2 = _LOADFONT("ARLRDBD.ttf", 40, "MONOSPACE")
145. _FONT fnt2
146. COLOR &HFF00FFFF, &H00000000
147.  
148. IF _FILEEXISTS("Asteroids High Score.txt") THEN
149.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
150.     INPUT #1, HS
151.     CLOSE #1
152. END IF
153. hs$ = "High Score:" + STR$(HS)
154.  
155. 'a little splash screen
156. rocks = 7: alienN = 3
157. FOR i = 1 TO nRocks
158.     newRock i
159.     IF i > rocks THEN r(i).live = 0
160. NEXT
161. FOR i = 1 TO alienN
162.     newAlien i
163. NEXT
164. i = 0
165. DO
166.     drawStars 0
167.     i = i + 1
168.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
169.     FOR r = 1 TO nRocks
170.         IF r(r).live THEN drawRock r
171.     NEXT
172.     FOR i = 1 TO alienN
173.         drawAliens i
174.     NEXT
175.     _FONT fnt2
176.     s$ = "*** b+QB64 Asteroids ***"
177.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 60), s$
178.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(hs$)) / 2, 140), hs$
179.     s$ = "A or arrow = Left spin"
180.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 220), s$
181.     s$ = "S or arrow = Right Spin"
182.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 300), s$
183.     s$ = "Space or Enter = Hyper jump"
184.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 380), s$
185.     s$ = "K or up arrow = Thrust"
186.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 460), s$
187.     s$ = "Escape quit, any plays"
188.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, 540), s$
189.     _FONT fnt
190.     IF _KEYDOWN(27) THEN SYSTEM
191.     k$ = INKEY$
192.     _DISPLAY
193.     _LIMIT 60
194. LOOP UNTIL LEN(k$)
195.  
196. _MOUSEHIDE
197. restart:
198. IF _FILEEXISTS("Asteroids High Score.txt") THEN
199.     OPEN "Asteroids High Score.txt" FOR INPUT AS #1
200.     INPUT #1, HS
201.     CLOSE #1
202. END IF
203. hs$ = "  High Score:" + STR$(HS)
204. lives = 10: alienN = 1: rocks = startRocks: ' always active rocks
205. points = 0: hits = 0: bullets = 0
206. WHILE lives > 0 AND _KEYDOWN(27) = 0 ' init start restart
207.     REDIM aliens(1 TO alienN) AS alienType
208.     FOR ai = 1 TO alienN
209.         newAlien ai
210.     NEXT
211.     FOR i = 1 TO nRocks 'reset rocks mainly clear baby rocks
212.         newRock (i)
213.         IF i > rocks THEN r(i).live = 0
214.     NEXT
215.     ship.x = xmax / 2 'avoids explosions top left corner at start, dang still get some!
216.     ship.y = ymax / 2
217.     ship.angle = 0
218.     ship.thrustAngle = 0
219.     ship.thrust = 0
220.     ship.live = 1
221.     rockPoints = 0
222.     roundPoints = 0
223.     WHILE ship.live AND _KEYDOWN(27) = 0
224.  
225.         _KEYCLEAR 'clear all previous INKEY$ or _KEYHIT and variables  so ship should always start in middle of sceen pointed east
226.         kh = 0
227.  
228.         'draw everything then process bullets
229.         drawStars 1
230.         LOCATE 1, 1: PRINT "Lives:"; lives
231.         LOCATE 2, 1: PRINT "Last Rock:"; STR$(rockPoints)
232.         LOCATE 3, 1: PRINT "Round:;"; STR$(roundPoints)
233.         LOCATE 4, 1: PRINT "Points:"; STR$(points)
234.         LOCATE 5, 1: PRINT "High Score:"; STR$(HS)
235.         FOR ai = 1 TO alienN
236.             drawAliens ai
237.         NEXT
238.         FOR i = 1 TO nRocks
239.             IF r(i).live THEN 'make sure if we crash into a ship it is a live rock, not one sitting on side waiting to be called up
240.                 drawRock i ' while drawing rocks the ship could be blown up
241.                 IF ((r(i).x - ship.x) ^ 2 + (r(i).y - ship.y) ^ 2) ^ .5 < r(i).r + 30 THEN 'rock collides with ship?
242.                     FOR br = 1 TO 200 STEP 5
243.                         CIRCLE ((ship.x + r(i).x) / 2, (ship.y + r(i).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
244.                     NEXT
245.                     drawRock i
246.                     drawship
247.                     ship.live = 0
248.                     IF i <= rocks THEN newRock i ELSE r(i).live = 0
249.                 END IF
250.             END IF
251.         NEXT
252.         FOR i = 1 TO nRocks 'smoke up the place with rock debris fields still flying out from hit frames ago
253.             IF r(i).explodeFrame THEN
254.                 r(i).explodeFrame = r(i).explodeFrame + 1
255.                 IF r(i).explodeFrame > .25 * r(i).r THEN
256.                     r(i).explodeFrame = 0
257.                     IF i <= rocks THEN newRock i ' now replace the rock
258.                 ELSE
259.                     explode r(i).x, r(i).y, r(i).r, r(i).explodeFrame
260.                 END IF
261.             END IF
262.         NEXT
263.         IF ship.live THEN
264.             FOR ai = 1 TO alienN
265.                 IF SQR((aliens(ai).x - ship.x) ^ 2 + (aliens(ai).y - ship.y) ^ 2) < 60 THEN 'aliens and ship collisde boom boom
266.                     FOR br = 1 TO 200 STEP 5
267.                         CIRCLE ((ship.x + aliens(ai).x) / 2, (ship.y + aliens(ai).y) / 2), br, _RGB32(255 - br, 255 - 2 * br, 0)
268.                     NEXT
269.                     drawship
270.                     ship.live = 0
271.                     _CONTINUE
272.                 ELSE
273.                     drawship
274.                 END IF
275.             NEXT
276.  
277.             '                                                                   ship controls update
278.             'a key or left arrow = left spin
279.             IF _KEYDOWN(97) OR _KEYDOWN(19200) THEN ship.angle = ship.angle - pi / 48
280.  
281.             's key or right arrow = right spin
282.             IF _KEYDOWN(115) OR _KEYDOWN(19712) THEN ship.angle = ship.angle + pi / 48
283.  
284.             'l is Fire!  JUST CONTINUOUS FIRE
285.             fire = 0
286.             'IF _KEYDOWN(108) THEN
287.             t = TIMER(.01)
288.             IF lastt = 0 OR t - lastt > .15 THEN fire = 1: SOUND 2088, .01: lastt = t
289.             'END IF
290.  
291.             kh = _KEYHIT
292.             SELECT CASE kh
293.                 CASE 107, 18432 'thrust  k key or up arrow
294.                     SOUND 488, .01
295.                     ship.thrustAngle = ship.angle: ship.thrust = 120
296.                 CASE 13, 32 ' space = hyperspace jump
297.                     RANDOMIZE TIMER
298.                     ship.x = (xmax - 300) * RND + 150: ship.y = (ymax - 300) * RND + 150: ship.thrust = 0
299.             END SELECT
300.  
301.             '                                                                   locate ship
302.             IF ship.thrust > 0 THEN
303.                 'relocate ship position
304.                 ship.x = ship.x + ship.speed * COS(ship.thrustAngle)
305.                 ship.y = ship.y + ship.speed * SIN(ship.thrustAngle)
306.             END IF
307.             '                                                                    jump borders
308.             IF ship.x < 0 THEN ship.x = xmax - ABS(ship.x)
309.             IF ship.x > xmax THEN ship.x = ship.x - xmax
310.             IF ship.y < 0 THEN ship.y = ymax - ABS(ship.y)
311.             IF ship.y > ymax THEN ship.y = ship.y - ymax
312.  
313.  
314.             FOR i = 0 TO nBullets '                                               handle bullets
315.                 IF b(i).live = 0 AND fire = 1 THEN 'have inactive bullet to use
316.                     b(i).x = ship.x + bSpeed * COS(ship.angle)
317.                     b(i).y = ship.y + bSpeed * SIN(ship.angle)
318.                     b(i).dx = bSpeed * COS(ship.angle)
319.                     b(i).dy = bSpeed * SIN(ship.angle)
320.                     b(i).live = -1
321.                     bullets = bullets + 1
322.                     fire = 0
323.                 END IF
324.                 IF b(i).live THEN 'new location
325.                     b(i).x = b(i).x + b(i).dx
326.                     b(i).y = b(i).y + b(i).dy
327.                     IF b(i).x > 0 AND b(i).x < xmax AND b(i).y > 0 AND b(i).y < ymax THEN 'in bounds draw it
328.  
329.                         'bullet hit aliens?
330.                         FOR ai = 1 TO alienN
331.                             IF SQR((aliens(ai).x - b(i).x) ^ 2 + (aliens(ai).y - b(i).y) ^ 2) < 30 THEN
332.                                 FOR br = 1 TO 120
333.                                     CIRCLE (aliens(ai).x, aliens(ai).y), br / 3, plasma~&(0)
334.                                 NEXT
335.                                 _DISPLAY
336.                                 _DELAY .05
337.                                 hits = hits + 1
338.                                 roundPoints = roundPoints + 100
339.                                 points = points + 100
340.                                 aliens(ai).live = 0
341.                                 newAlien ai
342.                                 b(i).live = 0
343.                                 _CONTINUE
344.                             END IF
345.                         NEXT
346.                         FOR r = 1 TO nRocks 'check for collision with rock
347.                             IF r(r).live THEN
348.                                 IF SQR((r(r).x - b(i).x) ^ 2 + (r(r).y - b(i).y) ^ 2) < r(r).r THEN 'its a hit!
349.                                     r(r).explodeFrame = 1 'linger with explosion
350.                                     r(r).live = 0
351.                                     hits = hits + 1
352.                                     rockPoints = 50 * ((r(r).speed - minRockSpeed) / rockSpeedRange + (rockSizeRange - (r(r).r - minRockSize)) / rockSizeRange)
353.                                     roundPoints = roundPoints + rockPoints
354.                                     points = points + rockPoints
355.                                     IF r(r).r > 30 THEN '       split rock  into ? new ones
356.                                         maxBabyRocks = INT((r(r).r - 10) / 10)
357.                                         maxBabyRocks = irnd&(2, maxBabyRocks) ' pick a number of baby Rocks
358.                                         FOR br = 1 TO maxBabyRocks
359.                                             '                        new rock
360.                                             newRockN = freeRock& '                          get inactive rock number
361.                                             newRock newRockN '                              new identity and activate
362.                                             r(newRockN).r = (r(r).r - 10) / maxBabyRocks '  split in equal parts minus 20% mass
363.                                             r(newRockN).x = r(r).x + irnd&(-30, 30) '       thrown from parent
364.                                             r(newRockN).y = r(r).y + irnd&(-30, 30)
365.                                             r(newRockN).c = r(r).c '                   same color as parent
366.                                             r(newRockN).heading = rrnd(ship.angle - .75 * pi, ship.angle + .75 * pi)
367.                                         NEXT
368.                                     END IF ' big enough to split
369.                                     b(i).live = 0 'kill bullet
370.                                 END IF ' hit rock
371.                             END IF 'rock is there
372.                         NEXT ' rock
373.                         IF b(i).live THEN fcirc b(i).x, b(i).y, 3, _RGB32(255, 255, 0) 'draws bullet
374.                     ELSE
375.                         b(i).live = 0 'out of bounds
376.                     END IF ' bullet is in bounds
377.                 END IF ' bullet live
378.             NEXT ' bullet
379.         END IF ' if ship still live
380.         _DISPLAY
381.         IF ship.live = 0 THEN
382.             lives = lives - 1
383.             IF lives MOD 4 = 0 THEN rocks = rocks + 1
384.             IF lives MOD 4 = 2 THEN alienN = alienN + 1
385.             s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
386.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
387.             _FONT fnt2
388.             s$ = STR$(points) + hs$
389.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
390.             _FONT fnt
391.             s$ = "Press enter to enter next life."
392.             _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
393.             _DISPLAY
394.             kh = 0
395.             WHILE kh <> 13
396.                 kh = _KEYHIT
397.             WEND 'wait for enter key
398.         ELSE
399.             _LIMIT 60 ' if ship dies let's rest and regroup  before restart next life
400.         END IF
401.     WEND
402.     _DISPLAY
403. WEND
404. IF points > HS THEN
405.     OPEN "Asteroids High Score.txt" FOR OUTPUT AS #1
406.     PRINT #1, points
407.     CLOSE #1
408. END IF
409. ship.x = -200: ship.y = -200 'get it out of the way
410. i = 0
411. DO
412.     drawStars 0
413.     i = i + 1
414.     IF i MOD 30 = 29 AND rocks < nRocks THEN rocks = rocks + 1: r(rocks).live = 1
415.     FOR r = 1 TO nRocks
416.         IF r(r).live THEN drawRock r
417.     NEXT
418.     s$ = "Lives:" + STR$(lives) + "  Hits:" + STR$(hits) + "  Bullets:" + STR$(bullets) + "  Shooting:" + STR$(INT(hits * 100 / bullets)) + "%"
419.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 - 80), s$
420.     _FONT fnt2
421.     s$ = STR$(points)
422.     IF points > HS THEN s$ = s$ + " a New Record!" ELSE s$ = STR$(points) + hs$
423.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2), s$
424.     _FONT fnt
425.     s$ = "Press q to quit, p or a to Play Again..."
426.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(s$)) / 2, ymax / 2 + 120), s$
427.     IF _KEYDOWN(ASC("a")) OR _KEYDOWN(ASC("p")) THEN GOTO restart
428.     _DISPLAY
429.     _LIMIT 60
430. LOOP UNTIL _KEYDOWN(ASC("q"))
431. SYSTEM
432.  
433. SUB drawStars (moving)
434.     TYPE starType
435.         x AS SINGLE
436.         y AS SINGLE
437.         size AS SINGLE
438.         c AS INTEGER
439.     END TYPE
440.     STATIC beenHere, stars(600) AS starType, cy AS LONG
441.     DIM i AS LONG
442.     IF beenHere = 0 THEN 'static part
443.         FOR i = 0 TO 200
444.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = 0
445.             stars(i).c = irnd&(80, 140)
446.         NEXT
447.         FOR i = 0 TO 200
448.             stars(i).x = RND * xmax: stars(i).y = RND * ymax: stars(i).size = .3
449.             stars(i).c = irnd&(80, 140)
450.         NEXT
451.  
452.         FOR i = 1 TO 140
453.             stars(i + 400).x = RND * xmax: stars(i + 400).y = RND * ymax: stars(i + 100).size = .6
454.             stars(i).c = irnd&(110, 170)
455.         NEXT
456.         FOR i = 1 TO 50
457.             stars(i + 540).x = RND * xmax: stars(i + 540).y = RND * ymax: stars(i + 170).size = 1.2
458.             stars(i).c = irnd&(140, 200)
459.         NEXT
460.         FOR i = 1 TO 10
461.             stars(i + 590).x = RND * xmax: stars(i + 590).y = RND * ymax: stars(i + 195).size = 2.4
462.             stars(i).c = irnd&(170, 235)
463.         NEXT
464.         cy = ymax / 2
465.         beenHere = 1
466.     END IF
467.     FOR i = 0 TO cy
468.         LINE (0, i)-(xmax, i), _RGB32(0, 0, .1 * i + 4)
469.         LINE (0, ymax - i)-(xmax, ymax - i), _RGB(0, 0, .1 * i + 4)
470.     NEXT
471.     FOR i = 0 TO 200
472.         IF moving THEN
473.             stars(i).x = stars(i).x + .2 * stars(i).size ^ stars(i).size
474.             IF stars(i).x > xmax THEN stars(i).x = -1 * RND * 20
475.         END IF
476.         fcirc stars(i).x, stars(i).y, stars(i).size, _RGB32(stars(i).c - 10, stars(i).c, stars(i).c + 10)
477.     NEXT
478. END SUB
479.  
480. SUB newAlien (i AS LONG)
481.     DIM side AS LONG, heading
482.     RANDOMIZE TIMER * RND 'to avoid making twins
483.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
484.     aliens(i).fireX = irnd(10, xmax - 10)
485.     aliens(i).fireY = irnd(10, ymax - 10)
486.     aliens(i).attackFrame = irnd(30, 400) ' EDIT a tweak to survive a little long before getting murdered with low lives over and over...
487.     SELECT CASE side
488.         CASE 1
489.             aliens(i).x = -10
490.             aliens(i).y = rrnd(20, ymax - 20)
491.         CASE 2
492.             aliens(i).x = xmax + 10
493.             aliens(i).y = rrnd(20, ymax - 20)
494.         CASE 3
495.             aliens(i).x = rrnd(20, xmax - 20)
496.             aliens(i).y = -10
497.         CASE 4
498.             aliens(i).x = rrnd(20, xmax - 20)
499.             aliens(i).y = ymax + 10
500.     END SELECT
501.     heading = _ATAN2(aliens(i).fireY - aliens(i).y, aliens(i).fireX - aliens(i).x)
502.     aliens(i).dx = alienSpeed * COS(heading)
503.     aliens(i).dy = alienSpeed * SIN(heading)
504.     aliens(i).live = 0
505.     aliens(i).transform = 0
506.     aliens(i).c = _RGB32(irnd(128, 255), irnd(0, 255), irnd(0, 255))
507. END SUB
508.  
509. FUNCTION plasma~& (new AS LONG)
510.     STATIC r, g, b, cnt, beenHere
511.     IF beenHere = 0 OR new THEN
512.         r = RND: g = RND: b = RND: beenHere = 1: cnt = 0
513.     END IF
514.     cnt = cnt + .2
515.     plasma~& = _RGB32(127 + 127 * SIN(r * cnt), 127 + 127 * SIN(g * cnt), 127 + 127 * SIN(b * cnt))
516. END FUNCTION
517.  
518. SUB drawAliens (i AS LONG) 'shipType
519.     DIM light AS LONG, heading, r AS LONG, g AS LONG, b AS LONG
520.     IF aliens(i).live THEN
521.         SOUND 6000 + i * 200, .07
522.         IF aliens(i).transform = 0 THEN
523.             r = _RED32(aliens(i).c): g = _GREEN32(aliens(i).c): b = _BLUE32(aliens(i).c)
524.             fellipse aliens(i).x, aliens(i).y, 6, 15, _RGB32(r, g - 120, b - 100)
525.             fellipse aliens(i).x, aliens(i).y, 18, 11, _RGB32(r, g - 60, b - 50)
526.             fellipse aliens(i).x, aliens(i).y, 30, 7, _RGB32(r, g, b)
527.             FOR light = 0 TO 5
528.                 fcirc aliens(i).x - 30 + 11 * light + aliens(i).ls, aliens(i).y, 1, _RGB32(aliens(i).ls * 50, aliens(i).ls * 50, aliens(i).ls * 50)
529.             NEXT
530.             aliens(i).ls = aliens(i).ls + 1
531.             IF aliens(i).ls > 5 THEN aliens(i).ls = 0
532.         ELSE
533.             drawBall aliens(i).x, aliens(i).y, 30, aliens(i).c
534.         END IF
535.         'time to shoot?
536.         aliens(i).x = aliens(i).x + aliens(i).dx
537.         aliens(i).y = aliens(i).y + aliens(i).dy
538.         IF SQR((aliens(i).fireX - aliens(i).x) ^ 2 + (aliens(i).fireY - aliens(i).y) ^ 2) < 5 THEN 'transform into the bolder of death
539.             aliens(i).transform = 1
540.             heading = _ATAN2(ship.y - aliens(i).y, ship.x - aliens(i).x)
541.             aliens(i).dx = 2.5 * COS(heading)
542.             aliens(i).dy = 2.5 * SIN(heading)
543.         END IF
544.         IF aliens(i).x < -10 OR aliens(i).x > xmax + 10 THEN
545.             IF aliens(i).y < -10 OR aliens(i).y > ymax + 10 THEN '  out of bounds goodbye bolder of death!
546.                 aliens(i).live = 0 'man we dodged a bullet here!!!!
547.                 newAlien i 'reset the trap
548.             END IF
549.         END IF
550.     ELSE
551.         IF aliens(i).attackFrame THEN
552.             aliens(i).attackFrame = aliens(i).attackFrame - 1
553.             IF aliens(i).attackFrame = 0 THEN
554.                 aliens(i).live = 1
555.             END IF
556.         END IF
557.     END IF
558. END SUB
559.  
560. FUNCTION freeRock&
561.     DIM i AS LONG
562.     FOR i = rocks + 1 TO nRocks ' look for inactive rock number
563.         IF r(i).live = 0 AND r(i).explodeFrame = 0 THEN freeRock& = i: EXIT FUNCTION
564.     NEXT
565. END FUNCTION
566.  
567. SUB explode (x AS LONG, y AS LONG, r AS LONG, frm AS LONG)
568.     DIM maxParticles AS LONG, i AS LONG, rounds AS LONG, loopCount AS LONG
569.     maxParticles = r * 4
570.     FOR i = 1 TO r
571.         NewDot i, x, y, r
572.     NEXT
573.     rounds = r
574.     FOR loopCount = 0 TO frm
575.         IF _KEYDOWN(27) THEN END
576.         FOR i = 1 TO rounds
577.             dots(i).x = dots(i).x + dots(i).dx
578.             dots(i).y = dots(i).y + dots(i).dy
579.             fcirc dots(i).x, dots(i).y, dots(i).size, dots(i).kolor
580.         NEXT
581.         IF rounds < maxParticles THEN
582.             FOR i = 1 TO r
583.                 NewDot (rounds + i), x, y, r
584.             NEXT
585.             rounds = rounds + r
586.         END IF
587.     NEXT
588. END SUB
589.  
590. SUB NewDot (i AS LONG, x AS LONG, y AS LONG, r AS LONG)
591.     DIM angle, rd
592.     angle = pi * 2 * RND
593.     rd = RND * 30
594.     dots(i).x = x + rd * COS(angle)
595.     dots(i).y = y + rd * SIN(angle)
596.     dots(i).size = RND * r * .05
597.     rd = RND 'STxAxTIC recommended for rounder spreads
598.     dots(i).dx = rd * 10 * (10 - 2 * dots(i).size) * COS(angle)
599.     dots(i).dy = rd * 10 * (10 - 2 * dots(i).size) * SIN(angle)
600.     rd = 20 + RND * 70
601.     dots(i).kolor = _RGBA32(rd, rd, rd, 80)
602. END SUB
603.  
604. SUB drawship 'simple red iso triangle pointed towards radianAngle
605.     DIM x1 AS LONG, y1 AS LONG, x2 AS LONG, y2 AS LONG, x3 AS LONG, y3 AS LONG
606.     DIM x4 AS LONG, y4 AS LONG, x5 AS LONG, y5 AS LONG
607.     IF ship.thrust > 0 THEN
608.         'burn out flame as thruster dies out
609.         x4 = ship.x + .5 * ship.thrust * COS(ship.angle - 17 / 18 * pi)
610.         y4 = ship.y + .5 * ship.thrust * SIN(ship.angle - 17 / 18 * pi)
611.         x5 = ship.x + .5 * ship.thrust * COS(ship.angle - 19 / 18 * pi)
612.         y5 = ship.y + .5 * ship.thrust * SIN(ship.angle - 19 / 18 * pi)
613.         ftri ship.x, ship.y, x4, y4, x5, y5, &H99FFFF88
614.         ship.thrust = ship.thrust - 1
615.     END IF
616.     'draw ship dead or alive thrust or not, calculate 3 points of triangle ship
617.     fcirc ship.x, ship.y, 30, &H05FFFFFF
618.     x1 = ship.x + 30 * COS(ship.angle) ' front point
619.     y1 = ship.y + 30 * SIN(ship.angle) '
620.     x2 = ship.x + 30 * COS(ship.angle + .6666 * pi) ' wing
621.     y2 = ship.y + 30 * SIN(ship.angle + .6666 * pi)
622.     x3 = ship.x + 30 * COS(ship.angle - .6666 * pi) ' other wing
623.     y3 = ship.y + 30 * SIN(ship.angle - .6666 * pi)
624.     ftri ship.x, ship.y, x1, y1, x2, y2, _RGB32(80, 120, 80, 80)
625.     ftri ship.x, ship.y, x1, y1, x3, y3, _RGB32(60, 100, 60, 80)
626.     LINE (x1, y1)-(ship.x, ship.y), _RGB32(255, 255, 128)
627.     LINE (x1, y1)-(x2, y2), _RGB32(255, 180, 40)
628.     LINE (x1, y1)-(x3, y3), _RGB32(255, 180, 40)
629. END SUB
630.  
631. SUB drawRock (iRock)
632.     RANDOMIZE USING r(iRock).seed 'this prevents having to save a particular sequence of random number
633.     DIM dx, dy, j AS LONG, rRad AS SINGLE, leg AS SINGLE, x0 AS LONG, y0 AS LONG, rc AS LONG, c~&, x1 AS LONG, y1 AS LONG, xoff, yoff, i AS LONG
634.     DIM x2 AS LONG, y2 AS LONG
635.     dx = r(iRock).speed * COS(r(iRock).heading)
636.     dy = r(iRock).speed * SIN(r(iRock).heading) 'update location
637.     r(iRock).ra = r(iRock).ra + r(iRock).spin
638.     IF r(iRock).x + dx + r(iRock).r < 0 OR r(iRock).x + dx - r(iRock).r > xmax OR r(iRock).y + dy + r(iRock).r < 0 OR r(iRock).y + dy - r(iRock).r > ymax THEN
639.         IF iRock <= rocks THEN newRock iRock ELSE r(iRock).live = 0
640.         EXIT SUB ' reassigned get out of here
641.     ELSE
642.         r(iRock).x = r(iRock).x + dx
643.         r(iRock).y = r(iRock).y + dy
644.     END IF
645.     FOR j = 10 TO 3 STEP -1 '                  rock drawing (see demo program where developed code)
646.         rRad = .1 * j * r(iRock).r
647.         leg = rRad * (RND * .7 + .3)
648.         x0 = r(iRock).x + leg * COS(r(iRock).ra)
649.         y0 = r(iRock).y + leg * SIN(r(iRock).ra)
650.         rc = r(iRock).c + 30 * RND - 15
651.         c~& = _RGB32(rc + 5, rc - 10, rc + 5)
652.         x1 = x0
653.         y1 = y0
654.         xoff = RND * 20 - 10 + r(iRock).x
655.         yoff = RND * 20 - 10 + r(iRock).y
656.         FOR i = 1 TO 12
657.             leg = rRad * (RND * .35 + .65)
658.             IF i = 12 THEN
659.                 x2 = x0: y2 = y0
660.             ELSE
661.                 x2 = xoff + leg * COS(i * polyAngle + r(iRock).ra)
662.                 y2 = yoff + leg * SIN(i * polyAngle + r(iRock).ra)
663.             END IF
664.             ftri r(iRock).x, r(iRock).y, x1, y1, x2, y2, c~&
665.             x1 = x2: y1 = y2
666.         NEXT
667.     NEXT
668. END SUB
669.  
670. SUB newRock (iRock)
671.     DIM side AS LONG
672.     RANDOMIZE TIMER * RND 'to avoid making twins
673.     side = irnd&(1, 4) 'bring rock in from one side, need to set heading according to side
674.     SELECT CASE side
675.         CASE 1
676.             r(iRock).x = -100
677.             r(iRock).y = rrnd(20, ymax - 20)
678.             r(iRock).heading = 3 * pi / 2 + RND * pi
679.         CASE 2
680.             r(iRock).x = xmax + 100
681.             r(iRock).y = rrnd(20, ymax - 20)
682.             r(iRock).heading = pi / 2 + RND * pi
683.         CASE 3
684.             r(iRock).x = rrnd(20, xmax - 20)
685.             r(iRock).y = -100
686.             r(iRock).heading = RND * pi
687.         CASE 4
688.             r(iRock).x = rrnd(20, xmax - 20)
689.             r(iRock).y = ymax + 100
690.             r(iRock).heading = pi + RND * pi
691.     END SELECT
692.     r(iRock).speed = rrnd(minRockSpeed, maxRockSpeed) 'speed, rotation angle, radius, gray coloring, spin, seed, hit for explosion
693.     r(iRock).ra = RND * 2 * pi
694.     r(iRock).r = irnd&(minRockSize * 3, maxRockSize) 'every parent rock can be split up into at least 2 - 10 size rocks
695.     r(iRock).c = irnd&(60, 110) ' Ken request increase in rock color
696.     r(iRock).spin = rrnd(-pi / 20, pi / 20)
697.     r(iRock).seed = INT(RND * 64000) - 32000
698.     r(iRock).explodeFrame = 0
699.     r(iRock).live = 1
700. END SUB
701.  
702. FUNCTION irnd& (n1, n2) 'return an integer between 2 numbers
703.     DIM l%, h%
704.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
705.     irnd& = INT(RND * (h% - l% + 1)) + l%
706. END FUNCTION
707.  
708. FUNCTION rrnd (n1, n2) ' return number (expecting reals =_single, double, _float depending on default / define setup)
709.     rrnd = (n2 - n1) * RND + n1
710. END FUNCTION
711.  
712. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
713.     DIM red AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
714.     red = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
715.     FOR rr = r TO 0 STEP -1
716.         f = 1 - rr / r
717.         fcirc x, y, rr, _RGB32(red * f, grn * f, blu * f)
718.     NEXT
719. END SUB
720.  
721. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
722.     IF xr = 0 OR yr = 0 THEN EXIT SUB
723.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
724.     DIM x AS LONG, y AS LONG
725.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
726.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
727.     DO WHILE y < yr
728.         y = y + 1
729.         x = SQR((h2w2 - y * y * w2) \ h2)
730.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
731.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
732.     LOOP
733. END SUB
734.  
735. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
736.     DIM D AS LONG
737.     STATIC a&
738.     D = _DEST
739.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
740.     _DEST a&
741.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
742.     PSET (0, 0), K
743.     _BLEND a& '<<<< new 2019-12-16 fix
744.     _DEST D
745.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
746. END SUB
747.  
748. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version
749.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
750.     x0 = R: y0 = 0: e = 0
751.     DO WHILE y0 < x0
752.         IF e <= 0 THEN
753.             y0 = y0 + 1
754.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
755.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
756.             e = e + 2 * y0
757.         ELSE
758.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
759.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
760.             x0 = x0 - 1: e = e - 2 * x0
761.         END IF
762.     LOOP
763.     LINE (x - R, y)-(x + R, y), C, BF
764. END SUB
765.