Scrollable output in QB64

[SMcNeill]

As per a question from chrisowen09 from the irc channel, here's a few brief demos of how you can create scrollable output for a  program:


First, and often easiest way is to simply dump the output to the $CONSOLE -- it's scrollable.

Code: QB64: [Select]

1. $CONSOLE
2. SCREEN _NEWIMAGE(640, 480, 32)
3. PRINT "Stuff to screen"
4. LINE (100, 100)-(200, 200), &HFFF0F000, BF
5. SLEEP
6. PRINT
7. PRINT "And now I have stuff which I might need to scroll, such as for diagnostics...."
8. FOR i = 1 TO 100 'Use _DEST to print to console
9.     _DEST _CONSOLE: PRINT "Diagnose this line #"; i 'Print to the console
10.     _DEST 0: PRINT "Diagnose this line #"; i 'and the main screen
11. NEXT
12. SLEEP
13. PRINT
14. PRINT
15. PRINT "If you notice, you can scroll from the console automatically..."
16. PRINT "It's the easiest way to handle scroll events, as it's native for us."
17. PRINT
18. SLEEP
19. FOR i = 1 TO 100 'And a second method to print to console, using ECHO
20.     _ECHO "Also Diagnose this line #" + STR$(i) 'ECHO to the console
21.     PRINT "Also Diagnose this line #"; i 'and the main screen
22. NEXT

A second method is to write a simple scroll routine yourself to display the data -- here's one which uses U and D to scroll up and down:

Code: QB64: [Select]

1. DIM array(100) AS STRING
2.  
3. OPEN "temp.txt" FOR OUTPUT AS #1
4. FOR i = 1 TO 100
5.     PRINT #1, "Junk Line of Input #"; i
6. NEXT
7. CLOSE
8.  
9. OPEN "temp.txt" FOR BINARY AS #1 'Load the data
10. l = LOF(1) 'all of it at once
11. junk$ = SPACE$(l)
12. GET #1, 1, junk$ 'The file is now in junk$
13. CLOSE
14.  
15.  
16. ParseData array(), junk$ 'And we parse junk$ into our array
17.  
18. ScrollableDisplay 1, 100, array()
19.  
20. SUB ScrollableDisplay (start, finish, array() AS STRING)
21.     IF start < LBOUND(array) THEN start = LBOUND(array)
22.     IF finish > UBOUND(array) THEN finish = UBOUND(array)
23.     maxcount = _HEIGHT - 2
24.     DO
25.         CLS
26.         FOR i = start TO finish
27.             PRINT i, array(i)
28.             IF i - start >= maxcount THEN EXIT FOR
29.         NEXT
30.         i$ = UCASE$(INKEY$)
31.         SELECT CASE i$
32.             CASE "U" 'scroll up
33.                 IF start > LBOUND(array) THEN start = start - 1
34.             CASE "D"
35.                 IF start < finish - maxcount THEN start = start + 1
36.         END SELECT
37.         _LIMIT 30
38.         _DISPLAY
39.     LOOP
40. END SUB
41.  
42. SUB ParseData (array() AS STRING, text$)
43.     temp$ = text$
44.     IF INSTR(text$, CHR$(13)) THEN CRLF = 2 ELSE CRLF = 1
45.     DO
46.         IF l >= LEN(temp$) THEN EXIT DO
47.         l = INSTR(temp$, CHR$(10))
48.         count = count + 1
49.         array(count) = LEFT$(temp$, l - CRLF)
50.         temp$ = MID$(temp$, l + 1)
51.     LOOP
52. END SUB

Neither are really that difficult to code, but $CONSOLE and _ECHO are definitely the quickest and simplest way to toss data to a program, for diagnostic purposes usually.

[SierraKen]

Pretty interesting! You also can output your data to a .txt file and use Notepad to scroll it, like I've done a few times. The trick though is to count how many words you want per-line and then add a print #1, " "   after that to move the data to the next line. This makes an Example.txt file and counts to 1000 numbers on the file with 10 per line. Notice how I also used INT (integer) with some math to make it go to the next line when the number is divisible by 10.

