A Simple Graphics To Text Converter

[SierraKen]

This is an example where I spent all night making a program, thinking I have probably made something similar in the past, finishing it, then finding it on this forum from almost exactly a year ago (July 31) LOL. But that's OK, I just looked over that old code and wow, I have changed a lot in knowing how to reduce the length of programs and only making what I need. I'll post the URL to the old one after I post the code to this one.
This is a tiny little program that can convert any graphics to make using graphics commands, to a Notepad .txt file that you can see in Notepad as ASCII text. Like I did a year ago, I found a list online of the brightest text to the least brightest and made that into a string to use POINT with. Other people have probably made things like this that look better, but this is an improvement for me. Try it out, you can use it as a tool or a toy to copy/paste text to all kinds of stuff or print it out on the printer. Read my Comment Section at the start of the code to know more about it. It saves the text file as TextPicture.txt automatically. I made a bunch of boxes as an example.

Code: QB64: [Select]

1. 'This tiny program converts your screen graphic to a Notepad TextPicture.txt file automatically.
2. 'I use a tiny 200 x 200 graphic window but feel free to change it. You will also need to change the loops below.
3. 'Just remember, the larger the graphic, the bigger the text file. You can use the zoom feature on Notepad to zoom in and out to see it better.
4. 'I don't suggest using a camera photo with this because they don't come out good I believe. I tried it.
5. 'But feel free to do what you wish with this.
6. 'Notice that ch$ has characters that go from brightest to least brightest. I found this list on the Internet.
7. 'Also, since the vertical length is twice the length of the horizontal on Notepad, there may be parts of a graphic missing.
8.  
9. _TITLE "Graphic To Text Converter by SierraKen"
10.  
11. SCREEN _NEWIMAGE(200, 200, 32)
12. _LIMIT 100
13. CLS
14. '---------------------------------------------------
15. 'Draw anything you want here with graphic commands.
16. 'Here are some boxes.
17. RANDOMIZE TIMER
18. FOR t = 0 TO 100 STEP 10
19.     c1 = INT(RND * 254) + 1
20.     c2 = INT(RND * 254) + 1
21.     c3 = INT(RND * 254) + 1
22.     LINE (100 - t, 100 - t)-(100 + t, 100 + t), _RGB32(c1, c2, c3), B
23. NEXT t
24. '---------------------------------------------------
25.  
26. ch$ = "'$@B%8&WM#*oahkbdpqwmZO0QLCJUYXzcvunxrjft/\|()1{}[]?-_+~<>i!lI;:,^`'. "
27. OPEN "TextPicture.txt" FOR OUTPUT AS #1
28. FOR y = 0 TO 200 STEP 2
29.     FOR x = 0 TO 200
30.         c& = POINT(x, y)
31.         red& = _RED(c&)
32.         green& = _GREEN(c&)
33.         blue& = _BLUE(c&)
34.         colors& = red& + green& + blue&
35.         IF colors& < 10 THEN colors& = 10
36.         letter$ = MID$(ch$, INT(colors& / 10), 1)
37.         PRINT #1, letter$;
38.     NEXT x
39.     PRINT #1, ""
40. NEXT y
41. CLOSE #1
42. PRINT "TextPicture.txt saved."
43.  

And here is the old thread from July 31, 2019. If you look at the old code, you can see how much longer that is. The old one also lets you open a .bmp file to convert it to text. I tried using the new JPG, etc. Open/Save on this and it opens it fine, but the text output is pretty bad on camera pictures because of the detail I believe. Here is the old one:
https://www.qb64.org/forum/index.php?topic=1551.msg107688#msg107688

[johnno56]

I remember using a program similar to this one... Where I used to work, the powers that be, did not permit the transmission of images on our local network. You guessed it. The image was converted to text... A little rough looking back then but a nice work-a-round...

[SierraKen]

LOL awesome Johno. Or the old email signatures. lol

[OldMoses]

Nice work, and very compact.

[SierraKen]

Thanks OldMoses. Well, I decided that showing the graphics is more important than keeping the vertical correct, so I did a small change to it here.

Code: QB64: [Select]

