Inversion Points, 2D Circle

[bplus]

What _vince is doing with Domain Coloring (Complex Number Plotting) reminds me of Inversion Points of Circle:

Code: QB64: [Select]

1. _TITLE "Inversion point sub" 'b+ 202-04-14
2. '2020-04-15 Oh man! there is a way way easier way to do this!!!   yep!
3.  
4. CONST xmax = 1200, ymax = 700
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 100, 40
7.  
8. DO
9.     IF LEN(INKEY$) THEN CLS
10.     CIRCLE (xmax / 2, ymax / 2), 200
11.  
12.     WHILE _MOUSEINPUT: WEND
13.     mx = _MOUSEX: my = _MOUSEY
14.     CIRCLE (mx, my), 2, &HFFF0000FF
15.     'test new sub
16.     inversionPoint xmax / 2, ymax / 2, 200, mx, my, Rx, Ry
17.     CIRCLE (Rx, Ry), 2, &HFFFFFF00 'yellow circle should be on line perprendicular to 3rd click point
18.  
19.     _DISPLAY
20. LOOP UNTIL _KEYDOWN(27)
21.  
22.  
23. SUB inversionPoint (CX, CY, CR, X, Y, IX, IY) 'update the easy way 2020-04-15
24.     a = _HYPOT(CX - X, CY - Y)
25.     IF a <> 0 THEN
26.         aPrime = CR ^ 2 / a
27.         ang = _ATAN2(Y - CY, X - CX)
28.         IX = CX + aPrime * COS(ang)
29.         IY = CY + aPrime * SIN(ang)
30.     ELSE
31.         IX = CX: IY = CY 'because a line across diamter is inverted to itself
32.     END IF
33. END SUB
34.  
35. SUB inversionPointOrig (CX, CY, CR, X, Y, IX, IY)
36.     dist = _HYPOT(CX - X, CY - Y)
37.  
38.     IF dist = CR THEN
39.         IX = X: IY = Y
40.     ELSEIF dist > CR THEN 'find angle of tangent line from x, y to circle radius
41.         a = _ASIN(CR / dist)
42.         adj = dist * COS(a)
43.         xDist = adj * COS(a)
44.         a = _ATAN2(CY - Y, CX - X)
45.         IX = X + xDist * COS(a)
46.         IY = Y + xDist * SIN(a)
47.     ELSE 'dist < r  x, y is inertenal and need to find external
48.         a = _ATAN2(Y - CY, X - CX) - _PI / 2 'perpendicular to X, Y and CX, CY
49.         'need another point on the line perpendicular  at x, y
50.         x1 = X + 100 * COS(a): y1 = Y + 100 * SIN(a)
51.         CIRCLE (x1, y1), 2, &HFF0000FF
52.  
53.  
54.         ' two points make a line find where it intersects circle
55.         nPts = lineIntersectCircle%(X, Y, x1, y1, CX, CY, CR, ix1, iy1, ix2, iy2)
56.  
57.  
58.         IF nPts = 2 THEN 'now we need 2 points to line perp to radius at ix1, ix2
59.             CIRCLE (ix1, iy1), 2, &HFF00AA00: CIRCLE (ix2, iy2), 2, &HFF00AA00 'green circle intersect  OK
60.  
61.  
62.             a = _ATAN2(CY - iy1, CX - ix1) - _PI / 2 ' the angle of tangent point to center of circle
63.             x2 = ix1 + 100 * COS(a): y2 = iy1 + 100 * SIN(a) ' extend tangent line in some direction
64.  
65.             'check work
66.             LINE (x2, y2)-(ix1, iy1), &HFF0000FF
67.             CIRCLE (ix1, iy1), 4, &HFF0000FF ' tangent point from x, y perpendicular
68.  
69.             ' intersect of 2 lines
70.             nPoints = lineIntersectLine%(CX, CY, X, Y, ix1, iy1, x2, y2, IX, IY)
71.             IF nPoints <> 1 THEN IX = 0: IY = 0: BEEP '???? no intersect
72.         END IF
73.     END IF
74. END SUB
75.  
76. SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept) ' fix for when x1 = x2
77.     IF X1 = X2 THEN
78.         slope = X1
79.         Yintercept = Y2
80.     ELSE
81.         slope = (Y2 - Y1) / (X2 - X1)
82.         Yintercept = slope * (0 - X1) + Y1
83.     END IF
84. END SUB
85.  
86. SUB PointOnLinePerp2Point (Lx1, Ly1, Lx2, Ly2, Px, Py, Rx, Ry)
87.     '
88.     'this sub needs  SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept) ' fix for when x1 = x2
89.     '
90.     'Lx1, Ly1, Lx2, Ly2     the two points that make a line
91.     'Px, Py is point off the line
92.     'Rx, Ry Return Point is the Point on the line perpendicular to Px, Py
93.     slopeYintersect Lx1, Ly1, Lx2, Ly2, m, Y0
94.     A = m ^ 2 + 1
95.     B = 2 * (m * Y0 - m * Py - Px)
96.     Rx = -B / (2 * A)
97.     Ry = m * Rx + Y0
98. END SUB
99.  
100. FUNCTION lineIntersectLine% (ax1, ay1, ax2, ay2, bx1, by1, bx2, by2, ix, iy)
101.     IF ax1 = ax2 THEN 'line a is vertical
102.         IF bx1 = bx2 THEN ' b is vertical
103.             IF ax1 = bx1 THEN lineIntersectLine% = -1 ' if x's are same it is same vertical line
104.             EXIT FUNCTION '
105.         ELSE
106.             ix = ax1
107.             slopeYintersect bx1, by1, bx2, by2, m2, y02
108.             iy = m2 * ix + y02
109.             lineIntersectLine% = 1 'signal a point was found
110.             EXIT FUNCTION
111.         END IF
112.     ELSE
113.         slopeYintersect ax1, ay1, ax2, ay2, m1, y01 ' -m = a, 1 = b, y0 = c  std form
114.     END IF
115.     IF bx1 = bx2 THEN 'b is vertical
116.         ix = bx1: iy = m1 * ix + y01: lineIntersectLine% = 1 'signal a point was found
117.         EXIT FUNCTION
118.     ELSE
119.         slopeYintersect bx1, by1, bx2, by2, m2, y02 ' -m = a, 1 = b, y0 = c  std form
120.     END IF
121.     d = -m1 - -m2 ' if = 0 then parallel or equal because slopes are same
122.     IF ABS(d) > .2 THEN 'otherwise about 0
123.         ix = (y01 - y02) / d: iy = (-m1 * y02 - -m2 * y01) / d
124.         lineIntersectLine% = 1 'signal one intersect point was found
125.     ELSE 'same line or parallel? if y0 are same they are the same
126.         IF ABS(y01 - y02) < 5 THEN lineIntersectLine% = -1 'signal same line!
127.     END IF
128. END FUNCTION
129.  
130. ' return 0 no Intersect, 1 = tangent 1 point touch, 2 = 2 point intersect
131. FUNCTION lineIntersectCircle% (lx1, ly1, lx2, ly2, cx, cy, r, ix1, iy1, ix2, iy2)
132.  
133.     'needs    SUB slopeYintersect (X1, Y1, X2, Y2, slope, Yintercept)
134.  
135.     IF lx1 <> lx2 THEN
136.         slopeYintersect lx1, ly1, lx2, ly2, m, Y0 ' Y0 otherwise know as y Intersect
137.  
138.         ' https://math.stackexchange.com/questions/228841/how-do-i-calculate-the-intersections-of-a-straight-line-and-a-circle
139.         A = m ^ 2 + 1
140.         B = 2 * (m * Y0 - m * cy - cx)
141.         C = cy ^ 2 - r ^ 2 + cx ^ 2 - 2 * Y0 * cy + Y0 ^ 2
142.         D = B ^ 2 - 4 * A * C 'telling part of Quadratic formula = 0 then circle is tangent  or > 0 then 2 intersect points
143.         IF D < 0 THEN ' no intersection
144.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
145.         ELSEIF D = 0 THEN ' one point tangent
146.             x1 = (-B + SQR(D)) / (2 * A)
147.             y1 = m * x1 + Y0
148.             ix1 = x1: iy1 = y1: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
149.         ELSE '2 points
150.             x1 = (-B + SQR(D)) / (2 * A): y1 = m * x1 + Y0
151.             x2 = (-B - SQR(D)) / (2 * A): y2 = m * x2 + Y0
152.             ix1 = x1: iy1 = y1: ix2 = x2: iy2 = y2: lineIntersectCircle% = 2
153.         END IF
154.     ELSE 'vertical line
155.         IF r = ABS(lx1 - cx) THEN ' tangent
156.             ix1 = lx1: iy1 = cy: ix2 = -999: iy2 = -999: lineIntersectCircle% = 1
157.         ELSEIF r < ABS(lx1 - cx) THEN 'no intersect
158.             ix1 = -999: iy1 = -999: ix2 = -999: iy2 = -999: lineIntersectCircle% = 0
159.         ELSE '2 point intersect
160.             ydist = SQR(r ^ 2 - (lx1 - cx) ^ 2)
161.             ix1 = lx1: iy1 = cy + ydist: ix2 = lx1: iy2 = cy - ydist: lineIntersectCircle% = 2
162.         END IF
163.     END IF
164. END FUNCTION
165.  
166.  