Code: QB64: [Select]

1. CLS
2. OPEN "Example.txt" FOR OUTPUT AS #1
3. FOR NUMBERS = 1 TO 1000
4.     PRINT NUMBERS; " ";
5.     PRINT #1, NUMBERS; " ";
6.     IF NUMBERS / 10 = INT(NUMBERS / 10) THEN PRINT #1, " ": PRINT
7. NEXT NUMBERS
8. CLOSE #1
9.  
10.  

[OldMoses]

Ah, now I see what the console is for. I always wondered what was so great about a console. If I had a console for every time I wanted to examine output that went off screen while I was blinking...

While on the subject, here's how I generally handle large data arrays with a mouse wheel scroll.

Code: QB64: [Select]

1. TYPE nmlst
2.     a AS INTEGER
3.     b AS INTEGER
4.     c AS INTEGER
5.     d AS STRING * 4
6. END TYPE
7.  
8. DIM SHARED Datr(100) AS nmlst
9. DIM SHARED offset AS INTEGER
10. FOR x = 1 TO 100
11.     Datr(x).a = x: Datr(x).b = x * 2: Datr(x).c = x * 5
12.     IF Datr(x).a MOD 2 = 0 THEN
13.         Datr(x).d = "even"
14.     ELSE
15.         Datr(x).d = "odd"
16.     END IF
17. NEXT x
18.  
19. IF UBOUND(Datr) > 20 THEN
20.     oi = 1: maxoff = UBOUND(Datr) - 20: offset = 0
21. END IF
22.  
23. SCREEN 0 '25x40
24. DO
25.     CLS
26.     LOCATE 1, 1
27.     PRINT " Scroll with mouse wheel. ESC to quit"
28.  
29.     FOR a = 1 TO 20
30.         LOCATE a + 1, 1
31.         PRINT Datr(a + offset).a; " is "; Datr(a + offset).d; ",  x 2 = "; Datr(a + offset).b; ",  x 5 = "; Datr(a + offset).c
32.     NEXT a
33.     Mouse_Loop oi, maxoff, offset
34.     _DISPLAY
35.     _LIMIT 50
36. LOOP UNTIL _KEYDOWN(27)
37.  
38.  
39. SUB Mouse_Loop (var AS INTEGER, var2 AS INTEGER, var3 AS INTEGER)
40.  
41.     '-------------------------ALGORITHM--------------------------------------------------CLEARED
42.     ' SUB: Mouse_Loop
43.     '
44.     ' Purpose:
45.     ' Primary mouse input loop. Controls mousewheel scrolling and conditions
46.     ' x,y position data.
47.     '
48.     ' Passed Variables:
49.     ' var sends whether data list is extensive enough for using offset printing values
50.     ' var2 sends maximum allowed offset value
51.     '
52.     '------------------------------------------------------------------------------------
53.  
54.     DO WHILE _MOUSEINPUT '                                      scan for changes in mouse position and save to global variables
55.         IF var = 1 THEN
56.             var3 = var3 + _MOUSEWHEEL '                     mousewheel offset determines starting element to print
57.             IF var3 < 0 THEN var3 = 0 '                     don't go beyond bottom of array
58.             IF var3 > var2 THEN var3 = var2 '               don't go beyond the end of the array
59.         END IF
60.         'mouse_y = _MOUSEY ' globals used where mouse positions are important.
61.         'mouse_x = _MOUSEX
62.     LOOP
63.  
64. END SUB 'Mouse_Loop
65.  
66.  

[SierraKen]

That's awesome OldMoses! I never seen that kind of thing before in any BASIC language. I saved it to learn by later sometime, thanks.

[OldMoses]

That's awesome OldMoses! I never seen that kind of thing before in any BASIC language. I saved it to learn by later sometime, thanks.

