Author Topic: Explore the world of Alefgard! and talk to some people! (Read 5735 times)

Cobalt · « **on:** October 16, 2019, 07:40:12 pm »

You can move all about the map, enter Towns, the Castle, and Caves(which are all lit at this time) to enter caves or use stairs press SpaceBar, select STAIRS then press SpaceBar again. Enter will cancel the Command window. There is an option to see the controls, but they are not customize-able while running yet. Just hit ESC to quit(after startup menu). The message handler is a bit buggy right now, But for the most part it works to this point, and you can enjoy the 8 bit style background music and sound effects(bump into a wall ,stairs)!
Tested on 1.3 build from 4/2019, working.
Be sure to download the MFI(Multi-File Index) resource file from below. Easier than having to download over a dozen or so files.

Code: QB64: [Select]

TYPE Player
 Nam AS STRING * 8 '24 'eventually
 HP AS _UNSIGNED _BYTE
 Max_HP AS _UNSIGNED _BYTE
 MP AS _UNSIGNED _BYTE
 Max_MP AS _UNSIGNED _BYTE
 Pack AS STRING * 32 '_MEM
 Items AS _BYTE 'items in pack
 Armor AS _BYTE
 Weapon AS _BYTE
 Shield AS _BYTE
 Gold AS _UNSIGNED INTEGER
 Exp AS _UNSIGNED INTEGER
 Age AS _BYTE 'as player gains experiance levels they age, age negativliy affects stats.
 Strength AS _BYTE
 Agility AS _BYTE
 Luck AS _BYTE
 Level AS _BYTE
 Spells AS INTEGER
 WorldX AS _BYTE 'players location in over world
 WorldY AS _BYTE
 MapX AS _BYTE 'players location in a castle\town or cave\temple
 MapY AS _BYTE
 Map AS _BYTE 'where is player? -1 to 27 (-1 = over world map)
 Facing AS _BYTE
 Has_Princess AS _BYTE 'is player carring Princess?
END TYPE
 
TYPE Monsters
 Nam AS STRING * 16
 Strength AS _UNSIGNED _BYTE
 Agility AS _UNSIGNED _BYTE
 Hp AS _UNSIGNED _BYTE
 Max_Hp AS _UNSIGNED _BYTE
 Mp AS _UNSIGNED _BYTE
 Max_Mp AS _UNSIGNED _BYTE
 SlpResist AS _UNSIGNED _BYTE
 StpSplResist AS _UNSIGNED _BYTE
 HurtResist AS _UNSIGNED _BYTE
 Evasion AS _UNSIGNED _BYTE
 Exp AS _UNSIGNED _BYTE
 Gold AS _UNSIGNED _BYTE
 Attk1 AS _BYTE 'special attack 1 - these are additional options to normal physical attack
 Attk1Prob AS _UNSIGNED _BYTE
 Attk2 AS _BYTE 'special attack 2
 Attk2Prob AS _UNSIGNED _BYTE
 Group AS _BYTE
END TYPE
 
TYPE Items
 Nam AS STRING * 16
 Valu AS INTEGER
 Power AS _BYTE
END TYPE
 
TYPE Tiles
 Sprite_ID AS _BYTE 'sprite used on tile
 Is_Town AS _BYTE 'Town ID/Castle ID
 Is_Cave AS _BYTE 'Cave ID
 Is_Stairs AS _BYTE 'Stairs ID
 Territory AS _BYTE 'Monster selection ID, determines which monster are picked for battle
 Encounter_rate AS _UNSIGNED _BYTE 'odds of engaging a monster
 Has_Special AS _BYTE 'does search find something here or is special battle here
END TYPE
 
TYPE Tiles_B
 Sprite_ID AS _BYTE 'sprite used on tile
 Is_Stairs AS _BYTE 'Where Stairs lead(ID)
 Territory AS _BYTE 'Monster selection ID, determines which monster are picked for battle
 Is_Exit AS _BYTE 'does tile lead out of castle or town
 Encounter_rate AS _UNSIGNED _BYTE 'odds of engaging a monster
 Has_Special AS _BYTE 'does search find something here or is special battle here
END TYPE
 
TYPE Place_Data
 Start_X AS _BYTE 'when Entering where do you start.
 Start_Y AS _BYTE '
 Is_Lit AS _BYTE 'is a Torch or Radiant needed to see?
END TYPE
 
TYPE Stair_Data
 Map AS _BYTE 'where is the stairs
 X AS _BYTE 'stairs position
 Y AS _BYTE
 Direction AS _BYTE 'going up or down
 Link AS _BYTE 'links to which other stairs
END TYPE
 
TYPE Treasure_Chest
 Map AS _BYTE
 X AS _BYTE
 Y AS _BYTE
 Treasure AS _BYTE
 Count AS INTEGER
END TYPE
 
TYPE Non_Playable_Character
 Sprite_ID AS _BYTE
 X AS _BYTE 'NPCs location
 Y AS _BYTE
 Map AS _BYTE 'Which town\castle\cave do they live in
 Facing AS _BYTE
 Lines AS _BYTE 'What lines do they say
 Flags AS _BYTE 'used if they change what they say over time
 Can_Move AS _BYTE
 Moving AS _BYTE
 MX AS _BYTE
 MY AS _BYTE
END TYPE
 
TYPE GameData
 Y AS _BYTE
 X AS _BYTE
 Flag AS _BYTE
 JustLeft AS _BYTE 'if player just left town\castle don't reprocess location
 In_Place AS _BYTE 'player is in a town\castle
 LastMove AS LONG 'timer, if player doesn't press any keys his current stats display
 Menu AS _BYTE 'does player have the menu up?
 Selection AS _BYTE 'what selection did player make from menu
 Message AS INTEGER 'current message
 Input_Wait AS _BYTE 'waiting for player input, after message display
 Action AS _BYTE 'what action is player currently performing?(talk,search,stair,take,door,spell,item)
 Lite_Level AS _BYTE 'how much light is there 0-none, 1-torch 2&3-Radiant
 Display_Status AS _BYTE
 Talk_To AS _BYTE 'who is the player talking to?
 Current_BGM AS _BYTE 'which music is currently in background
 f AS INTEGER
 YES_NO_Input AS _BYTE
END TYPE
 
TYPE Cords
 X AS _BYTE
 Y AS _BYTE
END TYPE
 
TYPE Flags
 Has_Left_Throne_Room AS _BYTE 'set when Player first leave thrown room after starting game.
 Just_Started AS _BYTE 'Set when player first starts game
 Message_Displaying AS _BYTE
END TYPE
 
CONST TRUE = -1, FALSE = NOT TRUE
CONST DOWN = 0, LEFT = 1, UP = 2, RIGHT = 3
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST A_Button = 32, B_Button = 13, Start_Button = 65, Select_Button = 66
CONST MoveDown = 1, MoveLeft = 2, MoveUp = 3, MoveRight = 4
CONST Talking = 1, Stairs = 2, Searching = 3, Spells = 4, Items = 5, Doors = 6, Taking = 7
 
DIM SHARED P(3) AS Player, G AS GameData, F AS Flags
DIM SHARED I(127) AS Items
DIM SHARED L(30) AS _UNSIGNED INTEGER
DIM SHARED M(64) AS Monsters, GF(5) AS SINGLE
DIM SHARED World(127, 127) AS Tiles
DIM SHARED Place(27, 45, 45) AS Tiles_B, PD(-1 TO 27) AS Place_Data, Stairs(127) AS Stair_Data
DIM SHARED Chest(127) AS Treasure_Chest, NPC(127) AS Non_Playable_Character, Script(360) AS STRING
DIM SHARED Lines(127, 8, 8) AS INTEGER 'dialog for NPCs
DIM SHARED SA(10) AS Cords, Frames%
DIM SHARED Layer(32) AS LONG, DWFont AS LONG, Frame%%, SFX(32) AS LONG, BGM(-1 TO 27) AS LONG
DIM SHARED ClearLayerMaster AS _MEM
 
T& = _FREETIMER
T1& = _FREETIMER
ON TIMER(T&, .25) Frame_Change
ON TIMER(T1&, 1) FPS
SCREEN _NEWIMAGE(640, 480, 32): RANDOMIZE TIMER
 
MFI_Loader "DragonW.MFI"
'selection arrows for command window
DATA 13,4,13,6,13,8,13,10,21,4,21,6,21,8,21,10,0,0,0,0
FOR i%% = 1 TO 10
 READ SA(i%%).X, SA(i%%).Y
NEXT i%%
'-----------------------------------
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(640, 480, 32)
Layer(2) = _NEWIMAGE(255 * 32, 255 * 32, 32) 'world map
'Layer(3) = _LOADIMAGE("tilebase2.bmp", 32)
'Layer(4) = _LOADIMAGE("characters.bmp", 32)
Layer(5) = _NEWIMAGE(640, 480, 32)
Layer(6) = _NEWIMAGE(640, 128, 32) 'temp layer to scroll text
Layer(7) = _NEWIMAGE(46 * 32, 46 * 32, 32) 'map layer
Layer(8) = _NEWIMAGE(46 * 32, 46 * 32, 32) 'NPC sprite layer
Layer(9) = _NEWIMAGE(640, 480, 32) 'debug info layer
'Layer(10) = _LOADIMAGE("controller.bmp", 32)
Layer(11) = _NEWIMAGE(640, 480, 32) 'light mask for underground
Layer(12) = _NEWIMAGE(46 * 32, 46 * 32, 32) 'NPC sprite Clear layer
 
