Author Topic: Line + Draw (Read 6977 times)

Unseen Machine · « **Reply #15 on:** September 27, 2020, 02:56:24 pm »

Hmmmm....looks a lot like my VQB_Frame command!

Code: QB64: [Select]

SUB VQB_Frame (X%, Y%, Width%, Height%, CLR&)
OldCLR& = CLR&
LINE (X%, Y%)-(X% + Width%, Y% + Height%), CLR&, BF
FOR Border% = 0 TO 4
  IF CLR& > _RGB(0, 0, 0) THEN
    NewRed& = _RED(CLR&) - (6 * Border%)
    NewGreen& = _GREEN(CLR&) - (6 * Border%)
    NewBlue& = _BLUE(CLR&) - (6 * Border%)
    CLR& = _RGB(NewRed&, NewGreen&, NewBlue&)
  ELSE
    NewRed& = _RED(CLR&) + (6 * Border%)
    NewGreen& = _GREEN(CLR&) + (6 * Border%)
    NewBlue& = _BLUE(CLR&) + (6 * Border%)
    CLR& = _RGBA(NewRed&, NewGreen&, NewBlue&, 120)
  END IF
  LINE (X% - Border%, Y% - Border%)-(X% + Width% + Border%, Y% - Border%), CLR&, BF
  LINE (X% - Border%, Y% + Height% + Border%)-(X% + Width% + Border%, Y% + Height% + Border%), CLR&, BF
  LINE (X% - Border%, Y% - Border%)-(X% - Border%, Y% + Height% + Border%), CLR&, BF
  LINE (X% + Width% + Border%, Y% - Border%)-(X% + Width% + Border%, Y% + Height% + Border%), CLR&, BF
NEXT
CLR& = OldCLR&
END SUB

I found this on my dropbox the other day, the code is ten years old but should still be good for shapes and lines etc...

Code: QB64: [Select]

SUB GDK_Triangle (x1%, y1%, x2%, y2%, x3%, y3%, CLR&)
LINE (x1%, y1%)-(x2%, y2%), CLR&
LINE (x1%, y1%)-(x3%, y3%), CLR&
LINE (x2%, y2%)-(x3%, y3%), CLR&
END SUB
 
 
SUB GDK_TriangleFill (x1%, y1%, x2%, y2%, x3%, y3%, CLR&, FillCLR&)
LINE (x1%, y1%)-(x2%, y2%), CLR&
LINE (x1%, y1%)-(x3%, y3%), CLR&
LINE (x2%, y2%)-(x3%, y3%), CLR&
paintx% = (x1% + x2% + x3%) / 3
painty% = (y1% + y2% + y3%) / 3
PAINT (paintx%, painty%), FillCLR&, CLR&
END SUB
 
 
SUB GDK_Ellipse (X%, Y%, XRadius!, YRadius!, CLR&)
IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = 0 TO 8 * ATN(1) STEP MinStep!
  pointx% = X% + (XRadius! * COS(i))
  pointy% = Y% + (YRadius! * SIN(i))
  PSET (pointx%, pointy%), CLR&
NEXT
END SUB
 
 
SUB GDK_EllipseFill (X%, Y%, XRadius!, YRadius!, CLR&, FillCLR&)
IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = 0 TO 8 * ATN(1) STEP MinStep!
  pointx% = X% + (XRadius! * COS(i))
  pointy% = Y% + (YRadius! * SIN(i))
  PSET (pointx%, pointy%), CLR&
NEXT
PAINT (X%, Y%), FillCLR&, CLR&
END SUB
 
 
SUB GDK_EllipseSegment (X%, Y%, XRadius!, YRadius!, Start!, End!, CLR&)
Firstloop% = 0
IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = Start! TO End! STEP MinStep!
  pointx% = X% + (XRadius! * COS(i))
  pointy% = Y% + (YRadius! * SIN(i))
  IF Firstloop% = 0 THEN
    LINE (X%, Y%)-(pointx%, pointy%), CLR&
    Firstloop% = 1
  END IF
  PSET (pointx%, pointy%), CLR&
NEXT
LINE (X%, Y%)-(pointx%, pointy%), CLR&
END SUB
 
 
SUB GDK_EllipseSegmentFill (X%, Y%, XRadius!, YRadius!, Start!, End!, CLR&, FillClr&)
Firstloop% = 0
DIM Firstloopxy(2) AS INTEGER
IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = Start! TO End! STEP MinStep!
  pointx% = X% + (XRadius! * COS(i))
  pointy% = Y% + (YRadius! * SIN(i))
  IF Firstloop% = 0 THEN
    Firstloopxy(0) = pointx%
    Firstloopxy(1) = pointy%
    LINE (X%, Y%)-(pointx%, pointy%), CLR&
    Firstloop% = 1
  END IF
  PSET (pointx%, pointy%), CLR&
