DIR$ function is missing

[sparjolly]

My old BASIC code that was working with 32-bit QBASIC compiler now shows error in QB64 on the following line with DIR$ function. Is there any way to walk around this issue?

F$=DIR$("*.LL1")

[SpriggsySpriggs]

Is the code supposed to show an output of files that match that wildcard? If so, I have some code that could help you.

[SpriggsySpriggs]

Here is some code that can help you. You need to download the attached "pipecom.h" file and put the DECLARE LIBRARY block in your program. The header contains code that pipes console output into the variable for printing, manipulating, etc.

Code: QB64: [Select]

1. DECLARE LIBRARY "pipecom"
2.     FUNCTION pipecom$ (cmd AS STRING)
3. END DECLARE
4.  
5. DIM F AS STRING
6.  
7. F = pipecom("dir *.BAS")
8. 'F = pipecom("dir /b *.BAS") 'if you need just the filenames and not the rest of the output
9.  
10. PRINT F

And a sample printout:

  [ You are not allowed to view this attachment ]    [ You are not allowed to view this attachment ]  

[FellippeHeitor]

QB64 is aimed at close to 100% compatibility with QBasic/QuickBASIC 4.5. DIR$() used to be available in PDS7. Here's an adaptation, from the wiki (although I'd go with Spriggsy's approach above):

The DIR$ function adapted from PDS (7.1) returns a filename or a list when more than one exist. The file spec can use a path and/or wildcards.

Code: QB64: [Select]

1. FOR i = 1 TO 2
2.   PRINT
3.   LINE INPUT "Enter a file spec: ", spec$
4.   file$ = DIR$(spec$) 'use a file spec ONCE to find the last file name listed
5.   PRINT DIRCount%, file$, 'function can return the file count using SHARED variable
6.   IF DIRCount% > 1 THEN
7.     DO
8.       K$ = INPUT$(1)
9.       file$ = DIR$("") 'use an empty string parameter to return a list of files!
10.       PRINT file$,
11.     LOOP UNTIL LEN(file$) = 0 'file list ends with an empty string
12.   END IF
13. NEXT
14.  
15. END
16.  
17. FUNCTION DIR$ (spec$)
18. CONST TmpFile$ = "DIR$INF0.INF", ListMAX% = 500 'change maximum to suit your needs
19. SHARED DIRCount% 'returns file count if desired
20. STATIC Ready%, Index%, DirList$()
21. IF NOT Ready% THEN REDIM DirList$(ListMAX%): Ready% = -1 'DIM array first use
22. IF spec$ > "" THEN 'get file names when a spec is given
23.   SHELL _HIDE "DIR " + spec$ + " /b > " + TmpFile$
24.   Index% = 0: DirList$(Index%) = "": ff% = FREEFILE
25.   OPEN TmpFile$ FOR APPEND AS #ff%
26.   size& = LOF(ff%)
27.   CLOSE #ff%
28.   IF size& = 0 THEN KILL TmpFile$: EXIT FUNCTION
29.   OPEN TmpFile$ FOR INPUT AS #ff%
30.   DO WHILE NOT EOF(ff%) AND Index% < ListMAX%
31.     Index% = Index% + 1
32.     LINE INPUT #ff%, DirList$(Index%)
33.   LOOP
34.   DIRCount% = Index% 'SHARED variable can return the file count
35.   CLOSE #ff%
36.   KILL TmpFile$
37. ELSE IF Index% > 0 THEN Index% = Index% - 1 'no spec sends next file name
38. END IF
39. DIR$ = DirList$(Index%)
40. END FUNCTION  

[bplus]

There is a non-Windows solution too but a little more work.

[SpriggsySpriggs]

There is a non-Windows solution too but a little more work.

@bplus Guess what? Mine is cross-platform ;) Works on Linux, Mac, and Windows. All the same code.

[bplus]

@bplus Guess what? Mine is cross-platform ;) Works on Linux, Mac, and Windows. All the same code.

Oh cool!

@SpriggsySpriggs  had you posted this? I must have missed.

[luke]

Obligatory friendly reminder that Linux is case sensitive for file names, so "dir *.BAS" won't match "foo.bas".

Also on Linux and MacOS the default output is plain filenames, "ls -l" is needed for a full listing with metadata.

[SpriggsySpriggs]

Obligatory friendly reminder that Linux is case sensitive for file names, so "dir *.BAS" won't match "foo.bas".

Also on Linux and MacOS the default output is plain filenames, "ls -l" is needed for a full listing with metadata.

@luke Yes, of course. I didn't mean that "dir /b *.BAS" was cross-platform. Only that the pipecom library was :)

