Line + Draw

[carloscordeiro]

Good night, Bplus
Me again here learning from you the instructions of Qbasic 64
This time I won't take your time too much.
I'm not used to code with graphics, I'm not familiar with graphics
The most I did was the boxes that I use in codes and that I want to use in the sequence code that you created for me.
Reading http://www.qb64.org/wiki/LINE I saw that the line is an excellent instruction for creating boxes.
The boxes that I create are with very obsolete instruction.
I managed to create a box with the line, but I wanted to make the lines a little thicker with the Draw statement.
As I mentioned, I have no knowledge of this instruction
I saw just one example of a slightly thick line that Draw created
Just below examples:
My obsolete boxes:

COLOR 11
LOCATE 1, 1: PRINT STRING$(80, CHR$(196)) 'box or frame
LOCATE 3, 1: PRINT STRING$(80, CHR$(196))
LOCATE 23, 1: PRINT STRING$(80, CHR$(196))
FOR R = 1 TO 23
    LOCATE R, 1: PRINT CHR$(179)
    LOCATE R, 80: PRINT CHR$(179)
NEXT R
LOCATE 3, 1: PRINT CHR$(195)
LOCATE 3, 80: PRINT CHR$(180)
LOCATE 1, 80: PRINT CHR$(191)
LOCATE 23, 80: PRINT CHR$(217)
LOCATE 23, 1: PRINT CHR$(192)
LOCATE 1, 1: PRINT CHR$(218)

Line instruction boxes: ‘Magnificent instruction
SCREEN 12
LINE (6, 5)-(632, 462), 11, B ' box or frame
'LINE (7, 6)-(631, 461), 11, B  'Slightly thicker lines
LINE (6, 5)-(632, 50), 11, B

Example I searched for at http://www.qb64.org/wiki/DRAW
SCREEN 12
PSET (20, 20), 12
DRAW "E2R30F2G2L30H2BR5P12,12" 'A little thick stroke

To summarize, I just want to make the box a little thicker.
I would like to know from you if there is this possibility.

Carlos

[bplus]

When I was creating my current avatar I made a very nifty sub:

Code: QB64: [Select]

