Author Topic: Pretentious not-yet-a-clone clone of Among Us in QB64 (Read 10058 times)

FellippeHeitor · « **on:** October 18, 2020, 11:43:54 am »

Watch as I talk about Among Us while writing something that vaguely resembles a player moving around a map.

Code: QB64: [Select]

OPTION _EXPLICIT
RANDOMIZE TIMER
SCREEN _NEWIMAGE(1000, 800, 32)
 
TYPE object
    x AS SINGLE
    y AS SINGLE
END TYPE
 
DIM SHARED player AS object
DIM SHARED camera AS object
DIM SHARED map AS LONG
DIM playerSpeed AS SINGLE
DIM i AS LONG
 
map = _NEWIMAGE(_WIDTH * 3, _HEIGHT * 2, 32)
_DEST map
FOR i = 1 TO 50
    CircleFill _WIDTH * RND, _HEIGHT * RND, 1000 * RND, _RGB32(255 * RND, 255 * RND, 255 * RND, 255 * RND)
NEXT
_DEST 0
 
player.x = _WIDTH / 2
player.y = _HEIGHT / 2
 
playerSpeed = 5
 
CONST keyUP = 18432
CONST keyDOWN = 20480
CONST keyLEFT = 19200
CONST keyRIGHT = 19712
 
DO
    IF _KEYDOWN(keyUP) THEN player.y = player.y - playerSpeed
    IF _KEYDOWN(keyDOWN) THEN player.y = player.y + playerSpeed
    IF _KEYDOWN(keyLEFT) THEN player.x = player.x - playerSpeed
    IF _KEYDOWN(keyRIGHT) THEN player.x = player.x + playerSpeed
 
    IF player.x < 0 THEN player.x = 0
    IF player.x > _WIDTH(map) THEN player.x = _WIDTH(map)
    IF player.y < 0 THEN player.y = 0
    IF player.y > _HEIGHT(map) THEN player.y = _HEIGHT(map)
 
    adjustCamera
    CLS
    _PUTIMAGE (camera.x, camera.y), map
 
    CircleFill player.x + camera.x, player.y + camera.y, 20, _RGB32(255)
    _DISPLAY
    _LIMIT 60
LOOP
 
SUB adjustCamera
    IF player.x + camera.x > _WIDTH / 2 OR player.x + camera.x < _WIDTH / 2 THEN
        camera.x = _WIDTH / 2 - player.x
    END IF
    IF camera.x > 0 THEN camera.x = 0
    IF camera.x < -(_WIDTH(map) - _WIDTH) THEN camera.x = -(_WIDTH(map) - _WIDTH)
 
    IF player.y + camera.y > _HEIGHT / 2 OR player.y + camera.y < _HEIGHT / 2 THEN
        camera.y = _HEIGHT / 2 - player.y
    END IF
    IF camera.y > 0 THEN camera.y = 0
    IF camera.y < -(_HEIGHT(map) - _HEIGHT) THEN camera.y = -(_HEIGHT(map) - _HEIGHT)
END SUB
 
SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    ' CX = center x coordinate
    ' CY = center y coordinate
    '  R = radius
    '  C = fill color
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R)
    RadiusError = -Radius
    X = Radius
    Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB

Dav · « **Reply #1 on:** October 18, 2020, 04:03:50 pm »

Lol. Thanks for leaving in the blooper. I needed a laugh..

- Dav

bplus · « **Reply #2 on:** October 18, 2020, 04:43:59 pm »

Wow just add image of a map and player is walking around map, nice!

FellippeHeitor · « **Reply #3 on:** October 19, 2020, 04:29:25 pm »

@Dav glad it was entertaining!

@bplus the illusion is the key, thanks for checking it out!

FellippeHeitor · « **Reply #4 on:** October 20, 2020, 12:53:07 pm »

Run this and choose "Connect to server" - arbitrarily limited to 10 simultaneous "players" for now.

It's the map+player code of the first post, with networking added. Still not a game, but you can see other players in real time, which is cool.

If you have trouble connecting to 98.29.249.134 (kindly hosted by SpriggsySprigs in the US), replace that on line 97 with alephc.xyz (kindly hosted by Luke in Australia).

Code: QB64: [Select]

OPTION _EXPLICIT
 
$LET DEBUGGING = FALSE
$IF DEBUGGING = TRUE THEN
    $CONSOLE
$END IF
 
CONST True = -1, False = 0
CONST mode_freeplay = 0
CONST mode_localhost = 1
CONST mode_localclient = 2
CONST mode_onlinehost = 3
CONST mode_onlineclient = 4
 
