Not working!

[Prithak]

Alright! Back to programming with my exams now gone! Here I coded this stuff:

Code: [Select]

screen _newimage(800,600,32)

dim shared x as integer
dim shared y as integer
dim shared oldx as integer
dim shared oldy as integer

x = 100
y = 200

color , _rgb32(50,200,0)

cls

do
cls

open "blocks.txt" for input as #1

while not eof(1)

input #1, x1,y1,x2,y2,r,g,b

makeobs x1,y1,x2,y2,r,g,b
wend

close #1

    IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y - 5   '_KEYDOWN(20480)
    IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y + 5   '_KEYDOWN(18432)
    IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x + 5   '_KEYDOWN(19200)
    IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x - 5   '_KEYDOWN(19712)

'The sprites will be 20x20 pixels, I believe...
line (_width/2,_height/2)-step(20,20),_rgb32(255,200,100),BF

_printstring(0,0),str$(x) + " " + str$(y)

_limit 100
_Display
loop
 
FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
    IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
        collision% = 0
    ELSE
        collision% = 1
    END IF
END FUNCTION

sub makeobs (x1,y1,w,h,r,g,b)

line(x + x1, y + y1)-step(w,h),_rgb32(r,g,b),BF
Line(x + x1, y + y1)-step(w,h),_Rgb32(255,255,255),B
'200, 200 - 220, 220

if collision%(_width/2,_height/2,20,20,x + x1, y + y1,w,h) then
y = oldy
x = oldx
else
oldy = y
oldx = x
end if


end sub

And here's "blocks.txt"

Code: [Select]

200,100,100,100,100,200,255
200,300,100,100,100,200,255
100,200,100,100,100,200,255
300,200,100,100,100,200,255

Ok. For some reason, the character's only being blocked by the first obstacle? WHY??

-Prithak

[bplus]

EDIT: oops! now I see where you are checking collisions...

Here is code without extra file:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM SHARED x AS INTEGER
4. DIM SHARED y AS INTEGER
5. DIM SHARED oldx AS INTEGER
6. DIM SHARED oldy AS INTEGER
7.  
8. x = 100
9. y = 200
10.  
11. COLOR , _RGB32(50, 200, 0)
12.  
13. CLS
14.  
15. DO
16.     CLS
17.  
18.     'OPEN "blocks.txt" FOR INPUT AS #1
19.  
20.     'WHILE NOT EOF(1)
21.  
22.     '    INPUT #1, x1, y1, x2, y2, r, g, b
23.  
24.     '    makeobs x1, y1, x2, y2, r, g, b
25.     'WEND
26.  
27.     'CLOSE #1
28.     RESTORE blocks
29.     FOR b = 1 TO 4
30.         READ x1, y1, x2, y2, r, g, b
31.         makeobs x1, y1, x2, y2, r, g, b
32.     NEXT
33.     IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y - 5 '_KEYDOWN(20480)
34.     IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y + 5 '_KEYDOWN(18432)
35.     IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x + 5 '_KEYDOWN(19200)
36.     IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x - 5 '_KEYDOWN(19712)
37.  
38.     'The sprites will be 20x20 pixels, I believe...
39.     LINE (_WIDTH / 2, _HEIGHT / 2)-STEP(20, 20), _RGB32(255, 200, 100), BF
40.  
41.     _PRINTSTRING (0, 0), STR$(x) + " " + STR$(y)
42.  
43.     _LIMIT 100
44.     _DISPLAY
45. LOOP
46. END
47. blocks:
48. DATA 200,100,100,100,100,200,255
49. DATA 200,300,100,100,100,200,255
50. DATA 100,200,100,100,100,200,255
51. DATA 300,200,100,100,100,200,255
52.  
53. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
54.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
55.         collision% = 0
56.     ELSE
57.         collision% = 1
58.     END IF
59. END FUNCTION
60.  
61. SUB makeobs (x1, y1, w, h, r, g, b)
62.  
63.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(r, g, b), BF
64.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(255, 255, 255), B
65.     '200, 200 - 220, 220
66.  
67.     IF collision%(_WIDTH / 2, _HEIGHT / 2, 20, 20, x + x1, y + y1, w, h) THEN
68.         y = oldy
69.         x = oldx
70.     ELSE
71.         oldy = y
72.         oldx = x
73.     END IF
74. END SUB
75.  

