Flip It

[bplus]

Here’s the video where I first say the lady explaining this little exercise:

&t=381s

Oh man! my strategy for play for guaranteed win is S+0! much simpler than that (hers in the video).

I am pretty sure it will never fail PLUS it has a symmetric opposite.

[bplus]

Flip It Squared, same read, same guaranteed strategy for success when possible, only now it is symmetric 4 ways:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Flip It Squared" 'b+ started 2019-11-05
3. ' inspired by Steve's recent QB64 thread:
4. ' https://www.qb64.org/forum/index.php?topic=1831.msg110717#msg110717
5. ' from Quick Flip It experiments, add another dimemsion for complexity.
6.  
7. 'Objective: to remove all cards from board
8. 'Play: can only remove face up cards (lighter color), cards adjacent to removed card will be toggled up/down (dark/light).
9.  
10. CONST across = 10, down = 7, sqSide = 50, sqSpace = 60, marg = 30 'should be enough to get the gist of what is going on
11. CONST cardUp = &HFFBBBBBB, cardDown = &HFF000066, cardOut = &HFF000000
12. DIM SHARED xmax AS INTEGER, ymax AS INTEGER
13. xmax = across * sqSpace + 2 * marg: ymax = down * sqSpace + 2 * marg
14.  
15. DIM SHARED state(1 TO across, 1 TO down) AS INTEGER, gameover AS INTEGER, ups AS INTEGER, downs AS INTEGER
16. RANDOMIZE TIMER
17. SCREEN _NEWIMAGE(xmax, ymax, 32)
18. _SCREENMOVE 300, 100
19. RANDOMIZE TIMER
20. DIM r AS INTEGER, c AS INTEGER
21. gameover = 1
22. WHILE _KEYDOWN(27) = 0
23.     IF gameover THEN initRound
24.     c = 0: r = 0
25.     getCardClicked c, r 'this card is removed and cards adjacent (if any) are toggled up/down
26.     IF c > 0 AND r > 0 THEN
27.         LOCATE 1, 1: PRINT c, r
28.         IF state(c, r) = 1 THEN
29.             IF c > 1 THEN
30.                 IF state(c - 1, r) <> -1 THEN state(c - 1, r) = 1 - state(c - 1, r)
31.             END IF
32.             IF c < across THEN
33.                 IF state(c + 1, r) <> -1 THEN state(c + 1, r) = 1 - state(c + 1, r)
34.             END IF
35.             IF r > 1 THEN
36.                 IF state(c, r - 1) <> -1 THEN state(c, r - 1) = 1 - state(c, r - 1)
37.             END IF
38.             IF r < down THEN
39.                 IF state(c, r + 1) <> -1 THEN state(c, r + 1) = 1 - state(c, r + 1)
40.             END IF
41.             state(c, r) = -1
42.         END IF
43.     END IF
44.     updateScreen
45.     _DISPLAY
46.     _LIMIT 60
47. WEND
48.  
49. SUB getCardClicked (col AS INTEGER, row AS INTEGER)
50.     DIM mb AS INTEGER, m AS INTEGER, mx AS INTEGER, my AS INTEGER
51.     WHILE _MOUSEINPUT: WEND
52.     mb = _MOUSEBUTTON(1) '            left button down
53.     IF mb THEN '                      get last place mouse button was down
54.         WHILE mb '                    wait for mouse button release as a "click"
55.             m = _MOUSEINPUT: mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
56.         WEND
57.         FOR row = 1 TO down
58.             FOR col = 1 TO across
59.                 IF mx > (col - 1) * sqSpace + marg AND mx < (col - 1) * sqSpace + marg + sqSide THEN
60.                     IF my > (row - 1) * sqSpace + marg AND my < (row - 1) * sqSpace + marg + sqSide THEN
61.                         EXIT SUB 'found it
62.                     END IF
63.                 END IF
64.             NEXT
65.         NEXT
66.         col = 0: row = 0
67.     END IF
68. END FUNCTION
69.  
70. SUB updateScreen 'and count the ups and downs of cards
71.     DIM ups AS INTEGER, downs AS INTEGER, y AS INTEGER, x AS INTEGER, clr~&
72.     CLS
73.     ups = 0: downs = 0 'count cards while displaying
74.     FOR y = 1 TO down
75.         FOR x = 1 TO across
76.             IF state(x, y) = 1 THEN
77.                 ups = ups + 1: clr~& = cardUp
78.             ELSEIF state(x, y) = 0 THEN
79.                 downs = downs + 1: clr~& = cardDown
80.             ELSEIF state(x, y) = -1 THEN
81.                 clr~& = cardOut
82.             END IF
83.             LINE ((x - 1) * sqSpace + marg, (y - 1) * sqSpace + marg)-STEP(sqSide, sqSide), clr~&, BF
84.         NEXT
85.     NEXT
86.     yCP 10, SPACE$(60): yCP 10, "Ups, Downs: " + TS$(ups) + ", " + TS$(downs)
87.     'check win
88.     IF ups = 0 THEN
89.         gameover = 1
90.         IF downs > 0 THEN
91.             yCP 10, SPACE$(60): yCP 10, "No win"
92.         ELSE
93.             yCP 10, SPACE$(60): yCP 10, "Win"
94.         END IF
95.         _DISPLAY: SLEEP 5
96.     END IF
97. END SUB
98.  
99. SUB initRound 'reassign letters and hide them all
100.     DIM x AS INTEGER, y AS INTEGER
101.     FOR y = 1 TO down
102.         FOR x = 1 TO across
103.             IF RND < .5 THEN state(x, y) = 1 ELSE state(x, y) = 0
104.         NEXT
105.     NEXT
106.     gameover = 0: updateScreen
107. END SUB
108.  
109. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
110.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
111. END SUB
112.  
113. FUNCTION TS$ (n AS INTEGER)
114.     TS$ = _TRIM$(STR$(n))
115. END FUNCTION
116.  
117.