Estimating Pi

[FellippeHeitor]

Of course we already have _PI, this is just a cool way to visualize it.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2.  
3. DIM inCircle AS _UNSIGNED LONG, total AS _UNSIGNED LONG
4. DIM pi AS _FLOAT
5.  
6. DO
7.     px = RND * _WIDTH
8.     py = RND * _HEIGHT
9.  
10.     total = total + 1
11.     IF dist(_WIDTH / 2, _HEIGHT / 2, px, py) <= 300 THEN
12.         inCircle = inCircle + 1
13.         PSET (px, py), _RGB32(100)
14.     ELSE
15.         PSET (px, py), _RGB32(70)
16.     END IF
17.     pi = (inCircle * 4) / total
18.  
19.     LOCATE 1, 1
20.     PRINT pi
21.  
22.     CIRCLE (_WIDTH / 2, _HEIGHT / 2), 299, _RGB32(216, 144, 22)
23.     _DISPLAY
24. LOOP
25.  
26. FUNCTION dist! (x1!, y1!, x2!, y2!)
27.     dist! = _HYPOT((x2! - x1!), (y2! - y1!))
28. END FUNCTION

As seen on:

[_vince]

It is a great simulation! Another one is called "buffon's needles", I wanted to write a program that demonstrates the experiment graphically and then numerically computes the results to iteratively approximated pi as more needles are dropped, open challenge I guess