NEXT
LINE (X%, Y%)-(pointx%, pointy%), CLR&
IF End! - Start! > 4 * ATN(1) THEN
  i = (End! / 4)
  pointx% = X% + (XRadius! * COS(i))
  pointy% = Y% + (YRadius! * SIN(i))
END IF
paintx% = (X% + Firstloopxy(0) + pointx%) / 3
painty% = (Y% + Firstloopxy(1) + pointy%) / 3
PAINT (paintx%, painty%), FillClr&, CLR&
END SUB
 
 
SUB GDK_Circle (X%, Y%, Radius!, CLR&)
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = 0 TO 8 * ATN(1) STEP MinStep!
  pointx% = X% + (Radius! * COS(i))
  pointy% = Y% + (Radius! * SIN(i))
  PSET (pointx%, pointy%), CLR&
NEXT
END SUB
 
 
SUB GDK_CircleFill (X%, Y%, Radius!, CLR&, FillCLR&)
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = 0 TO 8 * ATN(1) STEP MinStep!
  pointx% = X% + (Radius! * COS(i))
  pointy% = Y% + (Radius! * SIN(i))
  PSET (pointx%, pointy%), CLR&
NEXT
PAINT (X%, Y%), FillCLR&, CLR&
END SUB
 
 
SUB GDK_CircleSegment (X%, Y%, Radius!, CLR&, CircleStart!, CircleEnd!)
Firstloop% = 0
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = CircleStart! TO CircleEnd! STEP MinStep!
  pointx% = X% + (Radius! * COS(i))
  pointy% = Y% + (Radius! * SIN(i))
  IF Firstloop% = 0 THEN
    LINE (X%, Y%)-(pointx%, pointy%), CLR&
    Firstloop% = 1
  END IF
  PSET (pointx%, pointy%), CLR&
NEXT
LINE (X%, Y%)-(pointx%, pointy%), CLR&
END SUB
 
 
SUB GDK_CircleSegmentFill (X%, Y%, Radius!, CLR&, FillClr&, CircleStart!, CircleEnd!)
Firstloop% = 0
DIM Firstloopxy(2) AS INTEGER
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR i = CircleStart! TO CircleEnd! STEP MinStep!
  pointx% = X% + (Radius! * COS(i))
  pointy% = Y% + (Radius! * SIN(i))
  IF Firstloop% = 0 THEN
    LINE (X%, Y%)-(pointx%, pointy%), CLR&
    Firstloopxy(0) = pointx%
    Firstloopxy(1) = pointy%
    Firstloop% = 1
  END IF
  PSET (pointx%, pointy%), CLR&
NEXT
LINE (X%, Y%)-(pointx%, pointy%), CLR&
IF CircleEnd! - CircleStart! > 4 * ATN(1) THEN
  i = (CircleEnd! / 4)
  pointx% = X% + (Radius! * COS(i))
  pointy% = Y% + (Radius! * SIN(i))
END IF
paintx% = (X% + Firstloopxy(0) + pointx%) / 3
painty% = (Y% + Firstloopxy(1) + pointy%) / 3
PAINT (paintx%, painty%), FillClr&, CLR&
END SUB
 
 
SUB GDK_Line (X%, Y%, XX%, YY%, CLR&, WIDTH%)
IF WIDTH% MOD 2 = 0 THEN
  FOR offset = -(WIDTH% / 2) TO WIDTH% / 2
    LINE (X%, Y% + offset)-(XX%, YY% + offset), CLR&
  NEXT
ELSE
  FOR offset = -((WIDTH% + 1) / 2) TO (WIDTH% + 1) / 2
    LINE (X%, Y% + offset)-(XX%, YY% + offset), CLR&
  NEXT
END IF
END SUB
 
 
SUB GDK_LineAngle (X%, Y%, Angle!, Length!, CLR&)
x2% = X% + (Length! * COS(Angle!))
y2% = Y% + (Length! * SIN(Angle!))
LINE (X%, Y%)-(x2%, y2%), CLR&
END SUB
 
 
SUB GDK_LineH (X%, XX%, Y%, CLR&, WIDTH%)
IF WIDTH% MOD 2 = 0 THEN
  FOR offset = -(WIDTH% / 2) TO WIDTH% / 2
    LINE (X%, Y% + offset)-(XX%, Y% + offset), CLR&
  NEXT