1. SUB drawFrame (x, y, w, h, th, k AS _UNSIGNED LONG)
2.     LINE (x, y)-STEP(w, th), k, BF 'two horizontal
3.     LINE (x, y + h - th)-STEP(w, th), k, BF
4.     LINE (x, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF 'try not to overlap boxes in case k is transparent
5.     LINE (x + w - th, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF
6. END SUB

This creates a box top left corner is x, y.
Width and height is w, h
Thickness of lines (really they are skinny filled boxes) = th
k is color and may work in screen 12

The modern way to setup your screen is with:
SCREEN _NEWIMAGE(MyScreenWidth, MyScreenHeight, 32)  ' < the 32 is for 32 bit colors = _RGB32(red, green, blue)

It (the frame SUB) is exactly what you could use.

Demo:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. drawFrame 0, 0, 800, 600, 10, _RGB32(0, 0, 128)
3. drawFrame 10, 10, 780, 50, 10, _RGB(255, 0, 0)
4. drawFrame 10, 60, 780, 530, 10, _RGB32(200)
5. drawFrame 10, 60, 260, 530, 10, _RGB32(255, 255, 0)
6. drawFrame 270, 60, 260, 530, 10, _RGB32(0, 128, 0)
7. drawFrame 530, 60, 260, 530, 10, _RGB32(240, 120, 0)
8. SLEEP
9.  
10. SUB drawFrame (x, y, w, h, th, k AS _UNSIGNED LONG)
11.     LINE (x, y)-STEP(w, th), k, BF 'two horizontal
12.     LINE (x, y + h - th)-STEP(w, th), k, BF
13.     LINE (x, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF 'try not to overlap boxes in case k is transparent
14.     LINE (x + w - th, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF
15. END SUB
16.  
17.  

[bplus]

Here's another way to draw thick lines

Code: QB64: [Select]

1. 'update 2020-01-24 to include PD2 inside the sub
2. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
3.     DIM PD2 AS DOUBLE, t2 AS SINGLE, a AS SINGLE, x3 AS SINGLE, y3 AS SINGLE, x4 AS SINGLE, y4 AS SINGLE
4.     DIM x5 AS SINGLE, y5 AS SINGLE, x6 AS SINGLE, y6 AS SINGLE
5.     PD2 = 1.570796326794897
6.     t2 = thick / 2
7.     IF t2 < 1 THEN t2 = 1
8.     a = _ATAN2(y2 - y1, x2 - x1)
9.     x3 = x1 + t2 * COS(a + PD2)
10.     y3 = y1 + t2 * SIN(a + PD2)
11.     x4 = x1 + t2 * COS(a - PD2)
12.     y4 = y1 + t2 * SIN(a - PD2)
13.     x5 = x2 + t2 * COS(a + PD2)
14.     y5 = y2 + t2 * SIN(a + PD2)
15.     x6 = x2 + t2 * COS(a - PD2)
16.     y6 = y2 + t2 * SIN(a - PD2)
17.     ftri x6, y6, x4, y4, x3, y3, K
18.     ftri x3, y3, x5, y5, x6, y6, K
19. END SUB
20.  
21. '2019-12-16 fix by Steve saves some time with STATIC and saves and restores last dest
22. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
23.     DIM D AS LONG
24.     STATIC a&
25.     D = _DEST
26.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
27.     _DEST a&
28.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
29.     PSET (0, 0), K
30.     _BLEND a& '<<<< new 2019-12-16 fix
31.     _DEST D
32.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
33. END SUB
34.  
35.  
36.  

[carloscordeiro]

Bplus, it's like I said in the other posts, you make advanced codes. I wanted a code so I could choose the line thickness of the box. A very simple code.
It would be possible?
Carlos

[carloscordeiro]

The latter does not appear the box on the screen

[OldMoses]

You could run your line commands in a loop and just change its size to suit. Dead simple, unsophisticated, but if it works in your ap, go for it.

Code: QB64: [Select]

1. SCREEN 12
2. thick = 5
3. FOR x = 0 TO thick
4.     LINE (6 + x, 5 + x)-(632 - x, 462 - x), 11, B ' box or frame
5.     'LINE (7, 6)-(631, 461), 11, B  'Slightly thicker lines
6.     LINE (6 + x, 5 + x)-(632 - x, 50 - x), 11, B
7. NEXT x

[carloscordeiro]

Ok, great reasoning :)
I will do that.
thank you again

Carlos

[bplus]

Here's a demo for thick

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DEFINT A-Z
3. 'try a box target in middle of screem
4. DIM k AS _UNSIGNED LONG
5. FOR i = 1 TO 20
6.     IF i MOD 3 = 1 THEN k = _RGB32(255)
7.     IF i MOD 3 = 2 THEN k = _RGB32(200, 0, 0)
8.     IF i MOD 3 = 0 THEN k = _RGB32(0, 0, 200)
9.  
10.     thic _WIDTH / 2 - i * 10 - 3, _HEIGHT / 2 - i * 10, _WIDTH / 2 + i * 10 + 3, _HEIGHT / 2 - i * 10, 6, k
11.     thic _WIDTH / 2 - i * 10, _HEIGHT / 2 - i * 10, _WIDTH / 2 - i * 10, _HEIGHT / 2 + i * 10, 6, k
12.     thic _WIDTH / 2 + i * 10, _HEIGHT / 2 - i * 10, _WIDTH / 2 + i * 10, _HEIGHT / 2 + i * 10, 6, k
13.     thic _WIDTH / 2 - i * 10 - 3, _HEIGHT / 2 + i * 10, _WIDTH / 2 + i * 10 + 3, _HEIGHT / 2 + i * 10, 6, k
14.  
15.     _LIMIT 10
16. NEXT
17. SLEEP
18.  
19.  
20. 'update 2020-01-24 to include PD2 inside the sub
21. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
22.     DIM PD2 AS DOUBLE, t2 AS SINGLE, a AS SINGLE, x3 AS SINGLE, y3 AS SINGLE, x4 AS SINGLE, y4 AS SINGLE
23.     DIM x5 AS SINGLE, y5 AS SINGLE, x6 AS SINGLE, y6 AS SINGLE
24.     PD2 = 1.570796326794897
25.     t2 = thick / 2
26.     IF t2 < 1 THEN t2 = 1
27.     a = _ATAN2(y2 - y1, x2 - x1)
28.     x3 = x1 + t2 * COS(a + PD2)
29.     y3 = y1 + t2 * SIN(a + PD2)
30.     x4 = x1 + t2 * COS(a - PD2)
31.     y4 = y1 + t2 * SIN(a - PD2)
32.     x5 = x2 + t2 * COS(a + PD2)
33.     y5 = y2 + t2 * SIN(a + PD2)
34.     x6 = x2 + t2 * COS(a - PD2)
35.     y6 = y2 + t2 * SIN(a - PD2)
36.     ftri x6, y6, x4, y4, x3, y3, K
37.     ftri x3, y3, x5, y5, x6, y6, K
38. END SUB
39.  
40. '2019-12-16 fix by Steve saves some time with STATIC and saves and restores last dest
41. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
42.     DIM D AS LONG
43.     STATIC a&
44.     D = _DEST
45.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
46.     _DEST a&
47.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
48.     PSET (0, 0), K
49.     _BLEND a& '<<<< new 2019-12-16 fix
50.     _DEST D
51.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
52. END SUB
53.  
54.  
55.  

Here is how to draw a simple line:

Code: QB64: [Select]

1. line (x1, y1)-(x2, y2), Kolor

Here is how to draw a simple thick line:

Code: QB64: [Select]

1. thic x1, y1, x2, y2, thickness, Kolor

Can't get simpler, where ever you want a line just use thic

[carloscordeiro]

I wanted exactly that, but with few lines.
I will stay with your penultimate reasoning.

Code: QB64: [Select]
SCREEN 12
thick = 5
FOR x = 0 TO thick
    LINE (6 + x, 5 + x)-(632 - x, 462 - x), 11, B ' box or frame
    'LINE (7, 6)-(631, 461), 11, B  'Slightly thicker lines
    LINE (6 + x, 5 + x)-(632 - x, 50 - x), 11, B
NEXT x

[bplus]

Here is simpler demo:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DEFINT A-Z
3. DO
4.     FOR i = 1 TO 20
5.         thic RND * _WIDTH, RND * _HEIGHT, RND * _WIDTH, RND * _HEIGHT, RND * 30, _RGB32(RND * 255)
6.         _LIMIT 10
7.     NEXT
8.     _DELAY .5
9.     CLS
10. LOOP
11.  
12. 'update 2020-01-24 to include PD2 inside the sub
13. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
14.     DIM PD2 AS DOUBLE, t2 AS SINGLE, a AS SINGLE, x3 AS SINGLE, y3 AS SINGLE, x4 AS SINGLE, y4 AS SINGLE
15.     DIM x5 AS SINGLE, y5 AS SINGLE, x6 AS SINGLE, y6 AS SINGLE
16.     PD2 = 1.570796326794897
17.     t2 = thick / 2
18.     IF t2 < 1 THEN t2 = 1
19.     a = _ATAN2(y2 - y1, x2 - x1)
20.     x3 = x1 + t2 * COS(a + PD2)
21.     y3 = y1 + t2 * SIN(a + PD2)
22.     x4 = x1 + t2 * COS(a - PD2)
23.     y4 = y1 + t2 * SIN(a - PD2)
24.     x5 = x2 + t2 * COS(a + PD2)
25.     y5 = y2 + t2 * SIN(a + PD2)
26.     x6 = x2 + t2 * COS(a - PD2)
27.     y6 = y2 + t2 * SIN(a - PD2)
28.     ftri x6, y6, x4, y4, x3, y3, K
29.     ftri x3, y3, x5, y5, x6, y6, K
30. END SUB
31.  
32. '2019-12-16 fix by Steve saves some time with STATIC and saves and restores last dest
33. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
34.     DIM D AS LONG
35.     STATIC a&
36.     D = _DEST
37.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
38.     _DEST a&
39.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
40.     PSET (0, 0), K
41.     _BLEND a& '<<<< new 2019-12-16 fix
42.     _DEST D
43.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
44. END SUB
45.  

Just copy paste the 2 subs into your code and ignore them, all you need to know is

Code: QB64: [Select]

1. thic x1, y1, x2, y2, thickness, Kolor

Draws a thick line with thickness of thickness and color of Kolor. It's one line of code to draw a thick line!

[carloscordeiro]

You are very funny today, this is what I like about human beings. Witty.

Thanks Bplus for your reasoning of the loop, I will keep it, as it is the simplest and with few lines.

Thanks
Carlos

[FellippeHeitor]

Here's sub box. Pass it the x, y coordinates and the width, height of the box, then the thickness and color to draw.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. box 0, 0, 200, 130, 10, _RGB32(183, 133, 33)
4.  
5. SUB box (x, y, w, h, thickness, theColor AS _UNSIGNED LONG)
6.     LINE (x, y)-STEP(w, h), theColor, BF
7.     LINE (x + thickness, y + thickness)-STEP(w - thickness * 2, h - thickness * 2), _BACKGROUNDCOLOR, BF
8. END SUB

[bplus]

You are very funny today, this is what I like about human beings. Witty.

Thanks Bplus for your reasoning of the loop, I will keep it, as it is the simplest and with few lines.

Thanks
Carlos

Well now hold on, Old Moses had a great idea too!

Here I added something to make it look like a frame to a picture!

Again just copy/paste the sub into the program, ignore how it works and enjoy the one line call

Code: QB64: [Select]

1. framed2 x1, y1, x2, y2, thickness, kolor

x1, y1 has to top left corner of frame/box,  x2, y2 bottom right corner of frame or box, kolor best in mid range or more.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM k AS _UNSIGNED LONG
3. DO
4.     FOR i = 1 TO 10
5.         x1 = RND * _WIDTH: y1 = RND * _HEIGHT: x2 = RND * _WIDTH: y2 = RND * _HEIGHT
6.         IF x1 > x2 THEN SWAP x1, x2: SWAP y1, y2
7.         IF y1 > y2 THEN SWAP y1, y2
8.         k = _RGB32(RND * 200 + 55, RND * 255, RND * 255)
9.         framed2 x1, y1, x2, y2, RND * 15 + 2, k
10.         LOCATE 1, 1: PRINT SPACE$(50)
11.         LOCATE 1, 1: PRINT x1, y1, x2, y2
12.         SLEEP
13.     NEXT
14.     _DELAY .5
15.     CLS
16. LOOP
17.  
18. SUB framed2 (x1, y1, x2, y2, thick, kolor AS _UNSIGNED LONG)
19.     red = _RED32(kolor)
20.     green = _GREEN32(kolor)
21.     blue = _BLUE32(kolor)
22.     FOR i = 0 TO thick
23.         LINE (x1 + i, y1 + i)-(x2 - i, y2 - i), _RGB32(red - 10 * i, green - 10 * i, blue - 10 * i), B
24.     NEXT
25. END SUB
26.  

[bplus]

Yeah, I like Fellippe's width and height better as parameters x, y is top left corner and then width w to right and height h down:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM k AS _UNSIGNED LONG
3. DO
4.     COLOR , _RGB32(255 * RND, 255 * RND, 100 * RND + 155)
5.     CLS
6.     FOR i = 1 TO 10
7.         x1 = RND * (_WIDTH - 200) + 100: y1 = RND * (_HEIGHT - 200) + 100: w = 200 * RND + 35: h = RND * 200 + 35
8.         framed3 x1, y1, w, h, RND * 20 + 4, _RGB32(170 * RND + 80, 255 * RND, 255 * RND)
9.         LOCATE 1, 1: PRINT SPACE$(50)
10.         LOCATE 1, 1: PRINT x1, y1, w, h
11.         SLEEP
12.     NEXT
13.     _DELAY .5
14.     CLS
15. LOOP
16.  
17. SUB framed3 (x, y, w, h, thick, kolor AS _UNSIGNED LONG)
18.     red = _RED32(kolor)
19.     green = _GREEN32(kolor)
20.     blue = _BLUE32(kolor)
21.     FOR i = 0 TO thick
22.         LINE (x + i, y + i)-(x + w - i, y + h - i), _RGB32(red - 10 * i, green - 10 * i, blue - 10 * i), B
23.     NEXT
24. END SUB
25.  

 

Again to use copy/paste sub into program and call with:

Code: QB64: [Select]

1. framed3 x, y, w, h, thick, Kolor

[bplus]

Another 3D version of frame probably best yet:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. DIM k AS _UNSIGNED LONG
3. DO
4.     COLOR , _RGB32(128 + RND * 128 - 64)
5.     CLS
6.     FOR i = 1 TO 10
7.         x1 = RND * (_WIDTH - 200) + 100: y1 = RND * (_HEIGHT - 200) + 100: w = 200 * RND + 35: h = RND * 200 + 35
8.         framed4 x1, y1, w, h, RND * 10 + 4, _RGB32(128 + RND * 128 - 64, 128 + RND * 128 - 64, 128 + RND * 128 - 64)
9.         LOCATE 1, 1: PRINT SPACE$(50)
10.         LOCATE 1, 1: PRINT x1, y1, w, h
11.         SLEEP
12.     NEXT
13.     _DELAY .5
14.     CLS
15. LOOP
16.  
17. SUB framed4 (x, y, w, h, thick, kolor AS _UNSIGNED LONG)
18.     red = _RED32(kolor)
19.     green = _GREEN32(kolor)
20.     blue = _BLUE32(kolor)
21.     DIM saveC AS _UNSIGNED LONG
22.     FOR i = 0 TO thick * .5
23.         red = red + 15: green = green + 15: blue = blue + 15
24.         LINE (x + i, y + i)-(x + w - i, y + h - i), _RGB32(red, green, blue), B
25.     NEXT
26.     FOR i = thick * .5 TO thick
27.         red = red - 15: green = green - 15: blue = blue - 15
28.         LINE (x + i, y + i)-(x + w - i, y + h - i), _RGB32(red, green, blue), B
29.     NEXT
30. END SUB
31.