Smart Snake

[bplus]

This snake drives on auto-pilot:

Code: QB64: [Select]

1. _TITLE "Snake AI-1" 'b+ 2020-03-14
2. CONST sq = 20, sqs = 20, xmax = 400, ymax = 400
3. SCREEN _NEWIMAGE(xmax, ymax, 32)
4. _DELAY .25
5. _SCREENMOVE _MIDDLE
6. RANDOMIZE TIMER
7. DIM X(xmax + 100), Y(ymax + 100)
8. hx = 10: hy = 10: ax = 15: ay = 15: top = 0: X(top) = hx: Y(top) = hy 'initialize
9. DO
10.     _TITLE STR$(top + 1)
11.     LINE (0, 0)-(xmax, ymax), &HFF006600, BF 'clear garden
12.  
13.     '>>>>>>>>>>>       SNAKE BRAIN    <<<<<<<<<<<<<<<
14.     IF hx = 0 AND hy = 19 THEN
15.         hy = hy - 1
16.     ELSEIF hx MOD 2 = 0 AND hy <> 0 AND hy <> 19 THEN
17.         hy = hy - 1
18.     ELSEIF hx MOD 2 = 0 AND hy = 0 AND hy <> 19 THEN
19.         hx = hx + 1
20.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy < 18 THEN
21.         hy = hy + 1
22.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy = 18 THEN
23.         hx = hx + 1
24.     ELSEIF hx = 19 AND hy = 19 THEN
25.         hx = hx - 1
26.     ELSEIF hy = 19 AND hx <> 0 THEN
27.         hx = hx - 1
28.     ELSEIF hx MOD 2 = 1 AND hy = 0 AND hy <> 19 THEN
29.         hy = hy + 1
30.     ELSEIF hx = 19 AND hy < 19 THEN
31.         hy = hy + 1
32.     END IF
33.     FOR i = 0 TO top - 1
34.         X(i) = X(i + 1): Y(i) = Y(i + 1)
35.     NEXT
36.     X(top) = hx: Y(top) = hy
37.  
38.     'apple
39.     IF (ax = hx AND ay = hy) THEN 'snake eats apple, get new apple watch it's not where snake is
40.         top = top + 1
41.         X(top) = hx: Y(top) = hy
42.         DO 'check new apple
43.             ax = INT(RND * sqs): ay = INT(RND * sqs): good = -1
44.             FOR i = 0 TO top - 1
45.                 IF ax = X(i) AND ay = Y(i) THEN good = 0: EXIT FOR
46.             NEXT
47.         LOOP UNTIL good
48.     END IF
49.     LINE (ax * sq, ay * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
50.  
51.     'snake
52.     FOR i = 0 TO top
53.         IF i = top THEN
54.             c~& = &HFF000000
55.         ELSE
56.             SELECT CASE (top - i) MOD 4
57.                 CASE 0: c~& = &HFF000088
58.                 CASE 1: c~& = &HFF880000
59.                 CASE 2: c~& = &HFFBB8800
60.                 CASE 3: c~& = &HFF008888
61.             END SELECT
62.         END IF
63.         LINE (X(i) * sq, Y(i) * sq)-STEP(sq - 2, sq - 2), c~&, BF
64.     NEXT
65.     _DISPLAY
66.     _LIMIT 10
67. LOOP
68.  
69.  

It's smart because it will never crash into a wall, or itself and will (eventually) always get the fruit and grow to fill the garden BUT!
it's about the dumbest smart snake you could ask for.

Can anyone make it smarter? ie get to food faster without crashing into itself when it gets longer.

Oh also does anyone know why this runs to like 487 fruits eaten and not <= 400 that should fill garden with snake segments?

PS I mean theoretically this program should hang when there is no longer a place to put the fruit because the snake has filled the garden 400 squares by my calculations, so how is it going past that point before hanging?

[bplus]

Here is what I mean: at the end, it finally hangs at, in this case 473 fruits consumed.

Cool optical illusion too!

 

[bplus]

The mystery of the extra boxes is solved:

Code: QB64: [Select]

1. _TITLE "Snake AI-1_1" 'b+ 2020-03-16
2. '2020-03-14 Snake AI-1 first post
3. '2020-03-16  Snake AI-1.1 there must be overlap of the snake somewhere!
4. ' Found! :  White box in square is duplicate segment created
5. ' as eat fruit and deleted when reaches tail end.
6.  
7. CONST sq = 20, sqs = 20, xmax = 400, ymax = 400
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _DELAY .25
10. _SCREENMOVE _MIDDLE
11. RANDOMIZE TIMER
12. DIM X(xmax + 100), Y(ymax + 100), overlap(19, 19) AS INTEGER
13. hx = 10: hy = 10: ax = 15: ay = 15: top = 0: X(top) = hx: Y(top) = hy 'initialize
14. DO
15.     _TITLE STR$(top + 1)
16.     LINE (0, 0)-(xmax, ymax), &HFF006600, BF 'clear garden
17.  
18.     '>>>>>>>>>>>       SNAKE BRAIN    <<<<<<<<<<<<<<<
19.     IF hx = 0 AND hy = 19 THEN
20.         hy = hy - 1
21.     ELSEIF hx MOD 2 = 0 AND hy <> 0 AND hy <> 19 THEN
22.         hy = hy - 1
23.     ELSEIF hx MOD 2 = 0 AND hy = 0 AND hy <> 19 THEN
24.         hx = hx + 1
25.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy < 18 THEN
26.         hy = hy + 1
27.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy = 18 THEN
28.         hx = hx + 1
29.     ELSEIF hx = 19 AND hy = 19 THEN
30.         hx = hx - 1
31.     ELSEIF hy = 19 AND hx <> 0 THEN
32.         hx = hx - 1
33.     ELSEIF hx MOD 2 = 1 AND hy = 0 AND hy <> 19 THEN
34.         hy = hy + 1
35.     ELSEIF hx = 19 AND hy < 19 THEN
36.         hy = hy + 1
37.     END IF
38.     FOR i = 0 TO top - 1
39.         X(i) = X(i + 1): Y(i) = Y(i + 1)
40.     NEXT
41.     X(top) = hx: Y(top) = hy
42.     'apple
43.     IF (ax = hx AND ay = hy) THEN 'snake eats apple, get new apple watch it's not where snake is
44.         top = top + 1
45.         X(top) = hx: Y(top) = hy
46.         DO 'check new apple
47.             ax = INT(RND * sqs): ay = INT(RND * sqs): good = -1
48.             FOR i = 0 TO top - 1
49.                 IF ax = X(i) AND ay = Y(i) THEN good = 0: EXIT FOR
50.             NEXT
51.         LOOP UNTIL good
52.     END IF
53.     LINE (ax * sq, ay * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
54.  
55.     'snake
56.     ERASE overlap
57.     FOR i = 0 TO top
58.         IF i = top THEN
59.             c~& = &HFF000000
60.         ELSE
61.             SELECT CASE (top - i) MOD 4
62.                 CASE 0: c~& = &HFF000088
63.                 CASE 1: c~& = &HFF880000
64.                 CASE 2: c~& = &HFFBB8800
65.                 CASE 3: c~& = &HFF008888
66.             END SELECT
67.         END IF
68.         overlap(X(i), Y(i)) = overlap(X(i), Y(i)) + 1
69.         LINE (X(i) * sq, Y(i) * sq)-STEP(sq - 2, sq - 2), c~&, BF
70.         IF overlap(X(i), Y(i)) > 1 THEN LINE (X(i) * sq + .25 * sq, Y(i) * sq + .25 * sq)-STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
71.     NEXT
72.     _DISPLAY
73.     IF top < 300 THEN _LIMIT 400 ELSE _LIMIT 20
74. LOOP
75.  
76.  

 

Fascinating!

[bplus]

Fixed :

Code: QB64: [Select]

1. _TITLE "Snake AI-1_2" 'b+ 2020-03-17
2. '2020-03-14 Snake AI-1 first post
3. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
4. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
5. ' Now a new mystery, an occasional flashing duplicate box
6.  
7. CONST sq = 20, sqs = 20, xmax = 400, ymax = 400
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _DELAY .25
10. _SCREENMOVE _MIDDLE
11. RANDOMIZE TIMER
12. DIM X(xmax + 100), Y(ymax + 100), overlap(19, 19) AS INTEGER
13. hx = 10: hy = 10: ax = 15: ay = 15: top = 0: X(top) = hx: Y(top) = hy 'initialize
14. DO
15.     _TITLE STR$(top + 1)
16.     LINE (0, 0)-(xmax, ymax), &HFF006600, BF 'clear garden
17.  
18.     '>>>>>>>>>>>       SNAKE BRAIN    <<<<<<<<<<<<<<<
19.     IF hx = 0 AND hy = 19 THEN
20.         hy = hy - 1
21.     ELSEIF hx MOD 2 = 0 AND hy <> 0 AND hy <> 19 THEN
22.         hy = hy - 1
23.     ELSEIF hx MOD 2 = 0 AND hy = 0 AND hy <> 19 THEN
24.         hx = hx + 1
25.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy < 18 THEN
26.         hy = hy + 1
27.     ELSEIF hx MOD 2 = 1 AND hx <> 19 AND hy = 18 THEN
28.         hx = hx + 1
29.     ELSEIF hx = 19 AND hy = 19 THEN
30.         hx = hx - 1
31.     ELSEIF hy = 19 AND hx <> 0 THEN
32.         hx = hx - 1
33.     ELSEIF hx MOD 2 = 1 AND hy = 0 AND hy <> 19 THEN
34.         hy = hy + 1
35.     ELSEIF hx = 19 AND hy < 19 THEN
36.         hy = hy + 1
37.     END IF
38.     lastx = X(0): last(Y) = Y(0)
39.     FOR i = 0 TO top - 1
40.         X(i) = X(i + 1): Y(i) = Y(i + 1)
41.     NEXT
42.     X(top) = hx: Y(top) = hy
43.  
44.     'apple
45.     IF (ax = hx AND ay = hy) THEN 'snake eats apple, get new apple watch it's not where snake is
46.         top = top + 1
47.         FOR i = top TO 1 STEP -1
48.             X(i) = X(i - 1): Y(i) = Y(i - 1)
49.         NEXT
50.         X(0) = lastx: Y(0) = lasty
51.         'X(top) = hx: Y(top) = hy
52.         DO 'check new apple
53.             ax = INT(RND * sqs): ay = INT(RND * sqs): good = -1
54.             FOR i = 0 TO top
55.                 IF ax = X(i) AND ay = Y(i) THEN good = 0: EXIT FOR
56.             NEXT
57.             IF ax = lastx AND ay = lasty THEN good = 0
58.         LOOP UNTIL good
59.     END IF
60.  
61.     'snake
62.     ERASE overlap
63.     FOR i = 0 TO top
64.         IF i = top THEN
65.             c~& = &HFF000000
66.         ELSE
67.             SELECT CASE (top - i) MOD 4
68.                 CASE 0: c~& = &HFF000088
69.                 CASE 1: c~& = &HFF880000
70.                 CASE 2: c~& = &HFFBB8800
71.                 CASE 3: c~& = &HFF008888
72.             END SELECT
73.         END IF
74.         overlap(X(i), Y(i)) = overlap(X(i), Y(i)) + 1
75.         LINE (X(i) * sq, Y(i) * sq)-STEP(sq - 2, sq - 2), c~&, BF
76.         IF overlap(X(i), Y(i)) > 1 THEN LINE (X(i) * sq + .25 * sq, Y(i) * sq + .25 * sq)-STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
77.     NEXT
78.     LINE (ax * sq, ay * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
79.     _DISPLAY
80.     IF top < 330 THEN _LIMIT 400 ELSE _LIMIT 20
81. LOOP
82.  
83.  

 

Fixed except we have a new mystery, the occasional flashing duplicate box?

[bplus]

Reworked code and fixed all signs of duplicate segments, you can now toggle between human pilot and AI called Snake Brain, can also toggle pauses and speed or slow snake independently for human and AI. Now ready to plug-in different brains for snake, oh designer coloring too.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Snake AI-1_3 wRules" 'b+ 2020-03-17
3. '2020-03-14 Snake AI-1 first post
4. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
5. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
6. ' Now a new mystery, an ocassional flashing duplicate box
7. '2020-03-17 Install standard snake rules for testing brain evolving
8. ' First setup XY type and rename and convert variables using XY type.
9. ' 2nd Make snake brain and whole game only dependent sqrsX, sqrsY and sq for screen size
10. ' Got it!!! the code ends with hangup head next to fruit with 99 (1 cell less that whole board)
11. ' cells of snake length, no new place can be found for fruit, perfect finish and no duplicate cells! PLUS
12. ' now can turn on a dime go up one colume and down the next in 2 key press.
13. ' Now add autoPilot on -1 / off 0 toggle control, OK snake rules tested when human pilots snake.
14. ' Help screen & independent speeds for human or AI.
15.  
16. 'snakepit constraints   Snake Brain currently needs sqrsX to be even
17. CONST sq = 20, sqrsX = 20, sqrsY = 20, xmax = sq * sqrsX, ymax = sq * sqrsY
18. SCREEN _NEWIMAGE(800, 600, 32)
19. _DELAY .25
20. _SCREENMOVE _MIDDLE
21. RANDOMIZE TIMER
22.  
23. 'teach UDV
24. TYPE XY
25.     X AS INTEGER
26.     Y AS INTEGER
27. END TYPE
28.  
29. 'shared for screenUpdate
30. DIM SHARED fruit AS XY, snake(1 TO sqrsX * sqrsY) AS XY, sLen AS INTEGER '< sLen = length of snake
31. DIM SHARED overlap(sqrsX, sqrsY) AS INTEGER, pal(sqrsX * sqrsY) AS _UNSIGNED LONG, head AS XY
32. 'other data needed for program
33. DIM i AS INTEGER, good AS INTEGER, key$, r AS INTEGER, g AS INTEGER, b AS INTEGER
34. DIM autoPilot AS INTEGER, dx AS INTEGER, dy AS INTEGER, hSpeed, aSpeed
35.  
36. help
37. hSpeed = 3: aSpeed = 20
38. restart: 'reinitialize
39. r = .3 + RND * .7: g = r * .5 + RND * .3 - .15: b = .5 * r + RND * .3 - .15
40. FOR i = 1 TO sqrsX * sqrsY
41.     pal(i) = _RGB32(84 + 64 * SIN(r + i / 2), 84 + 64 * SIN(g + i / 2), 104 * SIN(b + i / 2))
42. NEXT
43. head.X = sqrsX / 2 - 2: head.Y = sqrsY / 2 - 2
44. fruit.X = sqrsX / 2 + 2: fruit.Y = sqrsY / 2 + 2
45. sLen = 1
46. snake(sLen).X = head.X: snake(sLen).Y = head.Y
47. autoPilot = 1
48. dx = 0: dy = 1
49. DO
50.     _TITLE STR$(sLen)
51.     LINE (0, 0)-(xmax, ymax), &HFF884422, BF 'clear snakepit
52.     IF sLen = sqrsX * sqrsY - 1 THEN screenUpdate: EXIT DO
53.     key$ = INKEY$
54.     IF key$ = "q" OR key$ = CHR$(27) THEN '                                           here is quit
55.         END '
56.     ELSEIF key$ = "a" THEN '                                                      toggle autoPilot
57.         autoPilot = 1 - autoPilot
58.         IF autoPilot = 0 THEN 'try to handover to human without immdeiate body crash
59.             dx = 0: IF head.X MOD 2 THEN dy = 1 ELSE dy = -1
60.         END IF
61.     ELSEIF key$ = "p" THEN '                                                                 pause
62.         _KEYCLEAR
63.         WHILE INKEY$ <> "p": _LIMIT 60: WEND
64.     ELSEIF key$ = "s" THEN
65.         IF autoPilot AND aSpeed + 5 < 400 THEN aSpeed = aSpeed + 5
66.         IF autoPilot = 0 AND hSpeed + .5 < 10 THEN hSpeed = hSpeed + .5
67.     ELSEIF key$ = "-" THEN
68.         IF autoPilot AND aSpeed - 5 > 0 THEN aSpeed = aSpeed - 5
69.         IF autoPilot = 0 AND hSpeed - .5 > 1 THEN hSpeed = hSpeed - .5
70.     END IF '                                                                                      '
71.     IF autoPilot THEN '                                                 who is piloting the snake?
72.  
73.         ' PLUG-IN YOUR Snake Brain AI here
74.         '===========================================================================  AI Auto Pilot
75.         snakeBrain
76.         '=========================================================================================
77.  
78.     ELSE ' '=======================================================================  human control
79.         IF key$ = CHR$(0) + CHR$(72) THEN '                                               up arrow
80.             dx = 0: dy = -1
81.         ELSEIF key$ = CHR$(0) + CHR$(80) THEN '                                         down arrow
82.             dx = 0: dy = 1
83.         ELSEIF key$ = CHR$(0) + CHR$(77) THEN '                                        right arrow
84.             dx = 1: dy = 0
85.         ELSEIF key$ = CHR$(0) + CHR$(75) THEN '                                         left arrow
86.             dx = -1: dy = 0
87.         END IF
88.         head.X = head.X + dx: head.Y = head.Y + dy
89.     END IF
90.  
91.     '                                                                  check snake head with Rules:
92.     ' 1. Snakepit boundary check, snake hits wall, dies.
93.     IF head.X < 0 OR head.X > sqrsX - 1 OR head.Y < 0 OR head.Y > sqrsY - 1 THEN
94.         _TITLE _TRIM$(STR$(sLen)) + " Wall Crash": screenUpdate: EXIT DO
95.     END IF
96.  
97.     ' 2. Snake eats body part, dies. This should kill snake if turn its head back on itself.
98.     FOR i = 1 TO sLen 'start 1 up from tail segment about to be dropped
99.         IF head.X = snake(i).X AND head.Y = snake(i).Y THEN
100.             _TITLE _TRIM$(STR$(sLen)) + " Body Crash": screenUpdate: EXIT DO
101.         END IF
102.     NEXT
103.  
104.     ' 3. Eats Fruit and grows or just move every segment up 1 space.
105.     IF (fruit.X = head.X AND fruit.Y = head.Y) THEN '                              snake eats apple
106.         sLen = sLen + 1
107.         snake(sLen).X = head.X: snake(sLen).Y = head.Y ' assimilate fruit into head for new segment
108.         DO 'check new apple
109.             fruit.X = INT(RND * sqrsX): fruit.Y = INT(RND * sqrsY): good = -1
110.             FOR i = 1 TO sLen
111.                 IF fruit.X = snake(i).X AND fruit.Y = snake(i).Y THEN good = 0: EXIT FOR
112.             NEXT
113.         LOOP UNTIL good
114.     ELSE
115.         FOR i = 1 TO sLen '                                                     move the snake data
116.             snake(i).X = snake(i + 1).X: snake(i).Y = snake(i + 1).Y
117.         NEXT
118.         snake(sLen).X = head.X: snake(sLen).Y = head.Y
119.     END IF
120.  
121.     screenUpdate
122.  
123.     IF autoPilot THEN
124.         'IF sLen < 80 THEN _LIMIT 40 ELSE _LIMIT 10
125.         _LIMIT aSpeed
126.     ELSE
127.         _LIMIT hSpeed
128.     END IF
129. LOOP
130.  
131. _DELAY 3
132. GOTO restart:
133.  
134. SUB screenUpdate ' draw snake and fruit, overlap code debugger
135.     DIM c~&, i AS INTEGER
136.  
137.     ERASE overlap
138.     FOR i = 1 TO sLen
139.         IF i = sLen THEN c~& = &HFF000000 ELSE c~& = pal(sLen - i)
140.  
141.         'overlap helps debug duplicate square drawing which indicates a flawed code
142.         overlap(snake(i).X, snake(i).Y) = overlap(snake(i).X, snake(i).Y) + 1
143.  
144.         LINE (snake(i).X * sq, snake(i).Y * sq)-STEP(sq - 2, sq - 2), c~&, BF
145.         IF overlap(snake(i).X, snake(i).Y) > 1 THEN
146.             LINE (snake(i).X * sq + .25 * sq, snake(i).Y * sq + .25 * sq)_
147.             -STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
148.         END IF
149.     NEXT
150.     LINE (fruit.X * sq, fruit.Y * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
151.     _DISPLAY
152. END SUB
153.  
154. SUB snakeBrain '>>>>>>>>>>   B+  SNAKE BRAIN  needs sqrsX to be even number  <<<<<<<<<<<<<<<
155.     IF head.X = 0 AND head.Y = sqrsY - 1 THEN
156.         head.Y = head.Y - 1
157.     ELSEIF head.X MOD 2 = 0 AND head.Y <> 0 AND head.Y <> sqrsY - 1 THEN
158.         head.Y = head.Y - 1
159.     ELSEIF head.X MOD 2 = 0 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
160.         head.X = head.X + 1
161.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y = sqrsY - 2 THEN
162.         head.X = head.X + 1
163.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y < sqrsY - 1 THEN
164.         head.Y = head.Y + 1
165.     ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
166.         head.X = head.X - 1
167.     ELSEIF head.Y = sqrsY - 1 AND head.X <> 0 THEN
168.         head.X = head.X - 1
169.     ELSEIF head.X MOD 2 = 1 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
170.         head.Y = head.Y + 1
171.     ELSEIF head.X = sqrsX - 1 AND head.Y < sqrsY - 1 THEN
172.         head.Y = head.Y + 1
173.     END IF
174. END SUB
175.  
176. SUB help
177.     _PRINTSTRING (600, 20), "Keys:"
178.     _PRINTSTRING (600, 40), "p toggles pause on/off"
179.     _PRINTSTRING (600, 60), "a toggles autoPilot"
180.     _PRINTSTRING (600, 100), "arrows control snake"
181.     _PRINTSTRING (600, 80), "q or esc quits"
182.     _PRINTSTRING (600, 120), "s increases speed"
183.     _PRINTSTRING (600, 140), "- decreases speed"
184. END SUB
185.  

 

[Ashish]

Good work, bplus. I personally like the new color of snake. Color of the snake in previous post was irritating to me (IDK why :) ).

[bplus]

Thanks Ashish, yeah snake coloring more natural I think.

You know I was hoping to get a little challenge going, Who can build the best snake AI or driver to plug into the game?

Now I wonder if anyone (including myself) can build a driver that can load up on fruit faster and fill the board in fewer steps on average. Because the fruit is placed randomly there will be better and worse runs but all need to get all the fruit eaten without crashing into wall (simple with AI that knows borders) or crashing the snake into it's own body including turning the head 180 degrees back onto it's body. This gets harder as snake gets longer. For humans the hardest part is not turning snake back on itself, IMHO, but for AI getting the fruit without running into another part of the body afterwards is where brains are needed.

So the object is to fill the board with snake until all but one board cell is snake (that starts new game).

Your Snake AI is allowed to know these things:
1. The Boundaries of the snake pit (I no longer call it a garden).
    for x between 0 and sqrsX-1, for y between 0 and sqrsY - 1
    BTW sqrsX is cells across and sqrsY is cells down.
2. Where the fruit is, fruit(x, y)
3. The listing of it's length and body segments, snake(i).(x, y), snake length = sLen
4. Track it's direction, I call dx and dy, the change on the x-axis = dx and the change on y-axis = dy.
    These are always just -1, 0, 1 and if ABS(dx) = 1 then dy = 0 and vice versa.
    ?hmm... use STATIC your own dx, dy in the SnakeBrain SUB (my demo is going strictly by board locations at
     present).
5. Oh! Most important of all, know where it's head is at! head(x, y)
Snake input is all above as SHARED and AI output just says where the head goes next by altering that value in the AI.

Now I realize my tester has to handle the case when both head x, y are 0 (a full stop) or both have a value other than 0 (s.t. the head starts heading diagonally).

My goal here was to create an AI tester, not so much a game with a pretty snake that's just icing ;-))

Update: here is the checks on the head change after the AI changes it in the Snake Brain plug-in code. The code will reset head(x, y) back if there is a problem with the head(x, y) returned from snake brain.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Snake AI-1_4 fix tester" 'b+ 2020-03-18
3. '2020-03-14 Snake AI-1 first post
4. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
5. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
6. ' Now a new mystery, an ocassional flashing duplicate box
7. '2020-03-17 Install standard snake rules for testing brain evolving
8. ' First setup XY type and rename and convert variables using XY type.
9. ' 2nd Make snake brain and whole game only dependent sqrsX, sqrsY and sq for screen size
10. ' Got it!!! the code ends with hangup head next to fruit with 99 (1 cell less that whole board)
11. ' cells of snake length, no new place can be found for fruit, perfect finish and no duplicate
12. ' cells! PLUS now can turn on a dime go up one colume and down the next in 2 key press.
13. ' Now add autoPilot on -1 / off 0 toggle control, OK snake rules tested when human pilots snake.
14. ' Help screen & independent speeds for human or AI.
15.  
16. '2020-03-18  "Snake AI-1_4 fix tester" The AI tester needs to save Head(x, y) in case the AI
17. ' does not change the head(x, y) or tries to move it diagonally.
18.  
19. 'snakepit constraints   Snake Brain currently needs sqrsX to be even
20. CONST sq = 20, sqrsX = 20, sqrsY = 20, xmax = sq * sqrsX, ymax = sq * sqrsY
21. SCREEN _NEWIMAGE(800, 600, 32)
22. _DELAY .25
23. _SCREENMOVE _MIDDLE
24. RANDOMIZE TIMER
25.  
26. 'teach UDV
27. TYPE XY
28.     X AS INTEGER
29.     Y AS INTEGER
30. END TYPE
31.  
32. 'shared for screenUpdate
33. DIM SHARED fruit AS XY, snake(1 TO sqrsX * sqrsY) AS XY, sLen AS INTEGER '< sLen = length of snake
34. DIM SHARED overlap(sqrsX, sqrsY) AS INTEGER, pal(sqrsX * sqrsY) AS _UNSIGNED LONG, head AS XY
35. 'other data needed for program
36. DIM i AS INTEGER, good AS INTEGER, KEY$, r AS INTEGER, g AS INTEGER, b AS INTEGER
37. DIM autoPilot AS INTEGER, dx AS INTEGER, dy AS INTEGER, hSpeed, aSpeed
38. DIM saveHead AS XY
39.  
40. help
41. hSpeed = 3: aSpeed = 20
42.  
43. restart: 'reinitialize
44. r = .3 + RND * .7: g = r * .5 + RND * .3 - .15: b = .5 * r + RND * .3 - .15
45. FOR i = 1 TO sqrsX * sqrsY
46.     pal(i) = _RGB32(84 + 64 * SIN(r + i / 2), 84 + 64 * SIN(g + i / 2), 104 * SIN(b + i / 2))
47. NEXT
48. head.X = sqrsX / 2 - 2: head.Y = sqrsY / 2 - 2
49. fruit.X = sqrsX / 2 + 2: fruit.Y = sqrsY / 2 + 2
50. sLen = 1
51. snake(sLen).X = head.X: snake(sLen).Y = head.Y
52. autoPilot = 1
53. dx = 0: dy = 1
54. DO
55.     _TITLE STR$(sLen)
56.     LINE (0, 0)-(xmax, ymax), &HFF884422, BF 'clear snakepit
57.     IF sLen = sqrsX * sqrsY - 1 THEN screenUpdate: EXIT DO
58.     KEY$ = INKEY$
59.     IF KEY$ = "q" OR KEY$ = CHR$(27) THEN '                                           here is quit
60.         END '
61.     ELSEIF KEY$ = "a" THEN '                                                      toggle autoPilot
62.         autoPilot = 1 - autoPilot
63.         IF autoPilot = 0 THEN 'try to handover to human without immdeiate body crash
64.             dx = 0: IF head.X MOD 2 THEN dy = 1 ELSE dy = -1
65.         END IF
66.     ELSEIF KEY$ = "p" THEN '                                                                 pause
67.         _KEYCLEAR
68.         WHILE INKEY$ <> "p": _LIMIT 60: WEND
69.     ELSEIF KEY$ = "s" THEN
70.         IF autoPilot AND aSpeed + 5 < 400 THEN aSpeed = aSpeed + 5
71.         IF autoPilot = 0 AND hSpeed + .5 < 10 THEN hSpeed = hSpeed + .5
72.     ELSEIF KEY$ = "-" THEN
73.         IF autoPilot AND aSpeed - 5 > 0 THEN aSpeed = aSpeed - 5
74.         IF autoPilot = 0 AND hSpeed - .5 > 1 THEN hSpeed = hSpeed - .5
75.     END IF '                                                                                      '
76.     IF autoPilot THEN '                                                 who is piloting the snake?
77.  
78.         saveHead.X = head.X: saveHead.Y = head.Y
79.         tryAgain:
80.         head.X = saveHead.X: head.Y = saveHead.Y
81.         ' PLUG-IN YOUR Snake Brain AI here
82.         '===========================================================================  AI Auto Pilot
83.         snakeBrain
84.         '=========================================================================================
85.  
86.         'check changes to head (x, y)
87.         IF ABS(saveHead.X - head.X) = 0 THEN 'must have diffence in y's
88.             IF ABS(saveHead.Y - head.Y) <> 1 THEN GOTO tryAgain
89.         ELSEIF ABS(saveHead.Y - head.Y) = 0 THEN
90.             IF ABS(saveHead.X - head.X) <> 1 THEN GOTO tryAgain
91.         ELSE ' must have a difference of 0 in either x or y but not both
92.             GOTO tryAgain
93.         END IF
94.  
95.     ELSE ' '=======================================================================  human control
96.         IF KEY$ = CHR$(0) + CHR$(72) THEN '                                               up arrow
97.             dx = 0: dy = -1
98.         ELSEIF KEY$ = CHR$(0) + CHR$(80) THEN '                                         down arrow
99.             dx = 0: dy = 1
100.         ELSEIF KEY$ = CHR$(0) + CHR$(77) THEN '                                        right arrow
101.             dx = 1: dy = 0
102.         ELSEIF KEY$ = CHR$(0) + CHR$(75) THEN '                                         left arrow
103.             dx = -1: dy = 0
104.         END IF
105.         head.X = head.X + dx: head.Y = head.Y + dy
106.     END IF
107.  
108.     '                                                                  check snake head with Rules:
109.     ' 1. Snakepit boundary check, snake hits wall, dies.
110.     IF head.X < 0 OR head.X > sqrsX - 1 OR head.Y < 0 OR head.Y > sqrsY - 1 THEN
111.         _TITLE _TRIM$(STR$(sLen)) + " Wall Crash": screenUpdate: EXIT DO
112.     END IF
113.  
114.     ' 2. Snake eats body part, dies. This should kill snake if turn its head back on itself.
115.     FOR i = 1 TO sLen 'start 1 up from tail segment about to be dropped
116.         IF head.X = snake(i).X AND head.Y = snake(i).Y THEN
117.             _TITLE _TRIM$(STR$(sLen)) + " Body Crash": screenUpdate: EXIT DO
118.         END IF
119.     NEXT
120.  
121.     ' 3. Eats Fruit and grows or just move every segment up 1 space.
122.     IF (fruit.X = head.X AND fruit.Y = head.Y) THEN '                              snake eats apple
123.         sLen = sLen + 1
124.         snake(sLen).X = head.X: snake(sLen).Y = head.Y ' assimilate fruit into head for new segment
125.         DO 'check new apple
126.             fruit.X = INT(RND * sqrsX): fruit.Y = INT(RND * sqrsY): good = -1
127.             FOR i = 1 TO sLen
128.                 IF fruit.X = snake(i).X AND fruit.Y = snake(i).Y THEN good = 0: EXIT FOR
129.             NEXT
130.         LOOP UNTIL good
131.     ELSE
132.         FOR i = 1 TO sLen '                                                     move the snake data
133.             snake(i).X = snake(i + 1).X: snake(i).Y = snake(i + 1).Y
134.         NEXT
135.         snake(sLen).X = head.X: snake(sLen).Y = head.Y
136.     END IF
137.  
138.     screenUpdate
139.  
140.     IF autoPilot THEN
141.         'IF sLen < 80 THEN _LIMIT 40 ELSE _LIMIT 10
142.         _LIMIT aSpeed
143.     ELSE
144.         _LIMIT hSpeed
145.     END IF
146. LOOP
147.  
148. _DELAY 3
149. GOTO restart:
150.  
151. SUB screenUpdate ' draw snake and fruit, overlap code debugger
152.     DIM c~&, i AS INTEGER
153.  
154.     ERASE overlap
155.     FOR i = 1 TO sLen
156.         IF i = sLen THEN c~& = &HFF000000 ELSE c~& = pal(sLen - i)
157.  
158.         'overlap helps debug duplicate square drawing which indicates a flawed code
159.         overlap(snake(i).X, snake(i).Y) = overlap(snake(i).X, snake(i).Y) + 1
160.  
161.         LINE (snake(i).X * sq, snake(i).Y * sq)-STEP(sq - 2, sq - 2), c~&, BF
162.         IF overlap(snake(i).X, snake(i).Y) > 1 THEN
163.             LINE (snake(i).X * sq + .25 * sq, snake(i).Y * sq + .25 * sq)_
164.             -STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
165.         END IF
166.     NEXT
167.     LINE (fruit.X * sq, fruit.Y * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
168.     _DISPLAY
169. END SUB
170.  
171. SUB snakeBrain '>>>>>>>>>>   B+  SNAKE BRAIN  needs sqrsX to be even number  <<<<<<<<<<<<<<<
172.     IF head.X = 0 AND head.Y = sqrsY - 1 THEN
173.         head.Y = head.Y - 1
174.     ELSEIF head.X MOD 2 = 0 AND head.Y <> 0 AND head.Y <> sqrsY - 1 THEN
175.         head.Y = head.Y - 1
176.     ELSEIF head.X MOD 2 = 0 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
177.         head.X = head.X + 1
178.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y = sqrsY - 2 THEN
179.         head.X = head.X + 1
180.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y < sqrsY - 1 THEN
181.         head.Y = head.Y + 1
182.     ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
183.         head.X = head.X - 1
184.     ELSEIF head.Y = sqrsY - 1 AND head.X <> 0 THEN
185.         head.X = head.X - 1
186.     ELSEIF head.X MOD 2 = 1 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
187.         head.Y = head.Y + 1
188.     ELSEIF head.X = sqrsX - 1 AND head.Y < sqrsY - 1 THEN
189.         head.Y = head.Y + 1
190.     END IF
191. END SUB
192.  
193. SUB help
194.     _PRINTSTRING (600, 20), "Keys:"
195.     _PRINTSTRING (600, 40), "p toggles pause on/off"
196.     _PRINTSTRING (600, 60), "a toggles autoPilot"
197.     _PRINTSTRING (600, 100), "arrows control snake"
198.     _PRINTSTRING (600, 80), "q or esc quits"
199.     _PRINTSTRING (600, 120), "s increases speed"
200.     _PRINTSTRING (600, 140), "- decreases speed"
201. END SUB
202.  
203.  

Update: the more I think about it, the more the Snake Brain needs access to or shared dx and dy. So I have to change the tester again to save those too before call to SnakeBrain plug-in driver... after lunch and errands, I will update again, sorry.

Update 2 (1 hour later): and the more I think about it the AI is likely to return the same change to head over and over and we get stuck in a loop so we might have to end with error message.

[bplus]

Got it! If there is an error in AI the control of snake is turned over to human with a beep to signal the switch.

I switched dx, dy to change AS XY (type) and now like the human control, the AI only changes the change.X, change.Y values, then the code takes over to update the head and check the rules for crashes, eats or just plain moves.

I had to rewrite the SnakeBrain SUB with these changes and cause an immediate exit if sqrsX (number of square on x-axis) is odd because at present it depends on an even amount of columns. It throws an error and made for excellent way to check the change checker part of the code. Did some more formal commenting of all the code and maybe now it is should be ready to try some brain transplants.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Snake AI-1_5 SHARE change AS XY" 'b+ 2020-03-18
3. '2020-03-14 Snake AI-1 first post
4. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
5. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
6. ' Now a new mystery, an ocassional flashing duplicate box
7. '2020-03-17 Install standard snake rules for testing brain evolving
8. ' First setup XY type and rename and convert variables using XY type.
9. ' 2nd Make snake brain and whole game only dependent sqrsX, sqrsY and sq for screen size
10. ' Got it!!! the code ends with hangup head next to fruit with 99 (1 cell less that whole board)
11. ' cells of snake length, no new place can be found for fruit, perfect finish and no duplicate
12. ' cells! PLUS now can turn on a dime go up one colume and down the next in 2 key press.
13. ' Now add autoPilot on -1 / off 0 toggle control, OK snake rules tested when human pilots snake.
14. ' Help screen & independent speeds for human or AI.
15. '2020-03-18  "Snake AI-1_4 fix tester" The AI tester needs to save Head(x, y) in case the AI
16. ' does not change the head(x, y) or tries to move it diagonally.
17.  
18. '2020-03-18 Snake AI-1_5 SHARE change AS XY
19. ' DIM SHARE change AS XY or change.x, change.y replaces variables called dx, dy.
20. ' I decided to switch over to human control if AI fails to return a proper change.
21. ' AI must leave change.x, change.y ready for human to take over control which means my changing
22. ' the code for toggling the autopilot and adding change.x, change.y updates in my snakeBrain SUB.
23. ' Rewrite SnakeBrain using only change.X and change.Y now. A BEEP will indicate an AI error and
24. ' signal control returned to human. This noted in Key Help part of screen.
25.  
26. '  Snakepit Dimensions: square size = sq, sqrsX = # of squares along x-axis and sqrsY squares down.
27. CONST sq = 20, sqrsX = 20, sqrsY = 20, xmax = sq * sqrsX, ymax = sq * sqrsY
28. SCREEN _NEWIMAGE(800, 600, 32)
29. _DELAY .25
30. _SCREENMOVE _MIDDLE
31. RANDOMIZE TIMER
32.  
33. ' Usually used to give a point on 2D board a single name that has an X dimension and a Y dimension.
34. TYPE XY
35.     X AS INTEGER
36.     Y AS INTEGER
37. END TYPE
38.  
39. '   SHARED variables for any version of SnakeBrain SUB to act as autoPilot for snake snake.
40. DIM SHARED change AS XY '                            directs the head direction through AI or Human
41. DIM SHARED head AS XY '                           leads the way of the snake(body) through snakepit
42. DIM SHARED sLen AS INTEGER '                                                        length of snake
43. DIM SHARED snake(1 TO sqrsX * sqrsY) AS XY '                   whole snake, head is at index = sLen
44. DIM SHARED fruit AS XY '     as snake eats fruit it grows, object is to grow snake to fill snakepit
45.  
46. '   SHARED for screenUpdate
47. DIM SHARED pal(sqrsX * sqrsY) AS _UNSIGNED LONG '                                  for snake colors
48.  
49. 'other data needed for program
50. DIM i AS INTEGER, good AS INTEGER, KEY$, r AS INTEGER, g AS INTEGER, b AS INTEGER
51. DIM autoPilot AS INTEGER, hSpeed, aSpeed, saveChange AS XY
52.  
53. help '                                                                                     Key Menu
54. hSpeed = 3: aSpeed = 20 '                     autopilot speed is independent of human control speed
55.  
56. restart: '                                                                             reinitialize
57. r = .3 + RND * .7: g = r * .5 + RND * .3 - .15: b = .5 * r + RND * .3 - .15 '    rnd pal color vars
58. FOR i = 1 TO sqrsX * sqrsY '                               enough colors for snake to fill snakepit
59.     pal(i) = _RGB32(84 + 64 * SIN(r + i / 2), 84 + 64 * SIN(g + i / 2), 104 * SIN(b + i / 2))
60. NEXT
61. head.X = sqrsX / 2 - 3: head.Y = sqrsY / 2 - 3 '                                         head start
62. fruit.X = sqrsX / 2 + 2: fruit.Y = sqrsY / 2 + 2 '                                      first fruit
63. sLen = 1 '                                                           for starters snake is all head
64. snake(sLen).X = head.X: snake(sLen).Y = head.Y '                         head is always at sLen end
65. autoPilot = 1 '                                                              start snake body count
66. change.X = 0: change.Y = 1 '                      head snake down board, Y direction of first fruit
67. DO
68.     _TITLE STR$(sLen)
69.     LINE (0, 0)-(xmax, ymax), &HFF884422, BF '                                       clear snakepit
70.     IF sLen = sqrsX * sqrsY - 1 THEN screenUpdate: EXIT DO '             game is won! start another
71.     KEY$ = INKEY$
72.     IF KEY$ = "q" OR KEY$ = CHR$(27) THEN '                                            here is quit
73.         END '
74.     ELSEIF KEY$ = "a" THEN '                                                       toggle autoPilot
75.         autoPilot = 1 - autoPilot '   it is now up to AI to keep change updated for human take over
76.     ELSEIF KEY$ = "p" THEN '                               pause toggle p starts pause p ends pause
77.         _KEYCLEAR: WHILE INKEY$ <> "p": _LIMIT 60: WEND
78.     ELSEIF KEY$ = "s" THEN
79.         IF autoPilot AND aSpeed + 5 < 400 THEN aSpeed = aSpeed + 5 ' max autopilot speed is 400 !!!
80.         IF autoPilot = 0 AND hSpeed + .5 < 10 THEN hSpeed = hSpeed + .5 '     max human speed is 10
81.     ELSEIF KEY$ = "-" THEN
82.         IF autoPilot AND aSpeed - 5 > 0 THEN aSpeed = aSpeed - 5
83.         IF autoPilot = 0 AND hSpeed - .5 > 1 THEN hSpeed = hSpeed - .5
84.     END IF '                                                                                      '
85.  
86.     IF autoPilot THEN '                                                 who is piloting the snake?
87.  
88.         saveChange.X = change.X: saveChange.Y = change.Y '   if AI screws up then human takes over
89.  
90.         ' PLUG-IN YOUR Snake Brain AI here
91.         '=========================================================================== AI Auto Pilot
92.         snakeBrain
93.         '=========================================================================================
94.  
95.         'check changes
96.         IF ABS(change.X) = 0 THEN '                                      must have diffence in y's
97.             IF ABS(change.Y) <> 1 THEN autoPilot = 0 '                       error switch to human
98.         ELSEIF ABS(change.Y) = 0 THEN
99.             IF ABS(change.X) <> 1 THEN autoPilot = 0 '                       error switch to human
100.         ELSE '                           must have a 0 in either change.x or change.y but not both
101.             autoPilot = 0 '                                                  error switch to human
102.         END IF
103.         IF autoPilot = 0 THEN '              switching control over to human restore change values
104.             change.X = saveChange.X: change.Y = saveChange.Y: BEEP '                   alert human
105.         END IF
106.  
107.     ELSE '  =======================================================================  human control
108.         IF KEY$ = CHR$(0) + CHR$(72) THEN '                                               up arrow
109.             change.X = 0: change.Y = -1
110.         ELSEIF KEY$ = CHR$(0) + CHR$(80) THEN '                                         down arrow
111.             change.X = 0: change.Y = 1
112.         ELSEIF KEY$ = CHR$(0) + CHR$(77) THEN '                                        right arrow
113.             change.X = 1: change.Y = 0
114.         ELSEIF KEY$ = CHR$(0) + CHR$(75) THEN '                                         left arrow
115.             change.X = -1: change.Y = 0
116.         END IF
117.  
118.     END IF
119.     head.X = head.X + change.X: head.Y = head.Y + change.Y '            OK human or AI have spoken
120.  
121.     '   ============================  check snake head with Rules: ===============================
122.  
123.     ' 1. Snakepit boundary check, snake hits wall, dies.
124.     IF head.X < 0 OR head.X > sqrsX - 1 OR head.Y < 0 OR head.Y > sqrsY - 1 THEN
125.         _TITLE _TRIM$(STR$(sLen)) + " Wall Crash": screenUpdate: EXIT DO
126.     END IF
127.  
128.     ' 2. Snake eats body part, dies. This should kill snake if turn its head back on itself.
129.     FOR i = 1 TO sLen '                                              did head just crash into body?
130.         IF head.X = snake(i).X AND head.Y = snake(i).Y THEN
131.             _TITLE _TRIM$(STR$(sLen)) + " Body Crash": screenUpdate: EXIT DO '                 yes!
132.         END IF
133.     NEXT '                                                                                       no
134.  
135.     ' 3. Eats Fruit and grows or just move every segment up 1 space.
136.     IF (fruit.X = head.X AND fruit.Y = head.Y) THEN '                              snake eats fruit
137.         sLen = sLen + 1
138.         snake(sLen).X = head.X: snake(sLen).Y = head.Y ' assimilate fruit into head for new segment
139.         DO 'check new apple
140.             fruit.X = INT(RND * sqrsX): fruit.Y = INT(RND * sqrsY): good = -1
141.             FOR i = 1 TO sLen
142.                 IF fruit.X = snake(i).X AND fruit.Y = snake(i).Y THEN good = 0: EXIT FOR
143.             NEXT
144.         LOOP UNTIL good
145.     ELSE
146.         FOR i = 1 TO sLen '                            move the snake data down 1 dropping off last
147.             snake(i).X = snake(i + 1).X: snake(i).Y = snake(i + 1).Y
148.         NEXT
149.         snake(sLen).X = head.X: snake(sLen).Y = head.Y '               and adding new head position
150.     END IF
151.  
152.     screenUpdate '                                                     on with the show this is it!
153.     IF autoPilot THEN _LIMIT aSpeed ELSE _LIMIT hSpeed ' independent speed control for human and AI
154. LOOP
155. _DELAY 3 '                                                                   win or loose, go again
156. GOTO restart:
157.  
158. SUB screenUpdate ' draw snake and fruit, overlap code debugger
159.     DIM c~&, i AS INTEGER, overlap(sqrsX, sqrsY) AS INTEGER
160.     FOR i = 1 TO sLen
161.         IF i = sLen THEN c~& = &HFF000000 ELSE c~& = pal(sLen - i)
162.  
163.         '                overlap helps debug duplicate square drawing which indicates a flawed code
164.         overlap(snake(i).X, snake(i).Y) = overlap(snake(i).X, snake(i).Y) + 1
165.  
166.         LINE (snake(i).X * sq, snake(i).Y * sq)-STEP(sq - 2, sq - 2), c~&, BF
167.         IF overlap(snake(i).X, snake(i).Y) > 1 THEN ' show visually where code flaws effect display
168.             LINE (snake(i).X * sq + .25 * sq, snake(i).Y * sq + .25 * sq)_
169.             -STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
170.         END IF
171.     NEXT
172.     LINE (fruit.X * sq, fruit.Y * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
173.     _DISPLAY
174. END SUB
175.  
176. SUB snakeBrain '>>>>>>>>>>   B+  SNAKE BRAIN  needs sqrsX to be even number  <<<<<<<<<<<<<<<
177.  
178.     IF sqrsX MOD 2 = 1 THEN change.X = 0: change.Y = 0: EXIT SUB 'throw error for code check to
179.     '                                                      discover and switch to human control
180.  
181.     IF head.X = 0 AND head.Y = sqrsY - 1 THEN
182.         change.X = 0: change.Y = -1
183.     ELSEIF head.X MOD 2 = 0 AND head.Y <> 0 AND head.Y <> sqrsY - 1 THEN
184.         change.X = 0: change.Y = -1
185.     ELSEIF head.X MOD 2 = 0 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
186.         change.X = 1: change.Y = 0
187.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y = sqrsY - 2 THEN
188.         change.X = 1: change.Y = 0
189.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y < sqrsY - 1 THEN
190.         change.X = 0: change.Y = 1
191.     ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
192.         change.X = -1: change.Y = 0
193.     ELSEIF head.Y = sqrsY - 1 AND head.X <> 0 THEN
194.         change.X = -1: change.Y = 0
195.     ELSEIF head.X MOD 2 = 1 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
196.         change.X = 0: change.Y = 1
197.     ELSEIF head.X = sqrsX - 1 AND head.Y < sqrsY - 1 THEN
198.         change.X = 0: change.Y = 1
199.     END IF
200. END SUB
201.  
202. SUB help
203.     _PRINTSTRING (610, 20), "Keys:"
204.     _PRINTSTRING (610, 40), "p toggles pause on/off"
205.     _PRINTSTRING (610, 60), "a toggles autoPilot"
206.     _PRINTSTRING (610, 100), "arrows control snake"
207.     _PRINTSTRING (610, 80), "q or esc quits"
208.     _PRINTSTRING (610, 120), "s increases speed"
209.     _PRINTSTRING (610, 140), "- decreases speed"
210.     _PRINTSTRING (610, 200), "A BEEP means AI error,"
211.     _PRINTSTRING (610, 216), "human put in control."
212. END SUB
213.  
214.  

Too bad I can't have 2 best Answers but the information provided in reply above is going to start a manual.

[Ashish]

@bplus
I attepmt to create my AI for the snake. Well, it does not fill the whole tile for now but it does grow faster than yours.
The best score which I saw it making was 49 on my system. I know it can do even better if I give more time to it.
The code of AI is crazy. It is fun to see how it makes its decision. Sometime, it just get stuck in an infinite loop and snake start
to follow a circular path.

Code: QB64: [Select]

1. 'Ashish MOD
2. 'Sorry bplus, but modified your a code a little. ;)
3. OPTION _EXPLICIT
4.  
5. $CONSOLE
6. 'debuging, if there is AI error, then prints the change value along with state of AI SUB
7. DIM SHARED state$ 'for debuging
8.  
9. _TITLE "Snake AI-1_5 SHARE change AS XY" 'b+ 2020-03-18
10. '2020-03-14 Snake AI-1 first post
11. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
12. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
13. ' Now a new mystery, an ocassional flashing duplicate box
14. '2020-03-17 Install standard snake rules for testing brain evolving
15. ' First setup XY type and rename and convert variables using XY type.
16. ' 2nd Make snake brain and whole game only dependent sqrsX, sqrsY and sq for screen size
17. ' Got it!!! the code ends with hangup head next to fruit with 99 (1 cell less that whole board)
18. ' cells of snake length, no new place can be found for fruit, perfect finish and no duplicate
19. ' cells! PLUS now can turn on a dime go up one colume and down the next in 2 key press.
20. ' Now add autoPilot on -1 / off 0 toggle control, OK snake rules tested when human pilots snake.
21. ' Help screen & independent speeds for human or AI.
22. '2020-03-18  "Snake AI-1_4 fix tester" The AI tester needs to save Head(x, y) in case the AI
23. ' does not change the head(x, y) or tries to move it diagonally.
24.  
25. '2020-03-18 Snake AI-1_5 SHARE change AS XY
26. ' DIM SHARE change AS XY or change.x, change.y replaces variables called dx, dy.
27. ' I decided to switch over to human control if AI fails to return a proper change.
28. ' AI must leave change.x, change.y ready for human to take over control which means my changing
29. ' the code for toggling the autopilot and adding change.x, change.y updates in my snakeBrain SUB.
30. ' Rewrite SnakeBrain using only change.X and change.Y now. A BEEP will indicate an AI error and
31. ' signal control returned to human. This noted in Key Help part of screen.
32.  
33. '################ MOD by Ashish ######################
34. 'Added my own AI. It took 3 hours xD
35.  
36. '  Snakepit Dimensions: square size = sq, sqrsX = # of squares along x-axis and sqrsY squares down.
37. CONST sq = 20, sqrsX = 20, sqrsY = 20, xmax = sq * sqrsX, ymax = sq * sqrsY
38. SCREEN _NEWIMAGE(800, 600, 32)
39. _DELAY .25
40. _SCREENMOVE _MIDDLE
41. RANDOMIZE TIMER
42.  
43. ' Usually used to give a point on 2D board a single name that has an X dimension and a Y dimension.
44. TYPE XY
45.     X AS INTEGER
46.     Y AS INTEGER
47. END TYPE
48.  
49. '   SHARED variables for any version of SnakeBrain SUB to act as autoPilot for snake snake.
50. DIM SHARED change AS XY '                            directs the head direction through AI or Human
51. DIM SHARED head AS XY '                           leads the way of the snake(body) through snakepit
52. DIM SHARED sLen AS INTEGER '                                                        length of snake
53. DIM SHARED snake(1 TO sqrsX * sqrsY) AS XY '                   whole snake, head is at index = sLen
54. DIM SHARED fruit AS XY '     as snake eats fruit it grows, object is to grow snake to fill snakepit
55.  
56. '   SHARED for screenUpdate
57. DIM SHARED pal(sqrsX * sqrsY) AS _UNSIGNED LONG '                                  for snake colors
58. 'other data needed for program
59. DIM i AS INTEGER, good AS INTEGER, KEY$, r AS INTEGER, g AS INTEGER, b AS INTEGER
60. DIM autoPilot AS INTEGER, hSpeed, aSpeed, saveChange AS XY
61.  
62. help '                                                                                     Key Menu
63. hSpeed = 3: aSpeed = 20 '                     autopilot speed is independent of human control speed
64.  
65. restart: '                                                                             reinitialize
66. r = .3 + RND * .7: g = r * .5 + RND * .3 - .15: b = .5 * r + RND * .3 - .15 '    rnd pal color vars
67. FOR i = 1 TO sqrsX * sqrsY '                               enough colors for snake to fill snakepit
68.     pal(i) = _RGB32(84 + 64 * SIN(r + i / 2), 84 + 64 * SIN(g + i / 2), 104 * SIN(b + i / 2))
69. NEXT
70. head.X = sqrsX / 2 - 3: head.Y = sqrsY / 2 - 3 '                                         head start
71. fruit.X = sqrsX / 2 + 2: fruit.Y = sqrsY / 2 + 2 '                                      first fruit
72. sLen = 1 '                                                           for starters snake is all head
73. snake(sLen).X = head.X: snake(sLen).Y = head.Y '                         head is always at sLen end
74. autoPilot = 1 '                                                              start snake body count
75. change.X = 0: change.Y = 1 '                      head snake down board, Y direction of first fruit
76. DO
77.     _TITLE STR$(sLen)
78.     LINE (0, 0)-(xmax, ymax), &HFF884422, BF '                                       clear snakepit
79.     IF sLen = sqrsX * sqrsY - 1 THEN screenUpdate: EXIT DO '             game is won! start another
80.     KEY$ = INKEY$
81.     IF KEY$ = "q" OR KEY$ = CHR$(27) THEN '                                            here is quit
82.         END '
83.     ELSEIF KEY$ = "a" THEN '                                                       toggle autoPilot
84.         autoPilot = 1 - autoPilot '   it is now up to AI to keep change updated for human take over
85.     ELSEIF KEY$ = "p" THEN '                               pause toggle p starts pause p ends pause
86.         _KEYCLEAR: WHILE INKEY$ <> "p": _LIMIT 60: WEND
87.     ELSEIF KEY$ = "s" THEN
88.         IF autoPilot AND aSpeed + 5 < 400 THEN aSpeed = aSpeed + 5 ' max autopilot speed is 400 !!!
89.         IF autoPilot = 0 AND hSpeed + .5 < 10 THEN hSpeed = hSpeed + .5 '     max human speed is 10
90.     ELSEIF KEY$ = "-" THEN
91.         IF autoPilot AND aSpeed - 5 > 0 THEN aSpeed = aSpeed - 5
92.         IF autoPilot = 0 AND hSpeed - .5 > 1 THEN hSpeed = hSpeed - .5
93.     END IF '                                                                                      '
94.  
95.     IF autoPilot THEN '                                                 who is piloting the snake?
96.  
97.         saveChange.X = change.X: saveChange.Y = change.Y '   if AI screws up then human takes over
98.  
99.         ' PLUG-IN YOUR Snake Brain AI here
100.         '=========================================================================== AI Auto Pilot
101.         snakeBrain
102.         '=========================================================================================
103.  
104.         'check changes
105.         IF ABS(change.X) = 0 THEN '                                      must have diffence in y's
106.             IF ABS(change.Y) <> 1 THEN autoPilot = 0 '                       error switch to human
107.         ELSEIF ABS(change.Y) = 0 THEN
108.             IF ABS(change.X) <> 1 THEN autoPilot = 0 '                       error switch to human
109.         ELSE '                           must have a 0 in either change.x or change.y but not both
110.             autoPilot = 0 '                                                  error switch to human
111.         END IF
112.         'DEBUG
113.         IF autoPilot = 0 THEN
114.             _ECHO STR$(change.X) + "," + STR$(change.Y)
115.             _ECHO state$
116.             SLEEP
117.         END IF
118.         IF autoPilot = 0 THEN '              switching control over to human restore change values
119.             change.X = saveChange.X: change.Y = saveChange.Y: BEEP '                   alert human
120.         END IF
121.  
122.     ELSE '  =======================================================================  human control
123.         IF KEY$ = CHR$(0) + CHR$(72) THEN '                                               up arrow
124.             change.X = 0: change.Y = -1
125.         ELSEIF KEY$ = CHR$(0) + CHR$(80) THEN '                                         down arrow
126.             change.X = 0: change.Y = 1
127.         ELSEIF KEY$ = CHR$(0) + CHR$(77) THEN '                                        right arrow
128.             change.X = 1: change.Y = 0
129.         ELSEIF KEY$ = CHR$(0) + CHR$(75) THEN '                                         left arrow
130.             change.X = -1: change.Y = 0
131.         END IF
132.  
133.     END IF
134.     head.X = head.X + change.X: head.Y = head.Y + change.Y '            OK human or AI have spoken
135.  
136.     '   ============================  check snake head with Rules: ===============================
137.  
138.     ' 1. Snakepit boundary check, snake hits wall, dies.
139.     IF head.X < 0 OR head.X > sqrsX - 1 OR head.Y < 0 OR head.Y > sqrsY - 1 THEN
140.         _TITLE _TRIM$(STR$(sLen)) + " Wall Crash": screenUpdate: EXIT DO
141.     END IF
142.  
143.     ' 2. Snake eats body part, dies. This should kill snake if turn its head back on itself.
144.     FOR i = 1 TO sLen '                                              did head just crash into body?
145.         IF head.X = snake(i).X AND head.Y = snake(i).Y THEN
146.             _TITLE _TRIM$(STR$(sLen)) + " Body Crash": screenUpdate: EXIT DO '                 yes!
147.         END IF
148.     NEXT '                                                                                       no
149.  
150.     ' 3. Eats Fruit and grows or just move every segment up 1 space.
151.     IF (fruit.X = head.X AND fruit.Y = head.Y) THEN '                              snake eats fruit
152.         sLen = sLen + 1
153.         snake(sLen).X = head.X: snake(sLen).Y = head.Y ' assimilate fruit into head for new segment
154.         DO 'check new apple
155.             fruit.X = INT(RND * sqrsX): fruit.Y = INT(RND * sqrsY): good = -1
156.             FOR i = 1 TO sLen
157.                 IF fruit.X = snake(i).X AND fruit.Y = snake(i).Y THEN good = 0: EXIT FOR
158.             NEXT
159.         LOOP UNTIL good
160.     ELSE
161.         FOR i = 1 TO sLen '                            move the snake data down 1 dropping off last
162.             snake(i).X = snake(i + 1).X: snake(i).Y = snake(i + 1).Y
163.         NEXT
164.         snake(sLen).X = head.X: snake(sLen).Y = head.Y '               and adding new head position
165.     END IF
166.  
167.     screenUpdate '                                                     on with the show this is it!
168.     IF autoPilot THEN _LIMIT aSpeed ELSE _LIMIT hSpeed ' independent speed control for human and AI
169. LOOP
170. _DELAY 3 '                                                                   win or loose, go again
171. GOTO restart:
172.  
173. SUB screenUpdate ' draw snake and fruit, overlap code debugger
174.     DIM c~&, i AS INTEGER, overlap(sqrsX, sqrsY) AS INTEGER
175.     FOR i = 1 TO sLen
176.         IF i = sLen THEN c~& = &HFF000000 ELSE c~& = pal(sLen - i)
177.  
178.         '                overlap helps debug duplicate square drawing which indicates a flawed code
179.         overlap(snake(i).X, snake(i).Y) = overlap(snake(i).X, snake(i).Y) + 1
180.  
181.         LINE (snake(i).X * sq, snake(i).Y * sq)-STEP(sq - 2, sq - 2), c~&, BF
182.         IF overlap(snake(i).X, snake(i).Y) > 1 THEN ' show visually where code flaws effect display
183.             LINE (snake(i).X * sq + .25 * sq, snake(i).Y * sq + .25 * sq)_
184.             -STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
185.         END IF
186.     NEXT
187.     LINE (fruit.X * sq, fruit.Y * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
188.     _DISPLAY
189. END SUB
190.  
191. SUB snakeBrain '>>>>>>>>>>   B+  SNAKE BRAIN  needs sqrsX to be even number  <<<<<<<<<<<<<<<
192.  
193.     'IF sqrsX MOD 2 = 1 THEN change.X = 0: change.Y = 0: EXIT SUB 'throw error for code check to
194.     ''                                                      discover and switch to human control
195.  
196.     'IF head.X = 0 AND head.Y = sqrsY - 1 THEN
197.     '    change.X = 0: change.Y = -1
198.     'ELSEIF head.X MOD 2 = 0 AND head.Y <> 0 AND head.Y <> sqrsY - 1 THEN
199.     '    change.X = 0: change.Y = -1
200.     'ELSEIF head.X MOD 2 = 0 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
201.     '    change.X = 1: change.Y = 0
202.     'ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y = sqrsY - 2 THEN
203.     '    change.X = 1: change.Y = 0
204.     'ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y < sqrsY - 1 THEN
205.     '    change.X = 0: change.Y = 1
206.     'ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
207.     '    change.X = -1: change.Y = 0
208.     'ELSEIF head.Y = sqrsY - 1 AND head.X <> 0 THEN
209.     '    change.X = -1: change.Y = 0
210.     'ELSEIF head.X MOD 2 = 1 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
211.     '    change.X = 0: change.Y = 1
212.     'ELSEIF head.X = sqrsX - 1 AND head.Y < sqrsY - 1 THEN
213.     '    change.X = 0: change.Y = 1
214.     'END IF
215.     DIM nx, ny, dx, dy 'Ashish AI
216.     STATIC decided
217.     dx = fruit.X - head.X
218.     dy = fruit.Y - head.Y
219.     nx = snakeBodyExists(1)
220.     ny = snakeBodyExists(2)
221.     IF sLen > 1 THEN 'collison at corners of square
222.         IF head.X = 0 AND head.Y = 0 THEN
223.             state$ = "corners"
224.             IF change.X = -1 THEN change.X = 0: change.Y = 1: decided = 0: EXIT SUB
225.             IF change.Y = -1 THEN change.Y = 0: change.X = 1: decided = 0: EXIT SUB
226.         ELSEIF head.X = 0 AND head.Y = sqrsY - 1 THEN
227.             state$ = "corners"
228.             IF change.X = -1 THEN change.X = 0: change.Y = -1: decided = 0: EXIT SUB
229.             IF change.Y = 1 THEN change.Y = 0: change.X = 1: decided = 0: decided = 0: EXIT SUB
230.         ELSEIF head.X = sqrsX - 1 AND head.Y = 0 THEN
231.             state$ = "corners"
232.             IF change.X = 1 THEN change.X = 0: change.Y = 1: decided = 0: EXIT SUB
233.             IF change.Y = -1 THEN change.Y = 0: change.X = -1: decided = 0: EXIT SUB
234.         ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
235.             state$ = "corners"
236.             IF change.X = 1 THEN change.X = 0: change.Y = -1: decided = 0: EXIT SUB
237.             IF change.Y = 1 THEN change.Y = 0: change.X = -1: decided = 0: EXIT SUB
238.         END IF
239.         IF decided = 0 THEN 'collision with walls
240.             IF head.X = sqrsX - 1 OR head.X = 0 THEN
241.                 state$ = "walls"
242.                 IF ny = 0 THEN
243.                                         IF dy>0 THEN ny = -1 ELSE ny = 1
244.                                 END IF
245.                 change.Y = ny * -1: change.X = 0
246.                 decided = 1
247.                 EXIT SUB
248.             ELSEIF head.Y = sqrsY - 1 OR head.Y = 0 THEN
249.                 state$ = "walls"
250.                 IF nx = 0 THEN
251.                                         IF dx>0 THEN nx = -1 ELSE nx = 1
252.                                 END IF
253.                 change.X = nx * -1: change.Y = 0
254.                 decided = 1
255.                 EXIT SUB
256.             END IF
257.         END IF
258.     END IF
259.     IF dx = 0 THEN 'when fruit and head in same direction and motion in same axis
260.         IF change.Y = 0 THEN
261.             state$ = "linear"
262.             IF dy > 0 AND ny <> 1 THEN
263.                 change.Y = 1: change.X = 0: decided = 0: EXIT SUB
264.             ELSEIF dy < 0 AND ny <> -1 THEN
265.                 change.Y = -1: change.X = 0: decided = 0: EXIT SUB
266.             END IF
267.         END IF
268.     END IF
269.     IF dy = 0 THEN
270.         IF change.X = 0 THEN
271.             state$ = "linear"
272.             IF dx > 0 AND nx <> 1 THEN
273.                 change.X = 1: change.Y = 0: decided = 0: EXIT SUB
274.             ELSEIF dx < 0 AND nx <> -1 THEN
275.                 change.X = -1: change.Y = 0: decided = 0: EXIT SUB
276.             END IF
277.         END IF
278.     END IF
279.  
280.     state$ = "common"
281.     'common decision
282.     IF ABS(dx) < ABS(dy) THEN
283.         state$ = "common ny=" + STR$(ny)
284.         IF ny = 0 THEN
285.             change.X = 0
286.             IF dy > 0 THEN change.Y = 1 ELSE change.Y = -1
287.             state$ = "common cy=" + STR$(change.Y)
288.             EXIT SUB
289.         END IF
290.         IF dy > 0 AND ny <> 1 THEN change.Y = 1: change.X = 0
291.         IF dy < 0 AND ny <> -1 THEN change.Y = -1: change.X = 0
292.         decided = 0
293.     ELSE
294.  
295.         state$ = "common nx=" + STR$(nx)
296.         IF nx = 0 THEN
297.             change.Y = 0
298.             IF dx > 0 THEN change.X = 1 ELSE change.X = -1
299.             state$ = "common cx=" + STR$(change.X)
300.             EXIT SUB
301.         END IF
302.         IF dx > 0 AND nx <> 1 THEN change.X = 1: change.Y = 0
303.         IF dx < 0 AND nx <> -1 THEN change.X = -1: change.Y = 0
304.         decided = 0
305.     END IF
306.  
307.     state$ = "rand_common"
308.     IF ABS(dx) = ABS(dy) THEN 'random choice will be made then, rest code is same as above
309.         IF RND > 0.5 THEN
310.             state$ = "rand_common ny=" + STR$(ny)
311.             IF ny = 0 THEN
312.                 change.X = 0
313.                 IF dy > 0 THEN change.Y = 1 ELSE change.Y = -1
314.                 state$ = "rand_common cy=" + STR$(change.Y)
315.                 EXIT SUB
316.             END IF
317.             IF dy > 0 AND ny <> 1 THEN change.Y = 1: change.X = 0
318.             IF dy < 0 AND ny <> -1 THEN change.Y = -1: change.X = 0
319.             decided = 0
320.         ELSE
321.             state$ = "rand_common nx=" + STR$(nx)
322.             IF nx = 0 THEN
323.                 change.Y = 0
324.                 IF dx > 0 THEN change.X = 1 ELSE change.X = -1
325.                 state$ = "rand_common cx=" + STR$(change.X)
326.                 EXIT SUB
327.             END IF
328.             IF dx > 0 AND nx <> 1 THEN change.X = 1: change.Y = 0
329.             IF dx < 0 AND nx <> -1 THEN change.X = -1: change.Y = 0
330.             decided = 0
331.         END IF
332.     END IF
333.     'END IF
334. END SUB
335.  
336. FUNCTION snakeBodyExists (which%)
337.     IF sLen = 1 THEN EXIT FUNCTION
338.     DIM n
339.     FOR n = 1 TO sLen - 1
340.         IF which% = 1 THEN 'x-direction
341.             IF snake(n).X - head.X > 0 AND snake(n).Y = head.Y THEN snakeBodyExists = 1: EXIT FUNCTION
342.             IF snake(n).X - head.X < 0 AND snake(n).Y = head.Y THEN snakeBodyExists = -1: EXIT FUNCTION
343.         ELSEIF which% = 2 THEN 'y-direction
344.             IF snake(n).Y - head.Y > 0 AND snake(n).X = head.X THEN snakeBodyExists = 1: EXIT FUNCTION
345.             IF snake(n).Y - head.Y < 0 AND snake(n).X = head.X THEN snakeBodyExists = -1: EXIT FUNCTION
346.         END IF
347.     NEXT
348. END FUNCTION
349. SUB help
350.     _PRINTSTRING (610, 20), "Keys:"
351.     _PRINTSTRING (610, 40), "p toggles pause on/off"
352.     _PRINTSTRING (610, 60), "a toggles autoPilot"
353.     _PRINTSTRING (610, 100), "arrows control snake"
354.     _PRINTSTRING (610, 80), "q or esc quits"
355.     _PRINTSTRING (610, 120), "s increases speed"
356.     _PRINTSTRING (610, 140), "- decreases speed"
357.     _PRINTSTRING (610, 200), "A BEEP means AI error,"
358.     _PRINTSTRING (610, 216), "human put in control."
359. END SUB
360.  
361.  

 

EDIT : The code is updated, just fixed a minor bug.

[bplus]

@Ashish this is great, you got the idea of only changing change.X and change.Y in snake brain SUB and yes allowed to make supplemental functions and subs to help make decisions on change. Everything is good as long as you don't mess with any other of the snake game variables of main program.

I see your AI getting stuck in loop going around and around 1 cell above fruit location, I switched to manual grabbed the fruit and then switched back to autoPilot and your code picked right up again, great start!

I am thinking we might need a status report on who / what is current driver, human or AI

Oh! if you keep your SnakeBrain code separate and list the supplemental procedures it uses, we can store other peoples versions of snake brain and maybe evolve better and better AI. ie SnakeBrainByAshish, SnakeBrainByBplus,...

[bplus]

NOW we have a "SMART" Snake.  Is this a Serpentine from one of the five tribes?  Great job!  This is addicting to watch but crashes all the time, especially when speed increases.
Moving the window also crashes the program.

All these crashes??? Are you using code from Best Answer? Are you toggling key "a" so human has to drive snake?

How can moving window possibly crash snake??? unless you are driving snake and paying attention to dragging window instead of driving. There is "p" for pause that can stop action so you can move the already centered window to where ever you like. Also the "-" key will slow down AI speed or human speed depending what mode you are in.

Wait... are you using this on DOS ;-))

[bplus]

Hi [banned user],

Thanks for feedback, I don't have Linux let alone Debian version so I have no idea the troubles you guys have.

[bplus]

Here is another snake who always gets it's fruit! Not the least bit faster than snakeBrainBplus1 but fancier!
Just leave in autoPilot and watch the show :)

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Snake AI-1_6 B+brain#2" 'b+ 2020-03-19
3. '2020-03-14 Snake AI-1 first post
4. '2020-03-16  Snake AI-1_1 there must be overlap of the snake somewhere! Aha!
5. '2020-03-17 Snake AI-1_2 fix the duplicate segment problem
6. ' Now a new mystery, an ocassional flashing duplicate box
7. '2020-03-17 Install standard snake rules for testing brain evolving
8. ' First setup XY type and rename and convert variables using XY type.
9. ' 2nd Make snake brain and whole game only dependent sqrsX, sqrsY and sq for screen size
10. ' Got it!!! the code ends with hangup head next to fruit with 99 (1 cell less that whole board)
11. ' cells of snake length, no new place can be found for fruit, perfect finish and no duplicate
12. ' cells! PLUS now can turn on a dime go up one colume and down the next in 2 key press.
13. ' Now add autoPilot on -1 / off 0 toggle control, OK snake rules tested when human pilots snake.
14. ' Help screen & independent speeds for human or AI.
15. '2020-03-18  "Snake AI-1_4 fix tester" The AI tester needs to save Head(x, y) in case the AI
16. ' does not change the head(x, y) or tries to move it diagonally.
17.  
18. '2020-03-18 Snake AI-1_5 SHARE change AS XY
19. ' DIM SHARE change AS XY or change.x, change.y replaces variables called dx, dy.
20. ' I decided to switch over to human control if AI fails to return a proper change.
21. ' AI must leave change.x, change.y ready for human to take over control which means my changing
22. ' the code for toggling the autopilot and adding change.x, change.y updates in my snakeBrain SUB.
23. ' Rewrite SnakeBrain using only change.X and change.Y now. A BEEP will indicate an AI error and
24. ' signal control returned to human. This noted in Key Help part of screen.
25.  
26. '2020-03-19 Snake AI-1_6 B+brain#2 begin a new snakeBrain sub routine
27. ' Add a driver report in title bar along with sLen.
28. ' Oh hey what a fancy snake dance, not the least bit faster than snakeBrainBplus1.
29.  
30.  
31. '  Snakepit Dimensions: square size = sq, sqrsX = # of squares along x-axis and sqrsY squares down.
32. CONST sq = 20, sqrsX = 17, sqrsY = 16, xmax = sq * sqrsX, ymax = sq * sqrsY
33. SCREEN _NEWIMAGE(800, 600, 32)
34. _DELAY .25
35. _SCREENMOVE _MIDDLE
36. RANDOMIZE TIMER
37.  
38. ' Usually used to give a point on 2D board a single name that has an X dimension and a Y dimension.
39. TYPE XY
40.     X AS INTEGER
41.     Y AS INTEGER
42. END TYPE
43.  
44. '   SHARED variables for any version of SnakeBrain SUB to act as autoPilot for snake snake.
45. DIM SHARED change AS XY '                            directs the head direction through AI or Human
46. DIM SHARED head AS XY '                           leads the way of the snake(body) through snakepit
47. DIM SHARED sLen AS INTEGER '                                                        length of snake
48. DIM SHARED snake(1 TO sqrsX * sqrsY) AS XY '                   whole snake, head is at index = sLen
49. DIM SHARED fruit AS XY '     as snake eats fruit it grows, object is to grow snake to fill snakepit
50.  
51. DIM SHARED brain2Directions(0 TO sqrsX - 1, 0 TO sqrsY - 1) AS STRING '     for snakeBrainBplus2 AI
52.  
53. '   SHARED for screenUpdate
54. DIM SHARED pal(sqrsX * sqrsY) AS _UNSIGNED LONG '                                  for snake colors
55.  
56. 'other data needed for program
57. DIM i AS INTEGER, good AS INTEGER, KEY$, r AS INTEGER, g AS INTEGER, b AS INTEGER
58. DIM autoPilot AS INTEGER, hSpeed, aSpeed, saveChange AS XY, title$
59.  
60. help '                                                                                     Key Menu
61. hSpeed = 3: aSpeed = 20 '                     autopilot speed is independent of human control speed
62.  
63.  
64. loadBrain2Directions '                    load array with directions for each cell for AI to follow
65.  
66. restart: '                                                                             reinitialize
67. r = .3 + RND * .7: g = r * .5 + RND * .3 - .15: b = .5 * r + RND * .3 - .15 '    rnd pal color vars
68. FOR i = 1 TO sqrsX * sqrsY '                               enough colors for snake to fill snakepit
69.     pal(i) = _RGB32(84 + 64 * SIN(r + i / 2), 84 + 64 * SIN(g + i / 2), 104 * SIN(b + i / 2))
70. NEXT
71. head.X = sqrsX / 2 - 3: head.Y = sqrsY / 2 - 3 '                                         head start
72. fruit.X = sqrsX / 2 + 2: fruit.Y = sqrsY / 2 + 2 '                                      first fruit
73. sLen = 1 '                                                           for starters snake is all head
74. snake(sLen).X = head.X: snake(sLen).Y = head.Y '                         head is always at sLen end
75. autoPilot = 1 '                                                              start snake body count
76. change.X = 0: change.Y = 1 '                      head snake down board, Y direction of first fruit
77. DO
78.     IF autoPilot THEN title$ = "AI." ELSE title$ = "human."
79.     _TITLE STR$(sLen) + " Current driver is " + title$
80.     LINE (0, 0)-(xmax, ymax), &HFF884422, BF '                                       clear snakepit
81.     IF sLen = sqrsX * sqrsY - 1 THEN screenUpdate: EXIT DO '             game is won! start another
82.     KEY$ = INKEY$
83.     IF KEY$ = "q" OR KEY$ = CHR$(27) THEN '                                            here is quit
84.         END '
85.     ELSEIF KEY$ = "a" THEN '                                                       toggle autoPilot
86.         autoPilot = 1 - autoPilot '   it is now up to AI to keep change updated for human take over
87.     ELSEIF KEY$ = "p" THEN '                               pause toggle p starts pause p ends pause
88.         _KEYCLEAR: WHILE INKEY$ <> "p": _LIMIT 60: WEND
89.     ELSEIF KEY$ = "s" THEN
90.         IF autoPilot AND aSpeed + 5 < 400 THEN aSpeed = aSpeed + 5 ' max autopilot speed is 400 !!!
91.         IF autoPilot = 0 AND hSpeed + .5 < 10 THEN hSpeed = hSpeed + .5 '     max human speed is 10
92.     ELSEIF KEY$ = "-" THEN
93.         IF autoPilot AND aSpeed - 5 > 0 THEN aSpeed = aSpeed - 5
94.         IF autoPilot = 0 AND hSpeed - .5 > 1 THEN hSpeed = hSpeed - .5
95.     END IF '                                                                                      '
96.  
97.     IF autoPilot THEN '                                                 who is piloting the snake?
98.  
99.         saveChange.X = change.X: saveChange.Y = change.Y '   if AI screws up then human takes over
100.  
101.         ' PLUG-IN YOUR Snake Brain AI here
102.         '=========================================================================== AI Auto Pilot
103.         snakeBrainBplus2 ' note: snakeBrainBplus1 won't work for this custom sqrsX, sqrsY version.
104.         '=========================================================================================
105.  
106.         'check changes
107.         IF ABS(change.X) = 0 THEN '                                      must have diffence in y's
108.             IF ABS(change.Y) <> 1 THEN autoPilot = 0 '                       error switch to human
109.         ELSEIF ABS(change.Y) = 0 THEN
110.             IF ABS(change.X) <> 1 THEN autoPilot = 0 '                       error switch to human
111.         ELSE '                           must have a 0 in either change.x or change.y but not both
112.             autoPilot = 0 '                                                  error switch to human
113.         END IF
114.         IF autoPilot = 0 THEN '              switching control over to human restore change values
115.             change.X = saveChange.X: change.Y = saveChange.Y: BEEP '                   alert human
116.         END IF
117.  
118.     ELSE '  =======================================================================  human control
119.         IF KEY$ = CHR$(0) + CHR$(72) THEN '                                               up arrow
120.             change.X = 0: change.Y = -1
121.         ELSEIF KEY$ = CHR$(0) + CHR$(80) THEN '                                         down arrow
122.             change.X = 0: change.Y = 1
123.         ELSEIF KEY$ = CHR$(0) + CHR$(77) THEN '                                        right arrow
124.             change.X = 1: change.Y = 0
125.         ELSEIF KEY$ = CHR$(0) + CHR$(75) THEN '                                         left arrow
126.             change.X = -1: change.Y = 0
127.         END IF
128.  
129.     END IF
130.     head.X = head.X + change.X: head.Y = head.Y + change.Y '            OK human or AI have spoken
131.  
132.     '   ============================  check snake head with Rules: ===============================
133.  
134.     ' 1. Snakepit boundary check, snake hits wall, dies.
135.     IF head.X < 0 OR head.X > sqrsX - 1 OR head.Y < 0 OR head.Y > sqrsY - 1 THEN
136.         _TITLE _TRIM$(STR$(sLen)) + " Wall Crash": screenUpdate: EXIT DO
137.     END IF
138.  
139.     ' 2. Snake eats body part, dies. This should kill snake if turn its head back on itself.
140.     FOR i = 1 TO sLen '                                              did head just crash into body?
141.         IF head.X = snake(i).X AND head.Y = snake(i).Y THEN
142.             _TITLE _TRIM$(STR$(sLen)) + " Body Crash": screenUpdate: EXIT DO '                yes!
143.         END IF
144.     NEXT '                                                                                      no
145.  
146.     ' 3. Eats Fruit and grows or just move every segment up 1 space.
147.     IF (fruit.X = head.X AND fruit.Y = head.Y) THEN '                             snake eats fruit
148.         sLen = sLen + 1
149.         snake(sLen).X = head.X: snake(sLen).Y = head.Y 'assimilate fruit into head for new segment
150.         DO 'check new apple
151.             fruit.X = INT(RND * sqrsX): fruit.Y = INT(RND * sqrsY): good = -1
152.             FOR i = 1 TO sLen
153.                 IF fruit.X = snake(i).X AND fruit.Y = snake(i).Y THEN good = 0: EXIT FOR
154.             NEXT
155.         LOOP UNTIL good
156.     ELSE
157.         FOR i = 1 TO sLen '                           move the snake data down 1 dropping off last
158.             snake(i).X = snake(i + 1).X: snake(i).Y = snake(i + 1).Y
159.         NEXT
160.         snake(sLen).X = head.X: snake(sLen).Y = head.Y '              and adding new head position
161.     END IF
162.  
163.     screenUpdate '                                                    on with the show this is it!
164.     IF autoPilot THEN _LIMIT aSpeed ELSE _LIMIT hSpeed ' ndependent speed control for human and AI
165. LOOP
166. _DELAY 3 '                                                                  win or loose, go again
167. GOTO restart:
168.  
169. SUB screenUpdate ' draw snake and fruit, overlap code debugger
170.     DIM c~&, i AS INTEGER, overlap(sqrsX, sqrsY) AS INTEGER
171.     FOR i = 1 TO sLen
172.         IF i = sLen THEN c~& = &HFF000000 ELSE c~& = pal(sLen - i)
173.  
174.         '               overlap helps debug duplicate square drawing which indicates a flawed code
175.         overlap(snake(i).X, snake(i).Y) = overlap(snake(i).X, snake(i).Y) + 1
176.  
177.         LINE (snake(i).X * sq, snake(i).Y * sq)-STEP(sq - 2, sq - 2), c~&, BF
178.         IF overlap(snake(i).X, snake(i).Y) > 1 THEN 'show visually where code flaws effect display
179.             LINE (snake(i).X * sq + .25 * sq, snake(i).Y * sq + .25 * sq)_
180.             -STEP(.5 * sq - 2, .5 * sq - 2), &HFFFFFFFF, BF
181.         END IF
182.     NEXT
183.     LINE (fruit.X * sq, fruit.Y * sq)-STEP(sq - 2, sq - 2), _RGB32(255, 100, 255), BF
184.     _DISPLAY
185. END SUB
186.  
187. SUB snakeBrainBplus1 '>>>>>>>>>>   B+  SNAKE BRAIN  needs sqrsX to be even number  <<<<<<<<<<<<<<<
188.  
189.     'todo fix this so that when takeover control won't crash into self
190.  
191.     IF sqrsX MOD 2 = 1 THEN change.X = 0: change.Y = 0: EXIT SUB 'throw error for code check to
192.     '                                                      discover and switch to human control
193.  
194.     IF head.X = 0 AND head.Y = sqrsY - 1 THEN
195.         change.X = 0: change.Y = -1
196.     ELSEIF head.X MOD 2 = 0 AND head.Y <> 0 AND head.Y <> sqrsY - 1 THEN
197.         change.X = 0: change.Y = -1
198.     ELSEIF head.X MOD 2 = 0 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
199.         change.X = 1: change.Y = 0
200.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y = sqrsY - 2 THEN
201.         change.X = 1: change.Y = 0
202.     ELSEIF head.X MOD 2 = 1 AND head.X <> sqrsX - 1 AND head.Y < sqrsY - 1 THEN
203.         change.X = 0: change.Y = 1
204.     ELSEIF head.X = sqrsX - 1 AND head.Y = sqrsY - 1 THEN
205.         change.X = -1: change.Y = 0
206.     ELSEIF head.Y = sqrsY - 1 AND head.X <> 0 THEN
207.         change.X = -1: change.Y = 0
208.     ELSEIF head.X MOD 2 = 1 AND head.Y = 0 AND head.Y <> sqrsY - 1 THEN
209.         change.X = 0: change.Y = 1
210.     ELSEIF head.X = sqrsX - 1 AND head.Y < sqrsY - 1 THEN
211.         change.X = 0: change.Y = 1
212.     END IF
213. END SUB
214.  
215. SUB snakeBrainBplus2 ' needs custom sqrsX = 17, sqrsY = 16 and SUB loadBrain2Directions
216.     DIM direction$
217.     direction$ = brain2Directions(head.X, head.Y)
218.     SELECT CASE direction$
219.         CASE "U": change.X = 0: change.Y = -1
220.         CASE "D": change.X = 0: change.Y = 1
221.         CASE "L": change.X = -1: change.Y = 0
222.         CASE "R": change.X = 1: change.Y = 0
223.     END SELECT
224. END SUB
225.  
226. SUB loadBrain2Directions ' for custom snakeBrainBplus2
227.     DIM x, y, s$
228.     FOR y = 0 TO sqrsY - 1
229.         READ s$
230.         FOR x = 0 TO sqrsX - 1
231.             brain2Directions(x, y) = MID$(s$, x + 1, 1)
232.         NEXT
233.     NEXT
234.     DATA RRRRRRRRRRRRRRRRD
235.     DATA UDLLLLLLLLLLLLLLD
236.     DATA UDRRRRRRRRRRRRDUD
237.     DATA UDUDLLLLLLLLLLDUD
238.     DATA UDUDRRRRRRRRDUDUD
239.     DATA UDUDUDLLLLLLDUDUD
240.     DATA UDUDUDRRRRDUDUDUD
241.     DATA UDUDUDUDLLDUDUDUD
242.     DATA UDUDUDUDRUDUDUDUD
243.     DATA UDUDUDUDULLUDUDUD
244.     DATA UDUDUDURRRRUDUDUD
245.     DATA UDUDUDULLLLLLUDUD
246.     DATA UDUDURRRRRRRRUDUD
247.     DATA UDUDULLLLLLLLLLUD
248.     DATA UDURRRRRRRRRRRRUD
249.     DATA ULULLLLLLLLLLLLLL
250. END SUB
251.  
252. SUB help
253.     _PRINTSTRING (610, 20), "Keys:"
254.     _PRINTSTRING (610, 40), "p toggles pause on/off"
255.     _PRINTSTRING (610, 60), "a toggles autoPilot"
256.     _PRINTSTRING (610, 100), "arrows control snake"
257.     _PRINTSTRING (610, 80), "q or esc quits"
258.     _PRINTSTRING (610, 120), "s increases speed"
259.     _PRINTSTRING (610, 140), "- decreases speed"
260.     _PRINTSTRING (610, 200), "A BEEP means AI error,"
261.     _PRINTSTRING (610, 216), "human put in control."
262. END SUB
263.  
264.  

 

[Ashish]

@[banned user]
The program do not crash on my machine.

@bplus Its nice. Another Good approach.
 I tried to improve my AI to take better decision by tracking the location of fruit and its body units but the result is worse. Only thing good is that It now never stuck in a loop but it do "body crash". I think I must not post the code. It has now become full of IF...THEN clause. And guess what, now I, myself not able to understand what I wrote (xD).

[TempodiBasic]

Hi guys
in windows 10 it runs well

in Lubuntu 14 06 on Oracle VirtualBox  it runs just few seconds and then it crashes!
I'm thinking that there is a substantial difference between Windows and Linux version of QB64.

Please can someone  test this code on Mac so we get a whole overview on the 3 platform of QB64 performances.