Ludo

[Unseen Machine]

Hi Gang,

After totally deleting and rewriting the CPU player code twice i finally have a playable version!

It needs some refinement and after my god daughters just played it they've suggested a few modifications but im quite happy with it as it stands.

Code: QB64: [Select]

1. '// Ludo v.01 By John Onyon a.k.a Unseen Machine \\
2.  
3. REM $include:'Vqb\Vqb.bi'
4.  
5. RANDOMIZE TIMER
6.  
7. CONST White = 1, Green = 2, Yellow = 3, Red = 4, Blue = 5, Home = 6, Human = 1, CPU = 2, MainMenu = 1, InGame = 2
8. CONST Attack = 1, Move = 2, GetOut = 3
9.  
10. DIM Mouse(1) AS MouseState, Kb(1) AS KeyBoardState, VQB_Mouse(1) AS MouseInfo
11. DIM Board(14, 14) AS _BYTE, Board2(14, 14) AS _BIT, BoardBits(14, 14) AS _BYTE, BBHlp(2) AS _BYTE, PlyrMove(3, 57) AS INTEGER
12. DIM Piece AS Sprite, D_Sprite AS Sprite, Num_Players AS _BYTE, Current_Plyr AS _BYTE
13. DIM Player(3) AS Player, GameState AS _BYTE, Selected(1) AS _BYTE, Btn(3) AS Button, Dice AS _BYTE, Rolling AS _BYTE
14. DIM SelectPiece AS _BYTE
15.  
16. GDK_Screen_SetRes MainScreen&, 800, 600
17.  
18. VQB_Button_New Btn(0), 300, 160, 200, 35, _RGB32(155, 155, 255), "One Player Game"
19. VQB_Button_New Btn(1), 300, 210, 200, 35, _RGB32(155, 155, 255), "Two Player Game"
20. VQB_Button_New Btn(2), 300, 260, 200, 35, _RGB32(155, 155, 255), "Three Player Game"
21. VQB_Button_New Btn(3), 300, 310, 200, 35, _RGB32(155, 155, 255), "Four Player Game"
22.  
23. GDK_Sprite_New Piece, "Ludo\Tiles.png", 6, 3, 18, _RGB32(255, 0, 255)
24. Piece.Scale = .8
25. GDK_Sprite_New D_Sprite, "Ludo\Dice.png", 6, 1, 6, _RGB32(255, 0, 255)
26. GDK_Sprite_SetRotationAsCenter D_Sprite
27.  
28. GameState = MainMenu
29. Debug% = TRUE
30.  
31. '////////// Main Screen Setup \\\\\\\
32.  
33. RESTORE Blank_Board
34. FOR k% = 0 TO 1
35.  FOR j% = 0 TO 14
36.   FOR i% = 0 TO 14
37.    READ Piece%
38.    IF k% = 0 THEN Board(i%, j%) = Piece% ELSE Board2(i%, j%) = Piece%
39.   NEXT
40.  NEXT
41. NEXT
42.  
43. VQB_Frame 5, 5, 790, 590, _RGB32(20, 70, 155)
44. VQB_Frame 155, 55, 490, 490, _RGB32(50, 40, 85)
45. VQB_Frame 300, 15, 200, 30, _RGB32(0, 0, 0)
46. COLOR _RGB32(255, 255, 255)
47. _PRINTSTRING (400 - (_PRINTWIDTH("LUDO v.01") / 2), 23), "LUDO v.01"
48. y% = 60
49. FOR j% = 0 TO 14
50.  x% = 160
51.  FOR i% = 0 TO 14
52.   GDK_Sprite_DrawXY Piece, x%, y%, 0, Board(i%, j%)
53.   IF Board2(i%, j%) THEN LINE (x%, y%)-(x% + 31, y% + 31), _RGB32(0, 0, 0), B
54.   x% = x% + 32
55.  NEXT
56.  y% = y% + 32
57. NEXT
58. BckGrnd& = VQB_StoreScreen&
59.  
60.  
61. '///////////// Load Path Data \\\\\\\\\\\
62.  
63. FOR Plyr% = 0 TO 3
64.  FOR Bit% = 0 TO 57
65.   READ PlyrMove(Plyr%, Bit%)
66.  NEXT
67. NEXT
68.  
69. '//////////////// Main Loop \\\\\\\\\\\\\
70. DO
71.  
72.  _LIMIT 30
73.  VQB_RestoreScreen BckGrnd&
74.  
75.  GDK_Mouse_GetState Mouse(0)
76.  GDK_Keyboard_GetState Kb(0)
77.  
78.  Col% = (Mouse(0).X - 160) \ 32
79.  Row% = (Mouse(0).Y - 60) \ 32
80.  '// Ensure we cant get an out off bounds error by capping the array refs
81.  IF Col% < 0 OR Col% > 14 OR Row% < 0 OR Row% > 14 THEN
82.   Row% = 0
83.   Col% = 0
84.  END IF
85.  
86.  SELECT CASE GameState
87.  
88.   CASE MainMenu
89.  
90.    VQB_Mouse_GetInfo VQB_Mouse(0)
91.  
92.    VQB_Frame 255, 135, 290, 240, _RGB32(150, 40, 5)
93.  
94.    FOR i% = 0 TO 3
95.     IF VQB_Button_Click(Btn(i%), VQB_Mouse(0)) THEN
96.      Num_Players% = i% + 1
97.      GameState = InGame
98.      FOR j% = 0 TO 3
99.       IF j% <= i% THEN
100.        Player(j%).Control = Human
101.       ELSE
102.        Player(j%).Control = CPU
103.        Player(j%).Persona = INT(RND * 3) + 1 '// randomize priority (a.i mode)
104.       END IF
105.      NEXT
106.      Current_Plyr = 1
107.      Rolling = TRUE
108.      EXIT FOR
109.     END IF
110.     VQB_Button_Draw Btn(i%)
111.    NEXT
112.  
113.   CASE InGame
114.  
115.    IF Rolling THEN
116.     IF NumRolls% < 10 THEN
117.      Dice = INT(RND * 6) + 1
118.      NumRolls% = NumRolls% + 1
119.     ELSE
120.      '// Check to see if player has only one piece out and the distance fits up to home, if not then skip to next player
121.      IF Player(Current_Plyr - 1).Num_Out = 1 THEN
122.       FOR j% = 0 TO 14
123.        FOR i% = 0 TO 14
124.         IF BoardBits(i%, j%) = Current_Plyr THEN
125.          ActualBlock% = (j% * 15) + i% + 1
126.         END IF
127.        NEXT
128.       NEXT
129.       Ref1% = -1
130.       FOR i% = 0 TO 57
131.        IF PlyrMove(Current_Plyr - 1, i%) = ActualBlock% THEN Ref1% = i%
132.       NEXT
133.       IF Ref1% = 57 - Dice THEN
134.        Rolling = FALSE
135.        SelectPiece = TRUE
136.       ELSEIF Ref1% > 57 - Dice THEN
137.        IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
138.        NumRolls% = 0
139.       ELSE
140.        Rolling = FALSE
141.        SelectPiece = TRUE
142.       END IF
143.      ELSE
144.       Rolling = FALSE
145.       SelectPiece = TRUE
146.      END IF
147.      NumRolls% = 0
148.     END IF
149.    ELSE
150.  
151.     IF SelectPiece THEN
152.  
153.      SELECT CASE Current_Plyr
154.       CASE 1
155.        BBHlp(0) = 2
156.        BBHlp(1) = 6
157.        BBHlp(2) = 1
158.       CASE 2
159.        BBHlp(0) = 8
160.        BBHlp(1) = 2
161.        BBHlp(2) = 2
162.       CASE 3
163.        BBHlp(0) = 12
164.        BBHlp(1) = 8
165.        BBHlp(2) = 3
166.       CASE 4
167.        BBHlp(0) = 6
168.        BBHlp(1) = 12
169.        BBHlp(2) = 4
170.      END SELECT
171.  
172.      IF Player(Current_Plyr - 1).Num_Home < 4 THEN '// Player still has availble bits to use (still in the game)
173.       IF Player(Current_Plyr - 1).Num_Out = 0 OR NewBit% = TRUE THEN '// If the player has no bits out automatically place one if a six is rolled
174.  
175.        IF Dice = 6 THEN '// roll a six to start moving a bit
176.         IF Player(Current_Plyr - 1).Num_Out + Player(Current_Plyr - 1).Num_Home < 4 THEN
177.          IF BoardBits(BBHlp(0), BBHlp(1)) <> Current_Plyr THEN
178.           IF BoardBits(BBHlp(0), BBHlp(1)) > 0 THEN
179.            '// Kick who ever is there back home
180.            Player(BoardBits(BBHlp(0), BBHlp(1)) - 1).Num_Out = Player(BoardBits(BBHlp(0), BBHlp(1)) - 1).Num_Out - 1
181.           END IF
182.           '// Allocate the square
183.           BoardBits(BBHlp(0), BBHlp(1)) = BBHlp(2)
184.           Player(Current_Plyr - 1).Num_Out = Player(Current_Plyr - 1).Num_Out + 1
185.           IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
186.           Rolling = TRUE
187.          END IF
188.         END IF
189.        ELSE
190.         IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
191.         Rolling = TRUE
192.        END IF
193.  
194.       ELSE '// Have pieces out on the board
195.  
196.        IF Player(Current_Plyr - 1).Control = Human THEN '// Human Player
197.  
198.         IF Dice = 6 THEN
199.  
200.          IF Player(Current_Plyr - 1).Num_Out + Player(Current_Plyr - 1).Num_Home < 4 THEN
201.           SELECT CASE Current_Plyr
202.            CASE 1
203.             clr& = _RGB32(0, 255, 0)
204.            CASE 2
205.             clr& = _RGB32(255, 255, 0)
206.            CASE 3
207.             clr& = _RGB32(0, 0, 255)
208.            CASE 4
209.             clr& = _RGB32(255, 0, 0)
210.           END SELECT
211.  
212.           Xpos% = 176 + (BBHlp(0) * 32)
213.           Ypos% = 76 + (BBHlp(1) * 32)
214.           CIRCLE (Xpos%, Ypos%), 6 + CSize%, clr&
215.           PAINT STEP(0, 0), clr&, clr&
216.           IF CSize% < 6 THEN CSize% = CSize% + 1 ELSE CSize% = 1
217.  
218.           IF Col% = BBHlp(0) AND Row% = BBHlp(1) THEN
219.            IF Mouse(0).LB THEN
220.             IF BoardBits(Col%, Row%) <> Current_Plyr THEN
221.              IF BoardBits(Col%, Row%) > 0 THEN
222.               Player(BoardBits(Col%, Row%) - 1).Num_Out = Player(BoardBits(Col%, Row%) - 1).Num_Out - 1
223.              END IF
224.              Player(Current_Plyr - 1).Num_Out = Player(Current_Plyr - 1).Num_Out + 1
225.              BoardBits(Col%, Row%) = Current_Plyr
226.              IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
227.              Rolling = TRUE
228.             END IF
229.            END IF
230.           END IF
231.          END IF
232.         END IF
233.  
234.         IF Mouse(0).LB AND NOT Mouse(1).LB THEN
235.          IF Board2(Col%, Row%) AND BoardBits(Col%, Row%) = Current_Plyr THEN '// Players bit
236.           Selected(0) = Col%
237.           Selected(1) = Row%
238.           SelectPiece = FALSE
239.          END IF
240.         END IF
241.  
242.        ELSE '// CPU Player
243.  
244.         IF Player(Current_Plyr - 1).Num_Out > 0 THEN '// Player has active pieces
245.          FOR Bit% = 0 TO Player(Current_Plyr - 1).Num_Out '// Cycle through all bits the player has out
246.           ScanDir% = INT(RND * 2) + 1
247.           IF ScanDir% = 1 THEN
248.            Lp_Start% = 0
249.            Lp_End% = 14
250.            StepVal% = 1
251.           ELSE
252.            Lp_Start% = 14
253.            Lp_End% = 0
254.            StepVal% = -1
255.           END IF
256.           FOR j% = Lp_Start% TO Lp_End% STEP StepVal% '// Rows
257.            FOR i% = Lp_Start% TO Lp_End% STEP StepVal% '// Columns
258.  
259.             IF Dice = 6 THEN
260.              IF Player(Current_Plyr - 1).Num_Out + Player(Current_Plyr - 1).Num_Home < 4 THEN '// Have pieces left to put out
261.               IF BoardBits(BBHlp(0), BBHlp(1)) <> Current_Plyr THEN '// Can place a new piece
262.                NewPiece% = TRUE
263.               END IF
264.              END IF
265.             END IF
266.  
267.             IF NewPiece% THEN
268.  
269.              IF BoardBits(BBHlp(0), BBHlp(1)) > 0 THEN '// Kick who ever is there back home
270.               Player(BoardBits(BBHlp(0), BBHlp(1)) - 1).Num_Out = Player(BoardBits(BBHlp(0), BBHlp(1)) - 1).Num_Out - 1
271.              END IF '// Allocate the square
272.              BoardBits(BBHlp(0), BBHlp(1)) = BBHlp(2)
273.              Player(Current_Plyr - 1).Num_Out = Player(Current_Plyr - 1).Num_Out + 1
274.              IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
275.              Rolling = TRUE
276.              NewPiece% = FALSE
277.              GOTO Skip_Loops
278.  
279.             ELSE
280.  
281.              IF BoardBits(i%, j%) = Current_Plyr THEN '// Current players piece
282.               '// Get Array ref's
283.               ActualBlock% = (j% * 15) + i% + 1
284.               FOR a% = 0 TO 57
285.                IF PlyrMove(Current_Plyr - 1, a%) = ActualBlock% THEN Ref1% = a%
286.               NEXT
287.  
288.               IF Ref1% + Dice < 57 THEN '// Move is within range
289.                NewActual% = PlyrMove(Current_Plyr - 1, Ref1% + Dice)
290.                NewRow% = (NewActual% - 1) \ 15
291.                NewCol% = (NewActual% - 1) MOD 15
292.                IF BoardBits(NewCol%, NewRow%) <> Current_Plyr THEN
293.                 IF BoardBits(NewCol%, NewRow%) > 0 THEN
294.                  Player(BoardBits(NewCol%, NewRow%) - 1).Num_Out = Player(BoardBits(NewCol%, NewRow%) - 1).Num_Out - 1
295.                 END IF
296.                 BoardBits(NewCol%, NewRow%) = Current_Plyr
297.                 BoardBits(i%, j%) = 0
298.                 IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
299.                 Rolling = TRUE
300.                 GOTO Skip_Loops
301.                ELSE
302.                 IF Bit% = Player(Current_Plyr - 1).Num_Out THEN '// Last piece we could check so no valid moves at all - skip to next player
303.                  IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1 '// Skip players who've won
304.                  Rolling = TRUE
305.                  GOTO Skip_Loops
306.                 ELSE
307.                  GOTO NextBit '// Skip to next player piece
308.                 END IF
309.                END IF
310.               ELSEIF Ref1% + Dice = 57 THEN '// move to home
311.                BoardBits(i%, j%) = 0
312.                Rolling = TRUE
313.                Player(Current_Plyr - 1).Num_Out = Player(Current_Plyr - 1).Num_Out - 1
314.                Player(Current_Plyr - 1).Num_Home = Player(Current_Plyr - 1).Num_Home + 1
315.                IF Player(crrent_plyr).Num_Home = 4 THEN '// Win event
316.  
317.  
318.                 '// Ask if new game
319.  
320.                END IF
321.                IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
322.                GOTO Skip_Loops
323.               ELSE '// No valid move for this piece
324.                IF Bit% = Player(Current_Plyr - 1).Num_Out THEN '// Last piece we could check so no valid moves at all - skip to next player
325.                 IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1 '// Skip players who've won
326.                 Rolling = TRUE
327.                 GOTO Skip_Loops
328.                END IF
329.               END IF
330.              END IF
331.  
332.             END IF
333.            NEXT
334.           NEXT
335.           NextBit:
336.          NEXT
337.  
338.         END IF
339.  
340.        END IF
341.       END IF
342.  
343.      ELSE
344.       IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1 '// Skip players who've won
345.      END IF
346.  
347.      Skip_Loops:
348.  
349.     ELSE '// SET DESTINATION
350.  
351.      IF Player(Current_Plyr - 1).Control = Human THEN
352.       IF Mouse(0).LB AND NOT Mouse(1).LB THEN
353.        '// Calculate how many squares the move is (must be same as dice roll value)
354.        ActualBlock% = (Selected(1) * 15) + Selected(0) + 1
355.        NewActual% = (Row% * 15) + Col% + 1
356.        Ref1% = -1: Ref2% = -1
357.        '// Find origin and new point in array and get differance in position
358.        FOR i% = 0 TO 57
359.         IF PlyrMove(Current_Plyr - 1, i%) = ActualBlock% THEN Ref1% = i%
360.         IF PlyrMove(Current_Plyr - 1, i%) = NewActual% THEN Ref2% = i%
361.        NEXT
362.        Distance% = Ref2% - Ref1%
363.  
364.        IF Distance% = Dice THEN
365.         IF Board2(Col%, Row%) THEN '// Selected destination is allowed to be moved to
366.          IF BoardBits(Col%, Row%) = Current_Plyr THEN '// Own piece, dependant on rule settings what happens here
367.           SelectPiece = TRUE
368.          ELSE '// Occupied by someone else, kick them home!
369.           IF BoardBits(Col%, Row%) <> Current_Plyr AND BoardBits(Col%, Row%) > 0 THEN
370.            Player(BoardBits(Col%, Row%) - 1).Num_Out = Player(BoardBits(Col%, Row%) - 1).Num_Out - 1
371.           END IF
372.           '// If dest was ok then move bit and change player
373.           BoardBits(Selected(0), Selected(1)) = 0
374.           BoardBits(Col%, Row%) = Current_Plyr
375.           IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
376.           Rolling = TRUE
377.          END IF
378.         ELSEIF NewActual% = PlyrMove(Current_Plyr - 1, 57) THEN '// Home Square
379.          BoardBits(Selected(0), Selected(1)) = 0
380.          Player(Current_Plyr - 1).Num_Home = Player(Current_Plyr - 1).Num_Home + 1
381.          Player(Current_Plyr - 1).Num_Out = Player(Current_Plyr - 1).Num_Out - 1
382.          IF Current_Plyr < 4 THEN Current_Plyr = Current_Plyr + 1 ELSE Current_Plyr = 1
383.          Rolling = TRUE
384.         END IF
385.        ELSE
386.         IF Col% = Selected(0) AND Row% = Selected(1) THEN
387.          SelectPiece = TRUE
388.          Selected(0) = 0
389.          Selected(1) = 0
390.         END IF
391.        END IF
392.       END IF
393.  
394.      END IF
395.     END IF
396.    END IF
397.  
398.    '/////////////////// Draw Bits \\\\\\\\\\\\\\\\\\\\\\\\\\
399.  
400.    y% = 76
401.    FOR j% = 0 TO 14
402.     x% = 176
403.     FOR i% = 0 TO 14
404.      IF BoardBits(i%, j%) THEN
405.       SELECT CASE BoardBits(i%, j%)
406.        CASE 1
407.         clr& = _RGB32(0, 255, 0)
408.        CASE 2
409.         clr& = _RGB32(255, 255, 0)
410.        CASE 3
411.         clr& = _RGB32(0, 0, 255)
412.        CASE 4
413.         clr& = _RGB32(255, 0, 0)
414.       END SELECT
415.       IF i% = Selected(0) AND j% = Selected(1) THEN
416.        CIRCLE (x%, y%), 16, _RGB32(0, 0, 0)
417.       ELSE
418.        CIRCLE (x%, y%), 12, _RGB32(0, 0, 0)
419.       END IF
420.       PAINT STEP(0, 0), clr&, _RGB32(0, 0, 0)
421.      END IF
422.      x% = x% + 32
423.     NEXT
424.     y% = y% + 32
425.    NEXT
426.  
427.    IF Rolling THEN Rot! = (RND * (8 * ATN(1))) ELSE Rot! = 0
428.    GDK_Sprite_DrawXY D_Sprite, 720, 300, Rot!, Dice
429.    GDK_Sprite_DrawXY Piece, 440, 550, 0, 10 + Current_Plyr
430.    GDK_Sprite_DrawXY Piece, 340, 550, 0, 15
431.    GDK_Sprite_DrawXY Piece, 372, 550, 0, 16
432.    GDK_Sprite_DrawXY Piece, 404, 550, 0, 17
433.  
434.  
435.  END SELECT
436.  
437.  '///////////////////
438.  
439.  Kb(1) = Kb(0)
440.  Mouse(1) = Mouse(0)
441.  VQB_Mouse(1) = VQB_Mouse(0)
442.  
443.  '///////////////////
444.  IF Debug% THEN
445.   NewActual% = (Row% * 15) + Col% + 1
446.  
447.   COLOR _RGB32(255, 255, 255)
448.   LOCATE 1, 1: PRINT "Col/Row : "; Col%; Row%
449.   PRINT "Last Dice Roll : "; Dice
450.   PRINT "Distance calc : "; Distance%
451.   PRINT "Select piece mode : "; SelectPiece
452.   PRINT "Current Player : "; Current_Plyr
453.   PRINT "Actual Block # : "; ActualBlock%
454.   PRINT "New Block # : "; NewActual%
455.   IF Current_Plyr THEN
456.    PRINT "Player Num Out : "; Player(Current_Plyr - 1).Num_Out
457.    PRINT "Player Num Home : "; Player(Current_Plyr - 1).Num_Home
458.   END IF
459.  END IF
460.  '///////////////////
461.  
462.  _DISPLAY
463.  
464. LOOP
465.  
466. Blank_Board:
467.  
468. DATA 2,2,2,2,2,2,1,1,1,3,3,3,3,3,3
469. DATA 2,1,2,2,1,2,1,3,3,3,1,3,3,1,3
470. DATA 2,2,2,2,2,2,1,3,1,3,3,3,3,3,3
471. DATA 2,2,2,2,2,2,1,3,1,3,3,3,3,3,3
472. DATA 2,1,2,2,1,2,1,3,1,3,1,3,3,1,3
473. DATA 2,2,2,2,2,2,1,3,1,3,3,3,3,3,3
474. DATA 1,2,1,1,1,1,7,3,8,1,1,1,1,1,1
475. DATA 1,2,2,2,2,2,2,6,5,5,5,5,5,5,1
476. DATA 1,1,1,1,1,1,10,4,9,1,1,1,1,5,1
477. DATA 4,4,4,4,4,4,1,4,1,5,5,5,5,5,5
478. DATA 4,1,4,4,1,4,1,4,1,5,1,5,5,1,5
479. DATA 4,4,4,4,4,4,1,4,1,5,5,5,5,5,5
480. DATA 4,4,4,4,4,4,1,4,1,5,5,5,5,5,5
481. DATA 4,1,4,4,1,4,4,4,1,5,1,5,5,1,5
482. DATA 4,4,4,4,4,4,1,1,1,5,5,5,5,5,5
483.  
484. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
485. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
486. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
487. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
488. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
489. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
490. DATA 1,1,1,1,1,1,0,0,0,1,1,1,1,1,1
491. DATA 1,1,1,1,1,1,0,0,0,1,1,1,1,1,1
492. DATA 1,1,1,1,1,1,0,0,0,1,1,1,1,1,1
493. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
494. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
495. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
496. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
497. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
498. DATA 0,0,0,0,0,0,1,1,1,0,0,0,0,0,0
499.  
500. '// Player movement data, actual square numbers. I had to make another program just to make this!
501. DATA 93,94,95,96,82,67,52,37,22,7,8,9,24,39,54,69,84,100,101,102,103,104,105,120,135,134,133,132,131,130,144,159,174,189,204,219,218,217,202,187,172,157,142,126,125,124,123,122,121,106,91,92,107,108,109,110,111,112
502. DATA 39,54,69,84,100,101,102,103,104,105,120,135,134,133,132,131,130,144,159,174,189,204,219,218,217,202,187,172,157,142,126,125,124,123,122,121,106,91,92,93,94,95,96,82,67,52,37,22,7,8,9,24,23,38,53,68,83,98
503. DATA 133,132,131,130,144,159,174,189,204,219,218,217,202,187,172,157,142,126,125,124,123,122,121,106,91,92,93,94,95,96,82,67,52,37,22,7,8,9,24,39,54,69,84,100,101,102,103,104,105,120,135,134,119,118,117,116,115,114
504. DATA 187,172,157,142,126,125,124,123,122,121,106,91,92,93,94,95,96,82,67,52,37,22,7,8,9,24,39,54,69,84,100,101,102,103,104,105,120,135,134,133,132,131,130,144,159,174,189,204,219,218,217,202,203,188,173,158,143,128
505.  
506. TYPE Player
507.  Control AS _BYTE
508.  Num_Home AS _BYTE
509.  Num_Out AS _BYTE
510.  Persona AS _BYTE
511. END TYPE
512.  
513. REM $INCLUDE:'UnseenGDK.bm'
514. REM $include:'Vqb\Vqb_lite.bm'
515.  

