Extended Input

[STxAxTIC]

Aright here's a bug for ya.

In "enter a float"... type something with a decimal, and then backspace through the decimal... you can never type a decimal again after that

[SMcNeill]

Ahem, where's OPTION _EXPLICIT?

I dunno.  In somebody else’s code??  Personally, I never use it.  It defeats the purpose of having BASIC allocate and define your variables on the fly for you.  :P

Feel free to add it if you need it.  I usually don’t get around to stuff like that until I’m completely finished tinkering with the code.

I’m thinking for floats to have them in a F12.2 format.  The example there would allow up to 12 digits before the decimal, 2 after.

I'll also add a command to move cursor to after a paste.

Maybe even add an option to auto-comma values...

So still some more tweaking to go here.

[SMcNeill]

Aright here's a bug for ya.

In "enter a float"... type something with a decimal, and then backspace through the decimal... you can never type a decimal again after that

Good catch.  I'll address that tomorrow as well. ;)

[STxAxTIC]

While the hood is open, maybe it's worth dressing up the whole thing in an ascii-box too? Then it'll be an alternative to this box used in several projects around here:

 

[SMcNeill]

@STxAxTIC -- Try this out and see if it's working as intended.  We now limit floats by digits before and after the decimal point, and that period shouldn't be a problem anymore, like you reported up above.

Code: QB64: [Select]

