Drawing Polygons

[Zeppelin]

Hey all,
I've been trying to make a program that can draw any polygon (pentagon, octagon, pentacontagon, etc...), although I can't get it to work.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. l = 100
3. s = 8
4.  
5. angle = (360 / s)
6. lx = (_WIDTH / 2) + ((COS(angle)) * l)
7. ly = (_HEIGHT / 2) + ((SIN(angle)) * l)
8.  
9. FOR n = 1 TO s
10.     x = (_WIDTH / 2) + ((COS(angle)) * l)
11.     y = (_HEIGHT / 2) + ((SIN(angle)) * l)
12.  
13.     LINE (lx, ly)-(x, y), _RGB(255, 255, 255)
14.  
15.     lx = x
16.     ly = y
17.  
18.     angle = (360 / s) * n
19.     PRINT angle
20. NEXT n
21.  

l is the length of each line
s is the amount of sides i want.

No matter what I do either the shape doesnt line up or it overlaps.

Thanks,
Zep

[bplus]

Man you are so close! Give me a sec...

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. l = 100
3. s = 8
4.  
5. angle = (360 / s)
6. lx = _WIDTH / 2 + COS(_D2R(angle)) * l
7. ly = _HEIGHT / 2 + SIN(_D2R(angle)) * l
8. FOR n = 0 TO s
9.  
10.     x = _WIDTH / 2 + COS(_D2R(n * angle)) * l
11.     y = _HEIGHT / 2 + SIN(_D2R(n * angle)) * l
12.  
13.     LINE (lx, ly)-(x, y), _RGB(255, 255, 255)
14.  
15.     lx = x
16.     ly = y
17.  
18.  
19.     PRINT n * angle
20. NEXT n
21.  

SIN and COS use radians not degrees 2*PI = 360 degrees, so we had to convert the angles from degree to radians
_D2R() function.

Then n*angle under SIN and COS function, you had that I think, then  to go full circle you have to do the first point again, I just start a 0 and go to n sides of poly.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. l = 100
3. FOR s = 3 TO 12
4.     CLS
5.     angle = (360 / s)
6.     lx = _WIDTH / 2 + COS(_D2R(0)) * l
7.     ly = _HEIGHT / 2 + SIN(_D2R(0)) * l
8.     FOR n = 1 TO s
9.         x = _WIDTH / 2 + COS(_D2R(n * angle)) * l
10.         y = _HEIGHT / 2 + SIN(_D2R(n * angle)) * l
11.         LINE (lx, ly)-(x, y), _RGB(255, 255, 255)
12.         lx = x
13.         ly = y
14.         PRINT n * angle
15.     NEXT n
16.     _DELAY 1
17. NEXT

[bplus]

Subtract 90 degrees in the _D2R() to get them all to start drawing (pointing North or UP):

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. l = 100
3. FOR s = 3 TO 12
4.     CLS
5.     angle = (360 / s)
6.     lx = _WIDTH / 2 + COS(_D2R(0 - 90)) * l
7.     ly = _HEIGHT / 2 + SIN(_D2R(0 - 90)) * l
8.     FOR n = 1 TO s
9.         x = _WIDTH / 2 + COS(_D2R(n * angle - 90)) * l
10.         y = _HEIGHT / 2 + SIN(_D2R(n * angle - 90)) * l
11.         LINE (lx, ly)-(x, y), _RGB(255, 255, 255)
12.         lx = x
13.         ly = y
14.         PRINT n * angle
15.     NEXT n
16.     _DELAY 1
17. NEXT
18.  

[Zeppelin]

Thanks bPlus,
It's always a small issue that underpins what could've been :D

Zep

[DANILIN]

? where are diagonals ?

 

[bplus]

Hi Danlin,

Ha! nice graphics, yours?

We leave the diagonals or chords as classic exercise with polygons along with drawing N pointed stars. :D
Oh, and twirling them as they streak across the screen... :)

https://www.google.com/search?client=opera&q=my+god+it%27s+full+of+stars&sourceid=opera&ie=UTF-8&oe=UTF-8

[DANILIN]

yes gif & youtube is my

in Russia task of connecting of vertices of polygon

this is a classical problem on loops and arrays

 

 

[bplus]

