QB64 v1.4 Release Candidate up for testing

[odin]

First things first, we have moved development to a new GitHub repository. Follow us at https://github.com/QB64Team/qb64.

Although we don't follow a strict schedule regarding updates to QB64, every once in a while a feature that's been requested gets implemented or a new bug is found and then fixed, and eventually we have enough for a new release.

We have named the upcoming release QB64 v1.4, and it's already available in the development channel (accessible at http://www.qb64.org/devbuilds.php). Although you can follow development by checking out our repository on GitHub (https://github.com/QB64Team/qb64/commits/development), the time for us to compile a more concise changelog has finally come.

One big change worth mentioning first, since it affects QB64 code from now on in a big way, is the new $NOPREFIX metacommand.

QB64-specific keywords, those that expand on the original set of keywords from QBasic/QuickBASIC 4.5, which we aim to replicate, are those that start with an underscore. It has been designed that way so that, in the event that you want to load an older program you wrote back in the day that had variables or procedures with identical names, they would not collide with the new keywords, making it possible to use QB64 entirely as you did with QBasic but also add the new functionality without breaking anything.

However, we have over the years been following our userbase create more and more programs that have no dependency whatsoever on older code, which means these aren't just QBasic programs with benefits, but actually QB64-native programs, written from scratch with QB64 in mind.

All that said, the new $NOPREFIX metacommand allows you, for the first time ever, to write QB64 programs without having to add the leading underscore to use the modern keywords.

That will allow code like this:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. COLOR _RGB32(255), _RGB32(255, 0, 255)
3. m$ = "Hello, world!"
4. _PRINTSTRING ((_WIDTH - _PRINTWIDTH(m$)) \ 2, (_HEIGHT - _FONTHEIGHT) \ 2), m$
5.  
6. DO
7.     _DISPLAY
8.     _LIMIT 30
9. LOOP UNTIL _KEYHIT

To be written as:

Code: QB64: [Select]

1. $NOPREFIX
2. SCREEN NEWIMAGE(800, 600, 32)
3. COLOR RGB32(255), RGB32(255, 0, 255)
4. m$ = "Hello, world!"
5. PRINTSTRING ((WIDTH - PRINTWIDTH(m$)) \ 2, (HEIGHT - FONTHEIGHT) \ 2), m$
6.  
7. DO
8.     DISPLAY
9.     LIMIT 30
10. LOOP UNTIL KEYHIT

With the new metacommand in use, a program can both use _DISPLAY and DISPLAY, for example. User variables and procedures still cannot start with a single underscore (double underscores are accepted).

Here's the complete changelog, for now. We invite you to try the development build and help us test (and try to break) the new features, so that we can polish everything for release as soon as possible:

https://www.qb64.org/portal/changelog-of-v1-4/

[FellippeHeitor]

Example of _DEFLATE$ and _INFLATE$ to compress/decompress a string:

Code: QB64: [Select]

1. _CONTROLCHR OFF
2.  
3. a$ = "The quick brown fox jumps over the lazy dog. "
4. PRINT "Original string (a$): ";
5. COLOR 15: PRINT a$: COLOR 7
6. FOR i = 1 TO 15
7.     a$ = a$ + a$
8. NEXT
9.  
10. PRINT "After concatenating it into itself several times, LEN(a$) =";
11. COLOR 12: PRINT LEN(a$): COLOR 7
12.  
13. PRINT "Hit any key..."
14. i$ = INPUT$(1)
15.  
16. b$ = _DEFLATE$(a$)
17. PRINT "After using _DEFLATE$ to compress it, LEN =";
18. COLOR 10: PRINT LEN(b$): COLOR 7
19.  
20. PRINT "Hit any key..."
21. i$ = INPUT$(1)
22.  
23. c$ = _INFLATE$(b$)
24. PRINT "After using _INFLATE$ to decompress it, LEN =";
25. COLOR 12: PRINT LEN(c$): COLOR 7
26.  
27. PRINT "Hit any key to display the decompressed string..."
28. i$ = INPUT$(1)
29.  
30. PRINT c$
31.  