1. OEInput "{F-.2}Enter a float (Unlimited.2)=>", a$
2. PRINT a$
3. OEInput "{F0.2}Enter a float (0.2) =>", a$
4. PRINT a$
5. OEInput "{F9.2}Enter a float (9.2) =>", a$
6. PRINT a$
7. OEInput "{F9.-}Enter a float (9.unlimited) =>", a$
8. PRINT a$
9.  
10. OEInput "{P}Enter a password =>", a$
11. PRINT a$
12.  
13. OEInput "{UI}Enter an unsigned integer =>", a$
14. PRINT a$
15.  
16. OEInput "{I}Enter an integer=>", a$
17. PRINT a$
18.  
19. OEInput "{IL10}Enter an integer of less than 10 digits =>", a$
20. PRINT a$
21.  
22. OEInput "{X15,Y15}Enter whatever at loc 15,15 =>", a$
23. PRINT a$
24.  
25. OEInput "{D}Check to make certain paste is disabled here =>", a$
26. PRINT a$
27.  
28. OEInput "Enter whatever here, but use paste.  See if the cursor remains BEFORE the paste. => ", a$
29. PRINT a$
30.  
31. OEInput "{V}Enter whatever here, but use paste.  See if the cursor moves AFTER the paste. => ", a$
32. PRINT a$
33.  
34. PRINT "Press <ANY KEY> to clear the screen -- we're getting full!"
35.  
36. SLEEP
37. CLS
38. OEInput "{H}This should hide itself, after you enter whatever =>", a$
39. PRINT "Is the question and input gone?  This line should be at the top left corner of your screen."
40. PRINT "And here's your input => "; a$
41.  
42.  
43.  
44. SUB OEInput (prompt$, result$) 'Over Engineered Input
45.     'limit VALUES:
46.     '1 = Unsigned
47.     '2 = Integer
48.     '4 = Float
49.     '8 = Who cares. It's handled via internal variables and we don't need to know a type for it.
50.  
51.     PCOPY 0, 1
52.     A = _AUTODISPLAY: X = POS(0): Y = CSRLIN
53.     OX = X: OY = Y 'original x and y positions
54.     CP = 0: OldCP = 0 'Cursor Position
55.     _KEYCLEAR
56.     length_limit = -1 'unlimited length input, by default
57.  
58.     IF LEFT$(prompt$, 1) = "{" THEN 'possible limiter
59.         i = INSTR(prompt$, "}")
60.         IF i THEN 'yep, we have something!
61.             limiter$ = UCASE$(MID$(prompt$, 2, i - 2))
62.             IF INSTR(limiter$, "U") THEN limit = limit OR 1 'Unsigned
63.             IF INSTR(limiter$, "I") THEN 'can't limit to BOTH an integer AND a float
64.                 limit = limit OR 2 'Integer
65.             ELSEIF INSTR(limiter$, "F") THEN
66.                 limit = limit OR 4 'Float
67.                 float_before_limit = GetValue(limiter$, "F")
68.                 float_after_limit = GetValue(MID$(limiter$, INSTR(limiter$, "F") + 1), ".")
69.             END IF
70.         END IF
71.         IF INSTR(limiter$, "P") THEN password_protected = -1: limit = limit OR 8 'don't show passwords.
72.         IF INSTR(limiter$, "L") THEN 'Length Limitation
73.             limit = limit OR 8
74.             length_limit = GetValue(limiter$, "L")
75.         END IF
76.         IF INSTR(limiter$, "X") THEN 'X position on screen
77.             limit = limit OR 8
78.             X = GetValue(limiter$, "X")
79.         END IF
80.         IF INSTR(limiter$, "Y") THEN 'Y position on scren
81.             limit = limit OR 8
82.             Y = GetValue(limiter$, "Y")
83.         END IF
84.         IF INSTR(limiter$, "D") THEN disable_paste = -1: limit = limit OR 8 'disable paste
85.         IF INSTR(limiter$, "V") THEN cursor_after_paste = -1: limit = limit OR 8 'disable paste
86.         IF INSTR(limiter$, "H") THEN clean_exit = -1: limit = limit OR 8 'disable paste
87.     END IF
88.     IF limit <> 0 THEN prompt$ = MID$(prompt$, i + 1)
89.  
90.  
91.     DO
92.         PCOPY 1, 0
93.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
94.         k = _KEYHIT
95.         IF AltDown THEN
96.             SELECT CASE k 'ignore all keypresses except ALT-number presses
97.                 CASE -57 TO -48: AltWasDown = -1: alt$ = alt$ + CHR$(-k)
98.             END SELECT
99.         ELSE
100.             SELECT CASE k 'without alt, add any keypresses to our input
101.                 CASE 8
102.                     oldin$ = in$
103.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
104.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
105.                 CASE 9
106.                     oldin$ = in$
107.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
108.                     OldCP = CP
109.                     CP = CP + 4
110.                 CASE 32 TO 128
111.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
112.                         IF k = 118 OR k = 86 THEN
113.                             IF disable_paste = 0 THEN
114.                                 oldin$ = in$
115.                                 temp$ = _CLIPBOARD$
116.                                 in$ = LEFT$(in$, CP) + temp$ + MID$(in$, CP + 1) 'ctrl-v paste
117.                                 'CTRL-V leaves cursor in position before the paste, without moving it after.
118.                                 'Feel free to modify that behavior here, if you want it to move to after the paste.
119.                                 IF cursor_after_paste THEN CP = CP + LEN(temp$)
120.                             END IF
121.                         END IF
122.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
123.                     ELSE
124.                         check_input:
125.                         oldin$ = in$
126.                         IF limit AND 1 THEN 'unsigned
127.                             IF k = 43 OR k = 45 THEN _CONTINUE 'remove signs +/-
128.                         END IF
129.                         IF limit AND 2 THEN 'integer
130.                             IF k = 45 AND CP = 0 THEN GOTO good_input 'only allow a - sign for the first digit
131.                             IF k < 48 OR k > 57 THEN _CONTINUE 'remove anything non-numeric
132.                         END IF
133.                         IF limit AND 4 THEN 'float
134.                             IF k = 45 AND CP = 0 THEN GOTO good_input 'only allow a - sign for the first digit
135.                             IF k = 46 AND INSTR(in$, ".") = 0 THEN GOTO good_input 'only one decimal point
136.                             IF k < 48 OR k > 57 THEN _CONTINUE 'remove anything non-numeric
137.                             IF LEFT$(in$, 1) = "-" THEN temp$ = MID$(in$, 2) ELSE temp$ = in$
138.                             IF INSTR(in$, ".") = 0 OR CP < INSTR(in$, ".") THEN
139.                                 IF LEN(temp$) < float_before_limit OR float_before_limit = -1 THEN
140.                                     in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
141.                                     OldCP = CP
142.                                     CP = CP + 1
143.                                 END IF
144.                             ELSE
145.                                 temp$ = MID$(in$, INSTR(in$, ".") + 1)
146.                                 IF LEN(temp$) < float_after_limit OR float_after_limit = -1 THEN
147.                                     in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
148.                                     OldCP = CP
149.                                     CP = CP + 1
150.                                 END IF
151.                             END IF
152.                             _CONTINUE
153.                         END IF
154.                         good_input:
155.                         IF CP < length_limit OR length_limit < 0 THEN
156.                             in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
157.  
158.                             OldCP = CP
159.                             CP = CP + 1
160.                         END IF
161.                     END IF
162.                 CASE 18176 'Home
163.                     CP = 0
164.                 CASE 20224 'End
165.                     CP = LEN(in$)
166.                 CASE 21248 'Delete
167.                     oldin$ = in$
168.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
169.                 CASE 19200 'Left
170.                     CP = CP - 1
171.                     IF CP < 0 THEN CP = 0
172.                 CASE 19712 'Right
173.                     CP = CP + 1
174.                     IF CP > LEN(in$) THEN CP = LEN(in$)
175.             END SELECT
176.         END IF
177.         alt$ = RIGHT$(alt$, 3)
178.         IF AltWasDown = -1 AND AltDown = 0 THEN
179.             v = VAL(alt$)
180.             IF v >= 0 AND v <= 255 THEN
181.                 k = v
182.                 alt$ = "": AltWasDown = 0
183.                 GOTO check_input
184.             END IF
185.         END IF
186.         blink = (blink + 1) MOD 30
187.         LOCATE Y, X
188.         PRINT prompt$;
189.         IF password_protected THEN
190.             PRINT STRING$(LEN(LEFT$(in$, CP)), "*");
191.             IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
192.             PRINT STRING$(LEN(MID$(in$, CP + 1)), "*")
193.         ELSE
194.             PRINT LEFT$(in$, CP);
195.             IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
196.             PRINT MID$(in$, CP + 1)
197.         END IF
198.  
199.         _DISPLAY
200.         _LIMIT 30
201.     LOOP UNTIL k = 13
202.  
203.     PCOPY 1, 0
204.     LOCATE OY, OX
205.     IF clean_exit = 0 THEN
206.         LOCATE Y, X
207.         IF password_protected THEN
208.             PRINT prompt$; STRING$(LEN(in$), "*")
209.         ELSE
210.             PRINT prompt$; in$
211.         END IF
212.     END IF
213.     result$ = in$
214.     IF A THEN _AUTODISPLAY
215. END FUNCTION
216.  
217.  
218. FUNCTION GetValue (limiter$, what$)
219.     jstart = INSTR(limiter$, what$): j = 0
220.     IF MID$(limiter$, INSTR(limiter$, what$) + 1, 1) = "-" THEN
221.         GetValue = -1 'unlimited
222.         EXIT FUNCTION
223.     END IF
224.  
225.     DO
226.         j = j + 1
227.         m$ = MID$(limiter$, jstart + j, 1)
228.     LOOP UNTIL m$ < "0" OR m$ > "9"
229.     GetValue = VAL(MID$(limiter$, jstart + 1, j - 1))
230. END FUNCTION