This calls for an experiment in grapphing. :)

[_vince]

Any idea why I can't run this?  Using QB64 version 1.4 on windows

[bplus]

Any idea why I can't run this?  Using QB64 version 1.4 on windows

Have no idea, copy paste from forum code works fine for me, but here is much briefer code with correct date and other tiny change(s). This is developed and tested in QB64 1.4 stable version in Windows 10 - 64 bit.

Code: QB64: [Select]

1. _TITLE "Inversion point sub" 'b+ 2020-04-14
2. '2020-04-15 Oh man! there is a way way easier way to do this!!!   yep!
3. '2020-08-19 remove original Inversion Point code and other tiny changes
4.  
5. CONST xmax = 1200, ymax = 700
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _DELAY .25
8. _SCREENMOVE _MIDDLE
9.  
10. DO
11.     IF LEN(INKEY$) THEN CLS
12.     CIRCLE (xmax / 2, ymax / 2), 200
13.     WHILE _MOUSEINPUT: WEND
14.     mx = _MOUSEX: my = _MOUSEY
15.     CIRCLE (mx, my), 2, &HFFF0000FF
16.     'test new sub
17.     inversionPoint xmax / 2, ymax / 2, 200, mx, my, Rx, Ry
18.     CIRCLE (Rx, Ry), 2, &HFFFFFF00 'yellow circle should be on line perprendicular to 3rd click point
19.     _DISPLAY
20.     _LIMIT 200
21. LOOP UNTIL _KEYDOWN(27)
22.  
23. SUB inversionPoint (CX, CY, CR, X, Y, IX, IY) 'update the easy way 2020-04-15
24.     a = _HYPOT(CX - X, CY - Y)
25.     IF a <> 0 THEN
26.         aPrime = CR ^ 2 / a
27.         ang = _ATAN2(Y - CY, X - CX)
28.         IX = CX + aPrime * COS(ang)
29.         IY = CY + aPrime * SIN(ang)
30.     ELSE
31.         IX = CX: IY = CY 'because a line across diamter is inverted to itself
32.     END IF
33. END SUB
34.  
35.  
36.  