[FellippeHeitor]

The $ASSERTS metacommand enables the _ASSERT macro, which can be used to perform tests in code that's in development, for debugging purposes. After the code is considered error-free, you can disable error checking by removing the $ASSERTS metacommand from the top of your program, and then all tests will be ignored.

IF $ASSERTS:CONSOLE is used instead, an optional error message is output to the console window, to help with debugging.

When the condition specified in the _ASSERTS statement isn't met, execution is interrupted and an error message with "_ASSERT failed on line #" is displayed.

Sample usage:

Code: QB64: [Select]

1. $ASSERTS:CONSOLE
2.  
3. DO
4.     a = INT(RND * 10)
5.     b$ = myFunc$(a)
6.     PRINT a, , b$
7.     _LIMIT 3
8. LOOP UNTIL _KEYHIT
9.  
10. FUNCTION myFunc$ (value AS SINGLE)
11.     _ASSERT value > 0, "Value cannot be zero"
12.     _ASSERT value <= 10, "Value cannot exceed 10"
13.  
14.     IF value > 1 THEN plural$ = "s"
15.     myFunc$ = STRING$(value, "*") + STR$(value) + " star" + plural$ + " :-)"
16. END FUNCTION

[FellippeHeitor]

_PUTIMAGE would generate an error if the source and destination images were the same. In the upcoming version, QB64 generates a copy of the source image in memory first, so that source and destination can be the same in a copy operation.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1000, 250, 32)
2.  
3. FOR i = 1 TO 100
4.     CIRCLE (250, 125), i, _RGB32(RND * 255, RND * 255, RND * 255)
5. NEXT
6.  
7. _PRINTSTRING (500, 0), "Press a key to copy that circle..."
8. a$ = INPUT$(1)
9.  
10. _PUTIMAGE (500, 0), , , (0, 0)-(500, 250)
11.  

[FellippeHeitor]

$COLOR:0 or $COLOR:32 add named color constants to your programs:

Code: QB64: [Select]

1. $COLOR:0
2. COLOR BrightWhite, Red
3. PRINT "Bright white on red."
4.  

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 400, 32)
2. $COLOR:32
3. COLOR CrayolaGold, DarkCyan
4. PRINT "CrayolaGold on DarkCyan."
5.  

Color references: color0.bi and color32.bi

These are not compatible with $NOPREFIX, as there are QB64 functions with color names (_RED, _GREEN, _BLUE), so the metacommands have exclusive usage over each other.

[FellippeHeitor]

Steve demoed the new $CONSOLE functionality for Windows:

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE: _SOURCE _CONSOLE
3.  
4. COLOR 15
5. PRINT "Welcome to a demostration of the Windows Console System for QB64,"
6. PRINT "as overhauled by Steve!"
7. PRINT
8. PRINT "First, allow me to illustrate two newly implemented commands: SLEEP and CLS"
9. Pause
10. CLS
11. PRINT "And now, I'll illustrate how to change colors in the console:"
12. FOR i = 0 TO 15
13.     COLOR i, 15 - i
14.     PRINT "COLORS:"; i; "ON"; 15 - i
15. NEXT
16. PRINT
17. Pause
18. CLS
19. PRINT "And now, we're going to have fun with the console size."
20. PRINT "Our original screen should be set at 80x25 for default."
21. PRINT "Press <ANY KEY> when ready to change modes."
22. Pause
23. WIDTH 120, 50
24. PRINT
25. PRINT "Here we're set at 120x50."
26. Pause
27. WIDTH 120, 50, 120, 50
28. PRINT
29. PRINT "And here we no longer have a scroll buffer; it's also 120x50."
30. PRINT "Notice the vertical scroll bar is gone?"
31. Pause
32. WIDTH 100, 33, 300, 150
33. PRINT "And here we now have both a vertical and a hortizontal scroll bar."
34. FOR i = 1 TO 50
35.     PRINT "See? ";
36.     _LIMIT 10
37. NEXT
38. PRINT
39. PRINT "Be certain to scroll the bar so you can 'See' all the text."
40. PRINT
41. Pause
42. CLS
43. PRINT "And, of course, I can now work with LOCATE..."
44. LOCATE 10, 10: PRINT "LOCATE 10,10"
45. LOCATE 20: PRINT "LOCATE 20"
46. LOCATE , 20: PRINT "LOCATE ,20"
47. Pause
48. CLS
49. PRINT "And, of course, I can now get back single character returns..."
50. PRINT "Press any key, and I'll give you the scan code for it.  <ESC> quits the demo."
51. PRINT
52. PRINT
53. DO
54.     x = _CONSOLEINPUT
55.     IF x = 1 THEN 'don't update for mouse input
56.         c = _CINP
57.         PRINT c;
58.     END IF
59. LOOP UNTIL c = 1
60. END
61.  
62. SUB Pause
63.     PRINT
64.     PRINT "Press <ANY KEY> to continue."
65.     SLEEP
66. END SUB
67.  