Extract the files to your qb64 directory.

Thanks and happy coding,

Unseen

[Ashish]

What? I played 20 min and home all my pieces before CPU and get no winning message?

 

Also, dice continues to spin and game never ends with result.

I like the graphics of the game, and CPU part is good. When a piece is selected, I can't select another piece until I deselect it again.
It will be nice if you fix this. :)

[Unseen Machine]

Hi Ashish,

Firstly, thanks for playing it, i apologise that you had no satisfactory "You Win" message at the end of your game, it's one of the things left to implement.

When a piece is selected, I can't select another piece until I deselect it again.
It will be nice if you fix this. :)

Ok, i'll have a look into that, thanks for the feedback.

Unseen

[Unseen Machine]

Hi Folks,

I FINISHED SOMETHING! Well, i got it to give you a win message! There are still many things i'd like to modify/give the option for but i won't be doing any of that any time soon.

Hopefully now i can finally get something posted in the GAMES forum! Whoppeeee!

Enjoy and i'd appreciate any feedback/bug reports.

Unseen

[bplus]

Hi @Unseen Machine

I am checking out the current .zip you posted today and am getting this for opening screen:
 

I don't think this is what you intended.

The code from original post seems OK? Except I don't have a clue how to play it, no arrow keys or mouse click does anything except increase size of piece.

