Ray-Tracing Engine by Zom-B

[The Librarian]

Ray-Tracing Engine

Author: Zom-B
Source: [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] Forum
URL: /forum/index.php?topic=1145.0]http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1145.0
Version: 2010
Tags: [3d], [raytrace]

Description:
This is a ray tracer I've been working on for the past 6 years. Well, on and off of course :) It's still a beta version. 43Kb. Bet this won't run in QB45.

Source Code:

Code: QB64: [Select]

1. '> Merged with Zom-B's smart $include merger 0.51
2.  
3. ' Best viewed with 120 or more columns
4.  
5. DEFDBL A-Z
6. OPTION BASE 1
7.  
8. '####################################################################################################################
9. '# Math Library V1.0 (include)
10. '# By Zom-B
11. '####################################################################################################################
12.  
13. CONST sqrt2 = 1.41421356237309504880168872420969807856967187537695 ' Knuth01
14. CONST sqrt3 = 1.73205080756887729352744634150587236694280525381038 ' Knuth02
15. CONST sqrt5 = 2.23606797749978969640917366873127623544061835961153 ' Knuth03
16. CONST sqrt10 = 3.16227766016837933199889354443271853371955513932522 ' Knuth04
17. CONST cubert2 = 1.25992104989487316476721060727822835057025146470151 ' Knuth05
18. CONST cubert3 = 1.44224957030740838232163831078010958839186925349935 ' Knuth06
19. CONST q2pow025 = 1.18920711500272106671749997056047591529297209246382 ' Knuth07
20. CONST phi = 1.61803398874989484820458683436563811772030917980576 ' Knuth08
21. CONST log2 = 0.69314718055994530941723212145817656807550013436026 ' Knuth09
22. CONST log3 = 1.09861228866810969139524523692252570464749055782275 ' Knuth10
23. CONST log10 = 2.30258509299404568401799145468436420760110148862877 ' Knuth11
24. CONST logpi = 1.14472988584940017414342735135305871164729481291531 ' Knuth12
25. CONST logphi = 0.48121182505960344749775891342436842313518433438566 ' Knuth13
26. CONST q1log2 = 1.44269504088896340735992468100189213742664595415299 ' Knuth14
27. CONST q1log10 = 0.43429448190325182765112891891660508229439700580367 ' Knuth15
28. CONST q1logphi = 2.07808692123502753760132260611779576774219226778328 ' Knuth16
29. CONST pi = 3.14159265358979323846264338327950288419716939937511 ' Knuth17
30. CONST deg2rad = 0.01745329251994329576923690768488612713442871888542 ' Knuth18
31. CONST q1pi = 0.31830988618379067153776752674502872406891929148091 ' Knuth19
32. CONST pisqr = 9.86960440108935861883449099987615113531369940724079 ' Knuth20
33. CONST gamma05 = 1.7724538509055160272981674833411451827975494561224 '  Knuth21
34. CONST gamma033 = 2.6789385347077476336556929409746776441286893779573 '  Knuth22
35. CONST gamma067 = 1.3541179394264004169452880281545137855193272660568 '  Knuth23
36. CONST e = 2.71828182845904523536028747135266249775724709369996 ' Knuth24
37. CONST q1e = 0.36787944117144232159552377016146086744581113103177 ' Knuth25
38. CONST esqr = 7.38905609893065022723042746057500781318031557055185 ' Knuth26
39. CONST eulergamma = 0.57721566490153286060651209008240243104215933593992 ' Knuth27
40. CONST expeulergamma = 1.7810724179901979852365041031071795491696452143034 '  Knuth28
41. CONST exppi025 = 2.19328005073801545655976965927873822346163764199427 ' Knuth29
42. CONST sin1 = 0.84147098480789650665250232163029899962256306079837 ' Knuth30
43. CONST cos1 = 0.54030230586813971740093660744297660373231042061792 ' Knuth31
44. CONST zeta3 = 1.2020569031595942853997381615114499907649862923405 '  Knuth32
45. CONST nloglog2 = 0.36651292058166432701243915823266946945426344783711 ' Knuth33
46.  
47. CONST logr10 = 0.43429448190325182765112891891660508229439700580367
48. CONST logr2 = 1.44269504088896340735992468100189213742664595415299
49. CONST pi05 = 1.57079632679489661923132169163975144209858469968755
50. CONST pi2 = 6.28318530717958647692528676655900576839433879875021
51. CONST q05log10 = 0.21714724095162591382556445945830254114719850290183
52. CONST q05log2 = 0.72134752044448170367996234050094606871332297707649
53. CONST q05pi = 0.15915494309189533576888376337251436203445964574046
54. CONST q13 = 0.33333333333333333333333333333333333333333333333333
55. CONST q16 = 0.16666666666666666666666666666666666666666666666667
56. CONST q2pi = 0.63661977236758134307553505349005744813783858296183
57. CONST q2sqrt5 = 0.89442719099991587856366946749251049417624734384461
58. CONST rad2deg = 57.2957795130823208767981548141051703324054724665643
59. CONST sqrt02 = 0.44721359549995793928183473374625524708812367192231
60. CONST sqrt05 = 0.70710678118654752440084436210484903928483593768847
61. CONST sqrt075 = 0.86602540378443864676372317075293618347140262690519
62. CONST y2q112 = 1.05946309435929526456182529494634170077920431749419 ' Chromatic base
63.  
64. '####################################################################################################################
65. '# Vector math library v0.1 (include part)
66. '# By Zom-B
67. '####################################################################################################################
68.  
69. TYPE VECTOR
70.     x AS DOUBLE
71.     y AS DOUBLE
72.     z AS DOUBLE
73. END TYPE
74.  
75. '####################################################################################################################
76. '# Screen mode selector v1.0 (include)
77. '# By Zom-B
78. '####################################################################################################################
79.  
80. videoaspect:
81. DATA "all aspect",15
82. DATA "4:3",11
83. DATA "16:10",10
84. DATA "16:9",14
85. DATA "5:4",13
86. DATA "3:2",12
87. DATA "5:3",9
88. DATA "1:1",7
89. DATA "other",8
90. DATA ,
91.  
92. videomodes:
93. DATA 256,256,7
94. DATA 320,240,1
95. DATA 400,300,1
96. DATA 512,384,1
97. DATA 512,512,7
98. DATA 640,480,1
99. DATA 720,540,1
100. DATA 768,576,1
101. DATA 800,480,2
102. DATA 800,600,1
103. DATA 854,480,3
104. DATA 1024,600,8
105. DATA 1024,640,2
106. DATA 1024,768,1
107. DATA 1024,1024,7
108. DATA 1152,768,5
109. DATA 1152,864,1
110. DATA 1280,720,3
111. DATA 1280,768,6
112. DATA 1280,800,2
113. DATA 1280,854,5
114. DATA 1280,960,1
115. DATA 1280,1024,4
116. DATA 1366,768,3
117. DATA 1400,1050,1
118. DATA 1440,900,2
119. DATA 1440,960,5
120. DATA 1600,900,3
121. DATA 1600,1200,1
122. DATA 1680,1050,2
123. DATA 1920,1080,3
124. DATA 1920,1200,2
125. DATA 2048,1152,3
126. DATA 2048,1536,1
127. DATA 2048,2048,7
128. DATA ,,
129.  
130.  
131. '####################################################################################################################
132. '# Ray Tracer (Beta version)
133. '# By Zom-B
134. '####################################################################################################################
135.  
136. CONST Doantialias = -1
137. CONST Usegaussian = 0
138.  
139. CONST FLOOR = 1
140. CONST SPHERE = 2
141.  
142. TYPE TEXTURE
143.     image AS LONG
144.     w AS INTEGER
145.     h AS INTEGER
146.     scaleU AS SINGLE
147.     scaleV AS SINGLE
148.     offsetU AS SINGLE
149.     offsetV AS SINGLE
150.     bumpfactor AS SINGLE
151. END TYPE
152.  
153. DIM SHARED sizeX%, sizeY%
154. DIM SHARED maxX%, maxY%
155. DIM SHARED halfX%, halfY%
156.  
157. DIM SHARED texture&(4)
158.  
159. DIM SHARED camPos AS VECTOR
160. DIM SHARED camDir AS VECTOR
161. DIM SHARED camUp AS VECTOR
162. DIM SHARED camRight AS VECTOR
163.  
164. 'Speed required with these variables, so not using TYPEs here
165. DIM SHARED objectType%(7) '                                 Object type
166. DIM SHARED positionX(7), positionY(7), positionZ(7) '       Object position
167. DIM SHARED size(7) '                                        Radius (in case of a sphere)
168. DIM SHARED colorR!(7), colorG!(7), colorB!(7), colorA!(7) ' RGBA color
169. DIM SHARED specular!(7), highlight!(7) '                    Phong parameters
170. DIM SHARED reflection!(7) '                                 Ray reflection amount
171. DIM SHARED textures(7) AS TEXTURE, bumpmap(7) AS TEXTURE '  image handle
172. DIM SHARED numObjects%
173.  
174. DIM SHARED lightX(4), lightY(4), lightZ(4) '                Light position
175. DIM SHARED lightR!(4), lightG!(4), lightB!(4) '             Light color
176. DIM SHARED numLights%
177.  
178. init
179. main
180.  
181. worldMap:
182. DATA "!~#!~#!~#!-#(.69AEGFC@5.224;DJMORQND:)(*$!:#'#$!e#+.+1WX\_`ab\MCOZ!/baaQ5&!)#'<;CB=,&!&#$06,8@6/$!%#&&##$8NL"
183. DATA ":1%!P#-=@@D25CGHIKJYZ]A)=^b`!0b]:!+#$0M?80!.#*-6.!&#%#%#/6?VR=6)!*#'%!B#,DDID?>>/LLPRINQE,!%#$#'F!.bZ0!;#=P="
184. DATA "-%$'$%)7GV^!)bA/)&6.##-BL/0+!,#/!'#$/80)&!'#$)5NA\]^]W3EQZ,[]baaN>0!&#J_!+bZ2!%#$$!+#$/3-!)#8V*##+R]PUV\!/ba"
185. DATA "bb8CBN[XRF26/!(#(=*##&B`!'b_YQPYaaVVMTVVX]YJY]YFMaZ_!%b9$##/Q!(b]TJ6$!-#%>V`ba`UJ<),2;<DCSTL[`O]!%ba!:baSTVT"
186. DATA "[XOOWT06OZ!.b_PNa!+b`WH._a]aOP%#&[!%baP@%##1@CF&!*#Dab\Mba\FFLQ`!*b\_!Gb##*--VS!1baa^ab_`abN0?E.=8GVT'!%#1_bb"
187. DATA "<!(#8=/##&!%#$9RbbN=Ya^aV\!,baY]`!@b^!%b]G##$#CUab`WXGKQ^!)b__a]!%abA!&#%ObZ3.,!&#-@I!0#&#/aa`b=6TLUQ[a!,b!%a"
188. DATA "!9ba^]Xa:)RNGF1!*#+AJ>!&#$@Y!+baZbb^=.##%Cbb^][)!4#2T+##9>Q^,3Q`!%b_!EbO*##$$1U\(!+#),3+!*#6Qa_a!&ba_abb`bbU"
189. DATA "G,Taab``U8!2#/LJK$#-ZO;>T!>babTa!'babbN1'!&#L`=#&!&#')'%&!-#$)L`baa!*b_!%bGa`baabaX-!1#;?KaGJ!@babbabZ\!-bT$"
190. DATA "!%#;6!&#&#'!4#*FYaa!)b`bQZ!'b[L7,PI%!2#9DZ!Rb[<*!%#'!=#+a!,bYPAU[!&b_@4(2)!2#%N!&b^!'bZMZWbbaW!@b^/5#'&!?#/a"
191. DATA "!-bYPQVXb_84-!4#)C@PbMEER=[bb`-$(.Sb`(T!*b`!4b\R.(Q;%!@#,a!-baa^`bY9%!6#-!%bA($:2N3aNWJW[KPbbG3!9b]``X)##08!C#"
192. DATA "N!1ba1!2#$!'#/[aP&*,3.;$B>D!%abbabM-!9b[7?U##)K2!C#)X!0bW&!9#4KJ`bbX!&#+('19!?bU&,Q.HQI$!E#K]!-bD!:#5a!(bQ:$"
193. DATA "HA/)/M!@b@$%J-$!G#*B^!&b`GJ<8Q/!7#$%(N!+b]!&b`a!&bL`!:bC##%!J#;=_!%bA!J5!7#+Z!2b=!&bW:KV!7bX&#'!L#:0]bb6!&#"
194. DATA "4BU,!6#I!3bLB!&b]\E(',\!2bU>3%!<#'*!3#Dbb@#-L)79Q4/!4#%a!4b5]!'b])##/V!&b_A?!&b`FL-#%!?#(!3#(H``HYX!%#/)E3,$"
195. DATA "!/#$##V!4bJ5!&b\2!&#(!%bU(##G!%bV1-##*6!R#';;^ZM8$!(#(!.#*#&_!5b?YbZ=!)#TbP'!%#0<!%bK!%#6;!U#&7\8##$4-$#%!1#"
196. DATA "a!6bJ3)'&!(#:bC!%#&'.PWbZ!%#)A5!V#5E31[^^QU:!1#2^!5b\[b+!*#ZF!%#$#,A)S-##&+9>!W#(0N!(b>0!0#8]!%bZX!1bJ!)#%#&"
197. DATA "E&!%#'$G-!    $3Q##$!V#F!*bQ!0#*;/0#&@W!.b[)!)#%%!(#&L?U$%%C_0!?#$!<#1a!+bG!6#J!)b`!%bS*!3#0[_,/Wb_/2*4!1#%!C#"
198. DATA "(!%#P!-bS4'!3#Q!(baB_bW&!5#=bR0`bK@<'*6F35$#%%!*#$!F#T!0bI+!1#)\!'b^bba-!6#$Da/05-=B%0+<Mb]C$,+!N#A!1bL!2#B!'b"
199. DATA "Xbba(!8#8EH:!&'$)/,\b\C.#0)!M#X!/ba7!2#3!'b`b^b3!;#&-5-6$(%%&U,?2%#'+!*#%!C#7!/bA!3#8!)bXb?$#;!<#'&U_K#R,##%"
200. DATA "!&#$!1#$!:#$Ia_!,b/!3#R!+b;)EY!;#1W`bbW4^T!)#.!%#)!,#$!=#1!-b)!3#Qa!(b]3#:bF!;#R!*b.!(#$$##0!I#`!+bJ!4#/a!(b"
201. DATA "F##@b2#%%!5#,M^!+b`:!?*!L#(!*bJ1$!5#X!(bE##A\!9#L!.bY*!Q#/!)bT!8#K!'bO!&#%!9#J!/bC!Q#=!)b:!8#(_!%ba0!>#/!/b"
202. DATA "C!Q#@!(bF!:#Hbb^6!@#]bbM=4I!'b^/!Q#R!&b^:!;#*3*$!@#$=0'!&#?[bb`D!)#/&!H#*a!%b]C!g#-NP@)!)#%Q1!G#/_b_K&!j#1:!*#"
203. DATA "=C##%!E#1^bZ*!k#'1!(#)K>!I#Cbb;!t#8;!J#Wb`3!Q#-!n#G_W##0*!P#$!l#%AO5$!*#'&!~#!H#(!~#!;#$##%!(#%!~#!8#)8;'!W#"
204. DATA "&!f#+>\O!G#&/EH3&!)#5?@:>[NLA7BD52;ONCDA92/!'#$$!F#$!'#.@>`bM%!5#+,)*+-41-'+8CD1GWa!(b_ZH8BY!9bTNOA8&!B#$6BA"
205. DATA "30.%#'4E`!%bM!0#.6DX^a!,babb`!,b^_!Cb^W7!0#'/37>DIQZVUPOIB>K!'b`X`!(bL*!,#)IT!@b]`!BbaK2&!%#21!%./7?JHTa!Bb_"
206. DATA "RG:7?;:GT`!db_;DDC?7!~b!=ba_!Uba!%baa!hbaabaa!%b`^!%bab]a`ba!?b_a!qba\_!~b!Ib"
207.  
208. '####################################################################################################################
209. '####################################################################################################################
210. '####################################################################################################################
211.  
212. SUB init ()
213. WIDTH , 40
214. COLOR 11: PRINT
215. PRINT TAB(27); "Ray Tracer (Beta version)"
216. COLOR 7
217. PRINT TAB(36); "By Zom-B"
218.  
219. scrn& = selectScreenMode&(4, 32)
220.  
221. makeTextures
222. 'texture&(1) = _LOADIMAGE("d:\0synced\software\qb64\wTex.png", 32)
223. 'texture&(2) = _LOADIMAGE("d:\0synced\software\qb64\wBump.png", 32)
224. 'texture&(3) = _LOADIMAGE("d:\0synced\software\qb64\fTex.png", 32)
225. 'texture&(4) = _LOADIMAGE("d:\0synced\software\qb64\fBump.png", 32)
226.  
227. makeScene
228.  
229. SCREEN scrn&
230. _DEST scrn&
231. 'SCREEN _NEWIMAGE(640, 480, 32)
232.  
233. sizeX% = _WIDTH
234. sizeY% = _HEIGHT
235. maxX% = sizeX% - 1
236. maxY% = sizeY% - 1
237. halfX% = sizeX% \ 2
238. halfY% = sizeY% \ 2
239.  
240. cameraPrepare 150, -250, 200, 0, 0, 66, 0, 0, 1, 60, maxX% / maxY%
241. 'cameraPrepare 0, 0, 400, 0, 0, 132, 0, -1, 0, 45, maxX% / maxY%
242. END SUB
243.  
244. '####################################################################################################################
245.  
246. SUB main ()
247. 'FOR i% = 0 TO 360 STEP 30
248. '  x = 100 * COS(i% * _deg2rad)
249. '  y = 100 * SIN(i% * _deg2rad)
250. '  cameraPrepare x, y, 400, 0, 0, 200, 0, 0, 1, 60, maxX% / maxY%
251.  
252. renderProgressive 256, 4
253.  
254. CIRCLE (maxX% \ 2, maxY% \ 2), 3, _RGB32(255, 255, 255), , , 1
255. 'NEXT
256. END SUB
257.  
258. '####################################################################################################################
259. '####################################################################################################################
260. '####################################################################################################################
261.  
262. SUB cameraPrepare (posX, posY, posZ, lookAtX, lookAtY, lookAtZ, upX, upY, upZ, fov, aspect)
263. camPos.x = posX
264. camPos.y = posY
265. camPos.z = posZ
266.  
267. camDir.x = lookAtX - posX
268. camDir.y = lookAtY - posY
269. camDir.z = lookAtZ - posZ
270. vectorNormalize camDir
271. 'PRINT camDir.x, camDir.y, camDir.z
272.  
273. camUp.x = upX
274. camUp.y = upY
275. camUp.z = upZ
276. 'vectorNormalize camUp
277. 'PRINT camUp.x, camUp.y, camUp.z
278.  
279. 'Right vec
280. vectorCross camUp, camDir, camRight
281. vectorNormalize camRight
282. 'PRINT camRight.x, camRight.y, camRight.z
283.  
284. vectorCross camDir, camRight, camUp
285. vectorNormalize camUp
286. 'PRINT camUp.x, camUp.y, camUp.z
287. 'END
288.  
289. scaleY = TAN(fov * (_PI / 360)) * 0.75
290. scaleX = scaleY * aspect
291.  
292. vectorScale camRight, scaleX
293. vectorScale camUp, scaleY
294.  
295. 'PRINT fov, scaleX, scaleY
296. 'END
297. END SUB
298.  
299. '####################################################################################################################
300.  
301. SUB renderProgressive (startSize%, endSize%)
302. pixStep% = startSize%
303.  
304. pixWidth% = pixStep% - 1
305. FOR y% = 0 TO maxY% STEP pixStep%
306.     FOR x% = 0 TO maxX% STEP pixStep%
307.         tracePoint x%, y%, r!, g!, b!
308.         LINE (x%, y%)-STEP(pixWidth%, pixWidth%), _RGB(r! * 255, g! * 255, b! * 255), BF
309.     NEXT
310.     IF INKEY$ = CHR$(27) THEN SYSTEM
311. NEXT
312.  
313. WHILE pixStep% > 2
314.     pixSize% = pixStep% \ 2
315.     pixWidth% = pixSize% - 1
316.     FOR y% = 0 TO maxY% STEP pixStep%
317.         y1% = y% + pixSize%
318.         FOR x% = 0 TO maxX% STEP pixStep%
319.             x1% = x% + pixSize%
320.  
321.             IF x1% < sizeX% THEN
322.                 tracePoint x1%, y%, r!, g!, b!
323.                 LINE (x1%, y%)-STEP(pixWidth%, pixWidth%), _RGB(r! * 255, g! * 255, b! * 255), BF
324.             END IF
325.             IF y1% < sizeY% THEN
326.                 tracePoint x%, y1%, r!, g!, b!
327.                 LINE (x%, y1%)-STEP(pixWidth%, pixWidth%), _RGB(r! * 255, g! * 255, b! * 255), BF
328.                 IF x1% < sizeX% THEN
329.                     tracePoint x1%, y1%, r!, g!, b!
330.                     LINE (x1%, y1%)-STEP(pixWidth%, pixWidth%), _RGB(r! * 255, g! * 255, b! * 255), BF
331.                 END IF
332.             END IF
333.         NEXT
334.         IF INKEY$ = CHR$(27) THEN SYSTEM
335.     NEXT
336.     pixStep% = pixStep% \ 2
337. WEND
338.  
339. FOR y% = 0 TO maxY%
340.     y1% = y% + 1
341.     FOR x% = 0 TO maxX%
342.         x1% = x% + 1
343.  
344.         IF x1% < sizeX% THEN
345.             tracePoint x1%, y%, r!, g!, b!
346.             PSET (x1%, y%), _RGB(r! * 255, g! * 255, b! * 255)
347.         END IF
348.         IF y1% < sizeY% THEN
349.             tracePoint x%, y1%, r!, g!, b!
350.             PSET (x%, y1%), _RGB(r! * 255, g! * 255, b! * 255)
351.             IF x1% < sizeX% THEN
352.                 tracePoint x1%, y1%, r!, g!, b!
353.                 PSET (x1%, y1%), _RGB(r! * 255, g! * 255, b! * 255)
354.             END IF
355.         END IF
356.     NEXT
357.     IF INKEY$ = CHR$(27) THEN SYSTEM
358. NEXT
359.  
360. IF NOT Doantialias THEN EXIT SUB
361.  
362. factor! = 255 / (endSize% * endSize%)
363.  
364. IF Usegaussian THEN
365.     FOR y% = 0 TO maxY%
366.         FOR x% = 0 TO maxX%
367.             c& = POINT(x%, y%)
368.             r! = _RED(c&)
369.             g! = _GREEN(c&)
370.             b! = _BLUE(c&)
371.             FOR i% = 2 TO endArea%
372.                 DO 'Marsaglia polar method for random gaussian
373.                     u! = RND * 2 - 1
374.                     v! = RND * 2 - 1
375.                     s! = u! * u! + v! * v!
376.                 LOOP WHILE s! >= 1 OR s! = 0
377.                 s! = SQR(-2 * LOG(s!) / s!) * 0.5
378.                 u! = u! * s!
379.                 v! = v! * s!
380.  
381.                 tracePoint x% + u!, y% + v!, r1!, g1!, b1!
382.  
383.                 r! = r! + r1!
384.                 g! = g! + g1!
385.                 b! = b! + b1!
386.             NEXT
387.  
388.             PSET (x%, y%), _RGB(r! * factor!, g! * factor!, b! * factor!)
389.             IF INKEY$ = CHR$(27) THEN SYSTEM
390.         NEXT
391.     NEXT
392. ELSE
393.     FOR y% = 0 TO maxY%
394.         FOR x% = 0 TO maxX%
395.             r! = 0
396.             g! = 0
397.             b! = 0
398.             FOR v% = 0 TO endSize% - 1
399.                 y1! = y% + v% / endSize%
400.                 FOR u% = 0 TO endSize% - 1
401.                     IF u% = 0 AND v& = 0 THEN
402.                         c& = POINT(x%, y%)
403.                     ELSE
404.                         x1! = x% + u% / endSize%
405.                         tracePoint x1!, y1!, r1!, g1!, b1!
406.                     END IF
407.                     r! = r! + r1!
408.                     g! = g! + g1!
409.                     b! = b! + b1!
410.                 NEXT
411.             NEXT
412.  
413.             PSET (x%, y%), _RGB(r! * factor!, g! * factor!, b! * factor!)
414.             IF INKEY$ = CHR$(27) THEN SYSTEM
415.         NEXT
416.     NEXT
417. END IF
418. END SUB
419.  
420. '####################################################################################################################
421.  
422. SUB tracePoint (x!, y!, r!, g!, b!)
423. x0! = (x! - halfX%) / halfX%
424. y0! = (halfY% - y!) / halfY%
425.  
426. rayX = camDir.x + x0! * camRight.x + y0! * camUp.x
427. rayY = camDir.y + x0! * camRight.y + y0! * camUp.y
428. rayZ = camDir.z + x0! * camRight.z + y0! * camUp.z
429.  
430. 'normalize to a vector length of 1
431. d = 1 / SQR(rayX * rayX + rayY * rayY + rayZ * rayZ)
432. traceRay camPos.x, camPos.y, camPos.z, rayX * d, rayY * d, rayZ * d, 3, -1, r!, g!, b!
433. END SUB
434.  
435. '####################################################################################################################
436.  
437. SUB traceRay (startX, startY, startZ, rayX, rayY, rayZ, depth%, lastObj%, lightR!, lightG!, lightB!)
438. findMinObj startX, startY, startZ, rayX, rayY, rayZ, lastObj%, minobj%, minDepth
439.  
440. IF minobj% = 0 THEN '                        Infinity
441.     lightR! = 0
442.     lightG! = 0
443.     lightB! = 0
444. ELSE '                                       An object was found
445.     intersectX = startX + rayX * minDepth
446.     intersectY = startY + rayY * minDepth
447.     intersectZ = startZ + rayZ * minDepth
448.  
449.     'Calculate normal vector
450.     SELECT CASE objectType%(minobj%)
451.         CASE FLOOR:
452.             normalX = 0
453.             normalY = 0
454.             normalZ = 1
455.         CASE SPHERE:
456.             normalX = (intersectX - positionX(minobj%)) / size(minobj%)
457.             normalY = (intersectY - positionY(minobj%)) / size(minobj%)
458.             normalZ = (intersectZ - positionZ(minobj%)) / size(minobj%)
459.     END SELECT
460.  
461.     'Calculate UV coordinates
462.     IF textures(minobj%).image <> -1 OR bumpmap(minobj%).image <> -1 THEN
463.         SELECT CASE objectType%(minobj%)
464.             CASE FLOOR:
465.                 texcoordU! = intersectX
466.                 texcoordV! = intersectY
467.             CASE SPHERE:
468.                 IF normalX = 0 THEN
469.                     IF normalY <= 0 THEN texcoordU! = 0 ELSE texcoordU! = 0.5
470.                 ELSE
471.                     texcoordU! = atan2(normalX, normalY) / pi2 + 0.5
472.                 END IF
473.  
474.                 texcoordV! = acos(normalZ) / _PI
475.         END SELECT
476.     END IF
477.  
478.     'Bumpmapping
479.     IF bumpmap(minobj%).image <> -1 THEN
480.         IF minobj% < 3 THEN
481.             texdirxx = 1
482.             texdirxy = 0
483.             texdirxz = 0
484.  
485.             texdiryx = 0
486.             texdiryy = 1
487.             texdiryz = 0
488.         ELSE
489.             texdirxx = normalY
490.             texdirxy = -normalX
491.             texdirxz = 0
492.  
493.             texdiryx = normalZ * normalX
494.             texdiryy = normalZ * normalY
495.             texdiryz = -(normalX * normalX + normalY * normalY)
496.         END IF
497.  
498.         x! = texcoordU! * bumpmap(minobj%).scaleU - bumpmap(minobj%).offsetU
499.         y! = texcoordV! * bumpmap(minobj%).scaleV - bumpmap(minobj%).offsetV
500.         x1% = INT(x!)
501.         y1% = INT(y!)
502.  
503.         dx1! = x! - x1%
504.         dy1! = y! - y1%
505.         dx2! = 1 - dx1!
506.         dy2! = 1 - dy1!
507.         dx1dy1! = dx1! * dy1!
508.         dx1dy2! = dx1! * dy2!
509.         dx2dy1! = dx2! * dy1!
510.         dx2dy2! = dx2! * dy2!
511.  
512.         x0% = remainder%(x1%, bumpmap(minobj%).w)
513.         y0% = remainder%(y1%, bumpmap(minobj%).h)
514.         x1% = remainder%(x1% + 1, bumpmap(minobj%).w)
515.         y1% = remainder%(y1% + 1, bumpmap(minobj%).h)
516.  
517.         _SOURCE bumpmap(minobj%).image
518.         c0& = POINT(x0%, y0%)
519.         c1& = POINT(x1%, y0%)
520.         c2& = POINT(x0%, y1%)
521.         c3& = POINT(x1%, y1%)
522.  
523.         sx! = ((_RED(c0&) - 127) * dx2dy2! + (_RED(c1&) - 127) * dx1dy2! + (_RED(c2&) - 127) * dx2dy1! + (_RED(c3&) - 127) * dx1dy1!) * bumpmap(minobj%).bumpfactor / 127
524.         sy! = ((_GREEN(c0&) - 127) * dx2dy2! + (_GREEN(c1&) - 127) * dx1dy2! + (_GREEN(c2&) - 127) * dx2dy1! + (_GREEN(c3&) - 127) * dx1dy1!) * bumpmap(minobj%).bumpfactor / 127
525.  
526.         normalX = normalX - (texdirxx * sx! + texdiryx * sy)
527.         normalY = normalY - (texdirxy * sx! + texdiryy * sy)
528.         normalZ = normalZ - (texdirxz * sx! + texdiryz * sy)
529.  
530.         r = SQR(normalX * normalX + normalY * normalY + normalZ * normalZ)
531.         normalX = normalX / r
532.         normalY = normalY / r
533.         normalZ = normalZ / r
534.     END IF
535.  
536.     'lighting
537.     r = 2 * (rayX * normalX + rayY * normalY + rayZ * normalZ)
538.     rayX = rayX - normalX * r
539.     rayY = rayY - normalY * r
540.     rayZ = rayZ - normalZ * r
541.  
542.     diffuseR! = 0
543.     diffuseG! = 0
544.     diffuseB! = 0
545.     specularR! = 0
546.     specularG! = 0
547.     specularB! = 0
548.  
549.     FOR a% = numLights% TO 1 STEP -1
550.         dirX = lightX(a%) - intersectX
551.         dirY = lightY(a%) - intersectY
552.         dirZ = lightZ(a%) - intersectZ
553.  
554.         r = 1 / SQR(dirX * dirX + dirY * dirY + dirZ * dirZ)
555.         dirX = dirX * r
556.         dirY = dirY * r
557.         dirZ = dirZ * r
558.  
559.         'Shadows testing
560.         findShadow intersectX, intersectY, intersectZ, dirX, dirY, dirZ, minobj%, noShadows%
561.  
562.         IF noShadows% THEN
563.             'Diffuse lighting
564.             r = normalX * dirX + normalY * dirY + normalZ * dirZ
565.             IF r > 0 THEN
566.                 diffuseR! = diffuseR! + colorR!(minobj%) * lightR!(a%) * r
567.                 diffuseG! = diffuseG! + colorG!(minobj%) * lightG!(a%) * r
568.                 diffuseB! = diffuseB! + colorB!(minobj%) * lightB!(a%) * r
569.             END IF
570.  
571.             'Specular lighting
572.             r = rayX * dirX + rayY * dirY + rayZ * dirZ
573.             IF r > 0 THEN
574.                 c! = r ^ (1 / highlight!(minobj%)) * specular!(minobj%)
575.  
576.                 specularR! = specularR! + lightR!(a%) * c!
577.                 specularG! = specularG! + lightG!(a%) * c!
578.                 specularB! = specularB! + lightB!(a%) * c!
579.             END IF
580.         END IF
581.     NEXT
582.  
583.     lightR! = diffuseR! + specularR!
584.     lightG! = diffuseG! + specularG!
585.     lightB! = diffuseB! + specularB!
586.  
587.     'texturing
588.     IF textures(minobj%).image <> -1 THEN
589.         x! = texcoordU! * textures(minobj%).scaleU - textures(minobj%).offsetU
590.         y! = texcoordV! * textures(minobj%).scaleV - textures(minobj%).offsetV
591.         x0% = INT(x!)
592.         y0% = INT(y!)
593.  
594.         dx1! = x! - x0%
595.         dy1! = y! - y0%
596.         dx2! = 1 - dx1!
597.         dy2! = 1 - dy1!
598.         dx1dy1! = dx1! * dy1!
599.         dx1dy2! = dx1! * dy2!
600.         dx2dy1! = dx2! * dy1!
601.         dx2dy2! = dx2! * dy2!
602.  
603.         x1% = remainder%(x0% + 1, textures(minobj%).w) ' returns positive value only, in contrast to MOD
604.         y1% = remainder%(y0% + 1, textures(minobj%).h)
605.         x0% = remainder%(x0%, textures(minobj%).w)
606.         y0% = remainder%(y0%, textures(minobj%).h)
607.  
608.         _SOURCE textures(minobj%).image
609.         c0& = POINT(x0%, y0%)
610.         c1& = POINT(x1%, y0%)
611.         c2& = POINT(x0%, y1%)
612.         c3& = POINT(x1%, y1%)
613.  
614.         materialr! = _RED(c0&) * dx2dy2! + _RED(c1&) * dx1dy2! + _RED(c2&) * dx2dy1! + _RED(c3&) * dx1dy1!
615.         materialg! = _GREEN(c0&) * dx2dy2! + _GREEN(c1&) * dx1dy2! + _GREEN(c2&) * dx2dy1! + _GREEN(c3&) * dx1dy1!
616.         materialb! = _BLUE(c0&) * dx2dy2! + _BLUE(c1&) * dx1dy2! + _BLUE(c2&) * dx2dy1! + _BLUE(c3&) * dx1dy1!
617.  
618.         lightR! = lightR! * materialr! / 255F
619.         lightG! = lightG! * materialg! / 255F
620.         lightB! = lightB! * materialb! / 255F
621.     END IF
622.  
623.     'Reflection
624.     IF reflection!(minobj%) > 0 AND depth% > 0 THEN
625.         traceRay intersectX, intersectY, intersectZ, rayX, rayY, rayZ, depth% - 1, minobj%, reflectR!, reflectG!, reflectB!
626.         lightR! = lightR! + (reflectR! - lightR!) * reflection!(minobj%)
627.         lightG! = lightG! + (reflectG! - lightG!) * reflection!(minobj%)
628.         lightB! = lightB! + (reflectB! - lightB!) * reflection!(minobj%)
629.     END IF
630.  
631.     ' Global intensity
632.     r = EXP(-minDepth / 1000.0)
633.  
634.     lightR! = lightR! * r
635.     lightG! = lightG! * r
636.     lightB! = lightB! * r
637. END IF
638. END FUNCTION
639.  
640. '####################################################################################################################
641.  
642. SUB findMinObj (startX, startY, startZ, rayX, rayY, rayZ, lastObj%, minObj%, minDepth)
643. minObj% = 0
644. minDepth = 1E+308
645. FOR a% = numObjects% TO 1 STEP -1
646.     IF a% <> lastObj% THEN
647.         SELECT CASE objectType%(a%)
648.             CASE FLOOR:
649.                 depth = -startZ / rayZ
650.             CASE SPHERE:
651.                 posX = positionX(a%) - startX
652.                 posY = positionY(a%) - startY
653.                 posZ = positionZ(a%) - startZ
654.  
655.                 r = rayX * posX + rayY * posY + rayZ * posZ
656.                 d = r * r - posX * posX - posY * posY - posZ * posZ + size(a%) * size(a%)
657.                 IF d >= 0 THEN depth = r - SQR(d) ELSE depth = -1
658.         END SELECT
659.  
660.         IF depth >= 0 THEN
661.             IF minDepth > depth THEN minDepth = depth: minObj% = a%
662.         END IF
663.     END IF
664. NEXT
665. END SUB
666.  
667. '####################################################################################################################
668.  
669. SUB findShadow (startX, startY, startZ, rayX, rayY, rayZ, lastObj%, noShadows%)
670. noShadows% = -1
671. FOR a% = numObjects% TO 1 STEP -1
672.     IF a% <> lastObj% THEN
673.         SELECT CASE objectType%(a%)
674.             CASE FLOOR:
675.                 depth = -startZ / rayZ
676.             CASE SPHERE:
677.                 posX = positionX(a%) - startX
678.                 posY = positionY(a%) - startY
679.                 posZ = positionZ(a%) - startZ
680.  
681.                 r = rayX * posX + rayY * posY + rayZ * posZ
682.                 d = r * r - posX * posX - posY * posY - posZ * posZ + size(a%) * size(a%)
683.                 IF d >= 0 THEN depth = r - SQR(d) ELSE depth = -1
684.         END SELECT
685.  
686.         IF depth >= 0 THEN
687.             noShadows% = 0
688.             EXIT SUB
689.         END IF
690.     END IF
691. NEXT
692. END SUB
693.  
694. '####################################################################################################################
695. '####################################################################################################################
696. '####################################################################################################################
697.  
698. SUB makeTextures
699. PRINT "Generating textures. Press any key to see them generating."
700. VIEW PRINT 2 TO 40
701. showing = 0
702.  
703. world& = _NEWIMAGE(128, 64, 32)
704. texture&(1) = _NEWIMAGE(1024, 512, 32)
705. texture&(2) = _NEWIMAGE(1024, 512, 32)
706. texture&(3) = _NEWIMAGE(512, 512, 32)
707. texture&(4) = _NEWIMAGE(512, 512, 32)
708.  
709. IF showing THEN SCREEN world& ELSE _DEST 0: PRINT: PRINT "(1/5) Decompressing world template (RLE)";
710.  
711. x% = 0: y% = 0
712. FOR a% = 1 TO 25
713.     _DEST world&
714.     READ a$
715.     FOR b! = 1 TO LEN(a$)
716.         c% = (ASC(MID$(a$, b!, 1)) - 35) * 4
717.         IF c% < 0 THEN n% = ASC(MID$(a$, b! + 1, 1)) - 34: b! = b! + 2: c% = (ASC(MID$(a$, b!, 1)) - 35) * 4 ELSE n% = 1
718.         FOR n% = n% TO 1 STEP -1
719.             PSET (x%, y%), _RGB(c%, c%, c%)
720.             x% = x% + 1: IF x% = 128 THEN x% = 0: y% = y% + 1
721.         NEXT
722.     NEXT
723.     IF LEN(INKEY$) THEN showing = -1: SCREEN world& ELSE IF NOT showing THEN _DEST 0: PRINT ".";
724. NEXT
725.  
726. IF showing THEN SCREEN texture&(1) ELSE _DEST 0: PRINT: PRINT "(2/5) World bump map";
727.  
728. FOR y% = 0 TO 511
729.     _SOURCE world&
730.     _DEST texture&(1)
731.     FOR x% = 0 TO 1023
732.         getWorldBump x% / 3000, y% / 2000, a!
733.         a! = (a! - 0.387) / 0.502: a! = a! * a!
734.         getWorldPixel x% / 8 - 0.5, y% / 8 - 0.50, c!
735.         c! = c! / 255: IF c! > 1 THEN c! = 1
736.  
737.         r! = 11 + (24 + 231 * a! - 11) * c!
738.         g! = 10 + (49 + 198 * a! - 10) * c!
739.         b! = 50 + (8 + 181 * a! - 50) * c!
740.  
741.         PSET (x%, y%), _RGB32(r!, g!, b!)
742.     NEXT
743.     IF LEN(INKEY$) THEN showing = -1: SCREEN texture&(1) ELSE IF NOT showing THEN _DEST 0: PRINT ".";
744. NEXT
745.  
746. IF showing THEN SCREEN texture&(2) ELSE _DEST 0: PRINT: PRINT "(3/5) World bump map";
747.  
748. FOR y% = 0 TO 511
749.     _SOURCE world&
750.     _DEST texture&(2)
751.     FOR x% = 0 TO 1023
752.         getWorldPixel x% / 8 - 0.46, y% / 8 - 0.50, c0!: getWorldBump x% / 300 + 0.001, y% / 300, a0!: a0! = a0! * c0!
753.         getWorldPixel x% / 8 - 0.54, y% / 8 - 0.50, c1!: getWorldBump x% / 300 - 0.001, y% / 300, a1!: a1! = a1! * c1!
754.         getWorldPixel x% / 8 - 0.50, y% / 8 - 0.46, c2!: getWorldBump x% / 300, y% / 300 + 0.001, a2!: a2! = a2! * c2!
755.         getWorldPixel x% / 8 - 0.50, y% / 8 - 0.54, c3!: getWorldBump x% / 300, y% / 300 - 0.001, a3!: a3! = a3! * c3!
756.  
757.         r! = (a1! - a0!) * 7
758.         g! = (a2! - a3!) * 7
759.         PSET (x%, y%), _RGB32(r! + 127, g! + 127, 127)
760.     NEXT
761.     IF LEN(INKEY$) THEN showing = -1: SCREEN texture&(2) ELSE IF NOT showing THEN _DEST 0: PRINT ".";
762. NEXT
763.  
764. IF showing THEN SCREEN texture&(3) ELSE _DEST 0: PRINT: PRINT "(4/5) Floor texture";
765.  
766. FOR y% = 0 TO 511
767.     _DEST texture&(3)
768.     FOR x% = 0 TO 511
769.         getFloorTexture x% / 256, y% / 256, r!, g!, b!
770.         PSET (x%, y%), _RGB32(r! * 255, g! * 255, b! * 255)
771.     NEXT
772.     IF LEN(INKEY$) THEN showing = -1: SCREEN texture&(2) ELSE IF NOT showing THEN _DEST 0: PRINT ".";
773. NEXT
774.  
775. IF showing THEN SCREEN texture&(4) ELSE _DEST 0: PRINT: PRINT "(5/5) Floor bump map";
776.  
777. FOR y% = 0 TO 511
778.     _DEST texture&(4)
779.     FOR x% = 0 TO 511
780.         getFloorBump x% / 256 - 0.002, y% / 256, a0!
781.         getFloorBump x% / 256 + 0.002, y% / 256, a1!
782.         getFloorBump x% / 256, y% / 256 + 0.002, a2!
783.         getFloorBump x% / 256, y% / 256 - 0.002, a3!
784.  
785.         r! = (a1! - a0!) * 1400
786.         g! = (a2! - a3!) * 1400
787.  
788.         PSET (x%, y%), _RGB32(r! + 127, g! + 127, 127)
789.     NEXT
790.     IF LEN(INKEY$) THEN showing = -1: SCREEN texture&(4) ELSE IF NOT showing THEN _DEST 0: PRINT ".";
791. NEXT
792. END SUB
793.  
794. '####################################################################################################################
795.  
796. SUB getWorldPixel (x!, y!, c0!)
797. x% = INT(x!) AND &H7F
798. y% = INT(y!) AND &H3F
799. dx! = x! - x%: IF dx! < 0 THEN dx! = dx! + 128
800. dy! = y! - y%
801.  
802.  
803. c0! = POINT(x%, y%) AND &HFF
804. c1! = POINT((x% + 1) AND &H7F, y%) AND &HFF
805. c2! = POINT(x%, y% + 1) AND &HFF
806. c3! = POINT((x% + 1) AND &H7F, y% + 1) AND &HFF
807.  
808. c0! = c0! + (c1! - c0!) * dx!
809. c2! = c2! + (c3! - c2!) * dx!
810. c0! = c0! + (c2! - c0!) * dy!
811.  
812. c0! = c0! - 72: IF c0! < 0 THEN c0! = 0
813. END SUB
814.  
815.  
816. SUB getWorldBump (u!, v!, a!)
817. l! = 0
818. fbm u!, v!, 1, l!
819. a! = 0.3 * l! + 0.2
820. END SUB
821.  
822.  
823. SUB getFloorTexture (u!, v!, r!, g!, b!)
824. v1% = v! - INT(v!) < 0.5: u1% = u! - INT(u!) < 0.5
825.  
826. IF u1% = v1% THEN
827.     l! = 0
828.     fbm u!, v!, 3, l!
829.     l! = l! * 0.7
830.     fbm u!, v!, 2, l!
831.     r! = 0.054 * l! + 0.61
832.     g! = 0.054 * l! + 0.42
833.     b! = 0.054 * l! + 0.25
834. ELSE
835.     l! = 0
836.     fbm u!, v!, 1, l!
837.     l! = l! * 0.6
838.     fbm u!, v!, 0, l!
839.     r! = 0.10 * l! + 0.05
840.     g! = 0.08 * l! - 0.04
841.     b! = 0.07 * l! - 0.06
842. END IF
843. END SUB
844.  
845.  
846. SUB getFloorBump (u!, v!, a!)
847. v1% = v! - INT(v!) < 0.5: u1% = u! - INT(u!) < 0.5
848. v2! = v! * 2 - INT(v! * 2): v2! = 1 - v2! * (1 - v2!) * 4: v2! = v2! * v2!: v2! = 1 - v2! * v2!
849. u2! = u! * 2 - INT(u! * 2): u2! = 1 - u2! * (1 - u2!) * 4: u2! = u2! * u2!: u2! = 1 - u2! * u2!
850.  
851. IF u1% = v1% THEN
852.     l! = 0
853.     fbm u!, v!, 3, l!
854.     l! = l! * 0.7
855.     fbm u!, v!, 2, l!
856.     a! = 0.02 * l! + 0.7
857. ELSE
858.     l! = 0
859.     fbm u!, v!, 1, l!
860.     l! = l! * 0.6
861.     fbm u!, v!, 0, l!
862.     a! = 0.05 * l! + 0.6
863. END IF
864.  
865. a! = a! * u2! * v2!
866.  
867. 'a! = a! + (u2! * v2! - 1) ' * 0.88
868. 'IF a! < 0.06 THEN a = RND * 0.02
869. END SUB
870.  
871. '####################################################################################################################
872.  
873. SUB fbm (x!, y!, a%, o!)
874. SELECT CASE a%
875.     CASE 0:
876.         zx! = x! * 40 - y! * 2
877.         zy! = y!
878.         i% = -5
879.     CASE 1:
880.         zx! = x! * 50
881.         zy! = y! * 50
882.         i% = -2
883.     CASE 2:
884.         zx! = x! * 80
885.         zy! = y! * 80
886.         i% = -2
887.     CASE 3:
888.         zx! = x! * 30 + y! * 0.5
889.         zy! = y! * 2
890.         i% = -2
891. END SELECT
892.  
893. scale! = 1
894. FOR i% = i% TO 0
895.     zcx! = zx!: zx! = zcx! * 0.6 - zy! * 0.8: zy! = zcx! * 0.8 + zy! * 0.6
896.     zcx! = CINT(zx! / scale!) * scale!: zcy! = CINT(zy! / scale!) * scale!
897.  
898.     rx1! = zcx! + 0.5 * scale! + 14: ry1! = zcy! + 0.5 * scale!: r! = 123094 / (rx1! * rx1! + ry1! * ry1!)
899.     rx1! = rx1! * r!: ry1! = ry1! * r!: rx1! = rx1! - INT(rx1!): ry1! = ry1! - INT(ry1!)
900.     rx2! = zcx! - 0.5 * scale! + 14: ry2! = zcy! + 0.5 * scale!: r! = 123094 / (rx2! * rx2! + ry2! * ry2!)
901.     rx2! = rx2! * r!: ry2! = ry2! * r!: rx2! = rx2! - INT(rx2!): ry2! = ry2! - INT(ry2!)
902.     rx3! = zcx! + 0.5 * scale! + 14: ry3! = zcy! - 0.5 * scale!: r! = 123094 / (rx3! * rx3! + ry3! * ry3!)
903.     rx3! = rx3! * r!: ry3! = ry3! * r!: rx3! = rx3! - INT(rx3!): ry3! = ry3! - INT(ry3!)
904.     rx4! = zcx! - 0.5 * scale! + 14: ry4! = zcy! - 0.5 * scale!: r! = 123094 / (rx4! * rx4! + ry4! * ry4!)
905.     rx4! = rx4! * r!: ry4! = ry4! * r!: rx4! = rx4! - INT(rx4!): ry4! = ry4! - INT(ry4!)
906.     x0! = (zx! - zcx!) / scale! + 0.5: x0! = (3 - 2 * x0!) * x0! * x0!: x1! = 1 - x0!
907.     y0! = (zy! - zcy!) / scale! + 0.5: y0! = (3 - 2 * y0!) * y0! * y0!: y1! = 1 - y0!
908.     pixcompx! = rx1! * x0! * y0! + rx3! * x0! * y1! + rx2! * x1! * y0! + rx4! * x1! * y1!
909.     pixcompy! = ry1! * x0! * y0! + ry3! * x0! * y1! + ry2! * x1! * y0! + ry4! * x1! * y1!
910.     o! = o! + SQR(pixcompx! * pixcompx! + pixcompy! * pixcompy!) * scale! * scale!: scale! = scale! * 0.8
911. NEXT
912. END FUNCTION
913.  
914. '####################################################################################################################
915. '####################################################################################################################
916. '####################################################################################################################
917.  
918. SUB makeScene
919. objectType%(1) = FLOOR
920. colorR!(1) = 1
921. colorG!(1) = 1
922. colorB!(1) = 1
923. colorA!(1) = 1
924. specular!(1) = 2
925. highlight!(1) = 0.002
926. reflection!(1) = 0.5
927. texturePrepare textures(1), texture&(3), .005, .005, 0, 0, 0
928. texturePrepare bumpmap(1), texture&(4), .005, .005, 0, 0, 1
929.  
930. objectType%(2) = SPHERE
931. positionX(2) = 0
932. positionY(2) = 57.735
933. positionZ(2) = 50
934. size(2) = 50
935. colorR!(2) = 1
936. colorG!(2) = 0
937. colorB!(2) = 0
938. colorA!(2) = 1
939. specular!(2) = 1
940. highlight!(2) = 0.1
941. reflection!(2) = 0.1
942. texturePrepare textures(2), -1, 1, 1, 0, 0, 0
943. texturePrepare bumpmap(2), -1, 1, 1, 0, 0, 1
944.  
945. objectType%(3) = SPHERE
946. positionX(3) = -50
947. positionY(3) = -28.8675
948. positionZ(3) = 50
949. size(3) = 50
950. colorR!(3) = 0
951. colorG!(3) = 0
952. colorB!(3) = 1
953. colorA!(3) = 1
954. specular!(3) = 1
955. highlight!(3) = 0.04
956. reflection!(3) = 0.4
957. texturePrepare textures(3), -1, 1, 1, 0, 0, 0
958. texturePrepare bumpmap(3), -1, 1, 1, 0, 0, 1
959.  
960. objectType%(4) = SPHERE
961. positionX(4) = 50
962. positionY(4) = -28.8675
963. positionZ(4) = 50
964. size(4) = 50
965. colorR!(4) = 0
966. colorG!(4) = 1
967. colorB!(4) = 0
968. colorA!(4) = 1
969. specular!(4) = 10
970. highlight!(4) = 0.01
971. reflection!(4) = 0.2
972. texturePrepare textures(4), -1, 1, 1, 0, 0, 0
973. texturePrepare bumpmap(4), -1, 1, 1, 0, 0, 1
974.  
975. objectType%(5) = SPHERE
976. positionX(5) = 0
977. positionY(5) = 0
978. positionZ(5) = 132
979. size(5) = 50
980. colorR!(5) = 1
981. colorG!(5) = 1
982. colorB!(5) = 1
983. colorA!(5) = 1
984. specular!(5) = 5
985. highlight!(5) = 0.002
986. reflection!(5) = 0.15
987. texturePrepare textures(5), texture&(1), 1, 1, 0.35, 0, 0
988. texturePrepare bumpmap(5), texture&(2), 1, 1, 0.35, 0, 1
989.  
990. numObjects% = 5
991.  
992. lightX(1) = 460
993. lightY(1) = -460
994. lightZ(1) = 460
995. lightR!(1) = 1
996. lightG!(1) = 0.25
997. lightB!(1) = 0.25
998.  
999. lightX(2) = -640
1000. lightY(2) = -180
1001. lightZ(2) = 460
1002. lightR!(2) = 0.25
1003. lightG!(2) = 1
1004. lightB!(2) = 0.25
1005.  
1006. lightX(3) = 80
1007. lightY(3) = 260
1008. lightZ(3) = 760
1009. lightR!(3) = 0.25
1010. lightG!(3) = 0.25
1011. lightB!(3) = 1
1012.  
1013. lightX(4) = 0
1014. lightY(4) = 0
1015. lightZ(4) = 400
1016. lightR!(4) = 1
1017. lightG!(4) = 1
1018. lightB!(4) = 1
1019.  
1020. numLights% = 4
1021. END SUB
1022.  
1023. '####################################################################################################################
1024.  
1025. SUB texturePrepare (tex AS TEXTURE, handle&, sU!, sV!, oU!, oV!, bumpfactor!)
1026. tex.image = handle&
1027. IF handle& <> -1 THEN
1028.     tex.w = _WIDTH(tex.image)
1029.     tex.h = _HEIGHT(tex.image)
1030.     tex.scaleU = sU! * tex.w
1031.     tex.scaleV = sV! * tex.h
1032.     tex.offsetU = oU! * tex.w
1033.     tex.offsetV = oV! * tex.h
1034.     tex.bumpfactor = bumpfactor!
1035. END IF
1036. END SUB
1037.  
1038. '####################################################################################################################
1039. '# Math Library V0.11 (routines)
1040. '# By Zom-B
1041. '####################################################################################################################
1042.  
1043. FUNCTION remainder% (a%, b%)
1044. remainder% = a% - INT(a% / b%) * b%
1045. END FUNCTION
1046.  
1047. '> merger: Skipping unused FUNCTION fRemainder (a, b)
1048.  
1049. '####################################################################################################################
1050.  
1051. '> merger: Skipping unused FUNCTION safeLog (x)
1052.  
1053. '####################################################################################################################
1054.  
1055. '> merger: Skipping unused FUNCTION asin (y)
1056.  
1057. FUNCTION acos (y)
1058. IF y <= -0.99999999999999# THEN acos = _PI: EXIT FUNCTION
1059. IF y >= 0.99999999999999# THEN acos = 0: EXIT FUNCTION
1060. acos = pi05 - ATN(y / SQR(1 - y * y))
1061. END FUNCTION
1062.  
1063. '> merger: Skipping unused FUNCTION safeAcos (y)
1064.  
1065. FUNCTION atan2 (y, x)
1066. IF x > 0 THEN
1067.     atan2 = ATN(y / x)
1068. ELSEIF x < 0 THEN
1069.     IF y > 0 THEN
1070.         atan2 = ATN(y / x) + _PI
1071.     ELSE
1072.         atan2 = ATN(y / x) - _PI
1073.     END IF
1074. ELSEIF y > 0 THEN
1075.     atan2 = _PI / 2
1076. ELSE
1077.     atan2 = -_PI / 2
1078. END IF
1079. END FUNCTION
1080.  
1081. '####################################################################################################################
1082. '# Vector math library v0.1 (module part)
1083. '# By Zom-B
1084. '####################################################################################################################
1085.  
1086. SUB vectorScale (a AS VECTOR, scale)
1087. a.x = a.x * scale
1088. a.y = a.y * scale
1089. a.z = a.z * scale
1090. END SUB
1091.  
1092. SUB vectorNormalize (a AS VECTOR)
1093. r = 1 / SQR(a.x * a.x + a.y * a.y + a.z * a.z)
1094. a.x = a.x * r
1095. a.y = a.y * r
1096. a.z = a.z * r
1097. END SUB
1098.  
1099. '####################################################################################################################
1100.  
1101. SUB vectorCross (a AS VECTOR, b AS VECTOR, o AS VECTOR)
1102. o.x = a.y * b.z - a.z * b.y
1103. o.y = a.z * b.x - a.x * b.z
1104. o.z = a.x * b.y - a.y * b.x
1105. END SUB
1106.  
1107. '####################################################################################################################
1108. '# Screen mode selector v1.1 (routines)
1109. '# By Zom-B
1110. '####################################################################################################################
1111.  
1112. FUNCTION selectScreenMode& (yOffset%, colors%)
1113. DIM aspectName$(0 TO 9), aspectCol%(0 TO 9)
1114. RESTORE videoaspect
1115. FOR y% = 0 TO 10
1116.     READ aspectName$(y%), aspectCol%(y%)
1117.     IF aspectCol%(y%) = 0 THEN numAspect% = y% - 1: EXIT FOR
1118. NEXT
1119.  
1120. DIM vidX%(1 TO 100), vidY%(1 TO 100), vidA%(1 TO 100)
1121. RESTORE videomodes
1122. FOR y% = 1 TO 100
1123.     READ vidX%(y%), vidY%(y%), vidA%(y%)
1124.     IF (vidX%(y%) <= 0) THEN numModes% = y% - 1: EXIT FOR
1125. NEXT
1126.  
1127. IF numModes% > _HEIGHT - yOffset% - 1 THEN numModes% = _HEIGHT - yOffset% - 1
1128.  
1129. DEF SEG = &HB800
1130. LOCATE yOffset% + 1, 1
1131. PRINT "Select video mode:"; TAB(61); "Click "
1132. POKE yOffset% * 160 + 132, 31
1133.  
1134. y% = 0
1135. lastY% = 0
1136. selectedAspect% = 0
1137. reprint% = 1
1138. lastButton% = 0
1139. DO
1140.     IF INKEY$ = CHR$(27) THEN CLS: SYSTEM
1141.     IF reprint% THEN
1142.         reprint% = 0
1143.  
1144.         FOR x% = 1 TO numModes%
1145.             LOCATE yOffset% + x% + 1, 1
1146.             COLOR 7, 0
1147.             PRINT USING "##:"; x%;
1148.             IF selectedAspect% = 0 THEN
1149.                 COLOR aspectCol%(vidA%(x%))
1150.             ELSEIF selectedAspect% = vidA%(x%) THEN
1151.                 COLOR 15
1152.             ELSE
1153.                 COLOR 8
1154.             END IF
1155.             PRINT STR$(vidX%(x%)); ","; vidY%(x%);
1156.         NEXT
1157.  
1158.         FOR x% = 0 TO numAspect%
1159.             IF x% > 0 AND selectedAspect% = x% THEN
1160.                 COLOR aspectCol%(x%), 3
1161.             ELSE
1162.                 COLOR aspectCol%(x%), 0
1163.             END IF
1164.             LOCATE yOffset% + x% + 2, 64
1165.             PRINT "<"; aspectName$(x%); ">"
1166.         NEXT
1167.     END IF
1168.     IF _MOUSEINPUT THEN
1169.         IF lastY% > 0 THEN
1170.             FOR x% = 0 TO 159 STEP 2
1171.                 POKE lastY% + x%, PEEK(lastY% + x%) AND &HEF
1172.             NEXT
1173.         END IF
1174.  
1175.         x% = _MOUSEX
1176.         y% = _MOUSEY - yOffset% - 1
1177.  
1178.         IF x% <= 60 THEN
1179.             IF y% > 0 AND y% <= numModes% THEN
1180.                 IF _MOUSEBUTTON(1) = 0 AND lastButton% THEN EXIT DO
1181.                 y% = (yOffset% + y%) * 160 + 1
1182.                 FOR x% = 0 TO 119 STEP 2
1183.                     POKE y% + x%, PEEK(y% + x%) OR &H10
1184.                 NEXT
1185.             ELSE
1186.                 y% = 0
1187.             END IF
1188.         ELSE
1189.             IF y% > 0 AND y% - 1 <= numAspect% THEN
1190.                 IF _MOUSEBUTTON(1) THEN
1191.                     selectedAspect% = y% - 1
1192.                     reprint% = 1
1193.                 END IF
1194.                 y% = (yOffset% + y%) * 160 + 1
1195.                 FOR x% = 120 TO 159 STEP 2
1196.                     POKE y% + x%, PEEK(y% + x%) OR &H10
1197.                 NEXT
1198.             ELSE
1199.                 y% = 0
1200.             END IF
1201.         END IF
1202.         lastY% = y%
1203.         lastButton% = _MOUSEBUTTON(1)
1204.     END IF
1205. LOOP
1206.  
1207. selectScreenMode& = _NEWIMAGE(vidX%(y%), vidY%(y%), colors%)
1208.  
1209. COLOR 7
1210. CLS
1211. END FUNCTION
1212.