Personally, I think even what we have here so far, is a pretty neat little bit of input handling for us.  Being able to limit input by types (integer, unsigned, float, or string), is a pretty nice little option for any input routine, as it helps prevent errors from the user-entry level -- and that can stop a whole lot of error checking from ever being necessary.  After all, if I *KNOW* that all an user can input is values from 0 to 9 for a numeric input, then I don't have to error-check later for dollar signs, commas, or stray sneeze input.

We can now limit floats by a before the decimal and after the decimal syntax.  We have an option to move our cursor to after a paste (default has it staying before).  We have an option to turn our text into a pop-up style input, where it completely disappears off the screen once we're done with it.

I guess all the basic legwork is done now.  Now, I guess next, I'll work up an {A} option to create an ASCII-Box similar to the one STx presented above.  Unless  someone comes across a glitch somewhere for me to sort out?

(Which wouldn't surprise me one bit.  After all, OEInput is starting to become a rather complex little set of work here!  The more complex something gets, the more likely it is to have unexpected glitches pop-up in things!)

[FellippeHeitor]

While the hood is open, maybe it's worth dressing up the whole thing in an ascii-box too? Then it'll be an alternative to this box used in several projects around here:

 

🎶🎵 Don't go ditching my box
I know it's not so alright
Oh honey if it gets used then
there is something of good... pam pam, pam pam, pam 🎶🎵

[STxAxTIC]

That box^ is the best one anyone bothered to make. Still that way, so thank you muchly Fellippe. My versions of the input box are lazy and inferior.

But I don't want Steve to fall into the same trap. Now there's a milestone to *pass*, not just drive under.