Save Image Section

[bplus]

Practice with SMcNeill's SaveImage v2.3b package by creating 5 random drawings using mouse to select a screen section to save and then showing slide show of 5 saved screen sections:

Code: QB64: [Select]

1. _TITLE "mouse down at top left corner of image section, release down and to right for section to save image section."
2. 'Test Saveimage v2.3b by Steve McNeill BI 2020-6-11, BM 2020-6-27
3.  
4. '$INCLUDE:'SaveImage.BI'
5.  
6. CONST SaveTextAs256Color = 0 'Flag to Save as 256 color file or 32-bit color file, when converting SCREEN 0 to an image
7. '                             Set to TRUE (any non-zero value) to save text screens in 256 color mode.
8. '                             Set to FALSE (zero) to save text screens in 32-bit color mode.
9.  
10. SCREEN _NEWIMAGE(800, 600, 32)
11. _DELAY .25
12. _SCREENMOVE _MIDDLE
13.  
14. LOCATE 5, 1
15. yCP 7, "***  SaveImage Section ***         b+ 2020-09-06"
16. yCP 10, "Testing SaveImage v2.3 by saving 5 screen sections of randomly drawn boxes."
17. yCP 12, "Mouse down at the top, left corner of your selection, drag mouse down and left to"
18. yCP 14, "bottom, right of your selection. As soon as you release button this app should "
19. yCP 16, "show the section you selected centered in the middle of the screen."
20. yCP 18, "we will do this 5 times and then show a little slide show of our selections :)"
21. yCP 21, "press any to continue..."
22. SLEEP
23.  
24. FOR i& = 1 TO 5
25.     'draw some junk to save an image section
26.     image& = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
27.     CLS
28.     FOR i = 1 TO 100
29.         LINE (RND * _WIDTH, RND * _HEIGHT)-STEP(RND * 100 + 10, RND * 100 + 10), _RGB32(RND * 255, RND * 256, RND * 256), BF
30.     NEXT
31.     PRINT "Test Section #" + _TRIM$(STR$(i&))
32.     _PUTIMAGE , 0, image&
33.     COLOR , &HFF000000: CLS
34.     saveImageFile$ = "Test Save Image(" + _TRIM$(STR$(i&)) + ").png"
35.     IF _FILEEXISTS(saveImageFile$) THEN KILL saveImageFile$
36.     DO
37.         _PUTIMAGE , image&, 0 'cls with image
38.         WHILE _MOUSEINPUT: WEND
39.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
40.         IF mb THEN
41.             sx = mx: sy = my 'start mouse
42.             WHILE mb
43.                 CLS
44.                 _PUTIMAGE , image&, 0
45.                 WHILE _MOUSEINPUT: WEND
46.                 mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
47.                 LINE (sx, sy)-(mx, my), , B
48.                 LINE (sx - 1, sy - 1)-(mx + 1, my + 1), &HFF000000, B
49.                 _DISPLAY
50.                 _LIMIT 60
51.             WEND
52.             fx = mx - 1: fy = my 'finish mouse
53.             'Result = SaveImage(exportimage(i), l&, 0, 0, _WIDTH(l&) - 1, _HEIGHT(l&) - 1)
54.             Result = SaveImage(saveImageFile$, 0, sx + 1, sy + 1, fx - 1, fy - 1)
55.             IF Result = -1 THEN 'file already found on drive
56.                 PRINT "Image Section Saved to " + saveImageFile$ + ", we will load it in 4 secs."
57.                 EXIT DO
58.             ELSE
59.                 PRINT "Error #" + _TRIM$(STR$(Result)) + " occurred image not saved, goodbye."
60.                 END
61.             END IF
62.             _DISPLAY
63.             _DELAY 4
64.             END
65.         END IF
66.         _DISPLAY
67.         _LIMIT 60
68.     LOOP
69.     CLS
70.     L& = _LOADIMAGE(saveImageFile$)
71.     IF L& < -1 THEN
72.         _PUTIMAGE ((_WIDTH - _WIDTH(L&)) / 2, (_HEIGHT - _HEIGHT(L&)) / 2), L&, 0
73.     ELSE
74.         PRINT "Sorry, "; saveImageFile$; " failed to load."
75.     END IF
76.     _DISPLAY
77.     _DELAY 4
78.     _FREEIMAGE image&
79.     _FREEIMAGE L&
80. NEXT
81. FOR i& = 1 TO 5
82.     saveImageFile$ = "Test Save Image(" + _TRIM$(STR$(i&)) + ").png"
83.     CLS
84.     L& = _LOADIMAGE(saveImageFile$)
85.     IF L& < -1 THEN
86.         _PUTIMAGE ((_WIDTH - _WIDTH(L&)) / 2, (_HEIGHT - _HEIGHT(L&)) / 2), L&, 0
87.     ELSE
88.         PRINT "Sorry, "; saveImageFile$; " failed to load."
89.     END IF
90.     _DISPLAY
91.     _DELAY 4
92.     _FREEIMAGE L&
93. NEXT
94.  
95. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
96.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y * 16), s$
97. END SUB
98.  
99.  
100. '$INCLUDE:'SaveImage.BM'
101.  

Zip with BI and massive BM