TYPE object
    name AS STRING
    handle AS LONG
    x AS SINGLE
    y AS SINGLE
    state AS INTEGER
    color AS INTEGER
    basicInfoSent AS _BYTE
    ping AS SINGLE
END TYPE
 
DIM SHARED mode AS INTEGER
DIM SHARED totalClients AS INTEGER
DIM SHARED playerStream(1 TO 10) AS STRING
DIM SHARED serverStream AS STRING
DIM SHARED player(1 TO 10) AS object, me AS INTEGER
DIM SHARED colors(1 TO 15) AS _UNSIGNED LONG, r AS INTEGER, g AS INTEGER, b AS INTEGER
DIM SHARED warning(1 TO 30) AS object
DIM idSet AS _BYTE
DIM i AS LONG, j AS LONG
DIM newClient AS LONG
DIM serverPing AS SINGLE
DIM key$, value$
 
DIM SHARED endSignal AS STRING
endSignal = "<" + CHR$(254) + ">"
 
vgaPalette:
DATA 0,0,170
DATA 0,170,0
DATA 0,170,170
DATA 170,0,0
DATA 170,0,170
DATA 170,85,0
DATA 170,170,170
DATA 85,85,85
DATA 85,85,255
DATA 85,255,85
DATA 85,255,255
DATA 255,85,85
DATA 255,85,255
DATA 255,255,85
DATA 255,255,255
 
RESTORE vgaPalette
FOR i = 1 TO 15
    READ r%, g%, b%
    colors(i) = _RGB32(r%, g%, b%)
NEXT
 
CONST timeout = 30
DIM userName$, userColor%
INPUT "Name: ", userName$
DO
    INPUT "Color (1-15): ", userColor%
LOOP WHILE userColor% < 1 OR userColor% > 15
 
DO
    COLOR 15
    PRINT "-------------------------"
    PRINT "(1) Free play"
    PRINT "(2) Connect to server"
 
    DIM choice AS STRING
    DO
        choice = INKEY$
        _LIMIT 30
    LOOP UNTIL choice >= "1" AND choice <= "5"
 
    DIM SHARED server AS object, host AS LONG
    DIM c AS INTEGER, attempt AS INTEGER
    CONST maxAttempts = 100
    SELECT CASE VAL(choice)
        CASE 1
            EXIT DO
        CASE 2
            COLOR 7
            PRINT "Attempting to connect to local host... ";
            r = CSRLIN: c = POS(1)
            attempt = 0
            DO
                server.handle = 0
                server.handle = _OPENCLIENT("TCP/IP:51512:98.29.249.134")
                IF server.handle THEN EXIT DO
                attempt = attempt + 1
                LOCATE r, c: PRINT USING "###%"; (attempt / maxAttempts) * 100;
                _LIMIT 30
            LOOP WHILE attempt < 100
            IF server.handle THEN serverPing = TIMER: mode = mode_localclient: EXIT DO
            PRINT: COLOR 14: PRINT "/\ ";: COLOR 12
            PRINT "Failed to connect to local host."
            CLOSE server.handle
    END SELECT
LOOP
 
SCREEN _NEWIMAGE(800, 600, 32)
_FONT 8
_PRINTMODE _KEEPBACKGROUND
 
DIM SHARED playerSpeed AS SINGLE
DIM SHARED map AS LONG
DIM SHARED camera AS object
 
map = _NEWIMAGE(_WIDTH * 3, _HEIGHT * 2, 32)
_DEST map
RANDOMIZE 6
FOR i = 1 TO 50
    CircleFill RND * _WIDTH, RND * _HEIGHT, RND * 1000, _RGB32(RND * 255, RND * 255, RND * 255, RND * 150)
NEXT
_DEST 0
RANDOMIZE TIMER
 
CONST keyUP = 18432
CONST keyDOWN = 20480
CONST keyLEFT = 19200
CONST keyRIGHT = 19712
CONST keyLSHIFT = 100304
CONST keyRSHIFT = 100303
 
CONST cameraWindow = 100
 
CONST minSpeed = 3
CONST maxSpeed = 5
 
playerSpeed = maxSpeed
 
IF mode > 1 THEN
    idSet = False
ELSE
    idSet = True
    me = 1
    player(me).name = userName$
    player(me).x = _WIDTH / 2 + COS(RND * _PI) * (RND * 100)
    player(me).y = _HEIGHT / 2 + SIN(RND * _PI) * (RND * 100)
    player(me).state = True
    player(me).color = userColor%
