Drum Machine Prototype

[TrialAndTerror]

Great program! Thank you Dav. It helps me out when recording some musical ideas.
Very inspiring.

I haven't looked into the code but I have a question:
Can you make it run 3/4 too?
It's an essential feature for a drum machine.

T&T

[QBExile]

Great program Dav. Love the concept and implementation and coding style.

[TempodiBasic]

Hi Dav
I can say that this new version is a good improvement...and it runs well also in Kubuntu!


Great job

[Dav]

@QBExile: Thanks!

@TrialAndTerror: Not currently, but I will work on implementing other meters like 3/4.

@TempodiBasic: Thanks for the Linux report.  I was thinking about using Win API's for some things planned, but I will put that off to keep it Linux friendly.

- Dav

[Pete]

Sorry Dav, I march to the beat of a different drummer...

 

[Petr]

I started working on saving to WAV format for this program. It will take a few days, I still have little time.

[Dav]

Cool, Petr!  Then we can all WAV at Pete while he marches.

I tried to draw a reply Pete, but I couldn't fit in anything funny - now I just gotta expand the playing grid.

- Dav

[Pete]

No seriously Dav, I ran your prog on my computer, and that's just the way it displayed itself! Of course, I just had a Windows update installed. Anyway, sorry to cause you more work, but even sorrier if it takes your time away form creating more cool stuff, like this, to share. Nice work, as always!

Pete

[Petr]

So, the program WAV is coming out, but I have significant problems with time synchronization. Somehow I can't figure out how to correctly count the position of the beginning of the sound on the timeline using the TEMPO parameter. Next, it looks like setting the sound level for _SNDVOL in the range of 0 - 1 (even if the original of the program has values above 1) will have to adapt for WAV. Today I am very tired, I will continue tomorrow. Here is one of the first outputs.

 

drummachine3.wav

[Dav]

The wav sounds ok.  I sure appreciate your efforts helping my programs. 

- Dav

[Petr]

Hi.

I am very pleased to announce the completion of my resolution. You can now save the SAV file that creates this wonderful Dav´s  program using my utility as a WAV file. The only thing he needs to fine-tune is the volume level of some instruments, but I think, Dav can handle it better, because I absolutely do not have musical hearing.

To run the program, you need all the tools converted to WAV and the SAV file that is the output of Dave's drummachine program. All this, including the source code, is attached.

Code: QB64: [Select]

