Development of a program for automatic search for music and movies

[Petr]

Definitely yes, but this simple foundation would have to work first ...

[bplus]

@Petr

:) so again I ask, "Are you going for Cross Platform or Windows only."

 Windows only will have kick butt utilities for TREE that you might research but Cross Platform might be nice programming challenge. ;-))

The deciding factor, I think, is if you intend to use Windows only apps for playing these files we are digging around for?

[SpriggsySpriggs]

I know this is probably not an answer that anyone wants to hear but PowerShell is excellent for many things. I've been able to make WPF Message Boxes and Open/Save file dialogs in it with great ease. You might consider writing a PowerShell script that you can call from inside your program and check for exit codes. I love using PowerShell.

[bplus]

Yeah, I am thinking Shell or Powershell, why reinvent the wheel, if Windows only.

[SpriggsySpriggs]

Yeah, I am thinking Shell or Powershell, why reinvent the wheel, if Windows only.

Well there is even a cross-platform PowerShell now :)

[Petr]

BPlus, let's do this for windows first. When it's done, I can study on the Internet which Linux commands can be useful for the same purpose and then add functionality for Linux. But still - why it works not? I have big head from it...

[bplus]

BPlus, let's do this for windows first. When it's done, I can study on the Internet which Linux commands can be useful for the same purpose and then add functionality for Linux. But still - why it works not? I have big head from it...

;-)) "Big heads" love company.

I will look again when I finish errands.

Well there is even a cross-platform PowerShell now :)

Well then another one to learn. :)

[SpriggsySpriggs]

This displays a recursive list of every subdirectory from a given path. Just read in the file results into your program and enjoy!

Code: QB64: [Select]

1. SHELL _HIDE "PowerShell Get-ChildItem -Path \" + CHR$(34) + Path$ + "\" + CHR$(34) + " -Recurse -Directory -Force -ErrorAction SilentlyContinue | Select-Object -ExpandProperty FullName | Format-Table -AutoSize > directorylist.txt"

[SpriggsySpriggs]

BPlus, let's do this for windows first. When it's done, I can study on the Internet which Linux commands can be useful for the same purpose and then add functionality for Linux.

For Linux, according to the internet:

Code: QB64: [Select]

1. SHELL "find " + CHR$(34) + Path$ + CHR$(34) + " -path */* > directory.txt"

[bplus]

Hi @Petr

Couldn't figure out what you were doing when adding dirs from s to G so I did it my own way and now not a bunch of empty fills.