I couldn't do it before QB64. It used to be the stuff of assembly routines and interrupt calls, which I never did learn to fool with.

[SMcNeill]

And here's a direct example for scrolling text which suits Chris's long data structure:

Code: QB64: [Select]

1. TYPE InventoryDataStructure
2.     EmployeeScan AS STRING * 4
3.     Employeename AS STRING * 60
4.     Brand AS STRING * 60
5.     Number AS STRING * 40
6.     UnitName AS STRING * 60
7.     WeightBegin AS SINGLE
8.     UPCCode AS STRING * 20
9.     Cost AS SINGLE
10.     PurchaseDate AS STRING * 10
11.     ExpirationDate AS STRING * 10
12.     WeightCheckOut AS SINGLE
13.     WeightCheckIn AS SINGLE
14.     'STOCKUPC = 9, more corrupts the barcode print out.
15.     StockUPC AS STRING * 10 'Serial number
16.     TypeofProductInventory AS STRING * 20
17.     BatchNumber AS STRING * 4
18.     BoxNumber AS STRING * 4
19.     GallonorPound AS STRING * 8
20.     INorOut AS STRING * 3
21.     Room AS STRING * 10
22.     Rack AS STRING * 4
23.     Shelf AS STRING * 4
24.     Bin AS STRING * 4
25.     DT AS STRING * 10
26.     TM AS STRING * 8
27. END TYPE
28. DIM SHARED ProductInventory AS InventoryDataStructure
29. DIM SHARED RecordCount AS LONG
30. ProductInventoryDBase$ = "Product Inventory Stock.RND"
31.  
32. REDIM array(100000) AS STRING 'large enough to hold all the records
33.  
34.  
35. OPEN ProductInventoryDBase$ FOR BINARY AS #1 'Load the data
36. temp$ = SPACE$(LEN(ProductInventory)) 'the length of the data, as a single string so we can assign it to our array
37. DO UNTIL EOF(1)
38.     GET #1, , temp$ 'load one record at a time
39.     RecordCount = RecordCount + 1 'count the records as we go so we can put them in our array for display
40.     array(RecordCount) = temp$ 'assign the value to the array for display
41. LOOP
42. CLOSE ' Close the file
43.  
44. _FONT 8
45. WIDTH 200, 30 'Set to as large a value as possible to see more on the screen at once.
46. ScrollableDisplay 1, RecordCount, array()
47.  
48. SUB ScrollableDisplay (start, finish, array() AS STRING)
49.     IF start < LBOUND(array) THEN start = LBOUND(array)
50.     IF finish > UBOUND(array) THEN finish = UBOUND(array)
51.     DO
52.         CLS
53.         FOR i = start TO finish
54.             PRINT "RECORD" + STR$(i) + ":" + array(i)
55.             PRINT 'A space between records for readability
56.             IF CSRLIN > 25 THEN EXIT FOR
57.         NEXT
58.         i$ = UCASE$(INKEY$)
59.         SELECT CASE i$
60.             CASE CHR$(0) + CHR$(72) 'scroll up
61.                 IF start > 1 THEN start = start - 1
62.             CASE CHR$(0) + CHR$(80) 'scroll down
63.                 IF start < finish THEN start = start + 1
64.             CASE CHR$(27) 'Exit
65.                 EXIT SUB
66.         END SELECT
67.         _LIMIT 30
68.         _DISPLAY
69.     LOOP
70. END SUB

[Chris80194]

Thank you ill bang it into the compiler.

I have this bad habit of falling asleep from time to time, I just can not seem to get over it. 
Not sure if there is a support group that can help with it either.

[Chris80194]

OldMoses  Ok I hate you.... Now I have another idea to try in my program ughhhhh and if I only DID NOT KNOW how to do that I would not have even worried about but NOW I have to make it work.  LOL

SMcNeill That works great in the test window the data looks a bit corrupted which could be the issue I am having with some searching...
Of course I have also made changes and did not clear that main data file too but that is what I was looking for.
Thanks.