Raycasting

[TerryRitchie]

Sorry I've been scarce this past month. The wife was getting upset that the honey do list was not getting done. Had to limit my time on computer.

Any way, I've been trying to learn ray casting for another topic in my tutorial. I found a pretty good video on YouTube explaining the process. The narrator uses OpenGL and C. I converted it to QB64 as I watched the video. If you watch the video and look at the code below you'll be amazed at just how easy it is to do ray casting.

The code is sloppy. I threw it together as the narrator wrote his code. But it works. :-)

Code: QB64: [Select]

1. '  [youtube]https://www.youtube.com/watch?v=gYRrGTC7GtA[/youtube]
2.  
3.  
4.  
5. CONST DARKGRAY = _RGB32(76, 76, 76)
6. CONST WHITE = _RGB32(255, 255, 255)
7. CONST BLACK = _RGB32(0, 0, 0)
8. CONST YELLOW = _RGB32(255, 255, 0)
9. CONST GREEN = _RGB32(0, 255, 0)
10. CONST RED = _RGB32(255, 0, 0)
11. CONST DARKRED = _RGB32(128, 0, 0)
12. CONST PI = 3.1415926
13. CONST P2 = PI / 2
14. CONST P3 = 3 * PI / 2
15. CONST DR = .0174533
16.  
17. DIM SHARED px AS SINGLE '  player position
18. DIM SHARED py AS SINGLE
19. DIM SHARED pdx AS SINGLE ' delta X of player
20. DIM SHARED pdy AS SINGLE ' delta Y of player
21. DIM SHARED pa AS SINGLE '  angle of player
22. DIM SHARED mapX AS INTEGER
23. DIM SHARED mapY AS INTEGER
24. DIM SHARED mapS AS INTEGER
25. DIM SHARED map(64) AS INTEGER
26.  
27. mapX = 8
28. mapY = 8
29. mapS = 64
30. FOR i = 0 TO 63: READ map(i): NEXT i
31.  
32.  
33. Init
34. DO
35.     _LIMIT 60
36.     CLS , DARKGRAY
37.     drawMap2D
38.     drawRays2D
39.     DrawPlayer
40.     Buttons
41.  
42.  
43.     _DISPLAY
44. LOOP
45.  
46. DATA 1,1,1,1,1,1,1,1
47. DATA 1,0,1,0,0,0,0,1
48. DATA 1,0,1,0,0,0,0,1
49. DATA 1,0,1,0,0,0,0,1
50. DATA 1,0,0,0,0,0,0,1
51. DATA 1,0,0,0,0,1,0,1
52. DATA 1,0,0,0,0,0,0,1
53. DATA 1,1,1,1,1,1,1,1
54.  
55.  
56. FUNCTION dist (ax AS SINGLE, ay AS SINGLE, bx AS SINGLE, by AS SINGLE, ang AS SINGLE)
57.  
58.     dist = SQR((bx - ax) * (bx - ax) + (by - ay) * (by - ay))
59.  
60. END FUNCTION
61.  
62.  
63. SUB drawRays2D ()
64.  
65.     DIM r AS INTEGER
66.     DIM mx AS INTEGER
67.     DIM my AS INTEGER
68.     DIM mp AS INTEGER
69.     DIM dof AS INTEGER
70.     DIM rx AS SINGLE
71.     DIM ry AS SINGLE
72.     DIM ra AS SINGLE
73.     DIM xo AS SINGLE
74.     DIM yo AS SINGLE
75.     DIM aTan AS SINGLE
76.     DIM nTan AS SINGLE
77.     DIM disH AS SINGLE
78.     DIM hx AS SINGLE
79.     DIM hy AS SINGLE
80.     DIM disV AS SINGLE
81.     DIM vx AS SINGLE
82.     DIM vy AS SINGLE
83.     DIM disTT AS SINGLE
84.     DIM lineH AS SINGLE
85.     DIM lineO AS SINGLE
86.     DIM ca AS SINGLE
87.     DIM clr AS _UNSIGNED LONG
88.  
89.     ra = pa - DR * 30
90.     IF ra < 0 THEN ra = ra + 2 * PI
91.     IF ra > 2 * PI THEN ra = ra - 2 * PI
92.  
93.     FOR r = 0 TO 59
94.         '--- Check Horizontal Lines ---
95.         dof = 0
96.         disH = 1000000
97.         hx = px
98.         hy = py
99.         aTan = -1 / TAN(ra)
100.         IF ra > PI THEN
101.             'ry = ((INT(py) / 64) * 64) - .0001
102.  
103.             ry = INT(py / 64) * 64 - .0001
104.  
105.  
106.             rx = (py - ry) * aTan + px
107.             yo = -64
108.             xo = -yo * aTan
109.         END IF
110.         IF ra < PI THEN
111.             'ry = ((INT(py) / 64) * 64) + 64
112.  
113.             ry = INT(py / 64) * 64 + 64
114.  
115.  
116.             rx = (py - ry) * aTan + px
117.             yo = 64
118.             xo = -yo * aTan
119.         END IF
120.         IF (ra = 0) OR (ra = PI) THEN
121.             rx = px
122.             ry = py
123.             dof = 8
124.         END IF
125.         WHILE dof < 8
126.             'mx = INT(rx) / 64
127.             'my = INT(ry) / 64
128.  
129.             mx = INT(rx / 64)
130.             my = INT(ry / 64)
131.  
132.             mp = my * mapX + mx
133.  
134.             'LOCATE 1, 1: PRINT mp; pa;
135.             '_DISPLAY
136.  
137.             IF mp < 0 THEN mp = 0
138.             IF mp > 63 THEN mp = 63
139.  
140.             'IF (mp < mapX * mapY) AND map(mp) = 1 THEN ' -- hit wall
141.             IF map(mp) = 1 THEN
142.                 hx = rx
143.                 hy = ry
144.                 disH = dist(px, py, hx, hy, ra)
145.                 dof = 8
146.             ELSE '                                       -- next line
147.                 rx = rx + xo
148.                 ry = ry + yo
149.                 dof = dof + 1
150.             END IF
151.         WEND
152.  
153.  
154.         '--- Check Vertical Lines ---
155.         dof = 0
156.         disV = 1000000
157.         vx = px
158.         vy = py
159.  
160.         nTan = -TAN(ra)
161.         IF ra > P2 AND ra < P3 THEN
162.             'ry = ((INT(py) / 64) * 64) - .0001
163.  
164.             rx = INT(px / 64) * 64 - .0001
165.  
166.  
167.             ry = (px - rx) * nTan + py
168.             xo = -64
169.             yo = -xo * nTan
170.         END IF
171.         IF ra < P2 OR ra > P3 THEN
172.             'ry = ((INT(py) / 64) * 64) + 64
173.  
174.             rx = INT(px / 64) * 64 + 64
175.  
176.  
177.             ry = (px - rx) * nTan + py
178.             xo = 64
179.             yo = -xo * nTan
180.         END IF
181.         IF (ra = 0) OR (ra = PI) THEN
182.             rx = px
183.             ry = py
184.             dof = 8
185.         END IF
186.         WHILE dof < 8
187.             'mx = INT(rx) / 64
188.             'my = INT(ry) / 64
189.  
190.             mx = INT(rx / 64)
191.             my = INT(ry / 64)
192.  
193.             mp = my * mapX + mx
194.  
195.             'LOCATE 1, 1: PRINT mp; pa;
196.             '_DISPLAY
197.  
198.             IF mp < 0 THEN mp = 0
199.             IF mp > 63 THEN mp = 63
200.  
201.             'IF (mp < mapX * mapY) AND map(mp) = 1 THEN ' -- hit wall
202.             IF map(mp) = 1 THEN
203.                 vx = rx
204.                 vy = ry
205.                 disV = dist(px, py, vx, vy, ra)
206.                 dof = 8
207.             ELSE '                                       -- next line
208.                 rx = rx + xo
209.                 ry = ry + yo
210.                 dof = dof + 1
211.             END IF
212.         WEND
213.  
214.         IF disV < disH THEN ' -- Vertical wall hit
215.             rx = vx
216.             ry = vy
217.             disTT = disV
218.             clr = RED
219.         END IF
220.         IF disH < disV THEN ' -- Horizontal wall hit
221.             rx = hx
222.             ry = hy
223.             disTT = disH
224.             clr = DARKRED
225.         END IF
226.  
227.         LINE (px, py)-(rx, ry), RED
228.  
229.         '--- Draw 3D Walls ---
230.  
231.         ca = pa - ra
232.         IF ca < 0 THEN ca = ca + 2 * PI
233.         IF ca > 2 * PI THEN ca = ca - 2 * PI
234.         disTT = disTT * COS(ca) '          -- fix fish eye
235.  
236.         lineH = mapS * 320 / disTT
237.         IF lineH > 320 THEN lineH = 320 ' -- Line height
238.         lineO = 160 - lineH / 2 '         -- Line offset
239.         LINE (r * 8 + 530 - 4, lineO)-(r * 8 + 530 + 4, lineH + lineO), clr, BF
240.  
241.  
242.  
243.         ra = ra + DR
244.         IF ra < 0 THEN ra = ra + 2 * PI
245.         IF ra > 2 * PI THEN ra = ra - 2 * PI
246.  
247.  
248.  
249.     NEXT r
250.  
251.  
252.  
253. END SUB
254.  
255.  
256. SUB drawMap2D ()
257.  
258.     DIM x AS INTEGER
259.     DIM y AS INTEGER
260.     DIM xo AS INTEGER
261.     DIM yo AS INTEGER
262.     DIM clr AS _UNSIGNED LONG
263.  
264.     FOR y = 0 TO mapY - 1
265.         FOR x = 0 TO mapX - 1
266.             IF map(y * mapX + x) = 1 THEN clr = WHITE ELSE clr = BLACK
267.             xo = x * mapS
268.             yo = y * mapS
269.             LINE (xo + 1, yo + 1)-(xo + mapS - 1, yo + mapS - 1), clr, BF
270.         NEXT x
271.     NEXT y
272.  
273. END SUB
274.  
275.  
276. SUB Buttons ()
277.  
278.     IF _KEYDOWN(97) THEN
279.         pa = pa - .1
280.         IF pa < 0 THEN pa = pa + 2 * PI
281.     END IF
282.     IF _KEYDOWN(100) THEN
283.         pa = pa + .1
284.         IF pa > 2 * PI THEN pa = pa - 2 * PI
285.     END IF
286.     pdx = COS(pa) * 5
287.     pdy = SIN(pa) * 5
288.     IF _KEYDOWN(119) THEN px = px + pdx: py = py + pdy
289.     IF _KEYDOWN(115) THEN px = px - pdx: py = py - pdy
290.  
291. END SUB
292.  
293.  
294. SUB DrawPlayer ()
295.  
296.     LINE (px - 4, py - 4)-(px + 4, py + 4), YELLOW, BF
297.  
298.     LINE (px, py)-(px + pdx * 5, py + pdy * 5), YELLOW
299.  
300. END SUB
301.  
302.  
303.  
304. SUB Init ()
305.  
306.  
307.     SCREEN _NEWIMAGE(1024, 512, 32)
308.     CLS , DARKGRAY
309.     px = 300
310.     py = 300
311.     pdx = COS(pa) * 5
312.     pdy = SIN(pa) * 5
313.  
314. END SUB
315.  
316.  