[sparjolly]

Thanks for your suggestion. The issue is resolved.

[SpriggsySpriggs]

Thanks for your suggestion. The issue is resolved.

@sparjolly Glad to hear!

[SpriggsySpriggs]

Oh cool!

@SpriggsySpriggs  had you posted this? I must have missed.

@bplus I hadn't posted it. I have been keeping it on the Discord server only while I've been testing it across platforms. Although, I reckon I could make a post for it.

[sparjolly]

I am back again. While the "pipecom.h" library provides a solution, it captures all the file names in the folder meeting the specified criterion. Having a folder with hundreds of files will require creating a huge string array to store all the file names in the program.

The original code using DIR$ function of BASIC fetches only one name at a time, which is a more elegant solution.

I wonder if the "while (!feof(stream))" statement be pulled out of the library so that it provides only one file name at a time and returns a nul when all the files are covered.

Thanks


F$=DIR$("*.LL1")

DO WHILE F$ <> ""

    CNT$ = LEFT$(F$, 4)

    OPEN CNT$ + ".LL1" FOR INPUT AS #1
    OPEN CNT$ + ".LL" FOR OUTPUT AS #2

    F$ = DIR$

LOOP

[SpriggsySpriggs]

@sparjolly Here you go. This uses a method of splitting a string up into an array based on a delimiter. You can see that I have split the string into a new string array called filelist. You can then take it and do your operations on the files within. I would have to write up a new function for the library that uses the original stream and I don't think it would work the way you are wanting it to. For now, try the below code.

Code: QB64: [Select]

1. DECLARE LIBRARY "pipecom"
2.     FUNCTION pipecom$ (cmd AS STRING)
3. END DECLARE
4.  
5. DIM F AS STRING
6.  
7. F = pipecom("dir /b *.BAS")
8.  
9. REDIM filelist(0) AS STRING
10.  
11. String.Split F, CHR$(10), filelist(), 0
12.  
13. FOR x = 0 TO UBOUND(filelist) - 1
14.     PRINT filelist(x)
15. NEXT
16.  
17.  
18. SUB String.Split (Expression AS STRING, delimiter AS STRING, StorageArray() AS STRING, preserve AS INTEGER)
19.     DIM copy AS STRING, p AS LONG, curpos AS LONG, arrpos AS LONG, dpos AS LONG
20.     copy = Expression
21.     IF delimiter = " " THEN
22.         copy = RTRIM$(LTRIM$(copy))
23.         p = INSTR(copy, "  ")
24.         WHILE p > 0
25.             copy = MID$(copy, 1, p - 1) + MID$(copy, p + 1)
26.             p = INSTR(copy, "  ")
27.         WEND
28.     END IF
29.     curpos = 1
30.     IF preserve <> 0 THEN
31.         arrpos = UBOUND(StorageArray)
32.         dpos = INSTR(curpos, copy, delimiter)
33.         DO UNTIL dpos = 0
34.             StorageArray(UBOUND(StorageArray)) = MID$(copy, curpos, dpos - curpos)
35.             REDIM _PRESERVE StorageArray(UBOUND(StorageArray) + 1) AS STRING
36.             curpos = dpos + LEN(delimiter)
37.             dpos = INSTR(curpos, copy, delimiter)
38.         LOOP
39.         StorageArray(UBOUND(StorageArray)) = MID$(copy, curpos)
40.         REDIM _PRESERVE StorageArray(UBOUND(StorageArray) + 1) AS STRING
41.     ELSEIF preserve = 0 THEN
42.         arrpos = 0
43.         dpos = INSTR(curpos, copy, delimiter)
44.         DO UNTIL dpos = 0
45.             StorageArray(arrpos) = MID$(copy, curpos, dpos - curpos)
46.             arrpos = arrpos + 1
47.             IF arrpos > UBOUND(StorageArray) THEN REDIM _PRESERVE StorageArray(UBOUND(StorageArray) + 1) AS STRING
48.             curpos = dpos + LEN(delimiter)
49.             dpos = INSTR(curpos, copy, delimiter)
50.         LOOP
51.         StorageArray(arrpos) = MID$(copy, curpos)
52.         REDIM _PRESERVE StorageArray(arrpos) AS STRING
53.     END IF
54. END SUB

[doppler]

@SpriggsySpriggs Looking at best answer it's no different than

DIM F AS STRING
CHDIR "c:\qb64\my programs"

shell "dir /b *.bas | clip"
f=_clipboard$

PRINT F

But which way would be faster (by code execution time) ?  Which one could hold more data ? (me thinks windows clipboard)