ELSE
  FOR offset = -((WIDTH% + 1) / 2) TO (WIDTH% - 1) / 2
    LINE (X%, Y% + offset)-(XX%, Y% + offset), CLR&
  NEXT
END IF
END SUB
 
 
SUB GDK_LineV (Y%, YY%, X%, CLR&, WIDTH%)
IF WIDTH% MOD 2 = 0 THEN
  FOR offset = -(WIDTH% / 2) TO WIDTH% / 2
    LINE (X% + offset, Y%)-(X% + offset, YY%), CLR&
  NEXT
ELSE
  FOR offset = -((WIDTH% + 1) / 2) TO (WIDTH% - 1) / 2
    LINE (X% + offset, Y%)-(X% + offset, YY%), CLR&
  NEXT
END IF
END SUB
 
 
SUB GDK_Box (X%, Y%, Width%, Height%, CLR&)
LINE (X%, Y%)-(X% + Width%, Y% + Height%), CLR&, B
END SUB
 
 
SUB GDK_BoxFill (X%, Y%, Width%, Height%, CLR&, FillCLR&)
LINE (X%, Y%)-(X% + Width%, Y% + Height%), CLR&, B
PAINT (X% + 2, Y% + 2), FillCLR&, CLR&
END SUB
 
 
SUB GDK_BoxXS (X%, Y%, Width%, Height%, XWidth%, CLR&, ShadeClr&)
Oldclr& = CLR&
FOR j% = 0 TO XWidth% - 1
  IF _RED(CLR&) <= 255 AND _RED(ShadeClr&) > 0 THEN newred& = _RED(CLR&) - _RED(ShadeClr&)
  IF _BLUE(CLR&) <= 255 AND _BLUE(ShadeClr&) > 0 THEN newblue& = _BLUE(CLR&) - _BLUE(ShadeClr&)
  IF _GREEN(CLR&) <= 255 AND _GREEN(ShadeClr&) > 0 THEN newgreen& = _GREEN(CLR&) - _GREEN(ShadeClr&)
  CLR& = _RGB(newred&, newgreen&, newblue&)
  LINE (X% - j%, Y% - j%)-(X% + Width% + j%, Y% + Height% + j%), CLR&, B
NEXT
CLR& = Oldclr&
END SUB
 
 
SUB GDK_EllipseXS (X%, Y%, XRadius!, YRadius!, CLR&, Width%, ShadeClr&)
FOR j% = 0 TO Width% - 1
  IF _RED(CLR&) <= 255 AND _RED(ShadeClr&) > 0 THEN newred& = _RED(CLR&) - _RED(ShadeClr&)
  IF _BLUE(CLR&) <= 255 AND _BLUE(ShadeClr&) > 0 THEN newblue& = _BLUE(CLR&) - _BLUE(ShadeClr&)
  IF _GREEN(CLR&) <= 255 AND _GREEN(ShadeClr&) > 0 THEN newgreen& = _GREEN(CLR&) - _GREEN(ShadeClr&)
  CLR& = _RGB(newred&, newgreen&, newblue&)
  IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
  MinStep! = 1 / (2 * 3.1415926535 * Radius!)
  FOR i = 0 TO 8 * ATN(1) STEP MinStep!
    pointx% = X% + (XRadius! * COS(i))
    pointy% = Y% + (YRadius! * SIN(i))
    PSET (pointx%, pointy%), CLR&
  NEXT
  XRadius! = XRadius! + 1
  YRadius! = YRadius! + 1
NEXT
END SUB
 
 
SUB GDK_CircleXS (X%, Y%, Radius!, CLR&, Width%, ShadeClr&)
OldClr& = CLR&
FOR j% = 0 TO Width% - 1
  IF _RED(ShadeClr&) > 0 THEN newred& = _RED(CLR&) - _RED(ShadeClr&)
  IF _BLUE(ShadeClr&) > 0 THEN newblue& = _BLUE(CLR&) - _BLUE(ShadeClr&)
  IF _GREEN(ShadeClr&) > 0 THEN newgreen& = _GREEN(CLR&) - _GREEN(ShadeClr&)
  CLR& = _RGB(newred&, newgreen&, newblue&)
  MinStep! = 1 / (2 * 3.1415926535 * Radius!)
  FOR i = 0 TO 8 * ATN(1) STEP MinStep!
    pointx% = X% + (Radius! * COS(i))
    pointy% = Y% + (Radius! * SIN(i))
    PSET (pointx%, pointy%), CLR&
  NEXT
  Radius! = Radius! + 1