Oh click the piece it expands and then click dice amount of squares ahead, if roll 6 another piece comes out?

What's difference between this and Parcheesi?

[Unseen Machine]

Errrr, well thats not right! Let me have a look see...

Looking......Looking and poof! I forgot to update the sprite sheet! Thank god not many people actually try my stuff! New attachment added with correct sprite sheet. Thanks for the heads up.

Oh click the piece it expands and then click dice amount of squares ahead, if roll 6 another piece comes out?

Yep, you got it!

What's difference between this and Parcheesi?

I wouldnt know having never heard of parchessi.

Thanks for trying it mate and for the feedback.

Unseen

[bplus]

Yeah, I did some little Internet search and Ludo (I had never heard of before) turns out to be another name for pretty much same game under Traditional Board Race Games which includes Backgammon, Trouble, Sorry.

Wiki "Parcheesi is a brand-name American adaptation of the Indian cross and circle board game Pachisi,.."
The boards are nearly identical with the ancient Indian game.

[bplus]

Hi @Unseen Machine

RE: First impressions

Suggestion: show the players still waiting to go out in the 4 white squares provided on the game board.

Also it would be nice if you could list in the arrow heads at middle of board number of players in and retired. In my game Red suddenly wins as I am waiting to get my last piece in, unpleasant surprise. Dice rolls and pieces moved maybe a little too fast?

