OpenGL Context Capture Demo

[Ashish]

Hi everyone!
Now finally, it is possible to make OpenGL frame retain on screen.
The program code below does this -

Controls -  Press Space to capture OpenGL context and 'c' to clear software screen.

Code: QB64: [Select]

1. 'OpenGL context capture example
2. 'by Ashish Kushwaha
3.  
4. _TITLE "Hit *Space* to capture GL context and 'c' to clear software screen"
5. SCREEN _NEWIMAGE(600, 600, 32)
6.  
7. DIM SHARED glAllow AS _BYTE
8. DIM SHARED GL_Color_Buffer~%%(_WIDTH * _HEIGHT * 3)
9. DIM SHARED keyHit AS LONG
10.  
11. DIM SHARED GL_Context&, buffer_done
12. buffer_done = 0
13. 'CLS
14. _GLRENDER _BEHIND
15. glAllow = -1
16. DO
17.     keyHit = _KEYHIT
18.     IF keyHit = ASC("c") THEN CLS , 1
19.     IF buffer_done THEN
20.         _CLEARCOLOR _RGB(0, 0, 0), GL_Context&
21.         _PUTIMAGE , GL_Context&
22.         _FREEIMAGE GL_Context&
23.         buffer_done = 0
24.     END IF
25.     _DISPLAY
26.     _LIMIT 30
27. LOOP
28.  
29.  
30. SUB _GL ()
31.     STATIC fps AS LONG
32.     IF NOT glAllow THEN EXIT SUB
33.  
34.     '_glDisable _GL_MULTISAMPLE <<<< uncomment this line if you are using latest (06/18/2018) build of QB64.
35.  
36.     _glViewport 0, 0, _WIDTH, _HEIGHT
37.  
38.     _glClearColor 0, 0, 0, 1
39.     _glClear _GL_COLOR_BUFFER_BIT
40.  
41.     _glMatrixMode _GL_MODELVIEW
42.     _glLoadIdentity
43.  
44.     _glRotatef fps, 0, 0, 1
45.  
46.     _glBegin _GL_TRIANGLES
47.  
48.     _glColor3f 1, 0, 0
49.     _glVertex2f 0, 1
50.     _glColor3f 0, 1, 0
51.     _glVertex2f -1, -1
52.     _glColor3f 0, 0, 1
53.     _glVertex2f 1, -1
54.     _glEnd
55.  
56.     IF keyHit = ASC(" ") AND NOT buffer_done THEN GL_Context& = getOpenGLContextImage: buffer_done = 1
57.  
58.     _glFlush
59.  
60.     fps = fps + 1
61. END SUB
62.  
63. FUNCTION getOpenGLContextImage& ()
64.     'storing GL Color Buffer in our  GL_Color_Buffer() array
65.     _glReadBuffer _GL_BACK
66.     _glPixelStorei _GL_UNPACK_ALIGNMENT, 1
67.     _glReadPixels 0, 0, _WIDTH, _HEIGHT, _GL_RGB, _GL_UNSIGNED_BYTE, _OFFSET(GL_Color_Buffer~%%())
68.  
69.     $CHECKING:OFF
70.     getOpenGLContextImage& = _NEWIMAGE(_WIDTH, _HEIGHT, 32) 'create an image handle
71.     DIM m AS _MEM
72.     m = _MEMIMAGE(getOpenGLContextImage&) 'store it in memory
73.     i& = 0
74.     FOR y = _HEIGHT(getOpenGLContextImage&) - 1 TO 0 STEP -1
75.         FOR x = 0 TO _WIDTH(getOpenGLContextImage&) - 1
76.             index& = 4 * (x + y * _WIDTH(getOpenGLContextImage&))
77.             _MEMPUT m, m.OFFSET + index&, GL_Color_Buffer~%%(i& + 2) AS _UNSIGNED _BYTE 'blue
78.             _MEMPUT m, m.OFFSET + index& + 1, GL_Color_Buffer~%%(i& + 1) AS _UNSIGNED _BYTE 'green
79.             _MEMPUT m, m.OFFSET + index& + 2, GL_Color_Buffer~%%(i&) AS _UNSIGNED _BYTE 'red
80.             _MEMPUT m, m.OFFSET + index& + 3, 255 AS _UNSIGNED _BYTE 'alpha
81.             i& = i& + 3
82.     NEXT x, y
83.     _MEMFREE m
84.     $CHECKING:ON
85. END FUNCTION
86.  
87.  