END IF
DO
    SELECT CASE mode
        CASE mode_localhost
            'check for new connections (unless already at max)
            IF idSet = False THEN
                idSet = True
                me = 1
                player(me).name = userName$
                player(me).x = _WIDTH / 2 + COS(RND * _PI) * (RND * 100)
                player(me).y = _HEIGHT / 2 + SIN(RND * _PI) * (RND * 100)
                player(me).state = True
                player(me).color = userColor%
            END IF
 
            IF totalClients < UBOUND(player) THEN
                newClient = 0
                newClient = _OPENCONNECTION(host)
                IF newClient THEN
                    totalClients = totalClients + 1
                    FOR i = 1 TO UBOUND(player)
                        IF player(i).state = False THEN
                            player(i).color = 0
                            player(i).handle = newClient
                            player(i).state = True
                            sendData player(i), "ID", MKI$(i)
                            player(i).ping = TIMER
                            EXIT FOR
                        END IF
                    NEXT
                END IF
            END IF
 
            FOR i = 1 TO UBOUND(player)
                IF player(i).state = False OR i = me THEN _CONTINUE
                IF TIMER - player(i).ping > timeout THEN
                    'player inactive
                    player(i).state = False
                    CLOSE player(i).handle
                    addWarning player(i).name + " lost connection."
                    totalClients = totalClients - 1
                    _CONTINUE
                END IF
 
                getData player(i), playerStream(i)
 
                DO WHILE parse(playerStream(i), key$, value$)
                    player(i).ping = TIMER
                    SELECT CASE key$
                        CASE "NAME"
                            player(i).name = value$
                        CASE "COLOR" 'received once per player
                            DIM newcolor AS INTEGER, changed AS _BYTE
                            newcolor = CVI(value$)
                            changed = False
                            'check if this color is already in use, so a random one can be assigned
                            FOR j = 1 TO UBOUND(player)
                                IF player(j).state = True AND player(j).color = newcolor THEN
                                    newcolor = newcolor + 1
                                    IF newcolor > UBOUND(colors) THEN newcolor = 1
                                    changed = True
                                    j = 0 'check again
                                END IF
                            NEXT
                            player(i).color = newcolor
                            IF changed THEN
                                sendData player(i), "COLOR", MKI$(newcolor)
                            END IF
                        CASE "POS"
                            player(i).x = CVI(LEFT$(value$, 2))
                            player(i).y = CVI(RIGHT$(value$, 2))
                    END SELECT
                LOOP
 
                'send ping
                sendData player(i), "PING", ""
 
                'send all players' data
                FOR j = 1 TO UBOUND(player)
                    IF j = i THEN _CONTINUE
                    IF player(j).state = True THEN
                        sendData player(i), "PLAYERCOLOR", MKI$(j) + MKI$(player(j).color)
                        sendData player(i), "PLAYERPOS", MKI$(j) + MKS$(player(j).x) + MKS$(player(j).y)
                        sendData player(i), "PLAYERNAME", MKI$(j) + player(j).name
                    ELSE
                        sendData player(i), "PLAYEROFFLINE", MKI$(j)
                    END IF
                NEXT
            NEXT
 
        CASE mode_localclient, mode_onlineclient
            IF idSet THEN
                IF player(me).basicInfoSent = False THEN
                    player(me).basicInfoSent = True
                    sendData server, "COLOR", MKI$(player(me).color)
                    sendData server, "NAME", player(me).name
                END IF
 
                sendData server, "POS", MKI$(player(me).x) + MKI$(player(me).y)
            END IF
 
            getData server, serverStream
            DO WHILE parse(serverStream, key$, value$)
                SELECT CASE key$
                    CASE "ID" 'first info sent by server
                        idSet = True
                        me = CVI(value$)
                        player(me).name = userName$
                        player(me).x = _WIDTH / 2 + COS(RND * _PI) * (RND * 100)
                        player(me).y = _HEIGHT / 2 + SIN(RND * _PI) * (RND * 100)
                        player(me).state = True
                        player(me).color = userColor%
                    CASE "COLOR" 'server color changes must always be applied
                        player(me).color = CVI(value$)
                    CASE "PLAYERCOLOR"
                        player(CVI(LEFT$(value$, 2))).color = CVI(RIGHT$(value$, 2))
                    CASE "PLAYERPOS"
                        player(CVI(LEFT$(value$, 2))).state = True
                        player(CVI(LEFT$(value$, 2))).ping = TIMER
                        player(CVI(LEFT$(value$, 2))).x = CVS(MID$(value$, 3, 4))
                        player(CVI(LEFT$(value$, 2))).y = CVS(RIGHT$(value$, 4))
                    CASE "PLAYERNAME"
                        player(CVI(LEFT$(value$, 2))).name = MID$(value$, 3)
                    CASE "PLAYEROFFLINE"
                        IF player(CVI(value$)).state = True THEN
                            player(CVI(value$)).state = False
                            addWarning player(CVI(value$)).name + " left the game."
                        END IF
                    CASE "PING"
                        serverPing = TIMER
                END SELECT
            LOOP
    END SELECT
 
    IF playerSpeed < minSpeed THEN playerSpeed = minSpeed
    IF playerSpeed > maxSpeed THEN playerSpeed = maxSpeed
 
    IF idSet THEN
        IF _KEYDOWN(keyUP) THEN player(me).y = player(me).y - playerSpeed
        IF _KEYDOWN(keyDOWN) THEN player(me).y = player(me).y + playerSpeed
        IF _KEYDOWN(keyLEFT) THEN player(me).x = player(me).x - playerSpeed
        IF _KEYDOWN(keyRIGHT) THEN player(me).x = player(me).x + playerSpeed
 
        IF player(me).x < 0 THEN player(me).x = 0
        IF player(me).y < 0 THEN player(me).y = 0
        IF player(me).x > _WIDTH(map) THEN player(me).x = _WIDTH(map)
        IF player(me).y > _HEIGHT(map) THEN player(me).y = _HEIGHT(map)
 
        adjustCamera
    END IF
 
    CLS
 
    DIM shipFlotation AS SINGLE, shipFloatIntensity AS SINGLE
    shipFlotation = shipFlotation + .05
    IF shipFlotation > _PI(2) THEN shipFlotation = shipFlotation - _PI(2)
    shipFloatIntensity = 1.5
 
    _DONTBLEND
    _PUTIMAGE (camera.x + COS(shipFlotation) * shipFloatIntensity, camera.y + SIN(shipFlotation) * shipFloatIntensity), map
    _BLEND
 
    IF (mode = mode_localclient OR mode = mode_onlineclient) THEN
        IF TIMER - serverPing > timeout THEN
            SCREEN 0
            PRINT: COLOR 14: PRINT "/\ ";: COLOR 12
            PRINT "Disconnected from host."
            END
        ELSE
            PRINT USING "###ms"; ((TIMER - serverPing) - FIX(TIMER - serverPing)) * 1000;
        END IF
    END IF
 
    DIM x AS SINGLE, y AS SINGLE
    FOR i = 1 TO UBOUND(player)
        IF player(i).state = False OR player(i).color = 0 THEN _CONTINUE
        x = player(i).x + camera.x + COS(shipFlotation) * shipFloatIntensity
        y = player(i).y + camera.y + SIN(shipFlotation) * shipFloatIntensity
        CircleFill x, y + 6, 15, _RGB32(0, 50)
        CircleFill x, y, 15, _RGB32(0)
        CircleFill x, y, 10, colors(player(i).color)
        COLOR _RGB32(0)
        _PRINTSTRING (1 + x - _PRINTWIDTH(player(i).name) / 2, 1 + y - 20), player(i).name
        COLOR _RGB32(255)
        _PRINTSTRING (x - _PRINTWIDTH(player(i).name) / 2, y - 20), player(i).name
    NEXT
    'LINE (_WIDTH / 2 - cameraWindow, _HEIGHT / 2 - cameraWindow)-STEP(cameraWindow * 2, cameraWindow * 2), , B
 
    'display warnings
    FOR i = 1 TO UBOUND(warning)
        COLOR _RGB32(128, 50, 22)
        IF warning(i).state = True THEN
            _PRINTSTRING (10, _HEIGHT / 2 + _FONTHEIGHT * i), warning(i).name
            IF TIMER - warning(i).ping > 2 THEN warning(i).state = False
        END IF
    NEXT
 
    _DISPLAY
    _LIMIT 60