Plus I watched a 5 minute video of Ludo on You Tube, that game had a block option where a player can stack a piece atop of his other (as dice allow) and block incoming pieces. I tried that with my first game and no deal.

Oh you have that ugly (sorry) score board in top left corner, but I never looked at it. Wouldn't it be more elegant to just read the board? Where you could see the players still stuck at home and the number of players who ran the gauntlet and are finished. The total would always be 4, players home + player on track + players finished. A block could be the colored circle with a 2 in middle, number of players finished is white circle in center colored triangle with players color number 0 to 4.

I like games that play against computer like this, do you or have you thought of different AI strategies for the different colors?

[Unseen Machine]

Hi @bplus

Now thats what i call positive feedback, i appreciate it mate.

show the players still waiting to go out in the 4 white squares provided on the game board.

I agree, i'll implement that one.

Also it would be nice if you could list in the arrow heads at middle of board number of players in and retired.

  Again, i agree so that will get added too.

Dice rolls and pieces moved maybe a little too fast?

Yep, i can see that, i'm thinking im gonna make it so that the pieces glide to their new spots rather than jumping. Also, to negate the need for being able to switch selected pieces without having to deselect first (@Asish suggested this improvement) i'm gonna make it so that when you click on a piece it automatically moves to the right tile.

Plus I watched a 5 minute video of Ludo on You Tube, that game had a block option where a player can stack a piece atop of his other (as dice allow) and block incoming pieces. I tried that with my first game and no deal.