'DWFont = _LOADFONT("DW1.ttf", 16, "Monospace")
_CLEARCOLOR _RGB32(0, 128, 128), Layer(4)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(12)
ClearLayerMaster = _MEMIMAGE(Layer(12))
 
_FONT DWFont, Layer(1)
_FONT DWFont, Layer(5)
 
DO
LOCATE 1, 1: PRINT "Make a Choice"
PRINT "1- See Controls"
PRINT "2- Explore world"
R% = _KEYHIT
IF R% = 49 THEN CLS: _KEYCLEAR: Control_setup: SLEEP: CLS
_DELAY .1
LOOP UNTIL R% = 50
CLS
PRINT "Building world..."
 
Init_Player 0
P(0).Nam = "Newton"
Build_World_Layer Layer(2)
Build_Place_Layer Layer(7), P(0).Map
 
 
CLS
TIMER(T&) ON
who%% = 0
'G.Input_Wait = TRUE
'F.Just_Started = TRUE
 
G.LastMove = INT(TIMER + .49)
BGM(13) = BGM(3)
BGM(5) = BGM(3)
BGM(20) = BGM(3)
BGM(25) = BGM(3)
_SNDVOL BGM(-1), .09
_SNDVOL BGM(0), .09
_SNDVOL BGM(1), .09
_SNDVOL BGM(3), .09
'_SNDVOL BGM(13), .09
_SNDVOL SFX(0), .33
_SNDVOL SFX(1), .33
_SNDVOL SFX(2), .33
_SNDVOL SFX(3), .33
Change_BGM 0
TIMER(T1&) ON
 
DO
 IF P(0).Map >= 0 THEN L%% = 7: PMX%% = P(0).MapX: PMY%% = P(0).MapY ELSE L%% = 2: PMX%% = P(0).WorldX: PMY%% = P(0).WorldY
 
 IF NOT F.Message_Displaying THEN Result%% = Controls(0)
 IF Result%% = TRUE THEN ExitFlag%% = TRUE
 IF G.Flag THEN Move_Cycle 0
 
 Copy_Map_Layer Layer(L%%), PMX%% + WX%%, PMY%% + WY%%
 Draw_NPC_Sprites 0, 117, Layer(8)
 
 Copy_NPC_Layer Layer(8), PMX%% + WX%%, PMY%% + WY%%
 
 Draw_Player_Sprite 0, Layer(1)
 
 IF INT(TIMER) > G.LastMove + 1 THEN Draw_Stat_Window Layer(1), 0
 IF G.Menu THEN Draw_Command_Window Layer(1)
 IF G.Message THEN Draw_Info_Window Layer(1): Message_Handler Layer(5), ""
 IF G.Display_Status THEN Display_Player_Status Layer(5)
 ' IF G.Action = Talking THEN TalktoNPC G.Talk_To
 
 Debuginfo
 
 _PUTIMAGE , Layer(5), Layer(1)
 _PUTIMAGE , Layer(9), Layer(1)
 _PUTIMAGE , Layer(1), Layer(0)
 '_DELAY .124
 Process_NPC
 _LIMIT 60
 Frames% = Frames% + 1
LOOP UNTIL ExitFlag%% 'INKEY$ = CHR$(27)
 
TIMER(T&) OFF
TIMER(T1&) OFF
 
_SNDSTOP BGM(G.Current_BGM)
 
SUB FPS
 G.f = Frames%
 Frames% = 0
END SUB
 
SUB Process_NPC
 FOR i%% = 0 TO 120
  IF NPC(i%%).Can_Move THEN 'only move NPC that are not stationary
   IF NPC(i%%).Moving THEN NPC_Move_Cycle i%%
 
   IF Chance > 250 AND NPC(i%%).Moving = 0 THEN 'start the NPC moving
    SELECT CASE NPC(i%%).Facing 'make sure NPC can move that direction
     CASE UP
      Blocked%% = NPC_Collision(i%%, 0, -1)
     CASE DOWN
      Blocked%% = NPC_Collision(i%%, 0, 1)
     CASE LEFT
      Blocked%% = NPC_Collision(i%%, -1, 0)
     CASE RIGHT
      Blocked%% = NPC_Collision(i%%, 1, 0)
    END SELECT
    IF NOT Blocked%% THEN NPC_Move_Cycle i%%
   END IF
 
   IF Chance < 3 AND NPC(i%%).Moving = 0 THEN Turn_NPC i%%
  END IF
  IF NPC(i%%).X = 0 THEN i%% = 122 'reached the end of NPC list
 NEXT i%%
END SUB
 
SUB NPC_Move_Cycle (who%%)
 NPC(who%%).Moving = NPC(who%%).Moving + 2
 IF NPC(who%%).Moving = 32 THEN Move_NPC who%%: NPC(who%%).Moving = 0
 SELECT CASE NPC(who%%).Facing
  CASE UP
   NPC(who%%).MY = -NPC(who%%).Moving
  CASE RIGHT
   NPC(who%%).MX = NPC(who%%).Moving
  CASE LEFT
   NPC(who%%).MX = -NPC(who%%).Moving
  CASE DOWN
   NPC(who%%).MY = NPC(who%%).Moving
 END SELECT
END SUB
 
SUB Move_NPC (who%%)
 SELECT CASE NPC(who%%).Facing
  CASE UP
   NPC(who%%).Y = NPC(who%%).Y - 1
  CASE DOWN
   NPC(who%%).Y = NPC(who%%).Y + 1
  CASE LEFT
   NPC(who%%).X = NPC(who%%).X - 1
  CASE RIGHT
   NPC(who%%).X = NPC(who%%).X + 1
 END SELECT
END SUB
 
SUB Turn_NPC (who%%)
 T~%% = Chance
 SELECT CASE T~%%
  CASE 0 TO 63
   NPC(who%%).Facing = UP
  CASE 64 TO 127
   NPC(who%%).Facing = DOWN
  CASE 128 TO 191
   NPC(who%%).Facing = LEFT
  CASE 192 TO 255
   NPC(who%%).Facing = RIGHT
 END SELECT
END SUB
 
FUNCTION NPC_Collision%% (Who%%, X%%, Y%%)
 Result%% = TRUE
 SELECT CASE Place(NPC(Who%%).Map, NPC(Who%%).X + X%%, NPC(Who%%).Y + Y%%).Sprite_ID
  CASE 0 TO 13
   Result%% = FALSE
 END SELECT
 'dont let NPC leave map
 IF Place(NPC(Who%%).Map, NPC(Who%%).X + X%%, NPC(Who%%).Y + Y%%).Is_Exit THEN Result%% = TRUE
 IF NOT Result%% THEN 'check for NPC collision
  FOR i%% = 0 TO 120 '<--update when actual NPC count is known
   IF NPC(Who%%).X + X%% = NPC(i%%).X AND NPC(Who%%).Y + Y%% = NPC(i%%).Y AND NPC(Who%%).Map = NPC(i%%).Map THEN
    Result%% = TRUE: i%% = 122
   END IF
   IF NPC(i%%).X = 0 THEN i%% = 122 'no NPC can occupy a 0 location so we know we are past the last NPC
  NEXT i%%
 END IF
 
 IF NOT Result%% THEN 'check for collision with player
  IF NPC(Who%%).X + X%% = P(0).MapX AND NPC(Who%%).Y + Y%% = P(0).MapY AND NPC(Who%%).Map = P(0).Map THEN Result%% = TRUE
 END IF
 
 NPC_Collision = Result%%
END FUNCTION
 
 
 
SUB Process_Command
 SELECT CASE G.Selection
  CASE 1 'talk
   Run_Talk
  CASE 2 'Status
   Run_Status
  CASE 3 'Stairs
   Run_Stairs
  CASE 4 'search
   Run_search
  CASE 5 'spell
   Run_Spell
  CASE 6 'Items
   Run_Item
  CASE 7 'Door
   Run_Door
  CASE 8 'take(chest)
   Run_Take
 END SELECT
END SUB
 
SUB Run_Talk
 Who%% = Find_NPC(P(0).Facing)
 IF Who%% = -1 THEN
  G.Message = 15
 ELSE
  G.Message = Lines(Who%%, 0, 1)
  IF G.Message = 0 THEN G.Message = 360
 END IF
 G.Action = FALSE
END SUB
 
SUB Run_Status
 G.Display_Status = TRUE
 G.Input_Wait = TRUE
END SUB
 
SUB Run_search
 STATIC dialog AS _BYTE
 IF dialog = 1 THEN G.Message = 238: G.Action = FALSE: dialog = 0
 IF dialog = 0 THEN G.Message = 237: dialog = dialog + 1
END SUB
 
SUB Run_Spell
 G.Message = 48
END SUB
 
SUB Run_Item
 G.Message = 60
END SUB
 
SUB Run_Door
 G.Message = 311 'no door
 'g.message = 312 'no keys
END SUB
 
SUB Run_Take
 G.Message = 242
