Celtic Square Knot

[bplus]

My new Avatar!

Code: QB64: [Select]

1. _TITLE "Celtic Square Knot" 'b+ 2020-09-15 I am obsessed ;-))
2.  
3. SCREEN _NEWIMAGE(500, 500, 32)
4. _DELAY .25
5. _SCREENMOVE _MIDDLE
6.  
7. TYPE Box
8.     x AS SINGLE
9.     y AS SINGLE
10.     w AS SINGLE
11.     h AS SINGLE
12. END TYPE
13.  
14. 'check for overlap , dang ok fix OK good
15. drawFrame _WIDTH / 2 - 100, _HEIGHT / 2 - 100, 300, 200, 10, &H22FFFFFF
16. CLS
17. side = 390
18. CelticSqrKnot _WIDTH / 2 - side / 2, _HEIGHT / 2 - side / 2, side, &HFF00AA55
19.  
20.  
21. 'now for the knot
22. SUB CelticSqrKnot (x, y, side, backK AS _UNSIGNED LONG) 'if side and thick are multiples of 7 this could work side > 6*th
23.     ' calc 7*xSpace + 6*th = side  so xspace = (side - 6*th)/7
24.  
25.     'if we make it simple x = th then 7*th + 6*th = side so side has to be multiple of 13
26.     th = INT(side / 13)
27.  
28.  
29.     ' 3 frames  4 boxes each
30.     DIM f1(1 TO 4) AS Box, f2(1 TO 4) AS Box, f3(1 TO 4) AS Box
31.     DIM bxs(1 TO 12) AS Box, bi AS INTEGER
32.     DIM cF1 AS _UNSIGNED LONG, cF2 AS _UNSIGNED LONG, cF3 AS _UNSIGNED LONG
33.     cF1 = &HFF0000AA: cF2 = &HFFFFFF00: cF3 = &HFFAA0000: white = &HFFFFFFFF
34.  
35.     LINE (x, y)-STEP(13 * th, 13 * th), backK, BF 'back ground can be transparent
36.  
37.     drawFrame x + 5 * th, y + th, 3 * th, 11 * th, th, cF1 'vertical
38.     frameParts x + 5 * th, y + th, 3 * th, 11 * th, th, f1()
39.  
40.  
41.     drawFrame x + 3 * th, y + 3 * th, 7 * th, 7 * th, th, cF2 'square
42.     frameParts x + 3 * th, y + 3 * th, 7 * th, 7 * th, th, f2()
43.  
44.  
45.     drawFrame x + th, y + 5 * th, 11 * th, 3 * th, th, cF3 ' horizontal
46.     frameParts x + th, y + 5 * th, 11 * th, 3 * th, th, f3()
47.  
48.     count = 0
49.     'frame 1, 1234 intersect frame 2 square 5678
50.     FOR fb1 = 1 TO 4
51.         FOR fb2 = 1 TO 4
52.             IF collision(f1(fb1).x, f1(fb1).y, f1(fb1).w, f1(fb1).h, f2(fb2).x, f2(fb2).y, f2(fb2).w, f2(fb2).h) THEN
53.  
54.                 ' get the intersecting box
55.                 collisionIntersect2Boxes f1(fb1).x, f1(fb1).y, f1(fb1).w, f1(fb1).h, f2(fb2).x, f2(fb2).y, f2(fb2).w, f2(fb2).h, bix, biy, biw, bih
56.                 count = count + 1
57.                 IF count MOD 4 < 2 THEN LINE (bix, biy)-STEP(biw, bih), cF1, BF
58.                 IF count MOD 4 > 1 THEN LINE (bix, biy)-STEP(biw, bih), cF2, BF
59.                 'IF count MOD 4 = 3 THEN LINE (bix, biy)-STEP(biw, bih), cF2, BF
60.                 'IF count MOD 4 = 0 THEN LINE (bix, biy)-STEP(biw, bih), cF1, BF
61.             END IF
62.         NEXT
63.     NEXT
64.  
65.     count = 0
66.     'frame 1, 1234 intersect frame 3 intersect 9, 10, 11, 12
67.     FOR fb1 = 1 TO 4
68.         FOR fb2 = 1 TO 4
69.             IF collision(f1(fb1).x, f1(fb1).y, f1(fb1).w, f1(fb1).h, f3(fb2).x, f3(fb2).y, f3(fb2).w, f3(fb2).h) THEN
70.  
71.                 ' get the intersecting box
72.                 collisionIntersect2Boxes f1(fb1).x, f1(fb1).y, f1(fb1).w, f1(fb1).h, f3(fb2).x, f3(fb2).y, f3(fb2).w, f3(fb2).h, bix, biy, biw, bih
73.                 count = count + 1
74.                 IF count MOD 4 < 2 THEN LINE (bix, biy)-STEP(biw, bih), cF3, BF
75.                 IF count MOD 4 > 1 THEN LINE (bix, biy)-STEP(biw, bih), cF1, BF
76.                 'IF count MOD 4 = 3 THEN LINE (bix, biy)-STEP(biw, bih), cF1, BF
77.                 'IF count MOD 4 = 0 THEN LINE (bix, biy)-STEP(biw, bih), cF3, BF
78.             END IF
79.         NEXT
80.     NEXT
81.  
82.     count = 0
83.     'frame 2, 5678 intersect frame 3 intersect 9, 10, 11, 12
84.     FOR fb1 = 1 TO 4
85.         FOR fb2 = 1 TO 4
86.             IF collision(f2(fb1).x, f2(fb1).y, f2(fb1).w, f2(fb1).h, f3(fb2).x, f3(fb2).y, f3(fb2).w, f3(fb2).h) THEN
87.  
88.                 ' get the intersecting box
89.                 collisionIntersect2Boxes f2(fb1).x, f2(fb1).y, f2(fb1).w, f2(fb1).h, f3(fb2).x, f3(fb2).y, f3(fb2).w, f3(fb2).h, bix, biy, biw, bih
90.                 count = count + 1
91.                 IF count MOD 4 < 2 THEN LINE (bix, biy)-STEP(biw, bih), cF2, BF
92.                 IF count MOD 4 > 1 THEN LINE (bix, biy)-STEP(biw, bih), cF3, BF
93.                 'IF count MOD 4 = 3 THEN LINE (bix, biy)-STEP(biw, bih), cF3, BF
94.                 'IF count MOD 4 = 0 THEN LINE (bix, biy)-STEP(biw, bih), cF2, BF
95.             END IF
96.         NEXT
97.     NEXT
98.  
99. END SUB
100.  
101. SUB drawFrame (x, y, w, h, th, k AS _UNSIGNED LONG)
102.     LINE (x, y)-STEP(w, th), k, BF 'two horizontal
103.     LINE (x, y + h - th)-STEP(w, th), k, BF
104.     LINE (x, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF 'try not to overlap boxes in case k is transparent
105.     LINE (x + w - th, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF
106. END SUB
107.  
108. SUB frameParts (x, y, w, h, th, bxs() AS Box)
109.  
110.     'for each line in drawFrame
111.  
112.     'LINE (x, y)-STEP(w, th), k, BF 'two horizontal
113.     bxs(1).x = x
114.     bxs(1).y = y
115.     bxs(1).w = w
116.     bxs(1).h = th
117.  
118.     'LINE (x, y + h - th)-STEP(w, th), k, BF
119.     bxs(2).x = x
120.     bxs(2).y = y + h - th
121.     bxs(2).w = w
122.     bxs(2).h = th
123.  
124.     'LINE (x, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF 'try not to overlap boxes in case k is transparent
125.     bxs(3).x = x
126.     bxs(3).y = y + th + 1
127.     bxs(3).w = th
128.     bxs(3).h = h - 2 * th - 2
129.  
130.     'LINE (x + w - th, y + th + 1)-STEP(th, h - 2 * th - 2), k, BF
131.     bxs(4).x = x + w - th
132.     bxs(4).y = y + th + 1
133.     bxs(4).w = th
134.     bxs(4).h = h - 2 * th - 2
135.  
136. END SUB
137.  
138. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
139.     ' x, y represent the box left most x and top most y
140.     ' w, h represent the box width and height which is the usual way sprites / tiles / images are described
141.     ' such that boxbottom = by + bh
142.     '        and boxright = bx + bw
143.  
144.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
145.         collision% = 0
146.     ELSE
147.         collision% = 1
148.     END IF
149. END FUNCTION
150.  
151. SUB collisionIntersect2Boxes (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h, bix, biy, biw, bih)
152.     IF b2x >= b1x AND b2x <= b1x + b1w AND b2y >= b1y AND b2y <= b1y + b1h THEN 'top left corner in 2nd box
153.         bix = b2x: biy = b2y
154.         IF b2x + b2w <= b1x + b1w THEN
155.             biw = b2w
156.         ELSE
157.             biw = b1x + b1w - b2x
158.         END IF
159.         IF b2y + b2h <= b1y + b1h THEN
160.             bih = b2h
161.         ELSE
162.             bih = b1y + b1h - b2y
163.         END IF
164.     ELSEIF b2x >= b1x AND b2x <= b1x + b1w AND b2y + b2h >= b1y AND b2y + b2h <= b1y + b1h THEN 'bottom left corner of 2nd box in first
165.         bix = b2x
166.         IF b2x + b2w <= b1x + b1w THEN
167.             biw = b2w
168.         ELSE
169.             biw = b1x + b1w - b2x
170.         END IF
171.         IF b2y <= b1y THEN
172.             biy = b1y
173.             bih = b2y + b2h - b1y
174.         ELSE
175.             biy = b2y
176.             bih = b2h
177.         END IF
178.     ELSEIF b2x + b2w >= b1x AND b2x + b2w <= b1x + b1w AND b2y >= b1y AND b2y <= b1y + b1h THEN 'right top corner 2nd box in first
179.         IF b2x >= b1x THEN
180.             bix = b2x
181.             biw = b2w
182.         ELSE
183.             bix = b1x
184.             biw = b2x + b2w - b1x
185.         END IF
186.         biy = b2y
187.         IF b2y + b2h <= b1y + b1h THEN
188.             bih = b2h
189.         ELSE
190.             bih = b1y + b1h - b2y
191.         END IF
192.     ELSEIF b2x + b2w >= b1x AND b2x + b2w <= b1x + b1w AND b2y + b2h >= b1y AND b2y + b2h <= b1y + b1h THEN 'left bottom corners in first box
193.         IF b2x >= b1x THEN
194.             bix = b2x
195.             biw = b2w
196.         ELSE
197.             bix = b1x
198.             biw = b2x + b2w - b1x
199.         END IF
200.         IF b2y >= b1y THEN
201.             biy = b2y
202.             bih = b2h
203.         ELSE
204.             biy = b1y
205.             bih = b2y + b2h - b1y
206.         END IF
207.     ELSEIF collision%(b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h) THEN
208.         bix = max(b1x, b2x): biy = max(b1y, b2y)
209.         biw = min(b1x + b1w, b2x + b2w) - bix: bih = min(b1y + b1h, b2y + b2h) - biy
210.     ELSE 'no intersect
211.         bix = -1: biy = -1: biw = 0: bih = 0
212.     END IF
213. END SUB
214.  
215. FUNCTION max (a, b)
216.     IF a > b THEN max = a ELSE max = b
217. END FUNCTION
218.  
219. FUNCTION min (a, b)
220.     IF a < b THEN min = a ELSE min = b
221. END FUNCTION
222.  
223.  
224.  

[Cobalt]

New day, New avatar.....

Fairly cool, I must admit it surprised me how simple it was. I actually thought it was going to be a much more complex knot. But nice and simple!

Though it got me thinking, and I may start a new topic on it but wanted to ask here real quick cause I'm pretty sure you can probably think of a way to pull it off fairly easy, I have a continuing issue trying to pull something off that I just can't quite nail down.

I have a grid 194x79  with two boxes(or Rooms) on either side that I need a meandering path between. Not just a straight shot but something that uses a portion of the area to reach from one side to the other. My issue is the path I generate tends to just "scribble" ,best way I can describe, and it basically wipes the entire grid clear. rather than making a path.

There are no obstacles so no like path-finding(A*, what not) stuff of that type needed just a non-direct route between 2 points.

[bplus]

I am reminded of an old recursive routine that does lightning (connecting between 2 points) or mountain ranges also connecting between two points.

I imagine you'd want your path squared off, 90 degree turns? so a mod of lighting or mountain range.

Am I off track? or should I dig up code and mod? Maybe you know this code?

This might not meander enough because x step will advance to other room or won't advance but will never reverse meanwhile, y is going up and down but never so far away that it won't be back "in time" again to enter the opposite room.

Actually this sounds a little like what @SierraKen is working with cave paths. For real time meandering you'd need to track where you've meandered already and just how much you want to fill up the screen with meanderings :)

Come to think, you could generate a maze between the 2 rooms! Just feed it an enter point and exit point and the rectangle between the 2 rooms. Now there's meandering that doesn't waste a single square!

[Cobalt]

thats pretty spot on, right angle turns.

I'll have to look at SK's post.

it was just the look of your output that made me think about asking.

an example of what I am trying to come close too,

[Cobalt]

this is what I usually end up with,

[bplus]

That's kinda an interesting problem:

Measure the distance x, and y, for destination or target.

Every step towards or away will add to or subtract to distance, when time is up make bee line to next room first all x then all y or vice versa. If you changed x last time you have to change y at next change in direction.

Goody something to play with :)

[SierraKen]

Cobalt, what I do is this:

IF ROOMX > YOUX THEN YOUX = YOUX + 20
IF ROOMX < YOUX THEN YOUX = YOUX - 20
IF ROOMY > YOUY THEN YOUY = YOUY + 20
IF ROOMY < YOUY THEN YOUY = YOUY - 20

And to make longer paths before they turn, I use a counter before the random direction change.