Burning ship explorer

[_vince]

left mouse, zoom in
right mouse, zoom out
mousewheel, zoom size
+, increase iterations
-, decrease iterations

(edit: added other variations commented out)

Code: QB64: [Select]

1. defint a-z
2.  
3. const sw = 640
4. const sh = 480
5.  
6. dim shared mx,my,mbl,mbr,mw
7.  
8. dim u as double, v as double
9. dim uu as double, vv as double
10. dim xx as double, yy as double
11. dim x0 as double, y0 as double
12. dim z as double, zz as double
13. z = 0.01
14. zz = 0.1
15.  
16. dim p1 as long
17. p1 = _newimage(sw, sh, 12)
18. screen _newimage(sw, sh, 12)
19.  
20. redraw = -1
21. iter = 100
22.  
23. do
24.         mw = 0
25.         getMouse
26.  
27.         if redraw then
28.                 for y = 0 to sh-1
29.                 for x = 0 to sw-1
30.                         u = 0
31.                         v = 0
32.  
33.                         xx = (x - sw/2)*z + x0
34.                         yy = (y - sh/2)*z + y0
35.                         for i = 0 to iter
36.                                 '''mandelbrot
37.                                 'u = u
38.                                 'v = v
39.                                 'uu = u*u - v*v + xx
40.                                 'vv = 2*u*v + yy
41.                                 '''
42.  
43.                                 '''burning ship
44.                                 u = abs(u)
45.                                 v = abs(v)
46.                                 uu = u*u - v*v + xx
47.                                 vv = 2*u*v + yy
48.                                 '''
49.  
50.                                 '''tricorn
51.                                 'u = u
52.                                 'v = -v
53.                                 'uu = u*u - v*v + xx
54.                                 'vv = 2*u*v + yy
55.                                 '''
56.  
57.                                 '''tetration
58.                                 'u = u
59.                                 'v = v
60.                                 'cexp uu, vv, u, v, u, v
61.                                 'cexp uu, vv, uu, vv, xx, yy
62.                                 '''
63.  
64.                                 '''other, the possibilities are infinite
65.                                 'if u > v then
66.                                 '       u = -abs(u)
67.                                 '       v = v
68.                                 'elseif -1 then
69.                                 '       u = u
70.                                 '       v = -abs(v)
71.                                 'end if
72.                                 'uu = u*u - v*v + xx
73.                                 'vv = 2*u*v + yy
74.                                 '''
75.  
76.                                 u = uu
77.                                 v = vv
78.  
79.                                 if (u*u + v*v) > 4 then exit for
80.                         next
81.                         if i > iter then i = 0
82.                         pset(x, y), i
83.                 next
84.                 next
85.  
86.                 locate 1,1
87.                 print "iter =";iter
88.  
89.                 _dest p1
90.                 _putimage , 0
91.                 _dest 0
92.  
93.                 _putimage , p1
94.                 _display
95.  
96.                 redraw = 0
97.         end if
98.  
99.         if mw < 0 then
100.                 zz = zz + 0.01
101.         elseif mw > 0 then
102.                 if zz > 0.01 then zz = zz - 0.01
103.         end if
104.  
105.         'draw box
106.         if omx <> mx or omy <> my or mw <> 0 then
107.                 _putimage , p1
108.                 line (mx - (sw*zz/2), my - (sh*zz/2))-step(sw*zz,sh*zz),14,b
109.                 _display
110.  
111.                 omx = mx
112.                 omy = my
113.         end if
114.  
115.         if mbl then
116.                 do
117.                         getMouse
118.                 loop while mbl
119.  
120.                 x0 = x0 + (mx - sw/2)*z
121.                 y0 = y0 - (sh/2 - my)*z
122.                 z = z*zz
123.                 redraw = -1
124.         elseif mbr then
125.                 do
126.                         getMouse
127.                 loop while mbr
128.  
129.                 x0 = x0 + (mx - sw/2)*z
130.                 y0 = y0 - (sh/2 - my)*z
131.                 z = z/zz
132.                 redraw = -1
133.         end if
134.  
135.         k = _keyhit
136.         if k = 43 then
137.                 iter = iter + 50
138.                 redraw = -1
139.         elseif k = 45 then
140.                 if iter > 50 then iter = iter - 50
141.                 redraw = -1
142.         end if
143.  
144. loop until k = 27
145. system
146.  
147. sub getMouse ()
148.         do
149.                 mx = _mousex
150.                 my = _mousey
151.                 mbl = _mousebutton(1)
152.                 mbr = _mousebutton(2)
153.                 mw = mw + _mousewheel
154.         loop while _mouseinput
155. end sub
156.  
157. 'u + iv = (x + iy) ^ (a + ib)
158. sub cexp (u as double, v as double, x as double, y as double, a as double, b as double)
159.         dim mag as double, arg as double
160.         dim lnz as double, argz as double
161.  
162.         lnz = 0.5*log((x*x + y*y)+0.00001)
163.         argz = _atan2(y, x)
164.  
165.         mag = exp(a*lnz - b*argz)
166.         arg = a*argz + b*lnz
167.  
168.         u = mag * cos(arg)
169.         v = mag * sin(arg)
170. end sub
171.  

[bplus]

Nice, I've got some waves for your ship.

[STxAxTIC]

Beautiful. This deserves an entry at https://qb64.org/samples/. Let's hope that Odin gets around to it.

[Petr]

Very nice!

[FellippeHeitor]

I feel the time around me was going slower every time I zoomed in, and then suddenly I started hearing the initial chords of "Non je ne regrette rien" and decided to leave it.

Awesome job here, v.

[Ashish]

Wow! It's Awesome! :D

[SkyCharger001]

you only need to calculate the screen-center once

Code: QB64: [Select]

1. CONST sw=640
2. CONST sh=480
3. CONST zw=sw/2
4. CONST zh=sh/2
5.  

[_vince]

test