1. 'This tiny program converts your screen graphic to a Notepad TextPicture.txt file automatically.
2. 'I use a tiny 200 x 200 graphic window but feel free to change it. You will also need to change the loops below.
3. 'Just remember, the larger the graphic, the bigger the text file. You can use the zoom feature on Notepad to zoom in and out to see it better.
4. 'I don't suggest using a camera photo with this because they don't come out good I believe. I tried it.
5. 'But feel free to do what you wish with this.
6. 'Notice that ch$ has characters that go from brightest to least brightest. I found this list on the Internet.
7.  
8. _TITLE "Graphic To Text Converter by SierraKen"
9.  
10. SCREEN _NEWIMAGE(200, 200, 32)
11. _LIMIT 100
12. CLS
13. '---------------------------------------------------
14. 'Draw anything you want here with graphic commands.
15. 'Here are some boxes.
16. RANDOMIZE TIMER
17. FOR t = 0 TO 100 STEP 10
18.     c1 = INT(RND * 255) + 1
19.     c2 = INT(RND * 255) + 1
20.     c3 = INT(RND * 255) + 1
21.     LINE (100 - t, 100 - t)-(100 + t, 100 + t), _RGB32(c1, c2, c3), B
22. NEXT t
23. '---------------------------------------------------
24.  
25. ch$ = "'$@B%8&WM#*oahkbdpqwmZO0QLCJUYXzcvunxrjft/\|()1{}[]?-_+~<>i!lI;:,^`'. "
26. OPEN "TextPicture.txt" FOR OUTPUT AS #1
27. FOR y = 0 TO 200
28.     FOR x = 0 TO 200
29.         c& = POINT(x, y)
30.         red& = _RED(c&)
31.         green& = _GREEN(c&)
32.         blue& = _BLUE(c&)
33.         colors& = red& + green& + blue&
34.         IF colors& < 11 THEN colors& = 11
35.         letter$ = MID$(ch$, INT(colors& / 11), 1)
36.         PRINT #1, letter$;
37.     NEXT x
38.     PRINT #1, ""
39. NEXT y
40. CLOSE #1
41. PRINT "TextPicture.txt saved."
42.  

[johnno56]

I have been trying to find the program that I used years ago... It wasn't mine... But, back then, the image used was black and white (greyscale) and the "alphabet" was arranged from "darkest" to "lightest" eg: "B" may be the darkest and space the lightest. I think the program would 'grab' the first 8x8 (or whatever size) of the image; average the dark to light ratio of the pixels; Compare the average to a corresponding character and add that character to the file.

But the whole thing hinged on the correct order of the "alphabet".

Before I forget, and that happens a lot, to help reduce the overall physical size (width and height) of the finished document, set the font size to as small as possible... just a thought... haven't tested that yet... lol

[SierraKen]

Thanks Johno, I haven't used fonts with it yet. 
Today I have dived into making it into a graphics making program that saves as a text file. I am SOOO dang close. But I am stuck and been stuck for hours. And it's always the same old SCREEN/PUTIMAGE/etc. stuff that I always get stuck on. What's happening is, when someone tries to change the color after drawing first, it won't load the color wheel again. It loads fine the first time when you are setting up to draw, but not any time after that. I've tried everything I know how to do. Can someone help me? The problem is under the "paintcolor:" section at the bottom. It goes to that section and displays the _TITLE words but then your painting screen doesn't change to the color wheel. I'll zip up the .bas and the color wheel picture and put it in the attachments if anybody wants to help. Thanks.

[johnno56]

There seems to be a slight problem with your 'alphabet'.

The first character of the ch$ string should not be there. It is "too light" to be on the "dark end" of the string.

Try this one: ch$ = "$@B%8&WM#*oahkbdpqwmZO0QLCJUYXzcvunxrjft/\|()1{}[]?-_+~<>i!lI;:," + CHR$(34) + "^`'. "

See attached for result.

[SierraKen]

Johno, that's the black background. The black text gets in the way of the eyes when trying to make out the graphic. That is why I reversed it, black as the smallest symbol, so it won't get in the way of what you drew.

[johnno56]

Understood.

But, before I changed ch$ back to your original, I figured I might try it on an image of 100x120... Guess who?

[SierraKen]

ROFL AWESOME!! LOL

[johnno56]

I modified the img2txt program. At the moment, I was just trying to sort out a more unified "shading".

As you will notice, the image is much "clearer" and is only using one ascii character, "@". As a result, outputting to text file is completely useless. The "printed" image does not display the "shades" of the "@", only the "@" characters... W.I.P.

This example is based on a greyscale image. I will work on a colour version... after a coffee of course... lol

One thing I did notice that was strange... Scanning with point(), on the grey-scaled image, then using "color yahda", produces an almost sepia colour. Not a deal breaker. Just an observation. If I can get a colour image to happen then this won't be a problem.

[bplus]

