Author Topic: Calculate Pi (Read 4575 times)

SierraKen · « **on:** August 02, 2019, 07:26:52 pm »

Hi all,

I looked into this a lot today and I know there's the _PI command that has quite a few decimal places, which would be fine in probably any situation. But I wanted to see if it was possible to go beyond that with QB64 and after researching a bit, I found an old BASIC program someone posted on the codecodex wiki page, along with other computer languages to do the same thing, a program that lets the user type in how many decimals they want and it spurts it out from there. When I did it I noticed that the user only sees the bottom portion that's left on the screen, so I added to it the ability for the user to make Pi.txt that opens automatically at the end and you see it in Notepad (if you have Windows) or whatever default .txt viewer you have. Like I say in the program, I wouldn't go over 20,000 digits though because for that amount, I waited probably around 4 or 5 minutes for it to process it all on my semi-new computer. I also don't know if there's a limit on how much Notepad can hold. This program originally was made and put in the American Mathematical Monthly, it says in 1938 but that is probably just when they thought up a way to figure something like this out. This program is already in 2 places online, here: http://www.codecodex.com/wiki/Calculate_digits_of_pi and here: https://groups.google.com/forum/#!topic/alt.lang.basic/3ZdfRCIihOQ The second URL is originally from the old Newsgroup alt.lang.basic which I used go to in the 90's sometimes. So anyways, here is what I did with it, enjoy:

Note: Don't use this code, it uses a lot of computer computation without LIMIT. Scroll down to the bottom of this forum topic to get a better version.

Code: QB64: [Select]

'Almost all of the following code was posted by someone on http://www.codecodex.com/wiki/Calculate_digits_of_pi
'That was taken from American Mathematical Monthly (see below).
'I converted it to also make a .txt file of Pi.txt if the user wishes to.
 
 
'PI.BAS 'Prints PI to number of decimal places desired. 19830623tac.
'        Ref: American Mathematical Monthly vol#45,1938 p657-667.
'        Ref: Best of Micro vol.#1 p85-86.
'
'
'             *       ----                      ----
'        *****         \     16(-1)^(k+1)        \         4(-1)^(k+1)
'       * * *   ---     >   ------------    --    >    ----------------
'         * *   ---    /    (2k-1)5^(2k-1)       /      (2k-1)239^(2k-1)
'         * *         ----                      ----
'        *   *        k=1                       k=1
'
'
 
 
SCREEN _NEWIMAGE(800, 600, 32)
CLS
PRINT "                      Calculate Pi"
PRINT: PRINT: PRINT
PRINT "This program will produce Pi to as many digits as you wish."
PRINT "But I do not recommend going over 20000 because it's pretty slow."
PRINT: PRINT
PRINT "Do you wish to also have it make a .txt file called Pi.txt"
PRINT "that can be opened with a program such as Windows Notepad?"
PRINT "The program will also open Pi.txt after it is finished making it."
PRINT "If you just see it on the screen, you will only see as much as"
PRINT "the screen can show at the end."
INPUT "Type Yes or No here:"; ff$
IF LEFT$(ff$, 1) = "Y" OR LEFT$(ff$, 1) = "y" THEN file = 1
CLS
main:
TEN = 100
INPUT "Enter number of digits wanted"; SIZE:
SIZE = (SIZE + 1) OR 1
PLACES = SIZE - 1
 
IF SIZE > 200 THEN TEN = 10 ELSE SIZE = (SIZE + 1) / 2
 
DIM POWER(SIZE), TERM(SIZE), RESULT(SIZE)
K(1) = 25: K(2) = 239 'Constants
C(1) = 5: C(2) = 239
 
'Main loop.
FOR PASS = 1 TO 2
 
    Init:
    FOR L = 0 TO SIZE
        POWER(L) = 0: TERM(L) = 0: IF PASS = 1 THEN RESULT = 0
    NEXT L
    POWER(0) = 16 / PASS ^ 2
    MODE = 0
    DIVISOR = C(PASS)
    GOSUB divide
    XPONENT = 1
    SIGN = 3 - 2 * PASS
    '
 
    copy:
    FOR L = 0 TO SIZE: TERM(L) = POWER(L): NEXT L
    '
    MODE = 1
    DIVISOR = XPONENT
    GOSUB divide
 
    MODE = (SIGN < 0) + ABS(SIGN > 0)
    GOSUB addsub
 
    XPONENT = XPONENT + 2
    SIGN = -SIGN
 
    MODE = 0
    DIVISOR = K(PASS)
    GOSUB divide
 
    IF PASS = 2 THEN GOSUB divide
 
    IF ZERO <> 0 THEN GOTO copy
 