END SUB
 
 
SUB Run_Stairs
 IF P(who%%).Map >= 0 THEN
  IF Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Stairs THEN
   IF NOT F.Has_Left_Throne_Room THEN F.Has_Left_Throne_Room = TRUE 'if player has just started game
 
   IF Stairs(Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Stairs).Direction = 1 THEN _SNDPLAY SFX(1) ELSE _SNDPLAY SFX(2)
   P(who%%).Map = Stairs(Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Stairs).Link
   'get location information from the linked stair Record.
   P(who%%).MapX = Stairs(P(who%%).Map).X
   P(who%%).MapY = Stairs(P(who%%).Map).Y
   IF Stairs(P(who%%).Map).Map = -1 THEN P(who%%).WorldX = Stairs(P(who%%).Map).X: P(who%%).WorldY = Stairs(P(who%%).Map).Y
   P(who%%).Map = Stairs(P(who%%).Map).Map
   IF P(who%%).Map >= 0 THEN Build_Place_Layer Layer(7), P(who%%).Map
   Change_BGM 0
   G.Menu = FALSE
  ELSE
   G.Message = 13
  END IF
 ELSE
  IF World(P(who%%).WorldX, P(who%%).WorldY).Is_Stairs THEN
   IF Stairs(World(P(who%%).WorldX, P(who%%).WorldY).Is_Stairs).Direction = 1 THEN _SNDPLAY SFX(1) ELSE _SNDPLAY SFX(2)
   P(who%%).Map = Stairs(World(P(who%%).WorldX, P(who%%).WorldY).Is_Stairs).Link
   'get location information from the linked stair Record.
   P(who%%).MapX = Stairs(P(who%%).Map).X
   P(who%%).MapY = Stairs(P(who%%).Map).Y
   P(who%%).Map = Stairs(P(who%%).Map).Map
   Build_Place_Layer Layer(7), P(who%%).Map
   G.Menu = FALSE
   Change_BGM 0
  ELSE
   G.Message = 13
  END IF
 END IF
END SUB
 
 
SUB Check_Location_World (who%%)
 
 IF World(P(who%%).WorldX, P(who%%).WorldY).Is_Town AND G.In_Place = FALSE THEN
  P(who%%).Map = World(P(who%%).WorldX, P(who%%).WorldY).Is_Town
  IF P(who%%).Map = 1 THEN P(who%%).Map = 0
  P(who%%).MapX = PD(P(who%%).Map).Start_X
  P(who%%).MapY = PD(P(who%%).Map).Start_Y
  Build_Place_Layer Layer(7), P(who%%).Map
  Change_BGM 0
  G.In_Place = TRUE
 END IF
 
 IF World(P(who%%).WorldX, P(who%%).WorldY).Sprite_ID = 5 THEN _DELAY .05 'slow movement when crossing hills
 
 ' IF World(P(who%%).WorldX, P(who%%).WorldY).Is_Cave THEN P(who%%).Map = World(P(who%%).WorldX, P(who%%).WorldY).Is_Town
END SUB
 
SUB Check_Location_Place (who%%)
 IF Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Exit THEN P(who%%).Map = -1: G.JustLeft = TRUE: Change_BGM 0
END SUB
 
SUB Move_Cycle (Who%%)
 STATIC Move AS _BYTE
 Move = Move + 2
 IF Move = 32 THEN Move = 0: G.Flag = FALSE
 IF Move = 30 THEN Move_Player Who%%
 SELECT CASE P(Who%%).Facing
  CASE UP
   G.Y = -Move
  CASE RIGHT
   G.X = Move
  CASE LEFT
   G.X = -Move
  CASE DOWN
   G.Y = Move
 END SELECT
END SUB
 
SUB Move_Player (who%%)
 IF P(who%%).Map >= 0 THEN
  SELECT CASE P(who%%).Facing
   CASE UP
    P(who%%).MapY = P(who%%).MapY - 1
   CASE DOWN
    P(who%%).MapY = P(who%%).MapY + 1
   CASE LEFT
    P(who%%).MapX = P(who%%).MapX - 1
   CASE RIGHT
    P(who%%).MapX = P(who%%).MapX + 1
  END SELECT
  Check_Location_Place who%%
 ELSE
  SELECT CASE P(who%%).Facing
   CASE UP
    P(who%%).WorldY = P(who%%).WorldY - 1
   CASE DOWN
    P(who%%).WorldY = P(who%%).WorldY + 1
   CASE LEFT
    P(who%%).WorldX = P(who%%).WorldX - 1
   CASE RIGHT
    P(who%%).WorldX = P(who%%).WorldX + 1
  END SELECT
  IF G.JustLeft THEN G.JustLeft = FALSE
  IF G.In_Place THEN G.In_Place = FALSE
  Check_Location_World who%%
 END IF
END SUB
 
FUNCTION Controls%% (who%%)
 STATIC Move_delay AS SINGLE
 Result%% = FALSE
 KBD& = _KEYHIT
 
 IF G.Menu = FALSE THEN
  IF G.Selection <> 1 THEN G.Selection = 1
  IF _KEYDOWN(Key_Right) AND (NOT G.Flag) THEN
   G.LastMove = INT(TIMER + .49)
   IF P(who%%).Facing <> RIGHT THEN P(who%%).Facing = RIGHT
   IF Move_delay = 0 THEN
    Move_delay = TIMER
   ELSEIF TIMER > Move_delay + .125 THEN
    IF NOT Collision(who%%, 1, 0) THEN G.Flag = TRUE
   END IF
  END IF
  IF _KEYDOWN(Key_Left) AND (NOT G.Flag) THEN
   G.LastMove = INT(TIMER + .49)
   IF P(who%%).Facing <> LEFT THEN P(who%%).Facing = LEFT
   IF Move_delay = 0 THEN
    Move_delay = TIMER
   ELSEIF TIMER > Move_delay + .125 THEN
    IF NOT Collision(who%%, -1, 0) THEN G.Flag = TRUE
   END IF
  END IF
  IF _KEYDOWN(Key_Up) AND (NOT G.Flag) THEN
   G.LastMove = INT(TIMER + .49)
   IF P(who%%).Facing <> UP THEN P(who%%).Facing = UP
   IF Move_delay = 0 THEN
    Move_delay = TIMER
   ELSEIF TIMER > Move_delay + .125 THEN
    IF NOT Collision(who%%, 0, -1) THEN G.Flag = TRUE
   END IF
  END IF
  IF _KEYDOWN(Key_Down) AND (NOT G.Flag) THEN
   G.LastMove = INT(TIMER + .49)
   IF P(who%%).Facing <> DOWN THEN P(who%%).Facing = DOWN
   IF Move_delay = 0 THEN
    Move_delay = TIMER
   ELSEIF TIMER > Move_delay + .125 THEN
    IF NOT Collision(who%%, 0, 1) THEN G.Flag = TRUE
   END IF
  END IF
 
  IF KBD& = A_Button THEN G.Menu = TRUE: G.LastMove = G.LastMove - 2
  IF (NOT _KEYDOWN(Key_Right)) AND (NOT _KEYDOWN(Key_Left)) AND (NOT _KEYDOWN(Key_Down)) AND (NOT _KEYDOWN(Key_Up)) THEN Move_delay = 0
 
 ELSEIF G.Input_Wait THEN
 
  IF KBD& = B_Button OR KBD& = A_Button THEN
   G.Menu = FALSE: G.Input_Wait = FALSE: G.Message = 0: ClearLayer Layer(5): _CLEARCOLOR _RGB32(0, 0, 0), Layer(5)
   IF G.Display_Status THEN G.Display_Status = FALSE
  END IF
 ELSE
  IF KBD& = Key_Up AND G.Selection > 1 AND G.Selection <> 5 THEN G.Selection = G.Selection - 1
  IF KBD& = Key_Down AND G.Selection < 8 AND G.Selection <> 4 THEN G.Selection = G.Selection + 1
  IF KBD& = Key_Left AND G.Selection > 4 THEN G.Selection = G.Selection - 4
  IF KBD& = Key_Right AND G.Selection < 5 THEN G.Selection = G.Selection + 4
 
  IF KBD& = B_Button THEN G.Menu = FALSE
  IF KBD& = A_Button THEN Process_Command
 END IF
 
 IF KBD& = 27 THEN Result%% = TRUE
 
 Controls = Result%%
END FUNCTION
 
 
 
SUB Init_Player (Who%%)
 '---------------Player starting stats-----------------------
 P(Who%%).Max_HP = INT(RND * 8) + 12 'start 12-20hp
 P(Who%%).HP = P(Who%%).Max_HP
 IF INT(RND * 100) = 95 THEN P(Who%%).Max_MP = INT(RND * 3) + 4 '1 in 100 chance of starting with magical powers
 P(Who%%).MP = P(Who%%).Max_MP
 P(Who%%).Strength = INT(RND * 3) + 2 'determines base attack damage
 P(Who%%).Agility = INT(RND * 2) + 2 'determines base defence\evasion
 P(Who%%).Luck = INT(RND * 5) 'a "chance" bonus to hits and evasions
 P(Who%%).Level = 0 'starting at base; first fight elevates to level 1, no xp gain though
 P(Who%%).Age = 17 'level adds to age *1.5 (level 10 adds 15 to age, 20 adds 30, 30 adds 45, max age 72!)
 ' age affects Strength by subtracting INT((-5 + (Age - 20)) * (.15 + ((Age-17)/100))-.49)  ;  youth gives strength
 ' age affects Agility by subtracting INT((-8 + (Age - 20)) * (.4 + ((Age-17)/100))-.49)   ;  youth gives great agility, age loses agility quickly
 ' age affects Luck by adding (0 + (Age - 25)) * (.4 + ((Age-17)/50))  ;  age adds luck
 P(Who%%).Weapon = 0 'adds to Attack strength , start with Fists
 P(Who%%).Armor = 8 'adds to Defensive strength , start with Loin Cloth
 P(Who%%).Shield = 16 'adds to Defensive strength , start with None
 P(Who%%).Gold = 0
 P(Who%%).Exp = 0
 P(Who%%).WorldX = 44
 P(Who%%).WorldY = 44
 P(Who%%).MapX = 17 'when starting game player always starts here
 P(Who%%).MapY = 18
 P(Who%%).Map = 1
 '-----------------------------------------------------------