LOOP UNTIL _KEYHIT = 27
CLOSE
SYSTEM
 
SUB addWarning (text$)
    DIM i AS INTEGER
    FOR i = 1 TO UBOUND(warning)
        IF warning(i).state = False THEN
            warning(i).state = True
            warning(i).name = text$
            warning(i).ping = TIMER
            EXIT FOR
        END IF
    NEXT
END SUB
 
SUB sendData (client AS object, id$, value$)
    DIM key$
    key$ = id$ + ">" + value$ + endSignal
    PUT #client.handle, , key$
END SUB
 
SUB getData (client AS object, buffer AS STRING)
    DIM incoming$
    GET #client.handle, , incoming$
    buffer = buffer + incoming$
END SUB
 
FUNCTION parse%% (buffer AS STRING, key$, value$)
    DIM endMarker AS LONG
    endMarker = INSTR(buffer, endSignal)
    IF endMarker THEN
        key$ = LEFT$(buffer, endMarker - 1)
        buffer = MID$(buffer, endMarker + LEN(endSignal))
        endMarker = INSTR(key$, ">")
        value$ = MID$(key$, endMarker + 1)
        key$ = LEFT$(key$, endMarker - 1)
        parse%% = True
    END IF
END FUNCTION
 
SUB adjustCamera
    IF player(me).x + camera.x > _WIDTH / 2 + cameraWindow THEN
        camera.x = _WIDTH / 2 - player(me).x + cameraWindow
    ELSEIF player(me).x + camera.x < _WIDTH / 2 - cameraWindow THEN
        camera.x = _WIDTH / 2 - player(me).x - cameraWindow
    END IF
    IF camera.x > 0 THEN camera.x = 0
    IF camera.x < -(_WIDTH(map) - _WIDTH) THEN camera.x = -(_WIDTH(map) - _WIDTH)
 
    IF player(me).y + camera.y > _HEIGHT / 2 + cameraWindow THEN
        camera.y = _HEIGHT / 2 - player(me).y + cameraWindow
    ELSEIF player(me).y + camera.y < _HEIGHT / 2 - cameraWindow THEN
        camera.y = _HEIGHT / 2 - player(me).y - cameraWindow
    END IF
    IF camera.y > 0 THEN camera.y = 0
    IF camera.y < -(_HEIGHT(map) - _HEIGHT) THEN camera.y = -(_HEIGHT(map) - _HEIGHT)