[FellippeHeitor]

Use _NUMLOCK, _CAPSLOCK and _SCROLLLOCK to read these keys' states.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 300, 32)
2.  
3. PRINT "Try toggling your caps, num and scroll lock keys..."
4. PRINT "ESC to quit"
5.  
6. DO
7.     IF _CAPSLOCK THEN
8.         LINE (10, 150)-STEP(80, 50), _RGB32(255), B
9.         LINE (20, 160)-STEP(5, 5), _RGB32(255, 200, 0), BF
10.     ELSE
11.         LINE (10, 150)-STEP(80, 50), _RGB32(120), B
12.         LINE (20, 160)-STEP(5, 5), _RGB32(120), BF
13.     END IF
14.  
15.     IF _SCROLLLOCK THEN
16.         LINE (600, 10)-STEP(50, 50), _RGB32(255), B
17.         LINE (610, 20)-STEP(5, 5), _RGB32(255, 200, 0), BF
18.     ELSE
19.         LINE (600, 10)-STEP(50, 50), _RGB32(120), B
20.         LINE (610, 20)-STEP(5, 5), _RGB32(120), BF
21.     END IF
22.  
23.     IF _NUMLOCK THEN
24.         LINE (700, 60)-STEP(50, 50), _RGB32(255), B
25.         LINE (710, 70)-STEP(5, 5), _RGB32(255, 200, 0), BF
26.     ELSE
27.         LINE (700, 60)-STEP(50, 50), _RGB32(120), B
28.         LINE (710, 70)-STEP(5, 5), _RGB32(120), BF
29.     END IF
30.  
31.     _DISPLAY
32.     _LIMIT 30
33. LOOP UNTIL _KEYHIT = 27
34. SYSTEM

You can use _CAPSLOCK ON/OFF/_TOGGLE, _NUMLOCK ON/OFF/_TOGGLE or _SCROLLLOCK ON/OFF/_TOGGLE, although it is advisable to avoid changing these keys' states without your users' request.

[FellippeHeitor]

BIT functions and examples provided by Cobalt:

_TOGGLEBIT:

Code: QB64: [Select]

1. A~%% = 0 '_UNSIGNED _BYTE
2. PRINT A~%%
3. A~%% = _TOGGLEBIT(A~%%,4) 'toggle the fourth bit of A~%%
4. PRINT A~%%
5. A~%% = _TOGGLEBIT(A~%%,4) 'toggle the fourth bit of A~%%
6. PRINT A~%%

_RESETBIT:

Code: QB64: [Select]

1. A~%% = 0 '_UNSIGNED _BYTE
2. PRINT A~%%
3. A~%% = _SETBIT(A~%%,6) 'set the seventh bit of A~%%
4. PRINT A~%%
5. A~%% = _RESETBIT(A~%%,6) 'Reset the seventh bit of A~%%
6. PRINT A~%%