NEXT PASS
'
'Print result.
PRINT
PRINT
PRINT "The value of PI to"; PLACES; " decimal places"
PRINT
PRINT RESULT(0); ".";
IF file = 1 THEN OPEN "pi.txt" FOR OUTPUT AS #1
PRINT #1, "3 . ";
FOR L = 1 TO SIZE
    IF (TEN = 100) * (RESULT(L) < 10) THEN
        PRINT "0";
        PRINT USING "#"; RESULT(L);
        IF file = 1 THEN PRINT #1, "0";
        IF file = 1 THEN PRINT #1, USING "#"; RESULT(L);
        GOTO nxt
    END IF
    IF file = 1 THEN IF L / 30 = INT(L / 30) THEN PRINT #1, " "
    PRINT USING "##"; RESULT(L);
    IF file = 1 THEN PRINT #1, USING "##"; RESULT(L);
    nxt:
NEXT L
IF file = 1 THEN CLOSE #1
IF file = 1 THEN SHELL _DONTWAIT "Pi.txt"
END
 
divide:
'Division subroutine.   mode0 =  Power(x)/Div else mode1 =  Term(x)/Div.
DIGIT = 0: ZERO = 0
FOR L1 = 0 TO SIZE
    DIGIT = DIGIT + TERM(L1) * MODE + POWER(L1) - POWER(L1) * MODE
    QUOTIENT = INT(DIGIT / DIVISOR)
    RESIDUE = DIGIT MOD DIVISOR
    ZERO = ZERO OR (QUOTIENT + RESIDUE)
    IF MODE THEN TERM(L1) = QUOTIENT ELSE POWER(L1) = QUOTIENT
    DIGIT = RESIDUE * TEN
NEXT L1
MODE = 0
RETURN
 
addsub:
'Add/Subtract subroutine.       mode - 1 =  Subtract  else mode1 = Add.
CARRY = 0
FOR L1 = SIZE TO 0 STEP -1
    SUM = RESULT(L1) + TERM(L1) * MODE + CARRY * MODE: CARRY = 0
    IF (MODE = 1) * (SUM < TEN) + (MODE = -1) * (SUM >= 0) THEN GOTO t1
    SUM = SUM + MODE * -TEN: CARRY = 1
 
    t1:
    RESULT(L1) = SUM
NEXT L1
MODE = 0
RETURN
 

SierraKen · « **Reply #1 on:** August 02, 2019, 11:26:28 pm »

I just did it for 100,000 digits and it worked. But it took 39 minutes and I don't suggest this because I don't want to overheat the chip or anything. I suppose someone can add a _LIMIT command on the loop but it would take much longer so it might heat up that way, I don't know. But here is the attachment of the 100,000 Pi digits (actually 100,003 total, I checked it with Word). I renamed it afterward. It is 136 pages long. Check it out!

bplus · « **Reply #2 on:** August 02, 2019, 11:39:48 pm »

LOL so what are you going to do with all those digits?

Here is one thing we did:
https://www.qb64.org/forum/index.php?topic=1176.msg103748#msg103748

SierraKen · « **Reply #3 on:** August 02, 2019, 11:58:51 pm »

LOL, well I always wanted to process Pi for a lot of digits. :) Cool program you got there, I ran it to the end and it said 296.5056 seconds. :)

bplus · « **Reply #4 on:** August 03, 2019, 08:39:14 am »

That time is pretty much meaningless since the display was going slow for human eyes to watch, the meaningful statistic is that all the digits repeat after 560 digits, 7 being the last to do so.

Might be interesting to explore the distribution of digits, ie is one digit favored over another in say first 1000 or 10,000 digits ie, ie is the distribution of digits random or does it follow pattern? Would segments of PI make good random number generator?

SierraKen · « **Reply #5 on:** August 03, 2019, 02:53:54 pm »