END SUB
 
SUB Light_Effect
 _DEST Layer(11)
 CLS
 SELECT CASE G.Lite_Level
  CASE 0 'can only see player
   LINE (256, 224)-STEP(32, 32), _RGB(1, 1, 1), BF
  CASE 1 'one block around player visable
   LINE (224, 192)-STEP(96, 96), _RGB(1, 1, 1), BF
  CASE 2 'two blocks around player
   LINE (192, 176)-STEP(144, 144), _RGB(1, 1, 1), BF
  CASE 3 'three blocks around player
   LINE (160, 144)-STEP(208, 208), _RGB(1, 1, 1), BF
 END SELECT
 _CLEARCOLOR _RGB32(1, 1, 1), Layer(11)
 _DEST _DISPLAY
END SUB
 
SUB Message_Handler (L&, MSG$)
 STATIC Message_Length AS _UNSIGNED _BYTE
 STATIC Current_Char AS _BYTE
 STATIC Processed AS STRING, LineCount AS _BYTE, MYL AS _BYTE
 STATIC Lines(10) AS STRING * 22, Slowit AS _BYTE
 
 IF NOT G.Input_Wait THEN
  IF Message_Length = 0 THEN 'start of new message
   F.Message_Displaying = TRUE
   MYL = 1
   IF INSTR(Script(G.Message), "#") THEN
    Processed = Process_Message_Coding$(Script(G.Message)): Message_Length = LEN(Processed)
   ELSE
    Message_Length = LEN(Script(G.Message))
    Processed = Script(G.Message)
   END IF
  END IF
  'check message length word wrap if needed
  IF Message_Length > 22 AND LineCount = 0 THEN LineCount = Process_Word_Wrap(Lines(), Processed)
  IF Message_Length <= 22 THEN LineCount = 1: Lines(1) = Processed
  Slowit = Slowit + 1
  IF Slowit = 4 THEN Slowit = 0: Current_Char = Current_Char + 1: _SNDPLAY SFX(3)
 
  _PRINTSTRING (80, 288 + 16 * MYL), MID$(Lines(MYL), 1, Current_Char), L& 'print message 1 character at a time.
 
  IF Current_Char = LEN(RTRIM$(Lines(MYL))) THEN MYL = MYL + 1: Current_Char = 0
  IF MYL = LineCount + 1 THEN 'if the message is done then reset everything and wait for input
   G.Input_Wait = TRUE: Processed = "": Message_Length = 0
   MYL = 0: Lines(1) = "": LineCount = 0
   F.Message_Displaying = FALSE
  END IF
 END IF
 
END SUB
 
FUNCTION Process_Message_Coding$ (Txt$)
 FOR i~%% = 1 TO LEN(Txt$) 'check message for formating
  IF MID$(Txt$, i~%%, 1) = "#" THEN
   SELECT CASE MID$(Txt$, i~%% + 1, 1)
    CASE "E"
     Result$ = Result$ + RTRIM$(M(battle%%).Nam)
     i~%% = i~%% + 1
    CASE "P"
     Result$ = Result$ + RTRIM$(P(who%%).Nam)
     i~%% = i~%% + 1
    CASE "I"
     Result$ = Result$ + RTRIM$(I(which%%).Nam)
     i~%% = i~%% + 1
    CASE "N"
     'Processed = Processed + MID$(Script(G.Message), i~%%, 1)
   END SELECT
  ELSEIF MID$(Txt$, i~%%, 1) = "&" THEN
   SELECT CASE MID$(Txt$, i~%% + 1, 1)
    CASE "Y"
     G.YES_NO_Input = TRUE
     i~%% = i~%% + 1
   END SELECT
  ELSE
   Result$ = Result$ + MID$(Txt$, i~%%, 1)
  END IF
 NEXT i~%%
 
 Process_Message_Coding = Result$
END FUNCTION
 
 
 
SUB Control_setup
 _PUTIMAGE (40, 32), Layer(10), Layer(0)
 'up arrow
 LINE (128, 128)-(32, 132), _RGB32(255, 127, 0), BF
 LINE (32, 132)-(36, 460), _RGB32(255, 127, 0), BF
 LINE (32, 460)-(212, 464), _RGB32(255, 127, 0), BF
 'left arrow
 LINE (92, 160)-(48, 164), _RGB32(92, 192, 0), BF
 LINE (48, 164)-(52, 416), _RGB32(92, 192, 0), BF
 LINE (48, 416)-(240, 420), _RGB32(92, 192, 0), BF
 'down arrow
 LINE (128, 212)-(64, 216), _RGB32(0, 127, 255), BF
 LINE (64, 216)-(68, 372), _RGB32(0, 127, 255), BF
 LINE (64, 372)-(256, 376), _RGB32(0, 127, 255), BF
 'right arrow
 LINE (176, 184)-(180, 240), _RGB32(0, 64, 160), BF
 LINE (80, 240)-(180, 244), _RGB32(0, 64, 160), BF
 LINE (80, 244)-(84, 326), _RGB32(0, 64, 160), BF
 LINE (80, 326)-(260, 330), _RGB32(0, 64, 160), BF
 'select
 LINE (264, 212)-(268, 460), _RGB32(255, 64, 0), BF
 LINE (264, 460)-(416, 464), _RGB32(255, 64, 0), BF
 'start
 LINE (328, 212)-(332, 416), _RGB32(212, 0, 16), BF
 LINE (328, 416)-(496, 420), _RGB32(212, 0, 16), BF
 'B Button
 LINE (426, 208)-(430, 256), _RGB32(64, 92, 212), BF
 LINE (340, 256)-(430, 260), _RGB32(64, 92, 212), BF
 LINE (340, 260)-(344, 376), _RGB32(64, 92, 212), BF
 LINE (340, 372)-(496, 376), _RGB32(64, 92, 212), BF
 'A Button
 LINE (496, 208)-(500, 272), _RGB32(80, 64, 180), BF
 LINE (356, 272)-(500, 276), _RGB32(80, 64, 180), BF
 LINE (356, 272)-(360, 328), _RGB32(80, 64, 180), BF
 LINE (356, 328)-(528, 332), _RGB32(80, 64, 180), BF
 
 IF Key_Up = 18432 THEN _PRINTSTRING (64, 440), "Up Arrow"
 IF Key_Down = 20480 THEN _PRINTSTRING (96, 352), "Down Arrow"
 IF Key_Left = 19200 THEN _PRINTSTRING (80, 396), "Left Arrow"
 IF Key_Right = 19712 THEN _PRINTSTRING (112, 308), "Right Arrow"
 IF A_Button = 32 THEN _PRINTSTRING (388, 308), "Space Bar"
 IF B_Button = 13 THEN _PRINTSTRING (370, 352), "Enter"
 _PRINTSTRING (296, 440), CHR$(Select_Button)
 _PRINTSTRING (364, 396), CHR$(Start_Button)
 LOCATE 1, 1: PRINT "Press any key"
END SUB
 
SUB MFI_Loader (FN$)
 DIM Size(64) AS LONG, FOffset(64) AS LONG
 OPEN FN$ FOR BINARY AS #1
 GET #1, , c~%% 'retrieve number of files
 FOR I~%% = 1 TO c~%%
  GET #1, , FOffset(I~%%)
  GET #1, , Size(I~%%)
  FOffset&(I~%%) = FOffset&(I~%%) + 1
 NEXT I~%%
 Layer(10) = LoadGFX(FOffset(1), Size(1))
 Layer(3) = LoadGFX(FOffset(2), Size(2))
 Layer(4) = LoadGFX(FOffset(3), Size(3))
 BGM(-1) = LoadSFX(FOffset(4), Size(4))
 BGM(0) = LoadSFX(FOffset(10), Size(10))
 BGM(1) = LoadSFX(FOffset(12), Size(12))
 BGM(3) = LoadSFX(FOffset(12), Size(12))
 SFX(0) = LoadSFX(FOffset(5), Size(5))
 SFX(1) = LoadSFX(FOffset(8), Size(8))
 SFX(2) = LoadSFX(FOffset(9), Size(9))
 SFX(3) = LoadSFX(FOffset(11), Size(11))
 LoadData FOffset(6), Size(6)
 DWFont = LoadFFX(FOffset(7), Size(7), 16)
 
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
END SUB
 