1. 'Dav SAV to WAV utility
2. SCREEN _NEWIMAGE(100, 30, 0)
3.  
4. FileName$ = "drummachine.sav"
5.  
6.  
7.  
8.  
9. TYPE Snd
10.     Left AS SINGLE
11.     Right AS SINGLE
12. END TYPE
13. REDIM SHARED OutputSound(-1) AS Snd
14.  
15. TYPE OtpSndHelper
16.     Offset_Start AS LONG
17.     Offset_End AS LONG
18. END TYPE
19. REDIM SHARED OTP(1) AS OtpSndHelper
20.  
21.  
22.  
23. IF _FILEEXISTS(FileName$) THEN
24.     DIM tempo AS INTEGER, buttons AS INTEGER
25.     FF = FREEFILE
26.     OPEN FileName$ FOR BINARY AS #FF
27.     GET #FF, , tempo
28.     GET #FF, , buttons
29.     DIM s1(buttons) AS INTEGER
30.     GET #FF, , s1()
31. ELSE
32.     PRINT "Error loading DAV's SAV file.": SYSTEM
33. END IF
34.  
35. DIM Sounds(1 TO 32, 1 TO 16) AS INTEGER
36. y = 1
37. x = 0
38.  
39. 'converse from 1D array to 2D array (uncompatible with QB64 logic, IS NOT POSSIBLE read Sounds() direct with GET for the same data order!)
40. FOR a = 0 TO 511
41.     IF x = 32 THEN y = y + 1: x = 0
42.     x = x + 1
43.     Sounds(x, y) = s1(a)
44. NEXT
45.  
46. PRINT "Loading DAV's SAV file..."
47. PRINT "Tempo:"; tempo
48. PRINT "Buttons:"; buttons
49. PRINT "Patterns:"
50.  
51. 'test
52. FOR y = 1 TO 16
53.     PRINT
54.     FOR x = 1 TO 32
55.         PRINT Sounds(x, y);
56. NEXT x, y
57.  
58. PRINT "Loaded sounds data table. Press key..."
59. SLEEP
60.  
61.  
62. PRINT "Loading WAV samples"
63.  
64. DIM Samples(1 TO 16) AS LONG
65. RESTORE Samples
66. FOR LoadSamples = 1 TO 16
67.     READ s$
68.     Sample$ = "wavsamples\" + s$ + ".wav"
69.     Samples(LoadSamples) = WAVtoRAW(Sample$)
70.     PRINT "Loaded sample: "; s$
71. NEXT
72. PRINT "Total track time:"; 3 + 32 * (60 / 4 / tempo); "seconds (3 seconds added extra to end)."
73.  
74.  
75. 'DATA samples order MUST be in the same order as in drummachine.bas on left (from top to bottom)
76. Samples:
77. DATA "crash","ride","hhopen","hhclosed","tomhigh","tommid","tomlow","snare","kick","cowbell","shaker","tamb","vibraslap","gong","triangleshort","clave"
78.  
79. 'Insert samples to time track
80. DIM TimeTrack(1 TO 32, 1 TO 16) AS SINGLE
81. REDIM newsound(44100 * 30) AS Snd
82.  
83.  
84. DelayTime = 60 / 4 / tempo
85. FOR y = 1 TO 16 '              rows
86.     FOR x = 1 TO 32 '          column's
87.         IF Sounds(x, y) THEN
88.             TimeTrack(x, y) = DelayTime * x
89.         END IF
90. NEXT x, y
91. PRINT "Time track done. Creating WAV content..."
92.  
93.  
94.  
95.  
96. FOR row = 1 TO 16
97.     FOR column = 1 TO 32
98.         IF Sounds(column, row) THEN
99.             lenght& = 44100 * TimeTrack(column, row) '          calculate lenght for track in BYTES: Time lenght * sample rate (44100 is used also in WAV header)
100.             IF Sounds(column, row) = 1 THEN
101.                 RESTORE status1
102.                 FOR SearchVolume = 1 TO row
103.                     READ vol 'INFO for DAV:  This is the same as your SUB PLAYBEAT. status1: is for "1" values
104.                 NEXT
105.  
106.             END IF
107.             IF Sounds(column, row) = 2 THEN
108.                 RESTORE status2
109.                 FOR SearchVolume = 1 TO row
110.                     READ vol 'INFO for DAV:  This is the same as your SUB PLAYBEAT. status1: is for "2" values
111.                 NEXT
112.  
113.             END IF
114.             RAWCOPY Samples(row), newsound(), lenght&, vol '    copy sounds to correct places (in time) to array (if on this places is sound, is content
115.         END IF '                                                mixed in SUB RAWCOPY, RAWCOPY in this program is updated!)
116.     NEXT
117. NEXT
118.  
119. RealLenght newsound(), DelayTime * 32 + 3 ' (32 samples + 3 seconds lenght extra)
120. PRINT "Done. Saving file drummachine.wav... (16 bit stereo, 44100)"
121. SAVESOUND16S newsound(), "drummachine.wav"
122. PRINT "Operation comleted. SAV file is now saved as WAV music file."
123.  
124.  
125.  
126. 'DAV, here you can reset VOLUME values (if sound in WAV for sample is too loud, or too silent)
127. 'values are rewrited from original DAV's drummachine.bas program
128. status1: '1 in sav table
129. DATA 6,5,5,1,9,9,9,1,1,.3,.6,1,.1,.1,.3,.6
130. status2: '2 in sav table
131. DATA .2,.2,.15,.2,.1,.1,.1,.1,.1,.2,.1,.1,.05,.03,.3,.02
132.  
133. FUNCTION WAVtoRAW (file$) '                              Function load WAV file (this just 16bit, stereo format) and load it to array as RAW.
134.     TYPE head
135.         chunk AS STRING * 4 '       4 bytes  (RIFF)
136.         size AS LONG '              4 bytes  (?E??)
137.         fomat AS STRING * 4 '       4 bytes  (WAVE)
138.         sub1 AS STRING * 4 '        4 bytes  (fmt )
139.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
140.         format AS STRING * 2 '      2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
141.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
142.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
143.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
144.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
145.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
146.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
147.     END TYPE '                     40 bytes  total
148.     DIM H AS head
149.     ch = FREEFILE
150.  
151.     IF _FILEEXISTS(file$) THEN OPEN file$ FOR BINARY AS #ch ELSE PRINT file$; " not found": SLEEP 2: SYSTEM
152.     GET #ch, , H
153.  
154.     block = H.Block
155.     RATE = H.rate
156.     chan = H.channels
157.     bits = H.Bits
158.  
159.     SEEK #ch, Find_data_area(file$)
160.  
161.     OTP_Size = UBOUND(otp)
162.     OTP(OTP_Size).Offset_Start = UBOUND(outputsound) + 1
163.  
164.     DO WHILE NOT EOF(ch)
165.         IF bits = 16 AND chan = 2 THEN
166.             REDIM lefi AS INTEGER, righi AS INTEGER
167.             GET #ch, , lefi
168.             GET #ch, , righi
169.             lef = lefi / 65535
170.             righ = righi / 65535
171.         END IF
172.  
173.         IF RATE > 44100 THEN frekvence = RATE ELSE frekvence = 44100
174.  
175.         oss = UBOUND(OutputSound)
176.         REDIM _PRESERVE OutputSound(oss + (frekvence / RATE)) AS Snd
177.  
178.         FOR plll = 1 TO frekvence / RATE
179.             OutputSound(oss + plll).Left = lef
180.             OutputSound(oss + plll).Right = righ
181.         NEXT plll
182.  
183.         DO WHILE _SNDRAWLEN > 0: LOOP: REM comment this
184.     LOOP
185.  
186.     OTP(OTP_Size).Offset_End = UBOUND(outputsound)
187.     REDIM _PRESERVE OTP(OTP_Size + 1) AS OtpSndHelper
188.     CLOSE ch
189.     WAVtoRAW = OTP_Size
190. END FUNCTION
191.  
192. FUNCTION Find_data_area (handle$)
193.     REDIM D AS STRING * 1024
194.     ff = FREEFILE
195.     OPEN handle$ FOR BINARY AS #ff
196.     GET #ff, 1, D$
197.     CLOSE #ff
198.     Find_data_area = INSTR(1, D$, "data") + 8
199. END FUNCTION
200.  
201. SUB RAWCOPY (handle, arr() AS Snd, position AS LONG, Volume AS SINGLE)
202.     SoundLenghtInBytes = OTP(handle).Offset_End - OTP(handle).Offset_Start
203.     IF UBOUND(arr) < UBOUND(arr) + SoundLenghtInBytes THEN REDIM _PRESERVE arr(UBOUND(arr) + SoundLenghtInBytes) AS Snd
204.     DIM rc AS LONG, OTPS AS LONG
205.     OTPS = OTP(handle).Offset_Start
206.     FOR rc = position TO position + SoundLenghtInBytes
207.  
208.         IF arr(rc).Left THEN OutLeft = (arr(rc).Left + (OutputSound(OTPS).Left) * Volume) / 1 ELSE OutLeft = OutputSound(OTPS).Left * Volume
209.         IF arr(rc).Right THEN OutRight = (arr(rc).Right + (OutputSound(OTPS).Right) * Volume) / 1 ELSE OutRight = OutputSound(OTPS).Right * Volume
210.  
211.         IF OutLeft > .75 THEN OutLeft = .9
212.         IF OutLeft < -.75 THEN OutLeft = -.9
213.  
214.         IF OutRight > .75 THEN OutRight = .9
215.         IF OutRight < -.75 THEN OutRight = -.9
216.  
217.         arr(rc).Left = OutLeft
218.         arr(rc).Right = OutRight
219.         OTPS = OTPS + 1
220.     NEXT rc
221. END SUB
222.  
223. SUB RealLenght (arr() AS Snd, time AS SINGLE)
224.     Size = time * _SNDRATE
225.     REDIM _PRESERVE arr(Size) AS Snd
226. END SUB
227.  
228. SUB SAVESOUND16S (arr() AS Snd, file AS STRING)
229.  
230.     TYPE head16
231.         chunk AS STRING * 4 '       4 bytes  (RIFF)
232.         size AS LONG '              4 bytes  (file size)
233.         fomat AS STRING * 4 '       4 bytes  (WAVE)
234.         sub1 AS STRING * 4 '        4 bytes  (fmt )
235.         subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
236.         format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
237.         channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
238.         rate AS LONG '              4 bytes  (sample rate, standard is 44100)
239.         ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
240.         Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
241.         Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
242.         subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
243.         lenght AS LONG '            4 bytes  Data block size
244.     END TYPE '                     44 bytes  total
245.     DIM H16 AS head16
246.     ch = FREEFILE
247.  
248.     H16.chunk = "RIFF"
249.     H16.size = 44 + UBOUND(arr) * 4 'two channels, it create 16 bit, stereo wav file, one sample use 2 bytes to one channel
250.  
251.     H16.fomat = "WAVE"
252.     H16.sub1 = "fmt "
253.     H16.subchunksize = 16
254.     H16.format = 1
255.     H16.channels = 2
256.     H16.rate = 44100
257.     H16.ByteRate = 44100 * 2 * 16 / 8
258.     H16.Block = 4
259.     H16.Bits = 16
260.     H16.subchunk2 = "data"
261.     H16.lenght = UBOUND(arr) * 4
262.     IF _FILEEXISTS(file$) THEN KILL file$
263.  
264.     OPEN file$ FOR BINARY AS #ch
265.     PUT #ch, , H16
266.     DIM LeftChannel AS INTEGER, RightChannel AS INTEGER
267.  
268.     FOR audiodata = 0 TO UBOUND(arr)
269.         LeftChannel = arr(audiodata).Left * 32768
270.         RightChannel = arr(audiodata).Right * 32768
271.  
272.         PUT #ch, , LeftChannel
273.         PUT #ch, , RightChannel
274.     NEXT
275.     CLOSE ch
276. END SUB
277.  