NEXT
CLR& = OldClr&
END SUB
 
 
SUB GDK_EllipseX (X%, Y%, XRadius!, YRadius!, CLR&, Width%)
FOR j% = 0 TO Width% - 1
  IF XRadius! > YRadius! THEN Radius! = XRadius! ELSE Radius! = YRadius!
  MinStep! = 1 / (2 * 3.1415926535 * Radius!)
  FOR i = 0 TO 8 * ATN(1) STEP MinStep!
    pointx% = X% + (XRadius! * COS(i))
    pointy% = Y% + (YRadius! * SIN(i))
    PSET (pointx%, pointy%), CLR&
  NEXT
  XRadius! = XRadius! + 1
  YRadius! = YRadius! + 1
NEXT
END SUB
 
 
SUB GDK_CircleX (X%, Y%, Radius!, CLR&, Width%)
MinStep! = 1 / (2 * 3.1415926535 * Radius!)
FOR j% = 0 TO Width% - 1
  FOR i = 0 TO 8 * ATN(1) STEP MinStep!
    pointx% = X% + (Radius! * COS(i))
    pointy% = Y% + (Radius! * SIN(i))
    PSET (pointx%, pointy%), CLR&
  NEXT
  Radius! = Radius! + 1
NEXT
END SUB
 

Unseen

OldMoses · « **Reply #16 on:** September 27, 2020, 04:12:57 pm »

I did something very similar to Fellippe's "box" subroutine for making buttons in my star system simulator. SierraKen's calculator buttons inspired me to add a "beveling" SUB to add some 3D pop to them, also similar to the frame examples above. I also made it so that the button label would show any associated hotkeys in a highlight color. Easy to change the position & parameters of the buttons.

All that's required is to call:
Con_Blok x position, y position, width, height, button label, hotkey position, button color

Code: QB64: [Select]

A& = _NEWIMAGE(600, 400, 32)
SCREEN A&
'DIM SHARED f&
'f& = _LOADFONT("c:\windows\fonts\arialbd.ttf", 16, "monospace")
Con_Blok 50, 50, 80, 48, "Sit", 1, &HFF00FF00
Con_Blok 150, 50, 80, 48, "Stay", 2, &HFF0000FF
Con_Blok 300, 150, 80, 48, "Fetch", 1, &HFF04500FF
Con_Blok 500, 320, 80, 48, "Roll", 1, &HFFFF00FF
 
 
 
SUB Con_Blok (xpos AS INTEGER, ypos AS INTEGER, xsiz AS INTEGER, ysiz AS INTEGER, label AS STRING, high AS INTEGER, col AS _UNSIGNED LONG)
 
    'Create control block
    CN& = _NEWIMAGE(xsiz, ysiz, 32)
    _DEST CN&
    COLOR , col
    CLS
    BevelB xsiz, ysiz, col
    _PRINTMODE _KEEPBACKGROUND
    x = LEN(label)
    IF f& > 0 THEN '                                            if font is available
        sx = (xsiz / 2) - (x * _FONTWIDTH(f&)) / 3
        sy = ysiz / 2 - 6
        _FONT f&
    ELSE '                                                      if not
        sx = xsiz / 2 - x * 4: sy = ysiz / 2 - 8
    END IF
    FOR p = 1 TO x '                                            iterate through label characters
        IF p = high THEN '                                      print hotkey highlight color (red) else (black)
            COLOR &HFFFF0000
        ELSE
            COLOR &HFF000000
        END IF
        IF col = &HFFC80000 THEN COLOR 15
        _PRINTSTRING (sx + (p - 1) * 8, sy), MID$(label, p, 1)
    NEXT p
    _FONT 16
    _PUTIMAGE (xpos, ypos), CN&, A&
    _FREEIMAGE CN&
 
END SUB 'Con_Blok
 
SUB BevelB (xsiz AS INTEGER, ysiz AS INTEGER, col AS _UNSIGNED LONG)
 
    'Create control button bevels for 3D effect - called from Con_Blok
    'Inspiration and basic algorithm by SierraKen
    SELECT CASE ysiz
        CASE IS <= xsiz
            brdr = INT(ysiz / 4)
        CASE IS > xsiz
            brdr = INT(xsiz / 4)
    END SELECT
    FOR bb = 0 TO brdr
        c = c + 100 / brdr
        LINE (0 + bb, 0 + bb)-(xsiz - 1 - bb, ysiz - 1 - bb), _RGBA32(_RED32(col) - 100 + c, _GREEN32(col) - 100 + c, _BLUE32(col) - 100 + c, _ALPHA(col)), B
    NEXT bb
 