FUNCTION LoadGFX& (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadGFX& = _LOADIMAGE("temp.dat", 32)
END FUNCTION
 
FUNCTION LoadFFX& (Foff&, Size&, Fize%%)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadFFX& = _LOADFONT("temp.dat", Fize%%, "monospace")
END FUNCTION
 
FUNCTION LoadSFX& (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 LoadSFX& = _SNDOPEN("temp.dat")
END FUNCTION
 
SUB LoadData (Foff&, Size&)
 IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
 OPEN "temp.dat" FOR BINARY AS #3
 dat$ = SPACE$(Size&)
 GET #1, Foff&, dat$
 PUT #3, , dat$
 CLOSE #3
 
 F1 = FREEFILE
 OPEN "temp.dat" FOR BINARY AS #F1
 ' OPEN "GameDataV1_1b.dat" FOR BINARY AS #1
 GET #F1, , World()
 GET #F1, , Place()
 GET #F1, , I()
 GET #F1, , L()
 GET #F1, , GF()
 GET #F1, , M()
 GET #F1, , Stairs()
 GET #F1, , PD()
 GET #F1, , Chest()
 FOR i% = 1 TO 360
  GET #F1, , L~%%
  Script(i%) = SPACE$(L~%%)
  GET #F1, , Script(i%)
 NEXT i%
 GET #F1, , NPC()
 GET #F1, , Lines()
 CLOSE #F1
 
END SUB
 
SUB Change_BGM (who%%)
 IF P(who%%).Map <> G.Current_BGM THEN
  _SNDSTOP BGM(G.Current_BGM) 'stop the old music
  _DELAY .15
  _SNDLOOP BGM(P(who%%).Map) ' start the new music
  G.Current_BGM = P(who%%).Map ' store which music is now playing
 END IF
END SUB
 
SUB ClearLayerADV (L&)
 STATIC ML1 AS _MEM
 ML1 = _MEMIMAGE(L&)
 _MEMPUT ML1, ML1.OFFSET, _MEMGET(ClearLayerMaster, ClearLayerMaster.OFFSET, STRING * 8667136)
END SUB
 
FUNCTION Find_NPC%% (Direction%%)
 Result%% = -1
 X%% = 0: Y%% = 0
 SELECT CASE Direction%%
  CASE UP
   Y%% = -1
  CASE DOWN
   Y%% = 1
  CASE LEFT
   X%% = -1
  CASE RIGHT
   X%% = 1
 END SELECT
 
 FOR i%% = 0 TO 120
  IF NPC(i%%).Map = P(0).Map THEN
   IF NPC(i%%).X = P(0).MapX + X%% AND NPC(i%%).Y = P(0).MapY + Y%% THEN Result%% = i%%: i%% = 127
  END IF
  IF NPC(i%%).X = 0 THEN i%% = 127
 NEXT i%%
 Find_NPC = Result%%
END FUNCTION
 
SUB NPC_Monologue (Who%%)
 old%% = NPC(Who%%).Moving
 NPC(Who%%).Moving = FALSE 'make sure NPC does not walk away while we are talking to them
 G.Message = Lines(Who%%, 0, 1)
 DO
  '  IF INKEY$ = CHR$(27) THEN exitflag%% = TRUE
  IF NOT F.Message_Displaying THEN Result%% = Controls(0)
  IF Result%% = TRUE THEN ExitFlag%% = TRUE
  IF NOT G.Input_Wait THEN
   Draw_Info_Window Layer(1): Message_Handler Layer(5), ""
  ELSE
 
  END IF
 
  Debuginfo
 
  _PUTIMAGE , Layer(5), Layer(1)
  _PUTIMAGE , Layer(9), Layer(1)
  _PUTIMAGE , Layer(1), Layer(0)
  Process_NPC
  _LIMIT 60
  Frames% = Frames% + 1
 
 
 
 LOOP UNTIL ExitFlag%%
 
 G.Input_Wait = FALSE
 ClearLayer Layer(5)
 G.Message = 0
 NPC(Who%%).Moving = old%%
END SUB
 
FUNCTION YES_NO_Box
 G.YES_NO_Input = TRUE
 
END FUNCTION
 
REM'$include:'FinishedRoutines.bas'
FUNCTION Collision%% (Who%%, X%%, Y%%)
 Result%% = TRUE
 IF P(Who%%).Map >= 0 THEN 'check place map
  SELECT CASE Place(P(Who%%).Map, P(Who%%).MapX + X%%, P(Who%%).MapY + Y%%).Sprite_ID
   CASE 0 TO 13
    Result%% = FALSE
   CASE ELSE
    IF NOT _SNDPLAYING(SFX(0)) THEN _SNDPLAY SFX(0)
  END SELECT
 
  IF NOT Result%% THEN 'check for NPC collision
   FOR i%% = 0 TO 120 '<--update when actual NPC count is known
    IF P(Who%%).MapX + X%% = NPC(i%%).X AND P(Who%%).MapY + Y%% = NPC(i%%).Y AND P(Who%%).Map = NPC(i%%).Map THEN
     Result%% = TRUE: i%% = 122
     IF NOT _SNDPLAYING(SFX(0)) THEN _SNDPLAY SFX(0)
    END IF
    IF NPC(i%%).X = 0 THEN i%% = 122 'no NPC can occupy a 0 location so we know we are past the last NPC
   NEXT i%%
  END IF
 
 ELSE 'check world map
  SELECT CASE World(P(Who%%).WorldX + X%%, P(Who%%).WorldY + Y%%).Sprite_ID
   CASE 0 TO 13
    Result%% = FALSE
   CASE ELSE
    IF NOT _SNDPLAYING(SFX(0)) THEN _SNDPLAY SFX(0)
  END SELECT
 END IF
 Collision = Result%%
END FUNCTION
 
SUB Frame_Change
 IF Frame%% THEN Frame%% = 0 ELSE Frame%% = 1
END SUB
 
SUB Copy_Map_Layer (L&, MX%%, MY%%)
 IF P(0).Map >= 0 THEN
  _PUTIMAGE (16, 16), L&, Layer(1), (MX%% * 32 - 240 + G.X, MY%% * 32 - 208 + G.Y)-STEP(495, 447)
 ELSE
  _PUTIMAGE (16, 16), L&, Layer(1), (128 + MX%% * 32 - 240 + G.X, 128 + MY%% * 32 - 208 + G.Y)-STEP(495, 447)
 END IF
END SUB
 
SUB ClearLayer (L&)
 old& = _DEST
 _DEST L&
 CLS
 _DEST old&
END SUB
 
SUB Draw_Window (X%%, Y%%, Xs%%, Ys%%, L&)
 'top corners of window
 _PUTIMAGE (X%% * 16, Y%% * 16)-STEP(15, 15), Layer(3), L&, (0, 18)-STEP(7, 7)
 _PUTIMAGE (X%% * 16 + Xs%% * 16, Y%% * 16)-STEP(15, 15), Layer(3), L&, (8, 18)-STEP(7, 7)
 'bottom corners of window
 _PUTIMAGE (X%% * 16, Y%% * 16 + Ys%% * 16)-STEP(15, 15), Layer(3), L&, (16, 18)-STEP(7, 7)
 _PUTIMAGE (X%% * 16 + Xs%% * 16, Y%% * 16 + Ys%% * 16)-STEP(15, 15), Layer(3), L&, (24, 18)-STEP(7, 7)
 'top and bottom of window
 FOR i%% = 1 TO Xs%% - 1
  _PUTIMAGE (X%% * 16 + i%% * 16, Y%% * 16)-STEP(15, 15), Layer(3), L&, (56, 18)-STEP(7, 7)
  _PUTIMAGE (X%% * 16 + i%% * 16, Y%% * 16 + Ys%% * 16)-STEP(15, 15), Layer(3), L&, (48, 18)-STEP(7, 7)
 NEXT i%%
 'left and right sides of window
 FOR i%% = 1 TO Ys%% - 1
  _PUTIMAGE (X%% * 16, Y%% * 16 + 16 * i%%)-STEP(15, 15), Layer(3), L&, (32, 18)-STEP(7, 7)
  _PUTIMAGE (X%% * 16 + Xs%% * 16, Y%% * 16 + 16 * i%%)-STEP(15, 15), Layer(3), L&, (40, 18)-STEP(7, 7)
 NEXT i%%
 'fill in window
 _PUTIMAGE ((X%% + 1) * 16, (Y%% + 1) * 16)-STEP((Xs%% - 1) * 16, (Ys%% - 1) * 16), Layer(3), L&, (307, 1)-STEP(15, 15)
END SUB
 
SUB Draw_Command_Window (L&)
 Draw_Window 12, 2, 15, 9, Layer(1)
 _PUTIMAGE (16 * 16 - 2, 2 * 16)-STEP(7 * 15 + 4, 1 * 15), Layer(3), Layer(1), (205, 35)-STEP(15, 15)
 _PRINTSTRING (16 * 16, 16 * 2), "COMMAND", L&
 _PRINTSTRING (16 * 14, 16 * 4), "TALK", L&
 _PRINTSTRING (16 * 14, 16 * 6), "STATUS", L&
 _PRINTSTRING (16 * 14, 16 * 8), "STAIRS", L&
 _PRINTSTRING (16 * 14, 16 * 10), "SEARCH", L&
 _PRINTSTRING (16 * 22, 16 * 4), "SPELL", L&
 _PRINTSTRING (16 * 22, 16 * 6), "ITEM", L&
 _PRINTSTRING (16 * 22, 16 * 8), "DOOR", L&
 _PRINTSTRING (16 * 22, 16 * 10), "TAKE", L&
 Display_Selection_Arrow SA(G.Selection).X, SA(G.Selection).Y, L&
END SUB
 
SUB Display_Selection_Arrow (X%%, Y%%, L&)
 _PUTIMAGE (X%% * 16, Y%% * 16)-STEP(15, 15), Layer(3), L&, (64, 18)-STEP(7, 7)
END SUB
 
SUB Draw_Stat_Window (L&, Who%%)
 Draw_Window 2, 4, 7, 11, Layer(1)
 _PUTIMAGE (4 * 16 - 2, 4 * 16)-STEP(4 * 15 + 4, 1 * 15), Layer(3), Layer(1), (205, 35)-STEP(15, 15)
 _PRINTSTRING (16 * 4, 16 * 4), LEFT$(P(Who%%).Nam, 4), L&
 _PRINTSTRING (16 * 3, 16 * 6), "LV", L&
 _PRINTSTRING (16 * 3, 16 * 8), "HP", L&
 _PRINTSTRING (16 * 3, 16 * 10), "MP", L&
 _PRINTSTRING (16 * 3, 16 * 12), "G", L&
 _PRINTSTRING (16 * 3, 16 * 14), "E", L&
 _PRINTSTRING (16 * (9 - LEN(STR$(P(Who%%).Level))), 16 * 6), STR$(P(Who%%).Level), L&
 _PRINTSTRING (16 * (9 - LEN(STR$(P(Who%%).HP))), 16 * 8), (STR$(P(Who%%).HP)), L&
 _PRINTSTRING (16 * (9 - LEN(STR$(P(Who%%).MP))), 16 * 10), STR$(P(Who%%).MP), L&
 _PRINTSTRING (16 * (9 - LEN(STR$(P(Who%%).Gold))), 16 * 12), STR$(P(Who%%).Gold), L&
 _PRINTSTRING (16 * (9 - LEN(STR$(P(Who%%).Exp))), 16 * 14), STR$(P(Who%%).Exp), L&
END SUB
 
SUB Draw_Info_Window (L&)
 Draw_Window 4, 18, 23, 9, L&
END SUB
 
SUB Build_World_Layer (L&)
 FOR Y~%% = 0 TO 255
  FOR X~%% = 0 TO 255
   _PUTIMAGE (32 * X~%%, 32 * Y~%%)-STEP(31, 31), Layer(3), L&, (1 + 17 * 14, 1)-STEP(15, 15)
 NEXT X~%%, Y~%%
 FOR Y%% = 0 TO 121
  FOR X%% = 0 TO 121
   _PUTIMAGE (128 + 32 * X%%, 128 + 32 * Y%%)-STEP(31, 31), Layer(3), L&, (1 + 17 * World(X%%, Y%%).Sprite_ID, 1)-STEP(15, 15)
 NEXT X%%, Y%%
END SUB
 
SUB Build_Place_Layer (L&, ID%%)
 FOR Y%% = 0 TO 45
  FOR X%% = 0 TO 45
   _PUTIMAGE (0 + 32 * X%%, 0 + 32 * Y%%)-STEP(31, 31), Layer(3), L&, (1 + 17 * Place(ID%%, X%%, Y%%).Sprite_ID, 1)-STEP(15, 15)
 NEXT X%%, Y%%
END SUB
 
SUB Display_Player_Status (L&)
 Draw_Window 10, 6, 19, 21, L&
 _PRINTSTRING (16 * 16, 16 * 7), "NAME:" + RTRIM$(P(who%%).Nam), L&
 _PRINTSTRING (16 * 17, 16 * 9), "STRENGTH:", L&
 _PRINTSTRING (16 * 18, 16 * 11), "AGILITY:", L&
 _PRINTSTRING (16 * 15, 16 * 13), "MAXIMUM HP:", L&
 _PRINTSTRING (16 * 15, 16 * 15), "MAXIMUM MP:", L&
 _PRINTSTRING (16 * 13, 16 * 17), "ATTACK POWER:", L&
 _PRINTSTRING (16 * 12, 16 * 19), "DEFENSE POWER:", L&
 _PRINTSTRING (16 * 13, 16 * 21), "WEAPON:", L&
 _PRINTSTRING (16 * 14, 16 * 23), "ARMOR:", L&
 _PRINTSTRING (16 * 13, 16 * 25), "SHIELD:", L&
 V1$ = LTRIM$(STR$(P(who%%).Strength))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 9), V1$, L&
 V1$ = LTRIM$(STR$(P(who%%).Agility))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 11), V1$, L&
 V1$ = LTRIM$(STR$(P(who%%).Max_HP))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 13), V1$, L&
 V1$ = LTRIM$(STR$(P(who%%).Max_MP))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 15), V1$, L&
 V1$ = LTRIM$(STR$(Player_Attack(who%%)))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 17), V1$, L&
 V1$ = LTRIM$(STR$(Player_Defense(who%%)))
 _PRINTSTRING (16 * (26 + (3 - LEN(V1$))), 16 * 19), V1$, L&
 
 IF LEN(RTRIM$(I(P(who%%).Weapon).Nam)) < 9 THEN
  V1$ = RTRIM$(I(P(who%%).Weapon).Nam)
  _PRINTSTRING (16 * (20), 16 * 21), V1$, L&
 ELSE
  V1$ = MID$(I(P(who%%).Weapon).Nam, 1, INSTR(I(P(who%%).Weapon).Nam, CHR$(32)))
  _PRINTSTRING (16 * (20), 16 * 21), V1$, L&
  V2$ = RTRIM$(MID$(I(P(who%%).Weapon).Nam, INSTR(I(P(who%%).Weapon).Nam, CHR$(32))))
  _PRINTSTRING (16 * (20), 16 * 22), V2$, L&
 END IF
 
 IF LEN(RTRIM$(I(P(who%%).Armor).Nam)) < 9 THEN
  V1$ = RTRIM$(I(P(who%%).Armor).Nam)
  _PRINTSTRING (16 * (20), 16 * 23), V1$, L&
 ELSE
  V1$ = MID$(I(P(who%%).Armor).Nam, 1, INSTR(I(P(who%%).Armor).Nam, CHR$(32)))
  _PRINTSTRING (16 * (20), 16 * 23), V1$, L&
  V2$ = RTRIM$(MID$(I(P(who%%).Armor).Nam, INSTR(I(P(who%%).Armor).Nam, CHR$(32))))
  _PRINTSTRING (16 * (20), 16 * 24), V2$, L&
 END IF
 
 IF LEN(RTRIM$(I(P(who%%).Shield).Nam)) < 9 THEN
  V1$ = RTRIM$(I(P(who%%).Shield).Nam)
  _PRINTSTRING (16 * (20), 16 * 25), V1$, L&
 ELSE
  V1$ = MID$(I(P(who%%).Shield).Nam, 1, INSTR(I(P(who%%).Shield).Nam, CHR$(32)))
  _PRINTSTRING (16 * (20), 16 * 25), V1$, L&
  V2$ = RTRIM$(MID$(I(P(who%%).Shield).Nam, INSTR(I(P(who%%).Shield).Nam, CHR$(32))))
  _PRINTSTRING (16 * (20), 16 * 26), V2$, L&
 END IF
 