This looks better to me but not sure it ends correctly:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
3.     FUNCTION load_dir& (s AS STRING)
4.     FUNCTION has_next_entry& ()
5.     SUB close_dir ()
6.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
7. END DECLARE
8.  
9.  
10. SCREEN _NEWIMAGE(1280, 740, 32) '<<<<<<<<<<<<<  let's get bigger screen!
11. _DELAY .25
12. _SCREENMOVE _MIDDLE
13.  
14.  
15. REDIM D(0) AS STRING
16.  
17.  
18. TYPE GlobalDir
19.     Level AS INTEGER
20.     Path AS STRING
21. END TYPE
22.  
23. REDIM SHARED G(0) AS GlobalDir
24. REDIM Begin(0) AS STRING
25.  
26. GetDIRList _CWD$, Begin()
27. SA Begin()
28. AddDirsToGlobal Begin(), 1
29. ShowGlobal
30. DIM s
31. FOR s = 0 TO UBOUND(begin)
32.     'PRINT Begin(S)
33.     SLEEP
34.     CHDIR Begin(s)
35.     PRINT "Current path: "; _CWD$
36.     REDIM D(0) AS STRING
37.     GetDIRList _CWD$, D()
38.     SA D()
39.     AddDirsToGlobal D(), 2 '                 comment this
40.     CLS
41.  
42.     ShowGlobal ' <<<<<<<<<<<<<<<<<<< lets look at Global at each loop iteration
43.  
44.  
45.     CHDIR ".."
46.     PRINT "Current path: "; _CWD$
47.     PRINT "Global size:"; UBOUND(g) + 1
48. NEXT
49.  
50. ShowGlobal
51.  
52.  
53.  
54.  
55. SUB SA (a() AS STRING)
56.     DIM s
57.     FOR s = LBOUND(a) TO UBOUND(a)
58.         PRINT "Array List:"; a(s); " array size:"; UBOUND(a) + 1
59.         SLEEP
60.     NEXT
61. END SUB
62.  
63.  
64.  
65.  
66.  
67.  
68. SUB ShowGlobal
69.     PRINT "Start of next Golbal: keep pressing  any again until see End of global and then press 1 more time"
70.     DIM s
71.     FOR s = 0 TO UBOUND(g)
72.         PRINT G(s).Path, " Level: "; G(s).Level
73.         SLEEP
74.     NEXT
75.     PRINT "End of Global, press spacebar again..."
76.     SLEEP
77.  
78. END SUB
79.  
80.  
81.  
82. SUB AddDirsToGlobal (s() AS STRING, level AS INTEGER)
83.     IF UBOUND(s) = 0 THEN EXIT SUB
84.     PRINT "To global array added: "; UBOUND(g); "+"; UBOUND(s) + 1
85.     DIM a
86.     FOR a = LBOUND(s) TO UBOUND(s)
87.         sAppend G(), s(a), level
88.     NEXT
89. END SUB
90.  
91. SUB sAppend (arr() AS GlobalDir, addItem$, addlevel)
92.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS GlobalDir
93.     arr(UBOUND(arr)).Path = addItem$
94.     arr(UBOUND(arr)).Level = addlevel
95. END SUB
96.  
97.  
98.  
99. 'my modification just for directory names:
100. SUB GetDIRList (SearchDirectory AS STRING, DirList() AS STRING) 'opravena verze
101.     REDIM DirList(0) AS STRING
102.     CONST IS_DIR = 1
103.     DIM flags AS LONG, file_size AS LONG, DirCount, length, nam$, placeIt
104.     DirCount = 0
105.     IF load_dir(SearchDirectory) THEN
106.         DO
107.             length = has_next_entry
108.             IF length > -1 THEN
109.                 nam$ = SPACE$(length)
110.                 get_next_entry nam$, flags, file_size
111.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
112.                     IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
113.                     DirList(DirCount) = _CWD$ + "\" + nam$
114.                     DirCount = DirCount + 1
115.                 END IF
116.             END IF
117.         LOOP UNTIL length = -1
118.  
119.  
120.         IF RIGHT$(DirList(0), 1) = "." AND RIGHT$(DirList(1), 2) = ".." THEN
121.             DirCount = DirCount - 3
122.             REDIM Dirl(DirCount) AS STRING
123.             FOR placeIt = 0 TO DirCount
124.                 Dirl(placeIt) = DirList(placeIt + 2)
125.             NEXT
126.             REDIM DirList(DirCount) AS STRING
127.             FOR placeIt = 0 TO DirCount
128.                 DirList(placeIt) = Dirl(placeIt)
129.             NEXT
130.             REDIM Dirl(0)
131.         ELSE
132.             REDIM _PRESERVE DirList(DirCount - 1)
133.         END IF
134.     ELSE
135.     END IF
136.     close_dir
137. END SUB
138.  
139.  
140.  
141.  

[SpriggsySpriggs]

