_PRINTSTRING For INPUT

[Zeppelin]

Hey,
Is there a command like _PRINTSTRING that allows coordinate placement of text but for INPUT?
I am aware of LOCATE, but it doesnt use screen coordinates. If there isnt a way to do this, is there a way to convert LOCATE coords to _PRINTSCREEN coords?

Thanks,
Zep

[FellippeHeitor]

LOCATE row, col: PRINT text$ 'is the same as
_PRINTSTRING (col * _FONTWIDTH - _FONTWIDTH, row * _FONTHEIGHT - _FONTHEIGHT), text$ 'provided you’re using a fixed-width font

I just don’t know if INPUT will continue from the last _PRINTSTRING coordinates. You’ll have to try it out. (I have a hunch it won’t).

[TempodiBasic]

Hi Zeppelin
...about use of INPUT
I find INPUT treacherouse!

Why? Because
1. when you use INPUT your control of flow of program is suspended
2. if you press RETURN key the output text is a new line... so how do you have control of the output in your program interface?
3. if you, user of the program, give the erroneous input type , INPUT goes ahead asking again input from user... also this is out of control and creates problems with your interface of program
IMHO
so  INPUT is good only for programs with text line of output i.e. the command line of old OSes
It seems that you have to use INPUT in a graphic interface... evaluate your conditions

[SMcNeill]

You might want to check out Terry Ritchie’s Input library.  It has graphic coordinate input in it,

[TempodiBasic]

Hi again
here an example of a new INPUT function in graphic mode 32 bit

Code: QB64: [Select]

1. REM a function alternative to old INPUT of QBasic
2. REM this function
3. REM              must return the type of data of request   -->not yet implemented
4. REM          for now user gets back a string to be converted to desidered data type
5. REM          for now programmer can define desidered input with Krange string
6. REM              must accept the  range of key interesting for input
7. REM              must permit to correct the input of user before to press Return
8. REM              must control the max input keys
9. REM              ends to input after return key is pressed
10.  
11. SCREEN _NEWIMAGE(800, 600, 32)
12. _PRINTSTRING (100, 100), "What is your age?"
13. result$ = __NewInput$("I", "0123456789", 4, 100, 200, _RGBA32(200, 200, 10, 255), _RGBA(0, 10, 100, 255))
14. _PRINTSTRING (100, 300), "Your age is " + result$
15.  
16. END
17.  
18. FUNCTION __NewInput$ (Dtype AS STRING, Krange AS STRING, Kmax AS INTEGER, Xinp AS INTEGER, Yinp AS INTEGER, Forecol AS _UNSIGNED LONG, Backcol AS _UNSIGNED LONG)
19.     CONST Back = 8, Enter = 13, Del = 21248, Right = 19712, Left = 19200
20.     DIM temp$, InK AS SINGLE, Xpos AS SINGLE, Mcol AS _UNSIGNED LONG
21.     temp$ = "": InK = 0: Xpos = 0: Mcol = INT(Forecol + Backcol / 2)
22.     COLOR Forecol, Backcol
23.     DO
24.         _LIMIT 30
25.         InK = _KEYHIT
26.         IF InK < 256 AND InK > 13 THEN
27.             ' is a character to get?
28.             IF INSTR(Krange, CHR$(InK)) AND LEN(temp$) < Kmax THEN
29.                 ' is a charachter of interest to get?
30.                 temp$ = temp$ + CHR$(InK)
31.                 Xpos = LEN(temp$)
32.             END IF
33.         ELSE
34.             ' backspace
35.             IF InK = 8 THEN temp$ = LEFT$(temp$, Xpos - 2) + RIGHT$(temp$, LEN(temp$) - Xpos + 1): Xpos = Xpos - 1: IF Xpos < 0 THEN Xpos = 1
36.             ' right arrow
37.             IF InK = Right THEN IF Xpos < LEN(temp$) THEN Xpos = Xpos + 1
38.             ' left arrow
39.             IF InK = Left THEN IF Xpos > 1 THEN Xpos = Xpos - 1
40.             'Delete
41.             IF InK = Del THEN
42.                 IF Xpos <= LEN(temp$) THEN temp$ = LEFT$(temp$, Xpos - 1) + RIGHT$(temp$, LEN(temp$) - Xpos)
43.             END IF
44.         END IF
45.         ' output for feedback to user
46.         _PRINTSTRING (Xinp, Yinp), SPACE$(LEN(temp$) + 1)
47.         _PRINTSTRING (Xinp, Yinp), temp$
48.         ' output of cursor's position
49.         COLOR Mcol
50.         _PRINTSTRING (Xinp + (Xpos * _FONTWIDTH - _FONTWIDTH), Yinp), MID$(temp$, Xpos, 1)
51.         COLOR Forecol
52.     LOOP UNTIL InK = Enter AND LEN(temp$) <= Kmax
53.     __NewInput$ = temp$
54. END FUNCTION

I'ld see the function of Terry's Input library.. I'll search it.

[bplus]

Yeah, I've done this for different Basic's, here is a quicky I wrote up this morning for QB64, I see TempodiBasic has already posted one ;-)

Code: QB64: [Select]

1. _TITLE "Graphics Input, inputG test" 'b+ 2019-11-01
2. SCREEN _NEWIMAGE(800, 600, 32)
3. _SCREENMOVE 300, 20
4. y = 200: x = 100
5. DO
6.     P$ = "Enter something like *testing 1, 2, 3... * about 20 chars max > "
7.     expectedEnterLen% = 20
8.     inputG x, y, P$, inpt$, expectedEnterLen%
9.     IF inpt$ = "" THEN EXIT DO
10.     PRINT "You entered: "; inpt$
11.     y = y + 25
12.     x = x + 30
13.     IF x + (LEN(P$) + expectedEnterLen% + 5) * 8 > _WIDTH THEN x = 1
14. LOOP
15. PRINT "Test is done when empty string returned by inputG."
16.  
17. 'INPUT for Graphics screen
18. SUB inputG (x, y, prmpt$, var$, expectedLenVar%) 'input for a graphics screen x, y is where the prompt will start , returns through var$
19.     DIM tmp$, k$
20.     saveAD = _AUTODISPLAY
21.     _KEYCLEAR
22.     _PRINTSTRING (x, y), prmpt$ + " {}"
23.     DO
24.         k$ = INKEY$
25.         IF LEN(k$) THEN
26.             SELECT CASE ASC(k$)
27.                 CASE 13: var$ = tmp$: EXIT SUB
28.                 CASE 27: var$ = "": EXIT SUB
29.                 CASE 8 'backspace
30.                     IF LEN(tmp$) THEN
31.                         IF LEN(tmp$) = 1 THEN tmp$ = "" ELSE tmp$ = LEFT$(tmp$, LEN(tmp$) - 1)
32.                     END IF
33.                 CASE ELSE: tmp$ = tmp$ + k$
34.             END SELECT
35.             _PRINTSTRING (x, y), prmpt$ + " {" + tmp$ + "}" + SPACE$(expectedLenVar% - LEN(tmp$)) 'spaces needed at end to clear backspace chars
36.             IF saveAD <> -1 THEN _DISPLAY
37.         END IF
38.     LOOP
39. END SUB
40.  
41.  

You can modify for your needs eg adding colors and anticolors in user input section,
but this demos the general idea of doing this and should serve basic needs.