[Petr]

Thanks for sharing. This is very useful, knowing how to do it.

[Ashish]

Thanks for sharing. This is very useful, knowing how to do it.

I'm glad that it is useful to you. :)

[Ashish]

Here's a fading effect achieved by software screen -

Code: QB64: [Select]

1. 'OpenGL context capture example
2. 'by Ashish Kushwaha
3.  
4. _TITLE "Rendering OpenGL to software screen"
5. SCREEN _NEWIMAGE(600, 600, 32)
6.  
7. DIM SHARED glAllow AS _BYTE
8. DIM SHARED GL_Color_Buffer~%%((_WIDTH * _HEIGHT * 4) - 1)
9. DIM SHARED keyHit AS LONG
10.  
11. DIM SHARED GL_Context&, buffer_done
12.  
13. buffer_done = 0
14. 'CLS
15. _GLRENDER _BEHIND
16. glAllow = -1
17. DO
18.     keyHit = _KEYHIT
19.  
20.     IF buffer_done THEN
21.         _CLEARCOLOR _RGB(0, 0, 0), GL_Context&
22.         _PUTIMAGE (0, _HEIGHT - 1)-(_WIDTH - 1, 0), GL_Context& 'flip again the image (opengl returns a vertically fliped image)
23.         _FREEIMAGE GL_Context&
24.         buffer_done = 0
25.     END IF
26.     LINE (0, 0)-(600, 600), _RGBA(0, 0, 0, 10), BF
27.     _DISPLAY
28.     _LIMIT 60
29. LOOP UNTIL INKEY$ <> ""
30.  
31.  
32. SUB _GL ()
33.     STATIC fps AS LONG, tt#
34.     IF NOT glAllow THEN EXIT SUB
35.     IF fps = 0 THEN tt# = TIMER
36.  
37.     _glViewport 0, 0, _WIDTH, _HEIGHT
38.  
39.     _glMatrixMode _GL_MODELVIEW
40.     _glLoadIdentity
41.  
42.     _glRotatef fps, 0, 0, 1
43.  
44.     _glBegin _GL_TRIANGLES
45.  
46.     _glColor3f 1, 0, 0
47.     _glVertex2f 0, 1
48.     _glColor3f 0, 1, 0
49.     _glVertex2f -1, -1
50.     _glColor3f 0, 0, 1
51.     _glVertex2f 1, -1
52.     _glEnd
53.  
54.  
55.     IF NOT buffer_done THEN GL_Context& = getOpenGLContextImage: buffer_done = 1
56.  
57.     _glFlush
58.  
59.     fps = fps + 1
60. END SUB
61.  
62. FUNCTION getOpenGLContextImage& ()
63.     'storing GL Color Buffer in our  GL_Color_Buffer() array
64.     _glReadBuffer _GL_BACK
65.     _glPixelStorei _GL_UNPACK_ALIGNMENT, 1
66.     _glReadPixels 0, 0, _WIDTH, _HEIGHT, _GL_BGRA_EXT, _GL_UNSIGNED_BYTE, _OFFSET(GL_Color_Buffer~%%())
67.  
68.     $CHECKING:OFF
69.  
70.     ' the below one will store vertically flip image
71.     getOpenGLContextImage& = _NEWIMAGE(_WIDTH, _HEIGHT, 32) 'create an image handle
72.     DIM m AS _MEM, m2 AS _MEM
73.  
74.     m = _MEMIMAGE(getOpenGLContextImage&) 'store it in memory
75.     m2 = _MEM(GL_Color_Buffer~%%())
76.  
77.     _MEMCOPY m2, m2.OFFSET, m2.SIZE TO m, m.OFFSET 'using _MEMCOPY instead of nested loop
78.     _MEMFREE m
79.     _MEMFREE m2
80.  
81.     $CHECKING:ON
82. END FUNCTION
83.  
84.  

[FellippeHeitor]

Old topic but somehow I missed this: great job, Ashish!