Click It!

[SMcNeill]

Code: QB64: [Select]

1. CONST DefaultPort$ = "7993"
2. CONST DefaultIP$ = "172.93.60.23"
3. CONST True = -1, False = 0
4. CONST Verbose = True
5. _DEFINE A-Z AS _INTEGER64  'we're going to send/recieve int64s usually (8 bytes).  Deal with it.
6. DIM SHARED Host, Client, LastSeen
7.  
8.  
9. 'REQUIRED SERVER CODE ABOVE
10.  
11.  
12.  
13. SCREEN _NEWIMAGE(800, 600, 32)
14.  
15. _TITLE "Click It!"
16. _CONTROLCHR OFF 'not necessary, but used here to help diagnose stray characters passed back and forth
17.  
18. PRINT "Connecting to Server..";
19. Client = ConnectAsClient(DefaultPort, DefaultIP$)
20. PRINT Verify$
21. PRINT
22. PRINT "Press <ANY KEY> to continue..."
23. SLEEP
24. _KEYCLEAR
25.  
26.  
27. CLS
28. PRINT "Are you a new player?  (Y/N)"
29. DO
30.     a$ = UCASE$(INPUT$(1))
31. LOOP UNTIL a$ = "Y" OR a$ = "N"
32. DO
33.     IF a$ = "Y" THEN
34.         INPUT "REGISTER NAME:"; n$
35.         INPUT "REGISTER PASSWORD:"; p$
36.         Send Client, "[REGISTER]" + n$ + "," + p$ 'Register a new account
37.     ELSE
38.         INPUT "LOGIN NAME:"; n$
39.         INPUT "LOGIN PASSWORD:"; p$
40.         Send Client, "[LOG IN]" + n$ + "," + p$ 'Login from an existing account
41.     END IF
42.     OK$ = Verify$
43.     PRINT OK$ 'don't just print the results here
44. LOOP UNTIL LEFT$(OK$, 4) = "[OK]" 'we want to actually make use of them.
45. PRINT
46. PRINT "Press <ANY KEY> to continue..."
47. SLEEP
48. _KEYCLEAR
49.  
50. Send Client, "[GAME SET]Click It" 'Let the server know what game we're playing.
51. PRINT Verify$
52. Send Client, "[GAME GET]Highscore.txt"
53. OK$ = Verify$ 'same deal as above.  We don't want to just print the results; we want to use them.
54. IF LEFT$(OK$, 4) = "[OK]" THEN highscore$ = MID$(OK$, 5) 'the server just sent us the whole highscore listing,
55. 'all at once.  We can write it to our disk if we want (OPEN file$ FOR BINARY and PUT the whole file to drive),
56. 'or we can parse it as we want, to make sense of who/what it is.
57. 'What this file contains is what we sent to the server to store for us, so if we don't know how to decipher it
58. 'for our game, the server sure as hell doesn't know what to do with it either!
59. PRINT "Highscore.txt retrieved."
60. PRINT
61. PRINT "Press <ANY KEY> to continue..."
62. SLEEP
63. _KEYCLEAR
64.  
65. 'At this point, highscore.txt is either going to be one of two different things:
66. '1) It's going to be blank and have a file length of 0, as we haven't saved any highscores yet.
67. '2) It's going to be the whole highscore list.
68.  
69. 'Regardless, let's go ahead and just save file this to our drive as file handle #1.  (Our only needed filehandle)
70.  
71. OPEN "highscore.txt" FOR OUTPUT AS #1: CLOSE 1 'blank any old highscore file.
72. OPEN "highscore.txt" FOR BINARY AS #1
73. PUT #1, , highscore$ 'and put the whole file to the drive all at once.
74.  
75. 'AGAIN, You'll need to come up with your own method to handle however you process the file the server sent you.
76. 'This is just the simple style which I chose to use for this demo.
77.  
78. SEEK #1, 1 'This isn't the most efficient way to get my high score list, but it's the one I'm using
79. DIM Player$(1000), Score(1000) 'Up to 1000 players, and their score.
80. DO UNTIL EOF(1) OR LOF(1) = 0
81.     players = players + 1
82.     LINE INPUT #1, Player$(players)
83.     LINE INPUT #1, junk$
84.     Score(players) = VAL(junk$)
85.     IF Player$(players) = n$ THEN click = Score(players): found = players
86. LOOP
87. CLOSE 1
88.  
89. COLOR , 0
90. DO
91.     CLS
92.     LINE (100, 100)-(300, 200), &HFF00FF00, BF
93.     LINE (100, 100)-(300, 200), -1, B
94.     _PRINTSTRING (110, 140), "<CLICKS:" + STR$(click) + ">"
95.     WHILE _MOUSEINPUT: WEND
96.     IF _MOUSEBUTTON(1) <> 0 AND oldmouse = 0 THEN 'mouse is clicked
97.         IF _MOUSEX >= 100 AND _MOUSEX <= 300 AND _MOUSEY >= 100 AND _MOUSEY <= 200 THEN 'it's a click in the box
98.             click = click + 1
99.         ELSE 'we clicked outside the box!  We have to quit!
100.             EXIT DO
101.         END IF
102.     END IF
103.     oldmouse = _MOUSEBUTTON(1)
104.     _DISPLAY
105.     _LIMIT 60
106. LOOP
107.  
108. IF found THEN
109.     Score(found) = click
110. ELSE
111.     players = players + 1
112.     Score(players) = click
113.     Player$(players) = n$
114. END IF
115.  
116. FOR i = 1 TO players - 1 'a lazy bubble sort to rank our players.
117.     FOR j = i TO players 'this is inefficient as heck, but I don't expect there will be millions of players to rank!
118.         IF Score(i) < Score(j) THEN SWAP Player$(i), Player$(j): SWAP Score(i), Score(j)
119.     NEXT
120. NEXT
121.  
122. OPEN "highscore.txt" FOR OUTPUT AS #1 'replace the old highscore file.
123. FOR i = 1 TO players
124.     PRINT #1, Player$(i)
125.     PRINT #1, Score(i)
126. NEXT
127. CLOSE 1
128. OPEN "highscore.txt" FOR BINARY AS #1
129. s$ = SPACE$(LOF(1))
130. GET #1, 1, s$ 'get that information into a single large string
131. CLOSE 1
132.  
133.  
134. CLS
135.  
136. '****************************************************************
137. '**
138. '**  NEXT COMMAND IS STRESSED FOR EMPHASIS!  READ IT!!!!
139. '**
140. '*****************************************************************
141.  
142. Send Client, "[GAME PUT]highscore.txt" + CHR$(0) + s$ 'NOTICE THE SEPARATOR BETWEEN OUR COMMAND AND THE FILE CONTENTS
143. 'WITHOUT THAT SEPARATOR (CHR$(0)), YOU WILL GET ERRORS AND NOT SAVE YOUR FILE.
144.  
145. '****************************************************************
146. '**
147. '**  PREVIOUS COMMAND IS STRESSED FOR EMPHASIS!  READ IT!!!!
148. '**
149. '*****************************************************************
150.  
151. PRINT Verify$
152. PRINT
153. PRINT "PLAYER SCORELIST"
154. FOR i = 1 TO players 'just dump the player scores to the screen.
155.     'I'm not looking for pretty at this point, just trying to highlight the functionality.
156.     PRINT i; ") "; Player$(i), Score(i)
157. NEXT
158.  
159.  
160.  
161.  
162.  
163.  
164.  
165. 'SERVER CODE BELOW
166.  
167.  
168.  
169. FUNCTION ConnectAsClient (Port$, IP$)
170.     IF Verbose THEN PRINT "Connecting to Host as Client";
171.     DO
172.         count = count + 1
173.         temp = _OPENCLIENT("TCP/IP:" + Port$ + ":" + IP$) 'attempt to join as client
174.         _LIMIT 10
175.         IF Verbose THEN PRINT ".";
176.     LOOP UNTIL temp <> 0 OR count > 100
177.     IF Verbose THEN PRINT
178.     IF count > 50 THEN
179.         IF Verbose THEN PRINT "Cannot connect to Host.  Terminating program."
180.         END
181.     END IF
182.     IF Verbose THEN PRINT "Client Connected Successfully."
183.     ConnectAsClient = temp
184. END FUNCTION
185.  
186. SUB Send (Who, What$)
187.     IF Client = 0 OR What$ = "" THEN EXIT SUB
188.     out$ = CHR$(2) 'an initial byte to say, "We're sending data."
189.     out$ = out$ + _MK$(_INTEGER64, LEN(What$) + 8) '8 bytes to store the length of the data we're sending.
190.     out$ = out$ + What$
191.     PUT Client, , out$
192. END FUNCTION
193.  
194. SUB Receive (Who, What$)
195.     STATIC In AS STRING
196.     DIM B AS _UNSIGNED _BYTE
197.     IF Client = 0 THEN EXIT SUB
198.     IF In = "" THEN
199.         GET Client, , B
200.     ELSE
201.         B = ASC(In)
202.         r$ = r$ + In
203.         In = "" 'Is there a message waiting for us, after we processed one message?
204.     END IF
205.     IF B = 2 THEN
206.         DO
207.             GET Client, , a$
208.             IF a$ <> "" THEN r$ = r$ + a$
209.             IF LEN(r$) > 8 THEN length = _CV(_INTEGER64, LEFT$(r$, 8))
210.             _LIMIT 10
211.         LOOP UNTIL LEN(r$) >= length AND length <> 0
212.         What$ = MID$(r$, 9) '8 bytes for the length
213.         In = MID$(r$, length + 1)
214.     END IF
215. END SUB
216.  
217. FUNCTION Verify$
218.     DO
219.         Receive Client, OK$ 'Get the confirmation message.
220.         _LIMIT 10 'Use low CPU while waiting.  No need for a high number here... Be patient and let the server have time to respond.  Checking 10 times a second is more than enough to get an [OK] or [ERROR] message.
221.     LOOP UNTIL OK$ <> ""
222.     Verify$ = OK$
223. END FUNCTION
224.  

