best way to check for correct conditions

[Cobalt]

Okay,  I have 5 dice(an Array(5)) and I need to check for a full house (3 of one value and 2 of another)

Does anybody have a clever idea on how to check for that, otherwise I'm going to have to code a lot of

IF\THENs checking if 3 dice match and the other 2 match in multiple combos. seems to me there should

be an easier way but I can't think of any.

(if somebody[Odin] can think of a better title for this thread feel free)

[bplus]

Hot off the press!

Code: QB64: [Select]

1. DO
2.     INPUT "Test full house string$ Enter len = 5 digits 0 to 9... (nothing to quit) "; test$
3.     PRINT "Fullhouse = "; fullHouse%(test$)
4.     PRINT
5. LOOP UNTIL test$ = ""
6.  
7. FUNCTION fullHouse% (digits$)
8.     DIM sort(0 TO 9) AS INTEGER
9.     IF LEN(digits$) <> 5 THEN EXIT FUNCTION 'done
10.     FOR i = 1 TO 5
11.         sort(VAL(MID$(digits$, i, 1))) = sort(VAL(MID$(digits$, i, 1))) + 1
12.     NEXT
13.     FOR i = 0 TO 9
14.         IF sort(i) = 3 THEN threeF = 1
15.         IF sort(i) = 2 THEN twoF = 1
16.         IF threeF = 1 AND twoF = 1 THEN fullHouse% = -1: EXIT FUNCTION
17.     NEXT
18. END FUNCTION
19.  

for Array (1 to 5)

Code: QB64: [Select]

1. 'DO
2. DIM test(1 TO 5) AS INTEGER
3. test(1) = 9
4. test(2) = 1
5. test(3) = 1
6. test(4) = 3
7. test(5) = 9
8.  
9. PRINT "Fullhouse = "; fullHouse%(test())
10. PRINT
11. 'LOOP UNTIL test$ = ""
12.  
13. FUNCTION fullHouse% (digits() AS INTEGER)
14.     DIM sort(0 TO 9) AS INTEGER
15.     FOR i = 1 TO 5
16.         sort(digits(i)) = sort(digits(i)) + 1
17.     NEXT
18.     FOR i = 0 TO 9
19.         IF sort(i) = 3 THEN threeF = 1
20.         IF sort(i) = 2 THEN twoF = 1
21.         IF threeF = 1 AND twoF = 1 THEN fullHouse% = -1: EXIT FUNCTION
22.     NEXT
23. END FUNCTION
24.  

[SMcNeill]

Code: QB64: [Select]

1. DIM Count(6), Dice(5)
2.  
3. Dice(1) = 1
4. Dice(2) = 1
5. Dice(3) = 1
6. Dice(4) = 1
7. Dice(5) = 4
8.  
9. FOR i = 1 TO 5
10.     Count(Dice(i)) = Count(Dice(i)) + 1
11. NEXT
12.  
13. FOR i = 1 TO 6
14.     IF Count(i) >= 2 THEN
15.         Result = Result + Count(i)
16.         IF Count(i) > 3 THEN Result = Result + 2
17.     END IF
18. NEXT
19.  
20. PRINT Result
21. IF Result = 3 THEN PRINT "Three of Kind"
22. IF Result = 4 THEN PRINT "Two Pairs"
23. IF Result = 5 THEN PRINT "Full House"
24. IF Result = 6 THEN PRINT "Four of Kind"
25. IF Result = 7 THEN PRINT "Yahtzee"

[Pete]

Well late to the party, but I thought I'd have a go without looking at other responses. I wouldn't say this is clever, but it would be my practical approach to tackling this dice game analysis...

Code: QB64: [Select]

1. RANDOMIZE TIMER
2. LOCATE 25, 1: PRINT "Press Enter to continue or Esc to quit...";
3. LOCATE 1, 1
4. DO
5.     REDIM z(6)
6.     ' Roll 5 6-sided dice.
7.     FOR i = 1 TO 5
8.         x(i) = INT(RND * 6 + 1)
9.         PRINT x(i);
10.     NEXT
11.     xtotal = x(1) + x(2) + x(3) + x(4) + x(5)
12.     PRINT ,
13.     ' Evaluate
14.     FOR i = 1 TO 6
15.         z(x(i)) = z(x(i)) + 1
16.     NEXT
17.     marker = -1
18.     FOR i = 1 TO 6
19.         IF z(i) > 1 THEN
20.             marker = marker * -1
21.             cnt = cnt + z(i) - 1
22.         END IF
23.     NEXT
24.     ' PRINT "cnt ="; cnt, "marker ="; marker
25.     SELECT CASE cnt * marker
26.         CASE -2
27.             PRINT "Two pair"
28.         CASE -3
29.             PRINT "Full house"
30.         CASE 0
31.             IF xtotal = 1 + 2 + 3 + 4 + 5 OR xtotal = 2 + 3 + 4 + 5 + 6 THEN
32.                 PRINT "A straight"
33.             ELSE
34.                 PRINT "Nothing"
35.             END IF
36.         CASE 1
37.             PRINT "A pair"
38.         CASE 2
39.             PRINT "Three of a kind"
40.         CASE 3
41.             PRINT "Four of a kind"
42.         CASE 4
43.             PRINT "Five of a kind"
44.     END SELECT
45.     DO
46.         _LIMIT 30
47.         b$ = INKEY$
48.         IF LEN(b$) THEN
49.             IF b$ = CHR$(13) THEN EXIT DO
50.             IF b$ = CHR$(27) THEN SYSTEM
51.         END IF
52.     LOOP
53.     cnt = 0
54.     PRINT
55. LOOP

I hope it works. Too much lasagna today to do much more than SLEEP...

Hope everyone who celebrated Thanksgiving had a safe and happy one.

Pete

Edit: I tried Steve's. That IF Count(i) > 3 THEN Result = Result + 2 is a clever way of differentiating between pairs and kinds. Only problem is the SECOND FOR/NEXT count is off. It should be FOR i = 1 to 6, not 1 to 5. The 1 - 6 represents the possible numbers on each die. So as is, 1 to 5 will not analyze something like 6-6-2-6-1 as three of a kind, etc. Simple fix.