END SUB
 
SUB Copy_NPC_Layer (L&, MX%%, MY%%)
 _PUTIMAGE (16, 16), L&, Layer(1), (MX%% * 32 - 240 + G.X, MY%% * 32 - 208 + G.Y)-STEP(495, 447)
END SUB
 
FUNCTION Process_Word_Wrap (Lines() AS STRING * 22, txt$)
 Result%% = 1: I%% = 1
 DO
  'start on character 22 and work back to a space
  x%% = 22: Space%% = FALSE
  DO
   IF MID$(txt$, x%%, 1) <> CHR$(32) THEN x%% = x%% - 1 ELSE Space%% = TRUE
   IF x%% = 0 AND I%% = 1 THEN PRINT "ERROR": END
  LOOP UNTIL Space%%
  Lines(I%%) = MID$(txt$, 1, x%%)
  txt$ = MID$(txt$, x%% + 1)
  I%% = I%% + 1
  IF LEN(txt$) <= 22 THEN GoodLength%% = TRUE
 LOOP UNTIL GoodLength%%
 Lines(I%%) = txt$ 'put the last of the text into a line
 Result%% = I%%
 Process_Word_Wrap = Result%%
END FUNCTION
 
SUB Put_Player_In_Place (Who%%)
 'build map of players location
 Build_Place_Layer Layer(7), P(Who%%).Map
 'place player at entry point
 P(Who%%).MapX = PD(P(Who%%).Map).Start_X
 P(Who%%).MapY = PD(P(Who%%).Map).Start_Y
END SUB
 
SUB Draw_Player_Sprite (Who%%, L&)
 IF P(Who%%).Weapon AND P(Who%%).Shield > 16 THEN 'pick which sprite set to use
  Y1%% = 3 'has a shield and weapon
 ELSEIF P(Who%%).Weapon THEN
  Y1%% = 1 'only has weapon
 ELSEIF P(Who%%).Shield > 16 THEN 'No sheild is 16
  Y1%% = 2 'on has shield
 ELSE
  Y1%% = 0 'has nothing
 END IF
 IF P(Who%%).Armor > 9 THEN Y1%% = Y1%% + 4 'player has armor
 
 IF P(Who%%).Has_Princess THEN Y1%% = 8 'if player is returning princess over-ride tile set
 
 SX% = 3 + (Frame%% * 16) + (P(Who%%).Facing * 32)
 SY% = 4 + (Y1%% * 18)
 _PUTIMAGE (256, 224)-STEP(31, 31), Layer(4), L&, (SX%, SY%)-STEP(15, 15)
END SUB
 
SUB Draw_NPC_Sprites (Who%%, Count%%, L&)
 ClearLayerADV L&
 FOR i%% = 0 TO Count%%
  IF P(Who%%).Map = NPC(i%%).Map THEN
   SX% = 3 + (Frame%% * 16) + (NPC(i%%).Facing * 32)
   SY% = 4 + (NPC(i%%).Sprite_ID * 18)
   _PUTIMAGE (NPC(i%%).X * 32 + NPC(i%%).MX, NPC(i%%).Y * 32 + NPC(i%%).MY)-STEP(31, 31), Layer(4), L&, (SX%, SY%)-STEP(15, 15)
  END IF
 NEXT i%%
END SUB
 