[FellippeHeitor]

Wow!

[Petr]

Excellent!

[SierraKen]

I knew if I waited long enough someone would figure this out here! Thank you! Back in the mid 90's someone posted something just like this for QBasic on the newsgroup comp.lang.basic.misc and it was tons of code if I recall and they also used DATA for their map. It worked very slowly though back then. I wish I still had it but I think I lost it over time. I've wanted to learn this ever since and now that you made an example, I'm going to study like crazy. :)) It's a wish come true, thank you!

[TerryRitchie]

Yeah, I always viewed ray tracing as coding voodoo, probably because Wolfenstein 3D came out right around the time I was really getting into coding. I figured the math alone behind this was something to tackle. Turns out it's a very simple effect to achieve.

The narrator in the video does a good job of explaining each part of the code. I kept the variable names, functions, and subroutines named the same as well. I had to make a few changes here and there because of the funky way C handles IF statements but for the most part it's a one to one conversion.

[SierraKen]

I watched the video and it's a bit beyond me for now. He did say we can change the map so I made the map bigger with more walls, etc. Doing that we could even remove the 2D map and make it as large as you want I would think, just keep all of the 2D code so it knows where the walls are, but not the graphic. I also noticed that you can walk through the walls. I tried scanning through the code to see if there was a simple way to say something like hit = 1 when the wall is too close and you can't move anymore, but I can't really find it. Maybe you can add it sometime so people can't walk through them. But still an awesome job!

[FellippeHeitor]

Finally got around to watching the video too. The guy's really funny, which is a bonus.

[johnno56]

Cool video. I like the way he walks (no pun intended) you through the process. I have keyed in raycasters before but none of the listings really explained 'how' it all works. Knowledge of OpenGL, in this case, seems to be a per-requisite. Trigonometry was never by best subject, so I found the math, somewhat intimidating. The video was easy to follow - understanding completely will take some time - but the results are  there to see... Wow is right.

I hope he does do texture; collision; objects etc videos. Wolf3D. Watch out!

Thank you, Terry!!

[TempodiBasic]

Cool!
I find it more fun and clearer than this one of Biswit that I saw some year ago and I posted the first part (that written in Qbasic) in [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] for some issue about runtime errors.
https://www.youtube.com/watch?v=HQYsFshbkYw
LOL I find at the bottom of comments just 3 years ago a comment of an unknown TempodiBasic Programming

Thanks to share this resource !
Great translation into QB64!

[OldMoses]

[Ashish]

Amazing! :D