END SUB
 
 
SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    ' CX = center x coordinate
    ' CY = center y coordinate
    '  R = radius
    '  C = fill color
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R)
    RadiusError = -Radius
    X = Radius
    Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
SUB db (text$)
    $IF DEBUGGING = TRUE THEN
        _ECHO text$
    $ELSE
        DIM dummy$
        dummy$ = text$
    $END IF
END SUB

Rubidium · « **Reply #5 on:** October 20, 2020, 05:16:44 pm »

Impressive! do you have the code for the server as well? I'd like to try playing around with it :D

FellippeHeitor · « **Reply #6 on:** October 20, 2020, 05:29:17 pm »

It's all included above, actually!

Rubidium · « **Reply #7 on:** October 20, 2020, 06:09:22 pm »

Really cool. With some messenger features and a few collision objects, a lot of kids could get so into this! -for getting into qb64- :D

FellippeHeitor · « **Reply #8 on:** October 21, 2020, 01:08:11 pm »

True! I'm hoping to turn it into a real game soon.

If anyone decides to try the room and eventually finds no one currently logged in, just open two instances of the code above to see two instances of yourself running around.

SierraKen · « **Reply #9 on:** October 21, 2020, 04:04:11 pm »

This is great Felippe! I've been wondering how to do this for awhile. I'll try to learn it. I might also drop the CHR$(0) and inkey$ I use for the arrow keys, yours probably works better. Someone could make a really great dungeon type game this way. Thanks!

FellippeHeitor · « **Reply #10 on:** October 21, 2020, 04:08:07 pm »

Thanks, Ken! Glad you enjoyed it.

Did you have luck joining either server? They've both been up since yesterday.

The advantage of using _KEYDOWN for character movement is that all directions can coexist simultaneously and there's no buffer. Once released, the keys immediately stop coming.

SierraKen · « **Reply #11 on:** October 21, 2020, 05:33:55 pm »

LOL I see you! I wonder if we can add chat to it? Like text over your nickname.

FellippeHeitor · « **Reply #12 on:** October 21, 2020, 05:34:35 pm »

I'll be implementing chat soon, but for now there's no length limit for player name - it's a rudimentary messaging system as is!

Dav · « **Reply #13 on:** October 21, 2020, 05:55:40 pm »

Works for me. Connected as is. Code is so easy to understand. What a great learning example.

- Dav

FellippeHeitor · « **Reply #14 on:** October 21, 2020, 05:57:39 pm »

Damn, I missed you! Australia or US?

News:

Author Topic: Pretentious not-yet-a-clone clone of Among Us in QB64 (Read 10058 times)

FellippeHeitor

Pretentious not-yet-a-clone clone of Among Us in QB64

Dav

Re: Pretentious not-really-a-clone clone of Among Us in QB64

bplus

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

Rubidium

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

Rubidium

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

SierraKen

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

SierraKen

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64

Dav

Re: Pretentious not-really-a-clone clone of Among Us in QB64

FellippeHeitor

Re: Pretentious not-really-a-clone clone of Among Us in QB64