REM'$include:'CoreFunctions.bas'
SUB Add_To_Inventory (Who%%, Item%%, Count%%)
 STATIC m AS _MEM 'no need to initialize/free it over and over
 STATIC Pack AS _OFFSET
 m = _MEM(P(Who%%)) 'Just change where you want to point it to.
 Pack = m.OFFSET + 28 'æmove to where P(Who%%).Pack starts at in memory
 
 Match%% = FALSE
 FOR i%% = 0 TO 15
  IF Item%% = _MEMGET(m, Pack + i%% * 2, _BYTE) THEN Match%% = i%%: i%% = 30
 NEXT i%%
 IF NOT Match%% THEN 'new item
  _MEMPUT m, Pack + P(Who%%).Items * 2, Item%% 'POKE
  _MEMPUT m, Pack + P(Who%%).Items * 2 + 1, Count%% 'POKE
  P(Who%%).Items = P(Who%%).Items + 1
 ELSE
  temp%% = _MEMGET(m, Pack + Match%% * 2 + 1, _BYTE)
  temp%% = temp%% + 1
  _MEMPUT m, Pack + Match%% * 2 + 1, Count%% 'POKE
 END IF
END SUB
 
SUB Remove_Inventory (who%%, Item%%, Count%%)
 STATIC m AS _MEM 'no need to initialize/free it over and over
 STATIC Pack AS _OFFSET
 m = _MEM(P(who%%)) 'Just change where you want to point it to.
 Pack = m.OFFSET + 28 'æmove to where P(Who%%).Pack starts at in memory
 
 Match%% = FALSE
 FOR i%% = 0 TO 15 'find the item
  IF Item%% = _MEMGET(m, Pack + i%% * 2, _BYTE) THEN Match%% = i%%: i%% = 30
 NEXT i%%
 IF Match%% = FALSE THEN
  'something went horribly wrong!
 ELSE
  temp%% = _MEMGET(m, Pack + Match%% * 2 + 1, _BYTE)
  temp%% = temp%% - Count%%
 
  IF temp%% = 0 THEN 'item is out so remove from inventory
   temp$ = _MEMGET(m, Pack, STRING * 32) 'get entire pack string
   temp$ = LEFT$(temp$, Match%% * 2) + MID$(temp$, 2 * Match%% + 3)
   P(who%%).Items = P(who%%).Items - 1
 
   l%% = LEN(temp$)
   FOR i%% = l%% TO 31 'pad temp$ to full 32 characters
    temp$ = temp$ + CHR$(0)
   NEXT i%%
 
   _MEMPUT m, Pack, temp$ 'put invetory back
  ELSE
   _MEMPUT m, Pack + Match%% * 2 + 1, temp%% 'put adjusted count back
  END IF
 END IF
END SUB
 
SUB Drop_Inventory (Who%%, ID%%)
 STATIC m AS _MEM 'no need to initialize/free it over and over
 STATIC Pack AS _OFFSET
 m = _MEM(P(Who%%)) 'Just change where you want to point it to.
 Pack = m.OFFSET + 28 'æmove to where P(Who%%).Pack starts at in memory
 
 Match%% = FALSE
 FOR i%% = 0 TO 15 'find the item
  IF ID%% = _MEMGET(m, Pack + i%% * 2, _BYTE) THEN Match%% = i%%: i%% = 30
 NEXT i%%
 IF Match%% = FALSE THEN
  'something went horribly wrong!
 ELSE
  temp$ = _MEMGET(m, Pack, STRING * 32) 'get entire pack string
  temp$ = LEFT$(temp$, Match%% * 2) + MID$(temp$, 2 * Match%% + 3)
  P(Who%%).Items = P(Who%%).Items - 1
 
  l%% = LEN(temp$)
  FOR i%% = l%% TO 31 'pad temp$ to full 32 characters
   temp$ = temp$ + CHR$(0)
  NEXT i%%
 
  _MEMPUT m, Pack, temp$ 'put invetory back
 END IF
END SUB
 
SUB Level_Up (Who%%)
 P(Who%%).Level = P(Who%%).Level + 1
 P(Who%%).Age = P(Who%%).Age + INT(P(Who%%).Level * 1.5 - .49)
 P(Who%%).Strength = P(Who%%).Strength + INT(RND * 6) + 1 - INT((-5 + (P(Who%%).Age - 20)) * (.15 + ((P(Who%%).Age - 17) / 100)) - .49)
 P(Who%%).Agility = P(Who%%).Agility + INT(RND * 6) + 1 - INT((-8 + (P(Who%%).Age - 20)) * (.4 + ((P(Who%%).Age - 17) / 100)) - .49)
 P(Who%%).Luck = P(Who%%).Luck + INT(RND * 3) + INT(0 + (P(Who%%).Age - 25)) * (.4 + ((P(Who%%).Age - 17) / 50) + .49)
 P(Who%%).Max_HP = P(Who%%).Max_HP + INT(RND * 10 - (P(Who%%).Age / 10)) + 1
 P(Who%%).Max_MP = P(Who%%).Max_MP + INT(RND * 5 + (P(Who%%).Age / 10))
END SUB
 
 
 
FUNCTION Player_Battle_Defense~%% (who%%)
 'compute primary Defense value
 Result~%% = Player_Defense(who%%)
 'now check for luck bonus good or bad
 IF INT(RND * 255) <= (P(who%%).Luck \ 2) THEN 'if random chance is less than half player luck then give luck adjustment
  Result~%% = Result~%% + INT(RND * (P(who%%).Luck * 2) - (P(who%%).Luck - (P(who%%).Age * 2)))
 END IF
 Player_Battle_Defense = Result~%%
END FUNCTION
 
FUNCTION Player_Defense~%% (who%%)
 'compute defense value to display in status window and to use in battle defense function
 Result~%% = INT(P(who%%).Agility / 2 - .49) + I(P(who%%).Armor).Power + I(P(who%%).Shield).Power
 Player_Defense = Result~%%
END FUNCTION
 
FUNCTION Player_Attack~%% (who%%)
 'Compute Attack value to display in status window and to use in battle attack function
 Result~%% = INT(P(who%%).Strength) + I(P(who%%).Weapon).Power
 Player_Attack = Result~%%
END FUNCTION
 
FUNCTION Player_Battle_Attack~%% (who%%)
 'get primary attack value
 Result~%% = Player_Attack(who%%)
 C~%% = Chance
 IF C~%% < (P(who%%).Luck \ 2) THEN 'if random chance is less than half player luck then give luck adjustment
  Result~%% = Result~%% + INT(RND * (P(who%%).Luck * 2) - (P(who%%).Luck - (P(who%%).Age * 2)))
 ELSEIF C~%% >= (128 - P(who%%).Luck / 16) AND C~%% <= (128 + P(who%%).Luck / 16) THEN 'critical hit
  Result~%% = Result~%% + INT(Result~%% * .25) 'add 25% to hit value
 END IF
 Player_Battle_Attack = Result~%%
END FUNCTION
 
FUNCTION Enemy_Damage (ID%%, Who%%)
 IF Player_Battle_Defense(Who%%) / 2 > M(ID%%).Strength THEN Miss%% = INT(M(ID%%).Strength + 4 / 6) ELSE Miss%% = FALSE
 Low~%% = (M(ID%%).Strength - Player_Battle_Defense(Who%%) / 2) / 4
 High~%% = (M(ID%%).Strength - Player_Battle_Defense(Who%%) / 2) / 2
 
 IF (Chance < P(Who%%).Luck / 4) THEN 'player evades attack(-1)
  Result%% = TRUE
 ELSEIF Miss%% >= 0 THEN 'not really a miss just a weak hit
  Result%% = Miss%%
 ELSE 'normal attack damage
  Result%% = INT(RND * (High~%% - Low~%%)) + Low~%%
 END IF
END FUNCTION
 
FUNCTION Player_Damage (who%%, ID%%)
 IF Chance + P(who%%).Luck / 2 > 228 THEN 'critical hit
  Low~%% = (Player_Battle_Attack(who%%) / 2)
  High~%% = (Player_Battle_Attack(who%%))
 ELSE
  Low~%% = (Player_Battle_Attack(who%%) - M(ID%%).Agility / 2) / 4
  High~%% = (Player_Battle_Attack(who%%) - M(ID%%).Agility / 2) / 2
 END IF
 Result~%% = INT(RND * (High~%% - Low~%%)) + Low~%%
 IF Result~%% = 0 THEN
  IF Chance + (P(who%%).Luck / 2) > 127 THEN Result~%% = 1
 END IF
 Player_Damage = Result~%%
END FUNCTION
 
FUNCTION Enemy_Flee (ID%%, Who%%)
 IF Player_Attack(Who%%) >= M(ID%%).Strength * 2 THEN
  IF Chance > 192 THEN Result%% = TRUE ELSE Result%% = FALSE
 END IF
 Enemy_Flee = Result%%
END FUNCTION
 
FUNCTION Player_Flee (Who%%, Id%%)
 IF P(Who%%).Agility * Chance < M(Id%%).Agility * Chance * GF(M(Id%%).Group) THEN
  Result%% = FALSE 'player is blocked
 ELSE
  Result%% = TRUE 'player evades
 END IF
 Player_Flee = Result%%
END FUNCTION
 
FUNCTION Battle_Initiative (who%%, ID%%)
 'if false then enemy goes first else player goes first in battle
 IF P(who%%).Agility * Chance < M(ID%%).Agility * Chance * GF(1) THEN
  Result%% = FALSE 'Monster goes first
 ELSE
  Result%% = TRUE 'player Goes first
 END IF
 Battle_Initiative = Result%%
END FUNCTION
 
FUNCTION Chance~%%
 Chance = INT(RND * 255)