B+, I checked my text file to look for those repeating numbers you mentioned and couldn't find them. Then I looked online about it and it says since it's an irrational number, Pi never repeats. You can read about it here:
https://www.askamathematician.com/2013/12/q-how-do-we-know-that-%CF%80-never-repeats-if-we-find-enough-digits-isnt-it-possible-that-it-will-eventually-start-repeating/

bplus · « **Reply #6 on:** August 03, 2019, 03:42:14 pm »

By repeat here, I just mean two in a row like 2 and then 2 again right after last 2.

SierraKen · « **Reply #7 on:** August 03, 2019, 03:51:35 pm »

Ah cool I see now :). There's also a 9999 later on. :) Thanks.

bplus · « **Reply #8 on:** August 03, 2019, 04:51:54 pm »

BTW PI is not only irrational it is transcendental "—that is, not a root (i.e., solution) of a nonzero polynomial equation with integer coefficients."

SierraKen · « **Reply #9 on:** August 03, 2019, 05:24:30 pm »

I just found the World Record for calculating Pi... don't try it with this program LOL.
A person calculated up to 31 trillion digits! So I wondered to myself how long that would take with this little program, that is if the computer somehow stayed on the whole time without burning up into toast lol. So I made me a little program to calculate... BASIC is so cool with just doing math sometimes lol. I will say the answer after I post my little program. I think I did it right anyway.

Code: QB64: [Select]

DIM her AS DOUBLE
DIM me AS DOUBLE
DIM z AS DOUBLE
DIM minutes AS DOUBLE
DIM hours AS DOUBLE
DIM days AS DOUBLE
DIM years AS DOUBLE
'How many digits of Pi for the record, 31 trillion.
her = 31000000000000
'How many digita of Pi I made in 39 minutes.
me = 100000
 
'How many minutes it would take.
z = her / me
minutes = 39 / z
 
hours = minutes / 60
days = hours / 24
 
'How many years it would take to process 31 trillion digits with my program.
years = days / 365
PRINT years
 

Answer: It would take 15.123 Years! LOL She must have used a supercomputer.

SierraKen · « **Reply #10 on:** August 02, 2020, 12:52:34 am »

Here is an updated version of this Pi calculating program. I found this code exactly a year ago and updated it tonight to show how many numbers it has left to calculate. I don't suggest over 20000 digits though. Although I did use it once to get 100000. I also added a _LIMIT 300 command tonight so it doesn't use up so much computer computation.
I remembered this program from Felippe's graphical Pi program he posted tonight. I don't know how perfect this program is to calculate Pi, it's just code I found online a year ago.

Code: QB64: [Select]

'Almost all of the following code was posted by someone on http://www.codecodex.com/wiki/Calculate_digits_of_pi
'That was taken from American Mathematical Monthly (see below).
'I converted it to also make a .txt file of Pi.txt if the user wishes to.
 
 
'PI.BAS 'Prints PI to number of decimal places desired. 19830623tac.
'        Ref: American Mathematical Monthly vol#45,1938 p657-667.
'        Ref: Best of Micro vol.#1 p85-86.
'
'
'             *       ----                      ----
'        *****         \     16(-1)^(k+1)        \         4(-1)^(k+1)
'       * * *   ---     >   ------------    --    >    ----------------
'         * *   ---    /    (2k-1)5^(2k-1)       /      (2k-1)239^(2k-1)
'         * *         ----                      ----
'        *   *        k=1                       k=1
'
'
 
 
SCREEN _NEWIMAGE(800, 600, 32)
CLS
PRINT "                      Calculate Pi"
PRINT: PRINT: PRINT
PRINT "This program will produce Pi to as many digits as you wish."
PRINT "But I do not recommend going over 20000 because it's pretty slow."
PRINT: PRINT
PRINT "Do you wish to also have it make a .txt file called Pi.txt"
PRINT "that can be opened with a program such as Windows Notepad?"
PRINT "The program will also open Pi.txt after it is finished making it."
PRINT "If you just see it on the screen, you will only see as much as"
PRINT "the screen can show at the end."
INPUT "Type Yes or No here:"; ff$
IF LEFT$(ff$, 1) = "Y" OR LEFT$(ff$, 1) = "y" THEN file = 1
CLS
main:
TEN = 100
INPUT "Enter number of digits wanted"; SIZE:
SIZE = (SIZE + 1) OR 1
PLACES = SIZE - 1
 
