SQL and 64 bits version

[Juanjogomez]

Hi,
I have finished the billing program with which I have taken several months. To do this I have used version 1.3 of 32 bits.
Now, I have decided to use the 64-bit version to see if it achieved a higher speed, and when compiling any of the programs I get the "cannot find dynamic library file" window.
In the QB64 folder I have copied the files: mysql.dll and msql_helper.h
Did I have to do something else, or does the SQL library not work in 64 bits?
Thank you

[FellippeHeitor]

32bit version of QB64 can use 32bit version of a DLL. 64bit version of QB64 will require a 64bit version of said DLL.

[Juanjogomez]

And there is not a DLL64 bit version available?
Thank you

[FellippeHeitor]

There probably is, but you'll need to look for it with their developer - where did you get the 32bit one?

[EricE]

Is there a tutorial or thread about using QB64 with SQL?

[Juanjogomez]

There probably is, but you'll need to look for it with their developer - where did you get the 32bit one?

At [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]. I think Galeon did it.

[Juanjogomez]

Is there a tutorial or thread about using QB64 with SQL?

In a few minutes I will put the code that I use

[Juanjogomez]

This is an example of code to use SQL...
In the QB64 folder must download 'mysql.dll' and create a text file called 'mysql_herper.h' with the following lines

void *offset_to_offset(void* offset){
  return offset;
 }
 void *offset_at_offset(void** offset){
 return *offset;
 }

Code: QB64: [Select]