END FUNCTION
 
 
'Debugging stuff found below---------------------------------------------------
SUB Print_Inventory (who%%)
 'check that values in inventory are correct
 'DEBUGGING!_-------------------------------
 STATIC m AS _MEM 'no need to initialize/free it over and over
 STATIC Pack AS _OFFSET
 m = _MEM(P(who%%)) 'Just change where you want to point it to.
 Pack = m.OFFSET + 28 '‘move to where P(Who%%).Pack starts at in memory
 LOCATE 1, 1
 FOR i%% = 0 TO P(who%%).Items - 1
  PRINT "Item ID#:"; I(_MEMGET(m, Pack + 2 * i%%, _BYTE)).Nam
  PRINT "Item Count:"; _MEMGET(m, Pack + 2 * i%% + 1, _BYTE)
 NEXT i%%
END SUB
 
SUB Debuginfo
 IF P(who%%).Map >= 0 THEN
  _PRINTSTRING (528, 8), "Tile :" + STR$(Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Sprite_ID) + "  ", Layer(9)
  _PRINTSTRING (528, 24), "Map X:" + STR$(P(who%%).MapX) + "  ", Layer(9)
  _PRINTSTRING (528, 40), "Map Y:" + STR$(P(who%%).MapY) + "  ", Layer(9)
  _PRINTSTRING (528, 56), "ExitBlock:" + STR$(Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Exit) + "  ", Layer(9)
  _PRINTSTRING (528, 168), "Stairs:" + STR$(Place(P(who%%).Map, P(who%%).MapX, P(who%%).MapY).Is_Stairs) + "  ", Layer(9)
 ELSE
  _PRINTSTRING (528, 72), "Tile   :" + STR$(World(P(who%%).WorldX, P(who%%).WorldY).Sprite_ID) + "  ", Layer(9)
  _PRINTSTRING (528, 88), "World X:" + STR$(P(who%%).WorldX) + "  ", Layer(9)
  _PRINTSTRING (528, 104), "World Y:" + STR$(P(who%%).WorldY) + "  ", Layer(9)
  _PRINTSTRING (528, 168), "Stairs:" + STR$(World(P(who%%).WorldX, P(who%%).WorldY).Is_Stairs) + "  ", Layer(9)
 END IF
 _PRINTSTRING (528, 120), "Map ID:" + STR$(P(who%%).Map) + "  ", Layer(9)
 _PRINTSTRING (528, 136), "justleft:" + STR$(G.JustLeft) + "  ", Layer(9)
 _PRINTSTRING (528, 152), "message" + STR$(G.Message) + "  ", Layer(9)
 _PRINTSTRING (528, 184), "action:" + STR$(G.Action) + "  ", Layer(9)
 _PRINTSTRING (528, 200), "Command:" + STR$(G.Selection) + "  ", Layer(9)
 _PRINTSTRING (528, 216), "BGMusic:" + STR$(G.Current_BGM) + "  ", Layer(9)
 _PRINTSTRING (528, 232), "FPS:" + STR$(G.f) + "  ", Layer(9)
 _PRINTSTRING (528, 248), "NPC:" + STR$(Find_NPC(P(0).Facing)) + "  ", Layer(9)
END SUB
 

Updated: 10\20\2019 14:50UTC
Updated: 10\23\2019 05:07UTC
Updated: 10\27\2019 18:27UTC

STxAxTIC · « **Reply #1 on:** October 16, 2019, 08:06:24 pm »

Nicely done Cobalt - do enough people compliment your style? Killin the game, muh man... Keep it up.

FellippeHeitor · « **Reply #2 on:** October 16, 2019, 11:44:19 pm »

Great job, Cobalt! Very interesting engine!

Our user roadbloc (or maybe user pforpond, are you that?) is gonna have a blast, as she has done something very similar with her Mystery of Robot Planet.

Kudos! When's the making of video coming out?

Ashish · « **Reply #3 on:** October 17, 2019, 12:26:54 pm »

Wow! Nice graphics. I like it!

Cobalt · « **Reply #4 on:** October 17, 2019, 01:29:27 pm »

Quote from: FellippeHeitor on October 16, 2019, 11:44:19 pm

When's the making of video coming out?

I would hate to even imagine just how that would go!

I guess I could go over why I use the Layer() system I do, or how I get away with never needing an EXIT or GOTO statement to get things done in a program like this.

Beyond that I wouldn't even know where to start. :(

TempodiBasic · « **Reply #5 on:** October 17, 2019, 05:09:25 pm »

Hi Cobalt
It is cool!
Lovely music, graphic and movement of sprites...

about to make video here some tips and software
https://www.techradar.com/news/the-best-free-screen-recorder

Cobalt · « **Reply #6 on:** October 20, 2019, 11:02:15 am »

Updated, fixed Message Handler for command window, added the STATUS functionality for command window.

Added Loin Cloth sprite. Technically you start the game naked!, as you have to buy Cloths!

Always got a laugh out of that growing up. there was already sprites for when you don't have a weapon or shield.

It looks a little goofy but I was actually going for that, try to inspire the player to buy armor! but I guess you could play for a while with out armor, though even at the highest strength level a player wouldn't be able to beat mid-level creatures without armor. and the higher the XP level the more AGE starts to act against attack and defense.

Don't forget you'll need to update your MFI file as it has been rebuilt to accommodate new Sound Effects.

Cobalt · « **Reply #7 on:** October 23, 2019, 01:15:21 pm »

There are now some NPCs to watch walk around, the Background music changes from castle, towns, and overworld. no music for caves\temples and such yet.

Starting castle is the only location with NPCs at the moment, and they are still mute. added a little frame rate clock, to see how far below 60 it will drop, should never go below 60 for smooth play.

MFI file has been updated again.

Cobalt · « **Reply #8 on:** October 27, 2019, 02:31:54 pm »

All towns(that should) have NPCs now!, the NPCs in the Castle now have basic talking ability! Everybody else should just be 'speechless'

Don't Forget to (re)download the MFI file.

bplus · « **Reply #9 on:** October 27, 2019, 03:30:39 pm »

Wow talking! I assume this doesn't mean little bubbles of text above characters? well... even if it were, cool!

Please, what is NPC?

SMcNeill · « **Reply #10 on:** October 27, 2019, 03:36:09 pm »

Quote from: bplus on October 27, 2019, 03:30:39 pm

Wow talking! I assume this doesn't mean little bubbles of text above characters? well... even if it were, cool!

Please, what is NPC?

Non-Player Character.

bplus · « **Reply #11 on:** October 28, 2019, 01:24:44 am »

Seems like the King is about to make a speech but nothing happens, also I have to use arrow keys up and down in Command Menu box to get a talk box, just Enter wont work, is that the way it is?

Cobalt · « **Reply #12 on:** October 28, 2019, 11:52:49 am »

Quote from: bplus on October 28, 2019, 01:24:44 am

Seems like the King is about to make a speech but nothing happens, also I have to use arrow keys up and down in Command Menu box to get a talk box, just Enter wont work, is that the way it is?

The King has the most lines of anyone, but the Monologue system is proving arduous, at best, to figure out. Many NPCs(Non-Playable Characters, Steve was close) have multiple lines, and there should be a pause requiring a button(key in this case) press to move on, and others have a Yes\No option as well. The Completion of this program will hang on this unfortunately. Until then every NPC only speaks the first line of their script. and you can't speak to any shop keeps due to the tile in front of them, yet another hurtle to figure out. All the NPCs that say they are speechless don't have a DATA line yet, and just say that as default.

Space is the "action" button(key), or button A if we were using an old NES controller, while "enter" is the cancel or the B button. I know its a little counter-intuitive and I honestly can't remember why I came to that setup. Eventually the Controls will be customize-able though. so Space to bring up the command window, Space to choose an option. I'm afraid it is a short coming on my part to assume the player has some knowledge of the NES version of the game before hand, and knows which button (A or B) to use.

something that intrigues me about your screen shot is the 61FPS, as with the _LIMIT 60 that should not be able to happen, I thought. and that could actually cause some glitches with the movement and drawing of the screen. Which is why I'm taking the speed of this program more serious than others I have done. there are slight dips when changing maps which should be okay at that point once I finish that aspect, as the maps should fade out and in.

bplus · « **Reply #13 on:** October 28, 2019, 12:08:16 pm »

Thanks, OK.

I must compliment the smooth walk-around aspect of players movements, it seems even better than my little experiment demo in effort to help.

SierraKen · « **Reply #14 on:** October 29, 2019, 02:03:39 pm »

Cobalt this is really incredible. It reminds me of my days playing Legend of Zelda and other games. You are coming along on it great! I can't wait to see the final version to fight enemies and get weapons and gold. I walked around in almost the whole forest and went to that other town. I never knew such a cool game like this could be made with a BASIC language!

News:

Author Topic: Explore the world of Alefgard! and talk to some people! (Read 5735 times)

Cobalt

Explore the world of Alefgard! and talk to some people!

STxAxTIC

Re: Explore a world, visit ghost towns

FellippeHeitor

Re: Explore a world, visit ghost towns

Ashish

Re: Explore a world, visit ghost towns

Cobalt

Re: Explore a world, visit ghost towns

TempodiBasic

Re: Explore a world, visit ghost towns

Cobalt

Re: Explore a world, visit ghost towns

Cobalt

Re: Explore a world, visit ghost towns

Cobalt

Re: Explore the world of Alefgard! and talk to some people!

bplus

Re: Explore the world of Alefgard! and talk to some people!

SMcNeill

Re: Explore the world of Alefgard! and talk to some people!

bplus

Re: Explore the world of Alefgard! and talk to some people!

Cobalt

Re: Explore the world of Alefgard! and talk to some people!

bplus

Re: Explore the world of Alefgard! and talk to some people!

SierraKen

Re: Explore the world of Alefgard! and talk to some people!