Pattern Challenge By Ashish : #1

[Ashish]

Hi everyone!
I created a pattern and let me see who is the first to reproduce it! :D

Please see the attachment for the pattern.

[Pete]

That looks like an iris.

Iris everyone good luck trying to reproduce it!

Pete :D

[bplus]

Hi Ashish,

I accept your challenge:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "I See Ashish Challenge #1 Takes Us On A Tangent" 'bplus 2019-07-09
3. RANDOMIZE TIMER
4. CONST xmax = 740, ymax = 740, xc = xmax / 2, yc = ymax / 2, br = 370
5. TYPE tData
6.     n AS INTEGER 'n points
7.     r AS SINGLE 'inner radius
8.     osStart AS SINGLE
9.     osStop AS SINGLE
10.     osStep AS SINGLE
11.     c AS _UNSIGNED LONG
12. END TYPE
13.  
14. DIM t(10) AS tData
15. t(0).n = 150: t(0).r = .08 * br: t(0).c = &H5522AAEE
16. t(1).n = 220: t(1).r = .095 * br: t(1).c = &H3344DD55
17. t(2).n = 350: t(2).r = .14 * br: t(2).c = &H2222FFAA
18. t(3).n = 16: t(3).r = .35 * br: t(3).c = &H19AAFFFF: t(3).osStart = _PI / 72: t(3).osStop = _PI(3 / 72): t(3).osStep = _PI / 360
19. t(4).n = 199: t(4).r = .53 * br: t(4).c = &H22008800
20. t(5).n = 200: t(5).r = .67 * br: t(5).c = &H220000FF
21. t(6).n = 300: t(6).r = .81 * br: t(6).c = &H220000FF
22. t(10).n = 27: t(10).r = .88 * br: t(10).c = &H28FFFF77: t(10).osStart = .15: t(10).osStop = .16: t(10).osStep = _PI(1 / 1440)
23. t(7).n = 350: t(7).r = .9 * br: t(7).c = &H2244FF44
24. t(8).n = 350: t(8).r = .93 * br: t(8).c = &H226666FF
25. t(9).n = 350: t(9).r = .95 * br: t(9).c = &H228888FF
26.  
27. SCREEN _NEWIMAGE(xmax, ymax, 32)
28. _SCREENMOVE 100, 0
29. DIM tSet AS INTEGER, ao
30. FOR tSet = 0 TO 10
31.     IF t(tSet).osStep THEN
32.         FOR ao = t(tSet).osStart TO t(tSet).osStop STEP t(tSet).osStep
33.             tangentsC1C2 xc, yc, t(tSet).r, br, t(tSet).n, ao, t(tSet).c
34.         NEXT
35.     ELSE
36.         tangentsC1C2 xc, yc, t(tSet).r, br, t(tSet).n, 0, t(tSet).c
37.     END IF
38. NEXT
39. SLEEP
40.  
41. SUB tangentsC1C2 (x, y, rInner, rOuter, nAround, raOffset, c AS _UNSIGNED LONG)
42.     ' x, y are same as for circle,
43.     ' rOuter is the outer limit radius
44.     ' nAround to evenly distribute lines around the circle
45.     ' radAngleOffset to start lines at different places on circle
46.     DIM alpha, beta, cosLength, tAngle, x1, y1, x2, y2, x3, y3, i AS INTEGER
47.  
48.     'calc the length from rInner to Router at Tangent
49.     alpha = _ACOS(rInner / rOuter)
50.     beta = _PI(1 / 2) - alpha
51.     cosLength = rOuter * COS(beta)
52.     tAngle = _PI(2) / nAround
53.     FOR i = 1 TO nAround
54.         x1 = x + rInner * COS(i * tAngle + raOffset)
55.         y1 = y + rInner * SIN(i * tAngle + raOffset)
56.         x2 = x1 + cosLength * COS(i * tAngle + raOffset + _PI / 2)
57.         y2 = y1 + cosLength * SIN(i * tAngle + raOffset + _PI / 2)
58.         x3 = x1 + cosLength * COS(i * tAngle + raOffset + _PI(3 / 2))
59.         y3 = y1 + cosLength * SIN(i * tAngle + raOffset + _PI(3 / 2))
60.         LINE (x2, y2)-(x3, y3), c
61.     NEXT
62. END SUB
63.  

[Pete]

Nice!

I put a _DELAY .01 in the FOR/NEXT loop. It makes it look like a youtube vid of a Spirotot. Unfortunately, that original toddler version is no where to be found.

Put the ring in the square
And the pen in the slot
Go round, round, round
With Spirotot

Make a round round ball
And that's not all
You can draw a lot
With Spirotot

Well, at age 6, I wasn't impressed. I think I changed the lyrics to... You can't draw squat with Spirotot, but I digress.

Anyway, a better version, called Spirograph, is still on the market:

I beginning to think learning C is taking a toll...

Pete

I had a geometry once, but I chopped it down.

[bplus]

:) The _delay is nice aspect thanks Pete.

[Ashish]

Perfect Bplus!

[bplus]

Thanks Ashish, glad you approve.