This is known music for Dav's drummachine testers:
 

drummachine.wav

Is recorded sound in WAV file too fast or too slow? Go to row 84 in source code and try this: DelayTime = 1.25 * 60 / 4 / tempo

I sure appreciate your efforts helping my programs.

Thank you, it's training and preparation for my own music editor. For example. Have you considered the possibility of different TEMPO values for individual music tracks, or only in some parts? It's just the thing I'm thinking about.

[Dav]

Wow, great work, Petr!  What a great way to do it.  It sounds great - I'll play around with it and see IF there's anything I could add.  I think we could add a Export to WAV option in the drum machine with your tool.  Many Thanks!

About different TEMPO for individual tracks, I haven't considered it, but I'm open to it.  Right now I'm trying to come up with allowing set pattern lengths, and changing meters (1/2, 34,etc). 

I have a couple of other coding projects taking most of my attention at the moment (and working in the garden), but I will be continue improving the drum machine.  If I get a new job though (desperately  looking..) my coding projects will be slowing down.

You are a good coder.

- Dav

[Pete]

Petr certianly is a good coder, especially when, and I'm assuming, English is not his primary language. Actually, a lot of the regulars, who kept the faith with QBasic instead of bailing to FreeBasic, are good enough that if we ever all teamed up together, Bill gates would be working for us... as our Uber driver, of course.

Wow, now we have sight and sound. I'll have to link TheBOB to this thread, as he is quite the music lover.

Now step on it Gates, you dumbass bastard. I'm late for my Social Distancing class.

Pete

[Petr]

Hi Dav,

I'm not a musician, so my ask:

What do you mean by changing meters? Do you want to change the music sample length? Does this mean, for example, that the sound of a drum strike is slower or faster? This is also a solvable problem in QB64, just don't know if I understand it correctly. Or is it the speed at which the sound should be played?  If I know the problem, I can try to find a solution.

[Petr]

Pete: There in QB64 forum are many better programmers than I am.  But thanks :)