END SUB 'BevelB
 

bplus · « **Reply #17 on:** September 27, 2020, 04:22:19 pm »

@Unseen Machine yeah, yours look like 3D pads sticking up from a surface. You might like the fill triangle I used for thic line, no PAINT so no possible interference by other objects.

@OldMoses yeah I like those buttons too.

bplus · « **Reply #18 on:** September 27, 2020, 04:48:34 pm »

@carloscordeiro

Seeing as you've just begun using graphics screens you might like the QB4.5 colors used in SCREEN 12 converted to _RGB32() colors for your custom designed screen made with _NEWIMAGE

You can tinker with the numbers but I use an qb~& FUNCTION for 0-15 colors converted to 32 bit EGB

Code: QB64: [Select]

FUNCTION qb~& (n AS INTEGER)
    SELECT CASE n
        CASE 0: qb~& = &HFF000000
        CASE 1: qb~& = &HFF000088
        CASE 2: qb~& = &HFF008800
        CASE 3: qb~& = &HFF008888
        CASE 4: qb~& = &HFF880000
        CASE 5: qb~& = &HFF880088
        CASE 6: qb~& = &HFF888800
        CASE 7: qb~& = &HFFCCCCCC
        CASE 8: qb~& = &HFF888888
        CASE 9: qb~& = &HFF0000FF
        CASE 10: qb~& = &HFF00FF00
        CASE 11: qb~& = &HFF00FFFF
        CASE 12: qb~& = &HFFFF0000
        CASE 13: qb~& = &HFFFF00FF
        CASE 14: qb~& = &HFFFFFF00
        CASE 15: qb~& = &HFFFFFFFF
    END SELECT
END FUNCTION
 

If I want red 12, I use qb~&(12), blue qb~&(9)....

the ~& are the suffix to _UNSIGNED LONG the best type to use for 32 bit colors.

So to PRINT s$ in red on black:
COLOR qb~&(12), qb~&(0)
PRINT s$

What is also cool is you can adjust the colors to your liking! So you can get a real orange and green.

carloscordeiro · « **Reply #19 on:** September 27, 2020, 05:56:39 pm »

I will keep the two simpler ones for the box I want.

OldMoses:

Code: QB64: [Select]
SCREEN 12
thick = 5
FOR x = 0 TO thick
LINE (6 + x, 5 + x)-(632 - x, 462 - x), 11, B ' box or frame
'LINE (7, 6)-(631, 461), 11, B 'Slightly thicker lines
LINE (6 + x, 5 + x)-(632 - x, 50 - x), 11, B
NEXT x

And Felipe:

Código: QB64 : [Selecionar]
TELA _NOVAIMAGEM ( 800 , 600 , 32 )
caixa 0 , 0 , 200 , 130 , 10 , _RGB32 ( 183 , 133 , 33 )
SUB box ( x , y , w , h , espessura , a cor AS _UNSIGNED LONG )
LINE ( x , y ) - STEP ( w , h ) , theColor , BF
LINHA ( x + espessura , y + espessura ) - PASSO ( w - espessura * 2 , h - espessura * 2 ) , _BACKGROUNDCOLOR , BF
END SUB

Felipe's line code is great.
Simple and with few lines.

Thank you all

Carlos

TempodiBasic · « **Reply #20 on:** September 27, 2020, 06:07:40 pm »

Hi
I must admit that all you guys are very active and have so fantastic ideas to develope the request of carloscordeiro!
I find very interesting your solutions, only Bplus have posted nothing!
However I post my raw two cents :

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
Makeframe 100, 300, 500, 350, 5, _RGB32(255, 0, 0)
Makeframe 70, 400, 700, 10, 5, _RGB32(0, 150, 0)
Makeframe 150, 400, 170, 10, 5, _RGB32(50, 50, 50)
MakeLine 10, 300, 700, 400, 5, _RGB32(10, 100, 255)
MakeLine 100, 200, 500, 400, 4, _RGB32(100, 10, 55)
END
 