A slight change to my original SHELL suggestion:

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3. Path$ = "C:\Users\Zachary\Desktop\QB64 x64"
4. SHELL _HIDE "PowerShell Get-ChildItem -Path \" + CHR$(34) + Path$ + "\" + CHR$(34) + " -Recurse -Directory -Force -ErrorAction SilentlyContinue | Select-Object -ExpandProperty FullName | Format-Table -AutoSize | Out-File -FilePath directorylist.txt -Encoding ASCII"
5. DIRECTORIES = FREEFILE
6. n = 0
7. DIM Dirs(n) AS STRING
8. OPEN "directorylist.txt" FOR BINARY AS #DIRECTORIES
9. DO
10.     LINE INPUT #DIRECTORIES, Directory$
11.     Directory$ = LTRIM$(RTRIM$(String.Remove(Directory$, CHR$(13))))
12.     n = n + 1
13.     REDIM _PRESERVE Dirs(n)
14.     Dirs(n) = Directory$
15. LOOP UNTIL EOF(DIRECTORIES)
16. FOR i = 1 TO UBOUND(Dirs)
17.     PRINT Dirs(i)
18.     IF _DIREXISTS(Dirs(i)) THEN
19.         PRINT "LOCATED"
20.         IF LEFT$(Dirs(i), _INSTRREV(Dirs(i), "\") - 1) <> Path$ THEN 'i <> 1 OR
21.             FOR k = 1 TO UBOUND(Dirs)
22.                 IF LEFT$(Dirs(i), _INSTRREV(Dirs(i), "\") - 1) = Dirs(k) THEN
23.                     PRINT "Subdirectory of "; Dirs(k)
24.                 END IF
25.             NEXT
26.         ELSE
27.             PRINT "Subdirectory of "; Path$
28.         END IF
29.     END IF
30. NEXT
31.  
32. FUNCTION String.Remove$ (a AS STRING, b AS STRING)
33.     DIM c AS STRING
34.     c = ""
35.     j = INSTR(a, b)
36.     IF j > 0 THEN
37.         r$ = LEFT$(a, j - 1) + c + String.Remove(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b)
38.     ELSE
39.         r$ = a
40.     END IF
41.     String.Remove = r$
42. END FUNCTION

If you don't add the -Encoding ASCII then qb64 cannot locate the directories because of hidden characters.
Here is a screenshot showing the program running and using _DIREXISTS to make sure it can find the directories retrieved from PowerShell.
 

[bplus]

@Petr

This is a cleaner version of reply #24,
https://www.qb64.org/forum/index.php?topic=2742.msg119796#msg119796
upper bounds of arrays reflect actual item counts.

I am setting this up for a recursive TREE build.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
3.     FUNCTION load_dir& (s AS STRING)
4.     FUNCTION has_next_entry& ()
5.     SUB close_dir ()
6.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
7. END DECLARE
8.  
9. REDIM SHARED G(0) AS STRING '<<<<<<<<<<<<<<<<<<<<<< G(0) will remain empty
10.  
11. SCREEN _NEWIMAGE(1280, 740, 32) '<<<<<<<<<<<<<  let's get bigger screen!
12. _DELAY .25
13. _SCREENMOVE 80, 0
14.  
15. REDIM Begin(0) AS STRING, D(0) AS STRING, w$, s
16.  
17. GetSubDirs _CWD$, Begin()
18. SA Begin()
19. AddDirsToGlobal Begin()
20. ShowGlobal
21. FOR s = 1 TO UBOUND(begin)
22.     PRINT "About to change dir to: "; Begin(s)
23.     INPUT "Enter to continue... "; w$
24.     CHDIR Begin(s)
25.     PRINT "Current path: "; _CWD$
26.     GetSubDirs _CWD$, D()
27.     SA D()
28.     AddDirsToGlobal D()
29.     ShowGlobal
30. NEXT
31. PRINT "Last Global List: press any... "
32. SLEEP
33. ShowGlobal
34.  
35. SUB SA (a() AS STRING)
36.     DIM s
37.     PRINT "Start of SubDirs List: press any until End SubDirs."
38.     SLEEP
39.     FOR s = 1 TO UBOUND(a)
40.         PRINT "Array List:"; a(s); " array size:"; UBOUND(a)
41.         SLEEP
42.     NEXT
43.     PRINT "End of SubDirs List: press any..."
44.     SLEEP
45. END SUB
46.  
47. SUB ShowGlobal
48.     PRINT "Start of next Golbal: keep pressing  any again until see End of global and then press 1 more time"
49.     DIM s
50.     FOR s = 1 TO UBOUND(g)
51.         PRINT G(s)
52.         SLEEP
53.     NEXT
54.     PRINT "Global size:"; UBOUND(g)
55.     PRINT "End of Global List, size now:"; UBOUND(g); "   press any..."
56.     SLEEP
57. END SUB
58.  
59. SUB AddDirsToGlobal (s() AS STRING)
60.     IF UBOUND(s) = 0 THEN EXIT SUB
61.     DIM a
62.     FOR a = 1 TO UBOUND(s)
63.         sAppend G(), s(a)
64.     NEXT
65.     PRINT "Ubound of Global Array after addition: "; UBOUND(g); "  press any..."
66.     SLEEP
67. END SUB
68.  
69. SUB sAppend (arr() AS STRING, addItem$)
70.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
71.     arr(UBOUND(arr)) = addItem$
72. END SUB
73.  
74. SUB GetSubDirs (SearchDirectory AS STRING, DirList() AS STRING)
75.     REDIM DirList(0) AS STRING
76.     CONST IS_DIR = 1
77.     DIM flags AS LONG, file_size AS LONG, DirCount, length, nam$
78.     REDIM _PRESERVE DirList(100)
79.     IF load_dir(SearchDirectory) THEN
80.         DO
81.             length = has_next_entry
82.             IF length > -1 THEN
83.                 nam$ = SPACE$(length)
84.                 get_next_entry nam$, flags, file_size
85.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
86.                     IF RIGHT$(nam$, 1) <> "." AND RIGHT$(nam$, 2) <> ".." THEN
87.                         DirCount = DirCount + 1
88.                         IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
89.                         DirList(DirCount) = _CWD$ + "\" + nam$
90.                     END IF
91.                 END IF
92.             END IF
93.         LOOP UNTIL length = -1
94.     END IF
95.     close_dir
96.     REDIM _PRESERVE DirList(DirCount)
97. END SUB
98.  

[bplus]

Well it almost works:

Code: QB64: [Select]

1. OPTION _EXPLICIT 'Tree builder recursive.bas  b+ Petr 2020-06-26
2. DEFLNG A-Z
3. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
4.     FUNCTION load_dir& (s AS STRING)
5.     FUNCTION has_next_entry& ()
6.     SUB close_dir ()
7.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
8. END DECLARE
9.  
10. REDIM SHARED Tree(0) AS STRING '<<<<<<<<<<<<<<<<<<<<<< G(0) will remain empty
11.  
12. SCREEN _NEWIMAGE(1280, 740, 32) '<<<<<<<<<<<<<  let's get bigger screen!
13. _DELAY .25
14. _SCREENMOVE 80, 0
15. DIM cd$, i, w$
16.  
17. cd$ = _CWD$   'testing in QB64 folder
18. MakeTree cd$
19. FOR i = 1 TO UBOUND(Tree) 'show tree
20.     PRINT _TRIM$(STR$(i)); ": "; Tree(i)
21.     IF i MOD 40 = 0 THEN INPUT "Press enter to continue... "; w$: CLS
22. NEXT
23.  
24. SUB sAppend (arr() AS STRING, addItem$)
25.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
26.     arr(UBOUND(arr)) = addItem$
27. END SUB
28.  
29. SUB GetSubDirs (SearchDirectory AS STRING, DirList() AS STRING)
30.     REDIM DirList(0) AS STRING
31.     CONST IS_DIR = 1
32.     DIM flags AS LONG, file_size AS LONG, DirCount, length, nam$
33.     REDIM _PRESERVE DirList(100)
34.     IF load_dir(SearchDirectory) THEN
35.         DO
36.             length = has_next_entry
37.             IF length > -1 THEN
38.                 nam$ = SPACE$(length)
39.                 get_next_entry nam$, flags, file_size
40.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
41.                     IF RIGHT$(nam$, 1) <> "." AND RIGHT$(nam$, 2) <> ".." THEN
42.                         DirCount = DirCount + 1
43.                         IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
44.                         DirList(DirCount) = _CWD$ + "\" + nam$
45.                     END IF
46.                 END IF
47.             END IF
48.         LOOP UNTIL length = -1
49.     END IF
50.     close_dir
51.     REDIM _PRESERVE DirList(DirCount)
52. END SUB
53.  
54. SUB MakeTree (startDir AS STRING)
55.     DIM i
56.     REDIM D(0) AS STRING
57.     GetSubDirs startDir, D()
58.     IF UBOUND(D) THEN
59.         FOR i = 1 TO UBOUND(D)
60.             sAppend Tree(), D(i)
61.             CHDIR D(i)
62.             MakeTree D(i)
63.         NEXT
64.     END IF
65. END SUB
66.  
67.  

I start in QB64 folder, looks like it gets pretty deep into some directories but not \programs with one sub folder and then more in it. I am only getting 125 directories.

[SMcNeill]

Try this version:

Code: QB64: [Select]

1. OPTION _EXPLICIT 'Tree builder recursive.bas  b+ Petr 2020-06-26
2. DEFLNG A-Z
3. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
4.     FUNCTION load_dir& (s AS STRING)
5.     FUNCTION has_next_entry& ()
6.     SUB close_dir ()
7.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
8. END DECLARE
9.  
10. REDIM SHARED Tree(0) AS STRING '<<<<<<<<<<<<<<<<<<<<<< G(0) will remain empty
11.  
12. SCREEN _NEWIMAGE(1280, 740, 32) '<<<<<<<<<<<<<  let's get bigger screen!
13. _DELAY .25
14. _SCREENMOVE 80, 0
15. DIM cd$, i, w$
16.  
17. cd$ = _CWD$ 'testing in QB64 folder
18. MakeTree cd$
19. FOR i = 1 TO UBOUND(Tree) 'show tree
20.     PRINT _TRIM$(STR$(i)); ": "; Tree(i)
21.     IF i MOD 40 = 0 THEN INPUT "Press enter to continue... "; w$: CLS
22. NEXT
23.  
24. SUB sAppend (arr() AS STRING, addItem$)
25.     REDIM _PRESERVE arr(LBOUND(arr) TO UBOUND(arr) + 1) AS STRING
26.     arr(UBOUND(arr)) = addItem$
27. END SUB
28.  
29. SUB GetSubDirs (SearchDirectory AS STRING, DirList() AS STRING)
30.     REDIM DirList(0) AS STRING
31.     CONST IS_DIR = 1
32.     DIM flags AS LONG, file_size AS LONG, DirCount, length, nam$
33.     REDIM _PRESERVE DirList(100)
34.     IF load_dir(SearchDirectory) THEN
35.         DO
36.             length = has_next_entry
37.             IF length > -1 THEN
38.                 nam$ = SPACE$(length)
39.                 get_next_entry nam$, flags, file_size
40.                 IF (flags AND IS_DIR) OR _DIREXISTS(SearchDirectory + nam$) THEN
41.                     IF RIGHT$(nam$, 1) <> "." AND RIGHT$(nam$, 2) <> ".." THEN
42.                         DirCount = DirCount + 1
43.                         IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
44.                         DirList(DirCount) = SearchDirectory + "\" + nam$
45.                     END IF
46.                 END IF
47.             END IF
48.         LOOP UNTIL length = -1
49.     END IF
50.     close_dir
51.     REDIM _PRESERVE DirList(DirCount)
52. END SUB
53.  
54. SUB MakeTree (startDir AS STRING)
55.     DIM i
56.     REDIM D(0) AS STRING
57.     GetSubDirs startDir, D()
58.     IF UBOUND(D) THEN
59.         FOR i = 1 TO UBOUND(D)
60.             sAppend Tree(), D(i)
61.             CHDIR D(i)
62.             MakeTree D(i)
63.         NEXT
64.     END IF
65. END SUB
66.  
67.  
68.  

Edit:  Something still seems off here.  I'm thinking it's because you're not building the directories with the "\" as the last character.

Print the results as you go, and you'll see things such as :  C:\QB64\internal.. -- this should instead be C:\QB64\internal\..   Save the directories with that \ on the end of them, and it seems to work much better.

I'd dig deeper into this, but my stupid mouse has died on me, and it's a total PITA to try and work without one.  I'll make a trip to the store later today for a set of batteries (wherever my wife has them hidden in the house is beyond my ability to snoop and find), and once I get it back up and going, I'll delve into this once again.  ;)

[bplus]

Hi @SMcNeill

I see one line changed mine:
DirList(DirCount) = _CWD$ + "\" + nam$

Yours:
DirList(DirCount) = SearchDirectory + "\" + nam$

Am I missing any others?

Same exact results. 125 Sub-Directories.

I'd dig deeper into this,

It is cool problem ;-))