There are many different variations on the rules, african rules let you move backwards! Also some rules use two dice, these are both options i might implement as optional rules in the future.

Oh you have that ugly (sorry) score board in top left corner, but I never looked at it.

Lol, thats the debug readout, it shouldnt appear anymore as i turned it off.

I like games that play against computer like this, do you or have you thought of different AI strategies for the different colors?

Me too, and as for AI I did have that idea from the get go. If you look in the UDT for the players youll see a Persona variable...previously i attempted to give them 3 different traits but failed and ended up with the basic movement it currently has.

Thanks again for the feedback, it's inspired me to improve it.

Unseen

[bplus]

@Unseen Machine

Yeah I didn't think I wandered too far from intentions you already had. ;-))

But the potential of creating AI's to compete is what peaks my interest, that is why I found the blocking option interesting.

[Unseen Machine]

@bplus

But the potential of creating AI's to compete is what peaks my interest, that is why I found the blocking option interesting.

Yeah i suppose so, maybe i should just have a CPU only game s you can just watch the computer try to beat its self! I'm working on the updates slowly, mainly cause i figured the best way to implement the things that have been suggested is to change the way the bits are handled, previously they were just in 2d array but this ment that you wouldnt be able to to do blocking and the gliding movement would have been irriating to implement, so now i've been working on ripping out all of that and changing the pieces to be handled by their own type.

Thanks again for the feedback,

Unseen