Today I have dived into making it into a graphics making program that saves as a text file. I am SOOO dang close. But I am stuck and been stuck for hours. And it's always the same old SCREEN/PUTIMAGE/etc. stuff that I always get stuck on. What's happening is, when someone tries to change the color after drawing first, it won't load the color wheel again. It loads fine the first time when you are setting up to draw, but not any time after that. I've tried everything I know how to do. Can someone help me? The problem is under the "paintcolor:" section at the bottom. It goes to that section and displays the _TITLE words but then your painting screen doesn't change to the color wheel. I'll zip up the .bas and the color wheel picture and put it in the attachments if anybody wants to help. Thanks.

OH !@#~&^%$ It got me too!

This is a groaner:

Code: QB64: [Select]

1. paintcolor:
2. _LIMIT 100
3. a$ = ""
4. CLS
5. SCREEN _NEWIMAGE(800, 600, 32)
6. _TITLE "Click a paint color."
7. i& = _NEWIMAGE(800, 600, 32)
8. _DEST i&
9. i& = _LOADIMAGE("PaintColor.png", 32)
10. SCREEN i&
11. DO
12.     _LIMIT 100
13.     DO WHILE _MOUSEINPUT
14.         mousex = _MOUSEX
15.         mousey = _MOUSEY
16.         mouseLeftButton = _MOUSEBUTTON(1)
17.     LOOP
18.     IF mouseLeftButton THEN
19.         clr& = POINT(mousex, mousey)
20.         mouseLeftButton = 0
21.         CLS
22.         IF s& THEN _PUTIMAGE , s&: SCREEN s&
23.         RETURN
24.     END IF
25.     _DISPLAY '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<  here is the fix
26. LOOP
27.  

Once you use _DISPLAY, you always have to use it or turn off with _AUTODISPLAY

[SierraKen]

WOW Johno!!! That's incredible!!! It reminds me of when Nimoy passed away and I sent my picture with my blue shirt on doing the Vulcan Salute to a company that took 1000's of those pictures and made it into a giant picture of Spock. I would use shades and colors like that but mine is specifically to make .txt files that don't have that. Please edit your post with the code though and add your name to mine in the _TITLE, thanks. Great job!

B+, I don't know what I would do without you sometimes lol. I most likely would have given up on this program if you hadn't fixed it for me. THANK YOU!

Here is the program. You set a picture from 25 to 300 pixels horizontal and vertical and then you can draw what you want on it. The Instructions are on the welcome page. It doesn't have everything that Paint Pixels has, in fact I tried adding this to Paint Pixels and ran into memory problems so I'm sticking with this instead. But you can choose colors and draw and erase. The background is always black because it's easier to see in the text file. Added below is the updated zip file and also a screen shot of the text file I quickly drew with it. I like how you can zoom out in Notepad to see larger text pictures better. Check it out. :)

[SierraKen]

Johnno, here is a little update I made on your version. It randomly chooses an ASCII character from all the characters that can be displayed. Then it automatically changes to a different one in 1/4 of a second. It keeps going until you press a key on your keyboard. Some ASCII characters are very close to a whole brick of color. If you want, you can add a number in the corner showing you which chr$ (ASCII) number that it's showing. It's just the variable ch.

Code: QB64: [Select]

1. _TITLE "Graphic To Text Converter by SierraKen and Johnno"
2.  
3. SCREEN _NEWIMAGE(800, 1000, 32)
4. _LIMIT 100
5. CLS
6. '---------------------------------------------------
7. 'Draw anything you want here with graphic commands.
8. 'Here are some boxes.
9.  
10. spock& = _LOADIMAGE("spock100x120.png")
11. _PUTIMAGE (0, 0), spock&
12. _DELAY 1 '   short delay to view image source
13. '---------------------------------------------------
14. DIM pixel(100, 120)
15.  
16. '   Selected a small font to remove vertical "stretching"
17. _FONT 8
18.  
19. '   Separate loops for 'reading' and 'writing' - could be combined?
20.  
21. FOR y = 0 TO 119
22.     FOR x = 0 TO 99
23.         pixel(x, y) = POINT(x, y)
24.     NEXT x
25. NEXT y
26.  
27. '   Although the source image is "grey", "point()" does not think so...
28. _DELAY 1
29. RANDOMIZE TIMER
30. DO
31.     cc = INT(RND * 2) + 1
32.     IF cc = 1 THEN ch = INT(RND * 93) + 33
33.     IF cc = 2 THEN ch = INT(RND * 126) + 128
34.     FOR y = 0 TO 119
35.         FOR x = 0 TO 99
36.             COLOR pixel(x, y)
37.             letter$ = CHR$(ch)
38.             PRINT letter$;
39.         NEXT
40.         PRINT ""
41.     NEXT
42.     _DELAY .25
43.     _DISPLAY
44. LOOP UNTIL INKEY$ <> ""
45. END
46.