IF SIZE > 200 THEN TEN = 10 ELSE SIZE = (SIZE + 1) / 2
 
DIM POWER(SIZE), TERM(SIZE), RESULT(SIZE)
K(1) = 25: K(2) = 239 'Constants
C(1) = 5: C(2) = 239
 
'Main loop.
FOR PASS = 1 TO 2
    Init:
    FOR L = 0 TO SIZE
        POWER(L) = 0: TERM(L) = 0: IF PASS = 1 THEN RESULT = 0
    NEXT L
    POWER(0) = 16 / PASS ^ 2
    MODE = 0
    DIVISOR = C(PASS)
    GOSUB divide
    XPONENT = 1
    SIGN = 3 - 2 * PASS
    '
 
    copy:
    FOR L = 0 TO SIZE: TERM(L) = POWER(L): NEXT L
    '
    _LIMIT 300
    sz = sz + 1
    LOCATE 3, 1: PRINT SIZE - sz
 
    MODE = 1
    DIVISOR = XPONENT
    GOSUB divide
 
    MODE = (SIGN < 0) + ABS(SIGN > 0)
    GOSUB addsub
 
    XPONENT = XPONENT + 2
    SIGN = -SIGN
 
    MODE = 0
    DIVISOR = K(PASS)
    GOSUB divide
 
    IF PASS = 2 THEN GOSUB divide
 
    IF ZERO <> 0 THEN GOTO copy
 
NEXT PASS
'
'Print result.
PRINT
PRINT
PRINT "The value of PI to"; PLACES; " decimal places"
PRINT
PRINT RESULT(0); ".";
IF file = 1 THEN OPEN "pi.txt" FOR OUTPUT AS #1
PRINT #1, "3 . ";
FOR L = 1 TO SIZE
    IF (TEN = 100) * (RESULT(L) < 10) THEN
        PRINT "0";
        PRINT USING "#"; RESULT(L);
        IF file = 1 THEN PRINT #1, "0";
        IF file = 1 THEN PRINT #1, USING "#"; RESULT(L);
        GOTO nxt
    END IF
    IF file = 1 THEN IF L / 30 = INT(L / 30) THEN PRINT #1, " "
    PRINT USING "##"; RESULT(L);
    IF file = 1 THEN PRINT #1, USING "##"; RESULT(L);
    nxt:
NEXT L
IF file = 1 THEN CLOSE #1
IF file = 1 THEN SHELL _DONTWAIT "Pi.txt"
END
 
divide:
'Division subroutine.   mode0 =  Power(x)/Div else mode1 =  Term(x)/Div.
DIGIT = 0: ZERO = 0
FOR L1 = 0 TO SIZE
    DIGIT = DIGIT + TERM(L1) * MODE + POWER(L1) - POWER(L1) * MODE
    QUOTIENT = INT(DIGIT / DIVISOR)
    RESIDUE = DIGIT MOD DIVISOR
    ZERO = ZERO OR (QUOTIENT + RESIDUE)
    IF MODE THEN TERM(L1) = QUOTIENT ELSE POWER(L1) = QUOTIENT
    DIGIT = RESIDUE * TEN
NEXT L1
MODE = 0
RETURN
 
addsub:
'Add/Subtract subroutine.       mode - 1 =  Subtract  else mode1 = Add.
CARRY = 0
FOR L1 = SIZE TO 0 STEP -1
    SUM = RESULT(L1) + TERM(L1) * MODE + CARRY * MODE: CARRY = 0
    IF (MODE = 1) * (SUM < TEN) + (MODE = -1) * (SUM >= 0) THEN GOTO t1
    SUM = SUM + MODE * -TEN: CARRY = 1
 
    t1:
    RESULT(L1) = SUM
NEXT L1
MODE = 0
RETURN
 

News:

Author Topic: Calculate Pi (Read 4575 times)

SierraKen

Calculate Pi

SierraKen

Re: Calculate Pi

bplus

Re: Calculate Pi

SierraKen

Re: Calculate Pi

bplus

Re: Calculate Pi

SierraKen

Re: Calculate Pi

bplus

Re: Calculate Pi

SierraKen

Re: Calculate Pi

bplus

Re: Calculate Pi

SierraKen

Re: Calculate Pi

SierraKen

Re: Calculate Pi