SUB Makeframe (xStart, yStart, xEnd, yEnd, Thik, C AS _UNSIGNED LONG)
    IF xStart > xEnd THEN SWAP xStart, xEnd
    IF yStart > yEnd THEN SWAP yStart, yEnd
    LINE (xStart, yStart)-(xEnd, yEnd), C, B
    LINE (xStart + Thik, yStart + Thik)-(xEnd - Thik, yEnd - Thik), C, B
    PAINT (xStart + INT(Thik / 2), yStart + INT(Thik / 2)), C, POINT(xStart, yStart)
END SUB
 
SUB MakeLine (xStart, yStart, xEnd, yEnd, Thik, C AS _UNSIGNED LONG)
    LINE (xStart, yStart)-(xEnd, yEnd), C
    LINE (xStart, yStart + Thik)-(xEnd, yEnd + Thik), C
    LINE (xStart, yStart)-(xStart, yStart + Thik), C
    LINE (xEnd, yEnd)-(xEnd, yEnd + Thik), C
    PAINT (xStart + INT(Thik / 2), yStart + INT(Thik / 2)), C, POINT(xStart, yStart)
END SUB
 
SUB grid (xMin, yMin, xMax, yMax, xDelta, yDelta, C AS _UNSIGNED LONG)
    'this sub creates a costumizable grid on the screen
    FOR a = xMin TO xMax STEP xDelta
        LINE (a, yMin)-(a, yMax), C
    NEXT
    FOR a = yMin TO yMax STEP yDelta
        LINE (xMin, a)-(xMax, a), C
    NEXT
END SUB

@carloscordeiro
I must point out that with Draw you can increase only one dimension of the line that you draw...
see here this code show this concept.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
grid 1, 800, 10, 1, 600, 5, _RGB32(0, 155, 0)
LINE (100, 100)-(500, 100), _RGB32(255, 0, 0)
DRAW "s16bm100,200m500,200"
DRAW "s16bm100,300r100" ' the effect is on the direction of movement s4 = 1 pixel
DRAW "s32bm100,350r50" ' s8= 2 pixels, s16 = 4 pixels, s32 = 8 pixels
LINE (100, 400)-(500, 400), _RGB32(255, 0, 0)
END
 
SUB grid (xMin, yMin, xMax, yMax, xDelta, yDelta, C AS _UNSIGNED LONG)
    'this sub creates a costumizable grid on the screen
    FOR a = xMin TO xMax STEP xDelta
        LINE (a, yMin)-(a, yMax), C
    NEXT
    FOR a = yMin TO yMax STEP yDelta
        LINE (xMin, a)-(xMax, a), C
    NEXT
END SUB

Thanks to read

carloscordeiro · « **Reply #21 on:** September 27, 2020, 07:21:48 pm »

" TempodiBasic Thanks to read "

I read and executed all the codes

bplus · « **Reply #22 on:** September 27, 2020, 07:45:06 pm »

Quote

I find very interesting your solutions, only Bplus have posted nothing!

@TempodiBasic what?

What do you mean by this? I doubt it is how it looks. :)

carloscordeiro · « **Reply #23 on:** September 27, 2020, 08:30:37 pm »

Bplus
Why the error in Felipe's box?

bplus · « **Reply #24 on:** September 27, 2020, 08:39:09 pm »

@carloscordeiro

All SUBs and FUNCTIONs have to be listed after Main code, data statements and or GOSUBS from main code.

Should be OK to cut and paste the SUB lower or last in code.

Caution: Fellippe's box blacks out the interior space but if you use it first and then fill in the space with text you should be OK.

Old Moses has just what you would like I think, he did it without SUBs or FUNCTIONs which I don't think you are use to yet.

TempodiBasic · « **Reply #25 on:** September 28, 2020, 01:47:57 pm »

@bplus

Quote

What do you mean by this?

Yes so we can say that this is a joke, can we?

bplus · « **Reply #26 on:** September 28, 2020, 01:51:08 pm »

Quote from: TempodiBasic on September 28, 2020, 01:47:57 pm

@bplus
Yes so we can say that this is a joke, can we?

LOL OK but you had me wondering :)

News:

Author Topic: Line + Draw (Read 6977 times)

Unseen Machine

Re: Line + Draw

OldMoses

Re: Line + Draw

bplus

Re: Line + Draw

bplus

Re: Line + Draw

carloscordeiro

Re: Line + Draw

TempodiBasic

Re: Line + Draw

carloscordeiro

Re: Line + Draw

bplus

Re: Line + Draw

carloscordeiro

Re: Line + Draw

bplus

Re: Line + Draw

TempodiBasic

Re: Line + Draw

bplus

Re: Line + Draw