_READBIT:

Code: QB64: [Select]

1. A~%% = _SETBIT(A~%%,4)
2. PRINT "Bit 4 is currently ";
3. IF _READBIT(A~%%,4) = -1 THEN PRINT "ON" ELSE PRINT "OFF"
4. PRINT "And bit 2 is currently ";
5. IF _READBIT(A~%%,2) = -1 THEN PRINT "ON" ELSE PRINT "OFF"

_SETBIT:

Code: QB64: [Select]

1. A~%% = 0 '_UNSIGNED _BYTE
2. PRINT A~%%
3. A~%% = _SETBIT(A~%%,6) 'set the seventh bit of A~%%
4. PRINT A~%%

[SierraKen]

Thank you! I just put all the files on top of v. 1.3 and just to check it it works fine so far with the $NOPREFIX which is the first thing I checked. But I clicked Help and About and it still says v. 1.3. I wonder if it's because I overlapped the older files? I did it this way so I won't have to try and move all the programs I've made.
Also, for some reason it won't let me click About more than once when the window is maximized. I have to minimize it first to click it again. This is the 64 bit Windows version.

[bplus]

Thank you! I just put all the files on top of v. 1.3 and just to check it it works fine so far with the $NOPREFIX which is the first thing I checked. But I clicked Help and About and it still says v. 1.3. I wonder if it's because I overlapped the older files? I did it this way so I won't have to try and move all the programs I've made.
Also, for some reason it won't let me click About more than once when the window is maximized. I have to minimize it first to click it again. This is the 64 bit Windows version.

Yeah I have v 1.3 too and files not overlapped so I guess they haven't changed version number.

I notice and not just with this version when the window is maximized the screen is half a line off and all mouse clicks have to be done on the top half of every line.

Let me guess in full screen mode you have a black crack along the top like this:

[FellippeHeitor]

Yeah, version number hadn't been updated yet, only functionality. I just changed it on the server now.

Although you guys got lucky, it's never a good idea to unpack a new version of QB64 on top of an older one, keep that in mind if things go awry at some point. Since you guys are willing to help us test it, unpacking it to a clean folder is highly recommended, as we won't know if any issue that may arise only happened because of old files getting in the way.

About not being able to click the menu bar, it is indeed an old render issue that's in OpenGL's hands; it occurs with the IDE because it runs in text mode (SCREEN 0) and when the Window size isn't a multiple of 16 you'll get the black bars. I advise not using the maximize button if your screen resolution gives you that type of issue. Just stretch the window manually to fill the screen and it should resize properly.

[SierraKen]

Thanks B+ and Felippe. Oh well, if something bad happens I'll put the old version back where it was. lol

[Qwerkey]

By the time that all the skilled guys have beta-tested the latest version, you may be able to fully release on Feb 14th - the 14 and v1.4 correspond.  So why not (in the manner of the Ghastly Product Names dept. of Microsoft) name the new version QB64 Valentine?
I only say this because it happens to be my birthday, so please arrange delivery of suitably romantic gifts.  I thank you!

[RhoSigma]

Question for the IDE-Gurus,

would it be easily possible to add at least the proper indention to code which uses line continuation?
I understand it's tricky to properly format all the tokens, as there may also user intended formatting to align lines. What I mean is just to add the proper indention (according to the current block scope) in front of each line, but leave the rest of the lines as is, hence make this

Code: QB64: [Select]

1. IF 1 THEN
2. a$="Hello "+_
3.    "World "+_
4.    "!!"
5. END IF
6.  

into this

Code: QB64: [Select]

1. IF 1 THEN
2.     a$="Hello "+_
3.        "World "+_
4.        "!!"
5. END IF
6.  

it would already be a great enhencement for readability of those multiline statements, as they no longer completely disrupt the block formatting.

[FellippeHeitor]

I'll have a look into it, no promises for 1.4 though.