Here is a star or two to wish upon or connect :D

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Star Worlds" 'B+ 2019-11-26
3.  
4. CONST xmax = 1200, ymax = 700, nS = 500
5. TYPE starType
6.     x AS SINGLE
7.     y AS SINGLE
8.     dx AS SINGLE
9.     dy AS SINGLE
10.     ri AS SINGLE
11.     ro AS SINGLE
12.     nP AS INTEGER
13.     aOff AS SINGLE
14.     da AS SINGLE
15.     filled AS INTEGER
16.     cc AS _UNSIGNED LONG
17. END TYPE
18. DIM SHARED stars(1 TO nS) AS starType
19.  
20. RANDOMIZE TIMER
21. SCREEN _NEWIMAGE(xmax, ymax, 32)
22. _SCREENMOVE 100, 20
23. DIM i AS INTEGER
24.  
25. FOR i = 1 TO nS
26.     newStar i
27. NEXT
28. WHILE _KEYDOWN(27) = 0
29.     LINE (0, 0)-(xmax, ymax), _RGBA32(0, 0, 0, 30), BF
30.     FOR i = 1 TO nS
31.         drawStar i
32.         stars(i).x = stars(i).x + stars(i).dx: stars(i).y = stars(i).y + stars(i).dy
33.         IF stars(i).x < -50 OR stars(i).x > xmax + 50 OR stars(i).y < -50 OR stars(i).y > ymax + 50 THEN newStar i
34.         stars(i).aOff = stars(i).aOff + stars(i).da
35.     NEXT
36.     _DISPLAY
37.     _LIMIT 60
38. WEND
39.  
40. SUB newStar (i)
41.     stars(i).x = irnd%(0, xmax)
42.     stars(i).y = irnd%(0, ymax)
43.     stars(i).ri = irnd%(1, 6)
44.     stars(i).ro = stars(i).ri * (RND * 1 + 1.5)
45.     stars(i).nP = irnd%(3, 12)
46.     stars(i).aOff = RND * _PI(2)
47.     IF RND < .5 THEN stars(i).da = RND * _PI / -45 ELSE stars(i).da = RND * _PI / 45
48.     stars(i).filled = irnd%(0, 1)
49.     stars(i).dx = irnd%(-10, 10)
50.     stars(i).dy = irnd%(-10, 10)
51.     stars(i).cc = _RGBA32(irnd%(128, 255), irnd%(128, 255), irnd%(128, 255), irnd%(1, 255))
52. END SUB
53.  
54. FUNCTION irnd% (n1, n2) 'return an integer between 2 numbers
55.     DIM l%, h%
56.     IF n1 > n2 THEN l% = n2: h% = n1 ELSE l% = n1: h% = n2
57.     irnd% = INT(RND * (h% - l% + 1)) + l%
58. END FUNCTION
59.  
60. SUB fIrrPoly (arr() AS SINGLE, c AS _UNSIGNED LONG)
61.     'this just draws a bunch of triangles according to x, y points in arr()
62.     DIM ox AS SINGLE, oy AS SINGLE, i AS INTEGER
63.     ox = arr(0): oy = arr(1) 'the first 2 items in arr() need to be center
64.     FOR i = 2 TO UBOUND(arr) - 3 STEP 2
65.         ftri ox, oy, arr(i), arr(i + 1), arr(i + 2), arr(i + 3), c
66.     NEXT
67. END SUB
68.  
69. SUB drawStar (i AS INTEGER)
70.     ' x, y are same as for circle,
71.     ' rInner is center circle radius
72.     ' rOuter is the outer most point of star
73.     ' nPoints is the number of points,
74.     ' angleOffset = angle offset in radians
75.     ' this is to allow us to spin the star
76.     DIM pAngle AS SINGLE, radAngleOffset AS SINGLE, p AS INTEGER, idx AS INTEGER
77.     DIM ar(INT(stars(i).nP) * 4 + 3) AS SINGLE 'add two for origin
78.  
79.     pAngle = _PI(2) / stars(i).nP: radAngleOffset = stars(i).aOff - _PI(1 / 2)
80.     ar(0) = stars(i).x: ar(1) = stars(i).y
81.     ar(2) = stars(i).x + stars(i).ro * COS(radAngleOffset)
82.     ar(3) = stars(i).y + stars(i).ro * SIN(radAngleOffset)
83.     idx = 4
84.     FOR p = 0 TO stars(i).nP - 1
85.         ar(idx) = stars(i).x + stars(i).ri * COS(p * pAngle + radAngleOffset + .5 * pAngle)
86.         idx = idx + 1
87.         ar(idx) = stars(i).y + stars(i).ri * SIN(p * pAngle + radAngleOffset + .5 * pAngle)
88.         idx = idx + 1
89.         ar(idx) = stars(i).x + stars(i).ro * COS((p + 1) * pAngle + radAngleOffset)
90.         idx = idx + 1
91.         ar(idx) = stars(i).y + stars(i).ro * SIN((p + 1) * pAngle + radAngleOffset)
92.         idx = idx + 1
93.     NEXT
94.     IF stars(i).filled THEN
95.         fIrrPoly ar(), stars(i).cc
96.     ELSE
97.         FOR p = 2 TO stars(i).nP * 4 + 3 STEP 2
98.             IF p > 2 THEN LINE (ar(p - 2), ar(p - 1))-(ar(p), ar(p + 1)), stars(i).cc
99.         NEXT
100.     END IF
101. END SUB
102.  
103. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
104.     DIM D AS LONG
105.     STATIC a&
106.     D = _DEST
107.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
108.     _DEST a&
109.     PSET (0, 0), K
110.     _DEST D
111.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
112. END SUB
113.  
114.  

Until now, I never did get around to drawing filled polygons.

Oh! I just realized, run this long enough and all the stars will become stationary, survival of the slowest.