1.  
2. DECLARE CUSTOMTYPE LIBRARY "mysql_helper"
3.     FUNCTION offset_to_string$ ALIAS offset_to_offset (BYVAL offset AS _OFFSET)
4.     FUNCTION offset_at_offset%& (BYVAL offset AS _OFFSET)
5. END DECLARE
6.  
7. '---- download mysql.dll from http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/mysql.dll (~2MB) ----
8. DECLARE DYNAMIC LIBRARY "mysql"
9.     FUNCTION mysql_init%& (BYVAL always_0 AS _OFFSET)
10.     'MYSQL *mysql_init(MYSQL *mysql)
11.     FUNCTION mysql_error$ (BYVAL mysql AS _OFFSET)
12.     'const char *mysql_error(MYSQL *mysql)
13.     FUNCTION mysql_get_client_info$
14.     ' Returns a string that represents the client library version
15.     ' const char *mysql_get_client_info(void)
16.     FUNCTION mysql_real_connect%& (BYVAL mysql AS _OFFSET, host AS STRING, user AS STRING, password AS STRING, db AS STRING, BYVAL port AS _UNSIGNED LONG, BYVAL unix_socket AS _OFFSET, BYVAL client_flag AS _UNSIGNED _OFFSET)
17.     FUNCTION mysql_real_connect_dont_open%& ALIAS mysql_real_connect (BYVAL mysql AS _OFFSET, host AS STRING, user AS STRING, password AS STRING, BYVAL db AS _OFFSET, BYVAL port AS _UNSIGNED LONG, BYVAL unix_socket AS _OFFSET, BYVAL client_flag AS _UNSIGNED LONG)
18.     ' MYSQL *mysql_real_connect(MYSQL *mysql, const char *host, const char *user, const char *passwd, const char *db, unsigned int port, const char *unix_socket, unsigned long client_flag)
19.     '  The value of host may be either a host name or an IP address. If host is NULL or the string "localhost", a connection to the local host is assumed.
20.     '  db is the database name. If db is not NULL, the connection sets the default database to this value.
21.     '  If port is not 0, the value is used as the port number for the TCP/IP connection. Note that the host parameter determines the type of the connection.
22.     '  If unix_socket is not NULL, the string specifies the socket or named pipe to use. Note that the host parameter determines the type of the connection.
23.     '  The value of client_flag is usually 0, but can be set to a combination of the following flags to enable certain features.
24.     '  Return Value: A MYSQL* connection handle if the connection was successful, NULL if the connection was unsuccessful. For a successful connection, the return value is the same as the value of the first parameter.
25.     '*** REMEMBER, ALL STRINGS PASSED MUST BE NULL '+CHR$(0)' TERMINATED ***
26.     SUB mysql_query (BYVAL mysql AS _OFFSET, mysql_command AS STRING)
27.     FUNCTION mysql_query& (BYVAL mysql AS _OFFSET, mysql_command AS STRING)
28.     ' int mysql_query(MYSQL *mysql, const char *stmt_str)
29.     ' Executes the SQL statement pointed to by the null-terminated string stmt_str. Normally, the string must consist of a single SQL statement without a terminating semicolon (%u201C;%u201D) or \g. If multiple-statement execution has been enabled,
30.     'Returns Zero if the statement was successful. Nonzero if an error occurred.
31.     '*** REMEMBER, ALL STRINGS PASSED MUST BE NULL '+CHR$(0)' TERMINATED ***
32.     FUNCTION mysql_store_result%& (BYVAL mysql AS _OFFSET)
33.     ' MYSQL_RES *mysql_store_result(MYSQL *mysql)
34.     ' Returns a RESULT STRUCTURE
35.     FUNCTION mysql_num_fields~& (BYVAL result AS _OFFSET)
36.     ' unsigned int mysql_num_fields(MYSQL_RES *result)
37.     ' To pass a MYSQL* argument instead, use unsigned int mysql_field_count(MYSQL *mysql).
38.     ' Returns number of columns in result set
39.     FUNCTION mysql_num_rows&& (BYVAL result AS _OFFSET)
40.     ' my_ulonglong mysql_num_rows(MYSQL_RES *result)
41.     ' Returns the number of rows in the result set.
42.     FUNCTION mysql_fetch_row%& (BYVAL result AS _OFFSET)
43.     ' MYSQL_ROW mysql_fetch_row(MYSQL_RES *result)
44.     ' RETURNS A ROW STRUCTURE
45.     FUNCTION mysql_fetch_lengths%& (BYVAL result AS _OFFSET)
46.     ' unsigned long *mysql_fetch_lengths(MYSQL_RES *result)
47.     ' Returns the lengths of the columns of the current row within a result set.
48.     ' Returns a pointer to an array of lengths
49.     SUB mysql_close (BYVAL mysql AS _OFFSET)
50.     SUB mysql_free_result (BYVAL result AS _OFFSET)
51. END DECLARE
52.  
53. '--Example to search for a data in a database called `books' that has the database table 'book' whidt fields: 'id', 'title', 'publisher' and 'author'
54. my_server$ = "127.0.0.1"
55. my_user$ = "root"
56. my_key$ = "12345"
57. bdatos$ = "books"
58. port = 0
59.  
60. DIM SHARED conn AS _OFFSET
61. conn = mysql_init(0)
62. DIM SHARED errf AS LONG
63. REDIM SHARED DB_RESULT(columns, rows) AS STRING
64.  
65. IF conn = 0 THEN
66.     PRINT "I can't start MYSQL client!": SLEEP (0): x$ = INKEY$
67. END IF
68.  
69. DIM conexion AS _OFFSET
70.  
71. '------ Open Database
72. conexion = mysql_real_connect(conn, my_server$, my_user$, my_key$, bdatos$, port, 0, 0)
73. IF conexion = 0 THEN PRINT "I cannot connect to the server": x$ = INPUT$(1)
74.  
75. '-- Search for Shakespeare books
76. '-- Any SQL command could be used
77. busclave$ = "SELECT * FROM book WHERE author = 'Shakespeare'" + CHR$(0)
78. CALL basedato(busclave$, rows, columns)
79. IF rows = 0 THEN
80.     COLOR 4, 7
81.     LOCATE 10, 10: PRINT " I can't find any book by that author ";
82.     COLOR 15, 0
83.     SLEEP 2: x$ = INKEY$
84. ELSE
85.     PRINT "Shakespeare's Books"
86.     FOR n = 1 TO rows
87.         PRINT "Title    :"; DB_RESULT(2, n)
88.         PRINT "Publisher:"; DB_RESULT(3, n)
89.         PRINT
90.     NEXT
91. END IF
92.  
93. END
94.  
95.  
96. '----------------------------------------------------------- MYSQL -----------------------------------------------------------
97. SUB basedato (busclave$, rows, columns)
98.     '*** Hacer busqueda en la tabla ***
99.     errf = mysql_query(conn, busclave$)
100.     DIM result AS _OFFSET
101.     'DIM columns AS LONG
102.     result = mysql_store_result(conn)
103.     IF LEFT$(busclave$, 6) = "SELECT" THEN
104.         'DIM row AS _OFFSET
105.         'DIM dato AS _OFFSET
106.         columns = mysql_num_fields(result)
107.         rows = mysql_num_rows(result)
108.         '*** Guardar en Array ***
109.         REDIM DB_RESULT(columns, rows) AS STRING
110.         FOR filas = 1 TO rows
111.             DIM mysql_row AS _OFFSET
112.             mysql_row = mysql_fetch_row(result)
113.             DIM mem_mysql_row AS _MEM
114.             mem_mysql_row = _MEM(mysql_row, columns * LEN(an_offset%&)) 'The upper limit is unknown at this point
115.             DIM mysql_lengths AS _OFFSET
116.             mysql_lengths = mysql_fetch_lengths(result)
117.             DIM mem_mysql_lengths AS _MEM
118.             mem_mysql_lengths = _MEM(mysql_lengths, columns * 4)
119.             DIM mem_field AS _MEM
120.             FOR campos = 1 TO columns
121.                 length = _MEMGET(mem_mysql_lengths, mem_mysql_lengths.OFFSET + (campos - 1) * 4, _UNSIGNED LONG)
122.                 mem_field = _MEM(_MEMGET(mem_mysql_row, mem_mysql_row.OFFSET + (campos - 1) * LEN(an_offset%&), _OFFSET), length)
123.                 DB_RESULT(campos, filas) = SPACE$(length)
124.                 _MEMGET mem_field, mem_field.OFFSET, DB_RESULT(campos, filas)
125.                 _MEMFREE mem_field
126.             NEXT
127.             _MEMFREE mem_mysql_lengths
128.             _MEMFREE mem_mysql_row
129.         NEXT
130.     END IF
131.     mysql_free_result result
132. END SUB

I hope it works for you.

[EricE]

Thank you Juanjogomez.
I will study your program.