ie
(https://en.wikipedia.org/wiki/Buffon%27s_needle_problem#/media/File:Buffon_needle_experiment_compressed.gif)

[SierraKen]

Really awesome Felippe! I have no idea how you and others find Pi, was just ages ago since school. But I remembered a year ago (which turned out to be exactly a year ago), I found code to output as many digits as you want. I posted it in another thread if anyone is interested. Just funny that it's been one year, around the Sun, using Pi LOL. Oh, I also updated it tonight to make it show how many digits it has left to calculate before it shows a Notepad of it.

[FellippeHeitor]

Well, I guess that only proves that life is a circle, @SierraKen 😂

@_vince looking forward to your project!

[SierraKen]

LOL true.

[bplus]

It is a great simulation! Another one is called "buffon's needles", I wanted to write a program that demonstrates the experiment graphically and then numerically computes the results to iteratively approximated pi as more needles are dropped, open challenge I guess

ie
(https://en.wikipedia.org/wiki/Buffon%27s_needle_problem#/media/File:Buffon_needle_experiment_compressed.gif)

A very slow road to Pi:

Code: QB64: [Select]

1. _TITLE "Buffon Pi Calc " 'b+ 2020-08-2
2. '2020-08-02 try this with Buffon Pi Calc  pi ~ 2 * nTrials / nCross  from
3. ' pi ~ 2*L*N/(T*H) L=length of needle, T=spacing between lines N = Number of trials (or pins) H = number that cross line
4. _DEFINE A-Z AS _FLOAT
5. RANDOMIZE TIMER
6.  
7. CONST xmax = 800, ymax = 600
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _DELAY .25
10. _SCREENMOVE _MIDDLE
11. DIM N AS _INTEGER64, C AS _INTEGER64, SS AS _INTEGER64
12. L = 100 ' both pin length and line spacing
13. N = 0 '   number of trials
14. C = 0 '   number of pins that cross the line
15. SS = 0 '  pin head and point lay in Same Space
16.  
17. DO
18.     CLS
19.     'redraw lines
20.     FOR y = 0 TO _HEIGHT - 1 STEP L
21.         LINE (0, y)-(_WIDTH - 1, y), &HFFFFFFFF
22.     NEXT
23.  
24.     'drop a random pin
25.     px1 = RND * (_WIDTH - 200) + 100
26.     py1 = RND * (_HEIGHT - 200) + 100
27.     ra = RND * _PI(2)
28.     px2 = px1 + L * COS(ra)
29.     py2 = py1 + L * SIN(ra)
30.     LINE (px1, py1)-(px2, py2), _RGB32(50 + RND * 150)
31.     N = N + 1 '                             another trial pin
32.  
33.     'did our pin cross a line
34.     FOR y = 0 TO _HEIGHT - 1 STEP L
35.         IF py1 >= y AND py1 < y + L THEN ' one side of pin is between y and y + L
36.             IF py2 >= y AND py2 < y + L THEN ' the pin did NOT cross a line both the head and point lay in same space
37.                 SS = SS + 1
38.             END IF
39.         END IF
40.     NEXT
41.     C = N - SS
42.     'Print results of trials
43.     LOCATE 1, 1: PRINT "Trials:"; N
44.     LOCATE 2, 1: PRINT "Crossings:"; C
45.     LOCATE 3, 1: PRINT "Pi est:"; 2 * N / C
46.     _DISPLAY
47.     IF N = 1 THEN
48.         _DELAY 2
49.     ELSEIF N < 5 THEN
50.         _DELAY 1
51.     ELSEIF N < 10 THEN
52.         _DELAY .5
53.     ELSEIF N < 50 THEN
54.         _DELAY .25
55.     ELSEIF N < 1000 THEN
56.         _DELAY .05
57.     ELSEIF N <= 10000 THEN
58.         IF N MOD 1000 = 0 THEN _DELAY .25
59.     ELSE
60.         IF N MOD 10000 = 0 THEN _DELAY .05
61.     END IF
62. LOOP UNTIL _KEYDOWN(27)
63.  
64.  
65.  

[_vince]

Yes, that is it. I've uncommented CLS to watch the needles pile up. Nice work, bplus

[bplus]

Thanks @_vince  this might be slightly more efficient for check needle crossing the line, skipping a FOR loop and maybe an extra IF THEN check:

Code: QB64: [Select]

1. _TITLE "Buffon Pi Calc " 'b+ 2020-08-2
2. '2020-08-02 try this with Buffon Pi Calc  pi ~ 2 * nTrials / nCross  from
3. ' pi ~ 2*L*N/(T*H) L=length of needle, T=spacing between lines N = Number of trials (or pins) H = number that cross line
4. _DEFINE A-Z AS _FLOAT
5. RANDOMIZE TIMER
6.  
7. CONST xmax = 800, ymax = 600
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _DELAY .25
10. _SCREENMOVE _MIDDLE
11. DIM N AS _INTEGER64, C AS _INTEGER64, SS AS _INTEGER64
12. L = 100 ' both pin length and line spacing
13. N = 0 '   number of trials
14. C = 0 '   number of pins that cross the line
15. 'SS = 0 '  pin head and point lay in Same Space
16.  
17. DO
18.     CLS
19.     'redraw lines
20.     FOR y = 0 TO _HEIGHT - 1 STEP L
21.         LINE (0, y)-(_WIDTH - 1, y), &HFFFFFFFF
22.     NEXT
23.  
24.     'drop a random pin
25.     px1 = RND * (_WIDTH - 200) + 100
26.     py1 = RND * (_HEIGHT - 200) + 100
27.     ra = RND * _PI(2)
28.     px2 = px1 + L * COS(ra)
29.     py2 = py1 + L * SIN(ra)
30.     LINE (px1, py1)-(px2, py2), _RGB32(50 + RND * 150)
31.     N = N + 1 '                             another trial pin
32.  
33.     'did our pin cross a line
34.     IF py1 < py2 THEN
35.         IF py2 >= 100 * INT(py1 / 100) + L THEN C = C + 1
36.     ELSE
37.         IF py1 >= 100 * INT(py2 / 100) + L THEN C = C + 1
38.     END IF
39.     'FOR y = 0 TO _HEIGHT - 1 STEP L
40.     '    IF py1 >= y AND py1 < y + L THEN ' one side of pin is between y and y + L
41.     '        IF py2 >= y AND py2 < y + L THEN ' the pin did NOT cross a line both the head and point lay in same space
42.     '            SS = SS + 1
43.     '            EXIT FOR ' speed up a little
44.     '        END IF
45.     '    END IF
46.     'NEXT
47.     'C = N - SS
48.     'Print results of trials
49.     LOCATE 1, 1: PRINT "Trials:"; N
50.     LOCATE 2, 1: PRINT "Crossings:"; C
51.     LOCATE 3, 1: PRINT "Pi est:"; 2 * N / C
52.     _DISPLAY
53.     IF N = 1 THEN
54.         _DELAY 2
55.     ELSEIF N < 5 THEN
56.         _DELAY 2
57.     ELSEIF N < 10 THEN
58.         _DELAY 2
59.     ELSEIF N < 50 THEN
60.         _DELAY .25
61.     ELSEIF N < 1000 THEN
62.         _DELAY .05
63.     ELSEIF N <= 10000 THEN
64.         IF N MOD 1000 = 0 THEN _DELAY .25
65.     ELSE
66.         IF N MOD 10000 = 0 THEN _DELAY .05
67.     END IF
68. LOOP UNTIL _KEYDOWN(27)
69.  
70.  
71.  

[bplus]

There might be a problem with the code or the Random Number Generator as I have a definite pattern of "random" needle color "waves" along the bottom and right borders of the screen.

Anyone have an idea of the error, blunder or glitch?

 

Both versions produce this pattern.

[_vince]

looks like the bounds of the needle coordinates are too far inside the screen

[bplus]

looks like the bounds of the needle coordinates are too far inside the screen

No I don't think it was that, here is the fix of the "pattern" and even speedier calc's seems 3.140 is limit of precision.

Code: QB64: [Select]

1. _TITLE "Buffon Pi Calc " 'b+ 2020-08-2
2. '2020-08-02 try this with Buffon Pi Calc  pi ~ 2 * nTrials / nCross  from
3. ' pi ~ 2*L*N/(T*H) L=length of needle, T=spacing between lines N = Number of trials (or pins) H = number that cross line
4. _DEFINE A-Z AS DOUBLE
5. RANDOMIZE TIMER
6.  
7. CONST xmax = 800, ymax = 600
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _DELAY .25
10. _SCREENMOVE _MIDDLE
11. DIM N AS _INTEGER64, C AS _INTEGER64, SS AS _INTEGER64
12.  
13. L = 100 ' both pin length and line spacing
14. N = 0 '   number of trials
15. C = 0 '   number of pins that cross the line
16. DO
17.     'CLS
18.     'redraw lines
19.     'drop a random pin
20.     px1 = RND * (_WIDTH - 201) + 100
21.     py1 = RND * (_HEIGHT - 201) + 100
22.     ra = RND * _PI(2)
23.     IF RND < .5 THEN dir = -1 ELSE dir = 1 ' << this fixed the pattern developing along right and bottom border of screen
24.     px2 = px1 + dir * L * COS(ra)
25.     py2 = py1 + dir * L * SIN(ra)
26.  
27.     N = N + 1 '                             another trial pin
28.  
29.     'did our pin cross a line
30.     IF py1 < py2 THEN
31.         IF py2 >= 100 * INT(py1 / 100) + L THEN C = C + 1
32.     ELSE
33.         IF py1 >= 100 * INT(py2 / 100) + L THEN C = C + 1
34.     END IF
35.     IF N < 100000 THEN 'display
36.         FOR y = 0 TO _HEIGHT - 1 STEP L
37.             LINE (0, y)-(_WIDTH - 1, y), &HFFFFFFFF
38.         NEXT
39.         LINE (px1, py1)-(px2, py2), _RGB32(50 + RND * 150)
40.  
41.         'Print results of trials
42.         LOCATE 1, 1: PRINT "Trials:"; N
43.         LOCATE 2, 1: PRINT "Crossings:"; C
44.         LOCATE 3, 1: PRINT "Pi est:"; 2 * N / C
45.         _DISPLAY
46.         IF N = 1 THEN
47.             _DELAY 2
48.         ELSEIF N < 5 THEN
49.             _DELAY 2
50.         ELSEIF N < 10 THEN
51.             _DELAY 2
52.         ELSEIF N < 50 THEN
53.             _DELAY .25
54.         ELSEIF N < 1000 THEN
55.             _DELAY .05
56.         ELSEIF N <= 10000 THEN
57.             IF N MOD 1000 = 0 THEN _DELAY .25
58.         ELSE
59.             IF N MOD 10000 = 0 THEN _DELAY .05
60.         END IF
61.     ELSE
62.         IF N MOD 1000000 = 0 THEN
63.             LOCATE 1, 1: PRINT "Trials:"; N
64.             LOCATE 2, 1: PRINT "Crossings:"; C
65.             LOCATE 3, 1: PRINT "Pi est:"; 2 * N / C
66.             _DISPLAY
67.         END IF
68.     END IF
69. LOOP UNTIL _KEYDOWN(27)
70.