Move your mouse around edge of circle to see drawing on both inside and out.

Mouse is blue, Inversion Points of mouse position is yellow.

[_vince]

this one works, nice

[loudar]

waves and stuff!

[bplus]

I inverted a checkerboard in a circle in the middle of it:

Code: QB64: [Select]

1. _TITLE "Checkerboard mod Inverse" ' b+ 2020-08-19
2. SCREEN _NEWIMAGE(700, 700, 32)
3. _DELAY .25
4. _SCREENMOVE _MIDDLE
5.  
6. ' using const so the code can be more readable < great idea!
7. CONST GOLD = &HFFFF9900, BLACK = &HFF000000, RED = &HFFFF0000, SQ = 35
8. LINE (0 * SQ + .5 * SQ - 4, 0 * SQ + .5 * SQ - 4)-STEP(19 * SQ + 8, 19 * SQ + 8), GOLD, BF
9. n = 0
10. FOR y = 0 TO 18
11.     FOR x = 0 TO 18
12.         n = (n + 1) MOD 2
13.         IF n MOD 2 THEN colore& = RED ELSE colore& = BLACK
14.         LINE (x * SQ + .5 * SQ + 2, y * SQ + .5 * SQ + 2)-STEP(SQ - 4, SQ - 4), colore&, BF
15.     NEXT
16.     'n = (n + 1) MOD 2 '< for even amount of squares in a row
17. NEXT
18. fcirc 350, 350, 250, &HFF000000
19. DIM c AS _UNSIGNED LONG
20. FOR y = -1000 TO 1700
21.     FOR x = -1000 TO 1700
22.         IF _HYPOT(x - 350, y - 350) >= 250 THEN
23.             inversionPoint 350, 350, 250, x, y, ix, iy
24.             IF x > 0 AND x < 700 AND y > 0 AND y < 700 THEN
25.                 c = POINT(x, y)
26.                 PSET (ix, iy), c
27.             ELSE
28.                 PSET (ix, iy), &HFF000000
29.             END IF
30.         END IF
31.     NEXT
32. NEXT
33. SLEEP
34.  
35. SUB inversionPoint (CX, CY, CR, X, Y, IX, IY) 'update the easy way 2020-04-15
36.     a = _HYPOT(CX - X, CY - Y)
37.     IF a <> 0 THEN
38.         aPrime = CR ^ 2 / a
39.         ang = _ATAN2(Y - CY, X - CX)
40.         IX = CX + aPrime * COS(ang)
41.         IY = CY + aPrime * SIN(ang)
42.     ELSE
43.         IX = CX: IY = CY 'because a line across diamter is inverted to itself
44.     END IF
45. END SUB
46.  
47. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
48.     DIM Radius AS INTEGER, RadiusError AS INTEGER
49.     DIM X AS INTEGER, Y AS INTEGER
50.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
51.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
52.     LINE (CX - X, CY)-(CX + X, CY), C, BF
53.     WHILE X > Y
54.         RadiusError = RadiusError + Y * 2 + 1
55.         IF RadiusError >= 0 THEN
56.             IF X <> Y + 1 THEN
57.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
58.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
59.             END IF
60.             X = X - 1
61.             RadiusError = RadiusError - X * 2
62.         END IF
63.         Y = Y + 1
64.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
65.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
66.     WEND
67. END SUB
68.  
69.