My first game to take advantage of my little Open Game Server (topic here: https://www.qb64.org/forum/index.php?topic=1920.0).  If this works as it should for everyone, it'll highlight the process which people could follow to link their own games into the game server. 

All I can say at this point is to test it out and see if the thing works for you like it should, or not.  The first time you run it, you'll need to register a new account.  From them on, just log into your existing account.

Play the game -- it's quite complex, but I imagine you guys can sort it out without needing a ton of instructions -- and see who can get the highest score!  ;D

[bplus]

This might be tangential, but that is interesting way to get clear of a click, except stuck with mouse down point but fine for most uses.

[SMcNeill]

It’s how I generally get a lazy “click”.  Only when the mouse was up, and we push it down, does it count as a “click”.  Of course, we can hold it forever, and it won’t change anything or register any hold events, but it works excellent for getting single click events.

[SMcNeill]

And, I know there’s not much game to this “game”.  The main purpose here is to show folks how they can connect to my server and use it for their own games, if they don’t have a static ip, open ports, or a space PC to run 24/7 hosting one.  ;)


Looking at the data file where a few people have played already, it seems as if the file is getting corrupted with bad data.  I’ll need to do some double checking to see what/where the glitch is occurring.  Passing 3-4 records seems fine.  More than that and things get buggy internally. 

Almost there, but not quite 100% yet.  :(

[SMcNeill]

Post above has been replaced with a new version of Click It!

I completely redid the server/client communication protocol, making things much simpler and much more efficient on both ends.  (I think there was about 50 lines of code which got shortened over all.)

The file corruption with the high score lists has been corrected as well.  You guys are welcome to try it out once more, but I think things are finally working as intended with this little pet server project.

[Cobalt]

Wow, Lots faster and more streamlined! nice.

Arg in second place now! have to click more!

back in first! :D