When I press up key, "sprite" goes down and vice versa..
When I press left arrow, "sprite" goes right and vice versa...

[Dimster]

Just a shot in the dark here Prithak - might it be the Do loop, on the 2nd loop is already reading an EOF(1) in the inner While Loop (so Wend Until EOF(1)) rather than While not eof(1), if that can be done. (I haven't worked with While/Wend). I would be interested in knowing what the solution turned out to be.

[bplus]

Heck! the first question is why aren't all the obstacles being drawn!!!

[bplus]

There was some kind of naming conflict when reading into variables the data when I changed variable names I got the 4 boxes to draw, but the logic of acting as obstacle was off.

In main loop,
1. clear screen
2. draw obstacles
3. update sprite x, y with key press updates
4. check if can move sprite with updates with collision detection
5. if OK use new x, y else use saved old x, y to update sprite position
6. draw sprite

This works:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. DEFINT A-Z
3. SCREEN _NEWIMAGE(800, 600, 32)
4.  
5. DIM SHARED x
6. DIM SHARED y
7. DIM SHARED oldx
8. DIM SHARED oldy
9. DIM i, x1, y1, w1, h1, r1, g1, b1
10. x = 0
11. y = 0
12.  
13. COLOR , _RGB32(50, 200, 0)
14.  
15. CLS
16.  
17. 'Alternate Method check
18. 'read data into arrays and try drawing from arrays
19. 'DIM ox(3), oy(3), ow(3), oh(3), ored(3), og(3), ob(3)
20. 'FOR i = 0 TO 3
21. '    READ x1, y1, w1, h1, r1, g1, b1
22. '    ox(i) = x1: oy(i) = y1: ow(i) = w1: oh(i) = h1: ored(i) = r1: og(i) = g1: ob(i) = b1
23. 'NEXT
24.  
25. DO
26.     CLS
27.  
28.     'OPEN "blocks.txt" FOR INPUT AS #1
29.     'WHILE NOT EOF(1)
30.     '    INPUT #1, x1, y1, x2, y2, r, g, b
31.     '    makeobs x1, y1, x2, y2, r, g, b
32.     'WEND
33.     'CLOSE #1
34.  
35.     RESTORE blocks 'OK works now, there was a problem with variable naming
36.     FOR i = 0 TO 3
37.         READ x1, y1, w1, h1, r1, g1, b1
38.         makeobs x1, y1, w1, h1, r1, g1, b1
39.     NEXT
40.     '_DISPLAY
41.  
42.     'ok this draws all obstacles
43.     'FOR i = 0 TO 3
44.     '    makeobs ox(i), oy(i), ow(i), oh(i), ored(i), og(i), ob(i)
45.     'NEXT
46.  
47.     oldy = y: oldx = x
48.     IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y + 5 '_KEYDOWN(20480)
49.     IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y - 5 '_KEYDOWN(18432)
50.     IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x - 5 '_KEYDOWN(19200)
51.     IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x + 5 '_KEYDOWN(19712)
52.  
53.     RESTORE blocks 'OK works now, there was a problem with variable naming
54.     FOR i = 0 TO 3
55.         READ x1, y1, w1, h1, r1, g1, b1
56.         IF collision%(x, y, 20, 20, x1, y1, w1, h1) THEN
57.             y = oldy
58.             x = oldx
59.             'ELSE
60.             '    oldy = y
61.             '    oldx = x
62.         END IF
63.  
64.     NEXT
65.  
66.  
67.     'The sprites will be 20x20 pixels, I believe...
68.     LINE (x, y)-STEP(20, 20), _RGB32(255, 200, 100), BF
69.  
70.     _PRINTSTRING (0, 0), STR$(x) + " " + STR$(y)
71.  
72.     _LIMIT 100
73.     _DISPLAY
74. LOOP
75. END
76. blocks:
77. DATA 100,100,100,100,255,0,0
78. DATA 200,200,100,100,0,0,255
79. DATA 300,300,100,100,255,255,0
80. DATA 400,400,100,100,0,128,128
81.  
82. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
83.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
84.         collision% = 0
85.     ELSE
86.         collision% = 1
87.     END IF
88. END FUNCTION
89.  
90. SUB makeobs (x1, y1, w, h, r, g, b)
91.     LINE (x1, y1)-STEP(w, h), _RGB32(r, g, b), BF
92.     LINE (x1, y1)-STEP(w, h), _RGB32(255, 255, 255), B
93.  
94. END SUB
95.  
96.  

EDIT: commented out code no longer using, ie the alternate arrays method to hold block data.

[TempodiBasic]

Solved, now it works

before showing it please read:

2 remarks:

1. no need two consecutive CLS

Code: QB64: [Select]

1. 'CLS   <-- no needed
2.  
3. DO
4.     CLS

2. why do you use a single letter name variable? that is the trap that you have used against yourself!

Code: QB64: [Select]

1.     FOR b = 1 TO 4
2.         READ x1, y1, x2, y2, r, g, b
3.         makeobs x1, y1, x2, y2, r, g, b

O_o  you use b as counter of loop FOR NEXT and as value of rgb parameter read from file (original version) or from DATA block (Bplus version) in teh FOR NEXT loop.
So what's happening? Nothing else that the for next loop runs once a time and shows one block.

and this is the result

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM SHARED x AS INTEGER
4. DIM SHARED y AS INTEGER
5. DIM SHARED oldx AS INTEGER
6. DIM SHARED oldy AS INTEGER
7.  
8. x = 100
9. y = 200
10.  
11. COLOR , _RGB32(50, 200, 0)
12.  
13. 'CLS   <-- no needed
14.  
15. DO
16.     CLS
17.  
18.     'OPEN "blocks.txt" FOR INPUT AS #1
19.  
20.     'WHILE NOT EOF(1)
21.  
22.     '    INPUT #1, x1, y1, x2, y2, r, g, b
23.  
24.     '    makeobs x1, y1, x2, y2, r, g, b
25.     'WEND
26.  
27.     'CLOSE #1
28.     RESTORE blocks
29.     FOR b1 = 1 TO 4 ' here counter must have a different name of variables used into it
30.         READ x1, y1, x2, y2, r, g, b
31.         makeobs x1, y1, x2, y2, r, g, b
32.  
33.     NEXT
34.     IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y - 5 '_KEYDOWN(20480)
35.     IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y + 5 '_KEYDOWN(18432)
36.     IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x + 5 '_KEYDOWN(19200)
37.     IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x - 5 '_KEYDOWN(19712)
38.  
39.     'The sprites will be 20x20 pixels, I believe...
40.     LINE (_WIDTH / 2, _HEIGHT / 2)-STEP(20, 20), _RGB32(255, 200, 100), BF
41.  
42.     _PRINTSTRING (0, 0), STR$(x) + " " + STR$(y)
43.  
44.     _LIMIT 100
45.     _DISPLAY
46. LOOP
47. END
48. blocks:
49. DATA 200,100,100,100,100,200,255
50. DATA 200,300,100,100,100,200,255
51. DATA 100,200,100,100,100,200,255
52. DATA 300,200,100,100,100,200,255
53.  
54. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
55.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
56.         collision% = 0
57.     ELSE
58.         collision% = 1
59.     END IF
60. END FUNCTION
61.  
62. SUB makeobs (x1, y1, w, h, r, g, b)
63.  
64.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(r, g, b), BF
65.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(255, 255, 255), B
66.     '200, 200 - 220, 220
67.  
68.     IF collision%(_WIDTH / 2, _HEIGHT / 2, 20, 20, x + x1, y + y1, w, h) THEN
69.         y = oldy
70.         x = oldx
71.     ELSE
72.         oldy = y
73.         oldx = x
74.     END IF
75. END SUB
76.  
77.  

Well,
now you must fix some bugs:
1. collision detects only the collision of the first square (that is drawn first, the top of the crux)
2. when collision happens the top square dances whiel the rest of the crux stands there.

this second issue is fixed if in the sub Makeobs you first test the collision and then you draw the square/sprite
like here

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM SHARED x AS INTEGER
4. DIM SHARED y AS INTEGER
5. DIM SHARED oldx AS INTEGER
6. DIM SHARED oldy AS INTEGER
7.  
8. x = 100
9. y = 200
10.  
11. COLOR , _RGB32(50, 200, 0)
12.  
13. 'CLS   <-- no needed
14.  
15. DO
16.     CLS
17.  
18.     'OPEN "blocks.txt" FOR INPUT AS #1
19.  
20.     'WHILE NOT EOF(1)
21.  
22.     '    INPUT #1, x1, y1, x2, y2, r, g, b
23.  
24.     '    makeobs x1, y1, x2, y2, r, g, b
25.     'WEND
26.  
27.     'CLOSE #1
28.     RESTORE blocks
29.     FOR b1 = 1 TO 4 ' here counter must have a different name of variables used into it
30.         READ x1, y1, x2, y2, r, g, b
31.         makeobs x1, y1, x2, y2, r, g, b
32.  
33.     NEXT
34.     IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y - 5 '_KEYDOWN(20480)
35.     IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y + 5 '_KEYDOWN(18432)
36.     IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x + 5 '_KEYDOWN(19200)
37.     IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x - 5 '_KEYDOWN(19712)
38.  
39.     'The sprites will be 20x20 pixels, I believe...
40.     LINE (_WIDTH / 2, _HEIGHT / 2)-STEP(20, 20), _RGB32(255, 200, 100), BF
41.  
42.     _PRINTSTRING (0, 0), STR$(x) + " " + STR$(y)
43.  
44.     _LIMIT 100
45.     _DISPLAY
46. LOOP
47. END
48. blocks:
49. DATA 200,100,100,100,100,200,255
50. DATA 200,300,100,100,100,200,255
51. DATA 100,200,100,100,100,200,255
52. DATA 300,200,100,100,100,200,255
53.  
54. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
55.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
56.         collision% = 0
57.     ELSE
58.         collision% = 1
59.     END IF
60. END FUNCTION
61.  
62. SUB makeobs (x1, y1, w, h, r, g, b)
63.  
64.  
65.     IF collision%(_WIDTH / 2, _HEIGHT / 2, 20, 20, x + x1, y + y1, w, h) THEN
66.         y = oldy
67.         x = oldx
68.     ELSE
69.         oldy = y
70.         oldx = x
71.     END IF
72.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(r, g, b), BF
73.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(255, 255, 255), B
74.     '200, 200 - 220, 220
75.  
76. END SUB
77.  
78.  

the first issue IMHO is fixed if you use an array of dimensional cohordinates for each square/object/sprite of the compilation
for example

Code: QB64: [Select]

1. TYPE Cohor
2.     x AS INTEGER
3.     y AS INTEGER
4.     OldX AS INTEGER
5.     OldY AS INTEGER
6. END TYPE
7.  
8. DIM SHARED co_Sprites(1 TO 4) AS Cohor

and it would be better to divide the two action test_collision and Draw_Sprite with no nesting.

Thanks to read
and Good Coding

[bplus]

Ah yes! I doubled up on using the variable b in the first code mod avoiding the file load.

Thanks TempodiBasic, mystery solved, explains why my first mod wasn't drawing correctly.

Still my 2nd code mod works just fine.

Prithak had arguments to collision function pretty messed up.
This sprite ain't going nowhere:

Code: QB64: [Select]

1.    'The sprites will be 20x20 pixels, I believe...
2.     LINE (_WIDTH / 2, _HEIGHT / 2)-STEP(20, 20), _RGB32(255, 200, 100), BF
3.  

Wait are we moving the sprite around the blocks or the blocks around the sprite? It didn't occur to me it might be the 2nd thing. ;( That would explain why the arrows worked in reverse!

[bplus]

TempodiBasic:

and it would be better to divide the two action test_collision and Draw_Sprite with no nesting.

Yep! You have to check that the sprite is clear of all the obstacles before drawing any, because you can't draw some at new x, y and some at old x, y.

OK so we are moving the blocks around the sprite :)

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM SHARED x AS INTEGER
4. DIM SHARED y AS INTEGER
5. DIM SHARED oldx AS INTEGER
6. DIM SHARED oldy AS INTEGER
7.  
8. 'this makes blocks visible in top left corner
9. x = -100
10. y = -100
11. COLOR , _RGB32(50, 200, 0)
12. DO
13.     CLS
14.  
15.     'The sprites will be 20x20 pixels, I believe...
16.     LINE (_WIDTH / 2, _HEIGHT / 2)-STEP(20, 20), _RGB32(255, 200, 100), BF
17.  
18.     'save oldx, oldy NOW before changing x and y
19.     oldx = x: oldy = y
20.  
21.     'now change x, y and test with blocks
22.     IF _KEYDOWN(CVI(CHR$(0) + "P")) THEN y = y - 5 '_KEYDOWN(20480)
23.     IF _KEYDOWN(CVI(CHR$(0) + "H")) THEN y = y + 5 '_KEYDOWN(18432)
24.     IF _KEYDOWN(CVI(CHR$(0) + "K")) THEN x = x + 5 '_KEYDOWN(19200)
25.     IF _KEYDOWN(CVI(CHR$(0) + "M")) THEN x = x - 5 '_KEYDOWN(19712)
26.  
27.     'test new x, y with all the blocks before drawing anything, we must establish x, y is clear
28.     RESTORE blocks
29.     FOR b1 = 1 TO 4 ' here counter must have a different name of variables used into it
30.         READ x1, y1, x2, y2, r, g, b
31.         IF collision(x1 + x, y1 + y, x2, y2, _WIDTH / 2, _HEIGHT / 2, 20, 20) THEN
32.             x = oldx: y = oldy
33.             EXIT FOR
34.         END IF
35.     NEXT
36.     'OK now draw blocks with x, y
37.     RESTORE blocks
38.     FOR b1 = 1 TO 4 ' here counter must have a different name of variables used into it
39.         READ x1, y1, x2, y2, r, g, b
40.         makeobs x1, y1, x2, y2, r, g, b
41.     NEXT
42.     _PRINTSTRING (0, 0), STR$(x) + " " + STR$(y)
43.     _DISPLAY
44.     _LIMIT 100
45. LOOP
46. END
47. blocks:
48. DATA 200,100,100,100,100,200,255
49. DATA 200,300,100,100,100,200,255
50. DATA 100,200,100,100,100,200,255
51. DATA 300,200,100,100,100,200,255
52.  
53. FUNCTION collision% (b1x, b1y, b1w, b1h, b2x, b2y, b2w, b2h)
54.     IF (b1y + b1h < b2y) OR (b1y > b2y + b2h) OR (b1x > b2x + b2w) OR (b1x + b1w < b2x) THEN
55.         collision% = 0
56.     ELSE
57.         collision% = 1
58.     END IF
59. END FUNCTION
60.  
61. SUB makeobs (x1, y1, w, h, r, g, b)
62.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(r, g, b), BF
63.     LINE (x + x1, y + y1)-STEP(w, h), _RGB32(255, 255, 255), B
64. END SUB
65.  

OK so now it's works both ways!

[Prithak]

Thank you everyone for helping me out! Thanks to you now I can really continue making this game xD! Well... I guess I'm gonna go coding whilst solving a Rubik's cube lol!

-Prithak