Particles - just for fun

[FellippeHeitor]

Click to create an electromagnetic repeller field.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2. _DELAY .1
3. _TITLE "Particles"
4.  
5. TYPE PARTICLE
6.     x AS SINGLE
7.     xs AS SINGLE
8.     y AS SINGLE
9.     ys AS SINGLE
10.     w AS SINGLE
11.     h AS SINGLE
12.     a AS SINGLE
13.     r AS SINGLE
14.     c AS _UNSIGNED LONG
15. END TYPE
16.  
17. DIM particle(100) AS PARTICLE
18. DIM SHARED r AS SINGLE
19.  
20. RANDOMIZE TIMER
21. createParticles particle()
22.  
23. DO
24.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 50), BF
25.     updateAndShowParticles particle()
26.     IF _MOUSEBUTTON(1) THEN
27.         IF r < 150 THEN r = r + 1 ELSE r = 0
28.         CIRCLE (_MOUSEX, _MOUSEY), r, _RGBA32(255, 255, 0, 150 - r)
29.     END IF
30.     _DISPLAY
31.     _LIMIT 30
32. LOOP
33.  
34. SUB createParticles (this() AS PARTICLE)
35.     FOR i = 0 TO UBOUND(this)
36.         this(i).x = RND * _WIDTH
37.         this(i).xs = 2 + RND * 3
38.         this(i).y = RND * _HEIGHT
39.         this(i).ys = 2 + RND * 3
40.         this(i).w = RND * (_WIDTH / 4)
41.         this(i).h = RND * (_WIDTH / 6)
42.         this(i).a = RND * _PI(2)
43.         this(i).r = RND * 3 + 1
44.         this(i).c = _RGBA32(RND * 255, RND * 255, RND * 255, RND * 150 + 155)
45.     NEXT
46. END SUB
47.  
48. SUB updateAndShowParticles (this() AS PARTICLE)
49.     WHILE _MOUSEINPUT: WEND
50.     FOR i = 0 TO UBOUND(this)
51.         this(i).a = this(i).a + .1
52.         IF this(i).a > _PI(2) THEN this(i).a = this(i).a - _PI(2)
53.  
54.         IF _MOUSEBUTTON(1) THEN
55.             IF this(i).y > _MOUSEY THEN this(i).y = this(i).y + r / 15
56.             IF this(i).y < _MOUSEY THEN this(i).y = this(i).y - r / 15
57.             IF this(i).x > _MOUSEX THEN this(i).x = this(i).x + r / 15
58.             IF this(i).x < _MOUSEX THEN this(i).x = this(i).x - r / 15
59.         ELSE
60.             r = 0
61.             IF this(i).y > _MOUSEY THEN this(i).y = this(i).y - this(i).ys
62.             IF this(i).y < _MOUSEY THEN this(i).y = this(i).y + this(i).ys
63.             IF this(i).x > _MOUSEX THEN this(i).x = this(i).x - this(i).xs
64.             IF this(i).x < _MOUSEX THEN this(i).x = this(i).x + this(i).xs
65.         END IF
66.  
67.         CircleFill this(i).x + COS(this(i).a) * this(i).w, this(i).y + SIN(this(i).a) * this(i).h, this(i).r, this(i).c
68.     NEXT
69. END SUB
70.  
71. SUB CircleFill (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
72.     x0 = R
73.     y0 = 0
74.     e = 0
75.     DO WHILE y0 < x0
76.         IF e <= 0 THEN
77.             y0 = y0 + 1
78.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
79.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
80.             e = e + 2 * y0
81.         ELSE
82.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
83.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
84.             x0 = x0 - 1
85.             e = e - 2 * x0
86.         END IF
87.     LOOP
88.     LINE (x - R, y)-(x + R, y), C, BF
89. END SUB
90.  

[bplus]

That's cool how they form orbits around mouse position. :)

[johnno56]

Cool... Reminds me of blowflies following a dunny (sewage) truck... Not the programming... The movement of the particles... Stone the flammin' crows! Dodged a bullet there...

J

[FellippeHeitor]

Well, I gotta admit: my first naming choice for my variables was DIM fly(100) AS FLY, but then I decided to go with the more generic 'particle()', but I'm guilty as charged. They have been flies all along.

[Ashish]

Nice effect!

[FellippeHeitor]

Flies all over.

[bplus]

Inspiring! :-))

[KingRat]

I like these kind of effects... good job!

I saw the guy who programmed "Black Annex" doing something like this on youtube.