Blackjack

[bplus]

Here is that first version in SCREEN 0 with same functions as Big Brother Graphics versions ready to replace bplus participation with AI:

Code: QB64: [Select]

1. OPTION _EXPLICIT ' No suits shown for cards A is Ace, J, Q, K are Jack, Queen, King, X is for 10
2. DEFINT A-Z '       Player's Blackjack pays double the bet set at the beginning of the game
3. RANDOMIZE TIMER
4. '2020-07-05 fix hit (it wasn't brolen), delete line card$ = inkey$ before loop
5. ' force dealer to hit on 16 stay 17
6. ' ties are push
7. ' bring in double down option
8. ' fix dealer has Blackjack should tell also fix exposing 2nd card
9. ' work this towards converting to multiple AI players, so players stats are all located in PlayerType
10.  
11.  
12. _TITLE "Blackjack Best B+ mod" ' started 2019-06-06, revisit and match functions with B+J Balckjack with audio and graphics.
13. CONST rank$ = "A23456789XJQK"
14. CONST Player = 1
15. CONST Dealer = 2
16.  
17. TYPE PlayerType
18.     ID AS STRING
19.     Hand AS STRING
20.     Ace AS INTEGER
21.     Total AS INTEGER
22.     chips AS _INTEGER64
23.     setBet AS _INTEGER64
24.     bet AS _INTEGER64
25. END TYPE
26.  
27. DIM SHARED deck$(1 TO 52), Players(1 TO 2) AS PlayerType, deckIndex
28.  
29. DIM i, r, card$
30. Players(Player).ID = "Player"
31. Players(Dealer).ID = "Dealer"
32. FOR i = 1 TO 52
33.     deck$(i) = MID$(rank$ + rank$ + rank$ + rank$, i, 1)
34. NEXT
35. Players(Dealer).chips = -100
36. Players(Player).chips = 100
37. cp 8, "For this Blackjack Game, you start with 100 chips"
38. cp 9, "and can bet any amount of them for each game."
39. cp 10, "If you'd like to set your bet for each game now"
40. cp 11, "enter that amount otherwise enter 0 "
41. cp 12, "Dealer must hit on 16 or less."
42. cp 13, "Blackjack pays 1.5 X the bet."
43. cp 14, "Double down option available when you get 2 cards."
44. cp 15, "It Doubles the bet and you get one more card."
45.  
46. LOCATE 17, 38: INPUT ""; Players(Player).setBet
47. DO
48.     IF Players(Player).setBet = 0 THEN
49.         CLS
50.         cp 10, "You have" + STR$(Players(Player).chips) + "."
51.         LOCATE 11, 25: INPUT "(0 quits) Enter your bet > ", Players(Player).bet
52.         IF Players(Player).bet = 0 THEN EXIT DO
53.         IF Players(Player).bet >= Players(Player).chips THEN Players(Player).bet = Players(Player).chips
54.     ELSE
55.         IF Players(Player).chips < Players(Player).setBet THEN Players(Player).bet = Players(Player).chips ELSE Players(Player).bet = Players(Player).setBet
56.     END IF
57.     clearPlayers 'clears screen too
58.     cp 4, "BLACKJACK    chips:" + STR$(Players(Player).chips) + "   betting:" + STR$(Players(Player).bet) + " chips."
59.     FOR i = 52 TO 2 STEP -1 'shuffle
60.         r = INT(RND * i) + 1
61.         SWAP deck$(r), deck$(i)
62.     NEXT
63.     deckIndex = 0
64.     FOR i = 1 TO 2 'each Player is dealt 2 cards
65.         PlayerAddCard Player
66.         IF i = 1 THEN cp 10, playerShow$(Player)
67.         _DELAY 2
68.         PlayerAddCard Dealer
69.         IF i = 1 THEN cp 7, playerShow$(Dealer)
70.         _DELAY 2
71.     NEXT
72.     cp 10, playerShow$(Player)
73.     _DELAY 2
74.     cp 7, Players(Dealer).ID + ": " + MID$(Players(Dealer).Hand, 1, 1) + " ?  Total = ??"
75.     _DELAY 2
76.     '   BJ  debug players having BJ
77.     'Players(Dealer).Total = 21
78.     'Players(Player).Total = 21
79.     IF Players(Player).Total = 21 AND Players(Dealer).Total = 21 THEN
80.         cp 7, playerShow$(Dealer) + " Blackjack!"
81.         cp 10, playerShow$(Player) + " Blackjack!"
82.         cp 13, "Push"
83.         GOTO BJskip
84.     ELSEIF Players(Player).Total = 21 THEN
85.         cp 10, playerShow$(Player) + " Blackjack!"
86.         Players(Player).chips = Players(Player).chips + 1.5 * Players(Player).bet
87.         Players(Dealer).chips = Players(Dealer).chips - 1.5 * Players(Player).bet
88.         cp 13, "You won" + STR$(2 * Players(Player).bet)
89.         GOTO BJskip
90.     ELSEIF Players(Dealer).Total = 21 THEN
91.         cp 7, playerShow$(Dealer) + " Blackjack!"
92.         Players(Player).chips = Players(Player).chips - Players(Player).bet
93.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
94.         cp 13, "You lost" + STR$(Players(Player).bet)
95.         _DELAY 2
96.         GOTO BJskip
97.     END IF
98.     WHILE Players(Player).Total < 21
99.         IF LEN(Players(Player).Hand) = 2 THEN
100.             cp 15, "Press h for Hit,   d for Double Down,   or any other to stay..."
101.         ELSE
102.             cp 15, "Press h for Hit, any other to stay..."
103.         END IF
104.         card$ = ""
105.         WHILE LEN(card$) = 0: card$ = INKEY$: _LIMIT 60: WEND
106.         cp 15, SPACE$(70) 'erase line
107.         IF card$ = "h" THEN
108.             PlayerAddCard Player
109.             cp 11, SPACE$(50)
110.             cp 10, playerShow$(Player)
111.             _DELAY 2
112.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'busted! skip dealer expose 2nd and play
113.         ELSEIF card$ = "d" AND LEN(Players(Player).Hand) = 2 THEN
114.             Players(Player).bet = 2 * Players(Player).bet
115.             PlayerAddCard Player
116.             cp 11, SPACE$(50)
117.             cp 10, playerShow$(Player)
118.             _DELAY 2
119.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'bustest! skip dealer expose 2nd and play
120.             EXIT WHILE
121.         ELSE 'stayed
122.             cp 11, SPACE$(50)
123.             EXIT WHILE
124.         END IF
125.     WEND
126.     cp 7, playerShow$(Dealer)
127.     _DELAY 1
128.     WHILE Players(Player).Total < 22 AND Players(Dealer).Total < 17
129.         cp 8, "Dealer takes a card."
130.         _DELAY 2
131.         PlayerAddCard Dealer
132.         cp 7, playerShow$(Dealer)
133.         cp 8, SPACE$(50)
134.         _DELAY 2
135.     WEND
136.     finalReckoning:
137.     IF Players(Player).Total > 21 OR (Players(Player).Total < Players(Dealer).Total AND Players(Dealer).Total < 22) THEN
138.         cp 13, "You lose" + STR$(Players(Player).bet)
139.         Players(Player).chips = Players(Player).chips - Players(Player).bet
140.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
141.     ELSEIF Players(Player).Total = Players(Dealer).Total THEN
142.         cp 13, "Push"
143.     ELSE
144.         cp 13, "You win!" + STR$(Players(Player).bet)
145.         Players(Player).chips = Players(Player).chips + Players(Player).bet
146.         Players(Dealer).chips = Players(Dealer).chips - Players(Player).bet
147.     END IF
148.  
149.     BJskip:
150.     IF Players(Player).chips = 0 THEN cp 15, "Out of chips!"
151.     _DELAY 5
152. LOOP UNTIL Players(Player).chips = 0
153. cp 17, "Goodbye"
154.  
155. SUB clearPlayers
156.     DIM i
157.     CLS
158.     FOR i = 1 TO 2
159.         Players(i).Hand = ""
160.         Players(i).Ace = 0
161.         Players(i).Total = 0
162.     NEXT
163. END SUB
164.  
165. SUB PlayerAddCard (receiver) 'updates player's hand and total
166.     DIM i AS INTEGER, cv AS INTEGER
167.     deckIndex = deckIndex + 1
168.     Players(receiver).Hand = Players(receiver).Hand + deck$(deckIndex)
169.     IF deck$(deckIndex) = "A" THEN Players(receiver).Ace = -1
170.     Players(receiver).Total = 0
171.     FOR i = 1 TO LEN(Players(receiver).Hand)
172.         IF INSTR(rank, MID$(Players(receiver).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank, MID$(Players(receiver).Hand, i, 1))
173.         Players(receiver).Total = Players(receiver).Total + cv
174.     NEXT
175.     IF Players(receiver).Total < 12 AND Players(receiver).Ace THEN Players(receiver).Total = Players(receiver).Total + 10
176. END SUB
177.  
178. FUNCTION playerShow$ (shower) 'creates string with player name: hand Total = xx and "Busted!" if so.
179.     DIM i AS INTEGER, S$
180.     S$ = Players(shower).ID + ": "
181.     FOR i = 1 TO LEN(Players(shower).Hand)
182.         S$ = S$ + MID$(Players(shower).Hand, i, 1) + " "
183.     NEXT
184.     S$ = S$ + "Total =" + STR$(Players(shower).Total)
185.     IF Players(shower).Total > 21 THEN S$ = S$ + " Busted!"
186.     playerShow$ = S$
187. END FUNCTION
188.  
189. SUB cp (row, s AS STRING) 'print centered on row the string
190.     LOCATE row, 1: PRINT SPACE$(80); 'clear row of text
191.     LOCATE row, (80 - LEN(s)) / 2: PRINT s;
192. END SUB
193.  

[johnno56]

Aww man... Two hands and I'm cleaned out... lol

[bplus]

I am now phoning it in with AI:

Code: QB64: [Select]

1. OPTION _EXPLICIT ' No suits shown for cards A is Ace, J, Q, K are Jack, Queen, King, X is for 10
2. DEFINT A-Z '       Player's Blackjack pays double the bet set at the beginning of the game
3. RANDOMIZE TIMER
4. '2020-07-05 fix hit (it wasn't brolen), delete line card$ = inkey$ before loop
5. ' force dealer to hit on 16 stay 17
6. ' ties are push
7. ' bring in double down option
8. ' fix dealer has Blackjack should tell also fix exposing 2nd card
9. ' work this towards converting to multiple AI players, so players stats are all located in PlayerType
10. ' 2020-07-06 Installed AI and mods for it
11.  
12. _TITLE "Blackjack Best with AI" ' started 2019-06-06, revisit and match functions with B+J Balckjack with audio and graphics.
13. CONST rank$ = "A23456789XJQK"
14. CONST Player = 1
15. CONST Dealer = 2
16.  
17. TYPE PlayerType
18.     ID AS STRING
19.     Hand AS STRING
20.     Ace AS INTEGER
21.     Total AS INTEGER
22.     chips AS _INTEGER64
23.     setBet AS _INTEGER64
24.     bet AS _INTEGER64
25. END TYPE
26.  
27. DIM SHARED deck$(1 TO 52), Players(1 TO 2) AS PlayerType, deckIndex, round
28.  
29. DIM i, r, card$
30. Players(Player).ID = "Player"
31. Players(Dealer).ID = "Dealer"
32. FOR i = 1 TO 52
33.     deck$(i) = MID$(rank$ + rank$ + rank$ + rank$, i, 1)
34. NEXT
35. Players(Dealer).chips = -100
36. Players(Player).chips = 100
37. cp 8, "For this Blackjack Game, you start with 100 chips"
38. cp 9, "and can bet any amount of them for each game."
39. cp 10, "If you'd like to set your bet for each game now"
40. cp 11, "enter that amount otherwise enter 0, AI is setting at 2."
41. cp 12, "Dealer must hit on 16 or less."
42. cp 13, "Blackjack pays 1.5 X the bet."
43. cp 14, "Double down option available when you get 2 cards."
44. cp 15, "It Doubles the bet and you get one more card."
45. cp 17, "press any to continue..."
46. SLEEP
47. Players(Player).setBet = 2
48. 'LOCATE 17, 38: INPUT ""; Players(Player).setBet
49. DO
50.     IF Players(Player).setBet = 0 THEN
51.         CLS
52.         cp 10, "You have" + STR$(Players(Player).chips) + "."
53.         LOCATE 11, 25: INPUT "(0 quits) Enter your bet > ", Players(Player).bet
54.         IF Players(Player).bet = 0 THEN EXIT DO
55.         IF Players(Player).bet >= Players(Player).chips THEN Players(Player).bet = Players(Player).chips
56.     ELSE
57.         IF Players(Player).chips < Players(Player).setBet THEN Players(Player).bet = Players(Player).chips ELSE Players(Player).bet = Players(Player).setBet
58.     END IF
59.     clearPlayers 'clears screen too
60.     cp 4, "BLACKJACK    chips:" + STR$(Players(Player).chips) + "   betting:" + STR$(Players(Player).bet) + " chips."
61.     FOR i = 52 TO 2 STEP -1 'shuffle
62.         r = INT(RND * i) + 1
63.         SWAP deck$(r), deck$(i)
64.     NEXT
65.     deckIndex = 0
66.     FOR i = 1 TO 2 'each Player is dealt 2 cards
67.         PlayerAddCard Player
68.         IF i = 1 THEN cp 10, playerShow$(Player)
69.         _DELAY 1
70.         PlayerAddCard Dealer
71.         IF i = 1 THEN cp 7, playerShow$(Dealer)
72.         _DELAY 1
73.     NEXT
74.     cp 10, playerShow$(Player)
75.     _DELAY 1
76.     cp 7, Players(Dealer).ID + ": " + MID$(Players(Dealer).Hand, 1, 1) + " ?  Total = ??"
77.     _DELAY 1
78.     '   BJ  debug players having BJ
79.     'Players(Dealer).Total = 21
80.     'Players(Player).Total = 21
81.     IF Players(Player).Total = 21 AND Players(Dealer).Total = 21 THEN
82.         cp 7, playerShow$(Dealer) + " Blackjack!"
83.         cp 10, playerShow$(Player) + " Blackjack!"
84.         cp 13, "Push"
85.         GOTO BJskip
86.     ELSEIF Players(Player).Total = 21 THEN
87.         cp 10, playerShow$(Player) + " Blackjack!"
88.         Players(Player).chips = Players(Player).chips + 1.5 * Players(Player).bet
89.         Players(Dealer).chips = Players(Dealer).chips - 1.5 * Players(Player).bet
90.         cp 13, "You won" + STR$(2 * Players(Player).bet)
91.         GOTO BJskip
92.     ELSEIF Players(Dealer).Total = 21 THEN
93.         cp 7, playerShow$(Dealer) + " Blackjack!"
94.         Players(Player).chips = Players(Player).chips - Players(Player).bet
95.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
96.         cp 13, "You lost" + STR$(Players(Player).bet)
97.         _DELAY 1
98.         GOTO BJskip
99.     END IF
100.     WHILE Players(Player).Total < 21
101.         IF LEN(Players(Player).Hand) = 2 THEN
102.             cp 15, "Press h for Hit,   d for Double Down,   or any other to stay..."
103.         ELSE
104.             cp 15, "Press h for Hit, any other to stay..."
105.         END IF
106.         'card$ = ""
107.         'WHILE LEN(card$) = 0: card$ = INKEY$: _LIMIT 60: WEND   ' bplus calling it in now!
108.         card$ = bplusAI$
109.         IF card$ = "h" THEN cp 17, "Hit"
110.         IF card$ = "d" THEN cp 17, "Double Down"
111.         IF card$ <> "h" AND card$ <> "d" THEN cp 17, "Stay"
112.         cp 15, SPACE$(70) 'erase line
113.         _DELAY 2
114.         cp 17, SPACE$(50)
115.         IF card$ = "h" THEN
116.             PlayerAddCard Player
117.             'cp 11, SPACE$(50)
118.             cp 10, playerShow$(Player)
119.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'busted! skip dealer expose 2nd and play
120.         ELSEIF card$ = "d" AND LEN(Players(Player).Hand) = 2 THEN
121.             Players(Player).bet = 2 * Players(Player).bet
122.             PlayerAddCard Player
123.             'cp 11, SPACE$(50)
124.             cp 10, playerShow$(Player)
125.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'bustest! skip dealer expose 2nd and play
126.             EXIT WHILE
127.         ELSE 'stayed
128.             ' cp 11, SPACE$(50)
129.             EXIT WHILE
130.         END IF
131.     WEND
132.     cp 7, playerShow$(Dealer)
133.     _DELAY 1
134.     WHILE Players(Player).Total < 22 AND Players(Dealer).Total < 17
135.         cp 8, "Dealer takes a card."
136.         _DELAY 1
137.         PlayerAddCard Dealer
138.         cp 7, playerShow$(Dealer)
139.         cp 8, SPACE$(50)
140.         _DELAY 1
141.     WEND
142.     finalReckoning:
143.     IF Players(Player).Total > 21 OR (Players(Player).Total < Players(Dealer).Total AND Players(Dealer).Total < 22) THEN
144.         cp 13, "You lose" + STR$(Players(Player).bet)
145.         Players(Player).chips = Players(Player).chips - Players(Player).bet
146.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
147.     ELSEIF Players(Player).Total = Players(Dealer).Total THEN
148.         cp 13, "Push"
149.     ELSE
150.         cp 13, "You win!" + STR$(Players(Player).bet)
151.         Players(Player).chips = Players(Player).chips + Players(Player).bet
152.         Players(Dealer).chips = Players(Dealer).chips - Players(Player).bet
153.     END IF
154.  
155.     BJskip:
156.     IF Players(Player).chips = 0 THEN cp 15, "Out of chips!"
157.     _DELAY 2
158. LOOP UNTIL Players(Player).chips = 0
159. cp 17, "Goodbye"
160.  
161. SUB clearPlayers
162.     DIM i
163.     CLS
164.     round = round + 1
165.     cp 2, "Round:" + STR$(round)
166.     FOR i = 1 TO 2
167.         Players(i).Hand = ""
168.         Players(i).Ace = 0
169.         Players(i).Total = 0
170.     NEXT
171. END SUB
172.  
173. FUNCTION bplusAI$
174.     SELECT CASE Players(Player).Total
175.         CASE IS < 10: bplusAI$ = "h" 'no caps!
176.         CASE 10, 11
177.             IF LEN(Players(Player).Hand) = 2 THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
178.         CASE IS < 15
179.             IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
180.         CASE ELSE: bplusAI$ = "Show me the money!"
181.     END SELECT
182. END FUNCTION
183.  
184. SUB PlayerAddCard (receiver) 'updates player's hand and total
185.     DIM i AS INTEGER, cv AS INTEGER
186.     deckIndex = deckIndex + 1
187.     Players(receiver).Hand = Players(receiver).Hand + deck$(deckIndex)
188.     IF deck$(deckIndex) = "A" THEN Players(receiver).Ace = -1
189.     Players(receiver).Total = 0
190.     FOR i = 1 TO LEN(Players(receiver).Hand)
191.         IF INSTR(rank, MID$(Players(receiver).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank, MID$(Players(receiver).Hand, i, 1))
192.         Players(receiver).Total = Players(receiver).Total + cv
193.     NEXT
194.     IF Players(receiver).Total < 12 AND Players(receiver).Ace THEN Players(receiver).Total = Players(receiver).Total + 10
195. END SUB
196.  
197. FUNCTION playerShow$ (shower) 'creates string with player name: hand Total = xx and "Busted!" if so.
198.     DIM i AS INTEGER, S$
199.     S$ = Players(shower).ID + ": "
200.     FOR i = 1 TO LEN(Players(shower).Hand)
201.         S$ = S$ + MID$(Players(shower).Hand, i, 1) + " "
202.     NEXT
203.     S$ = S$ + "Total =" + STR$(Players(shower).Total)
204.     IF Players(shower).Total > 21 THEN S$ = S$ + " Busted!"
205.     playerShow$ = S$
206. END FUNCTION
207.  
208. SUB cp (row, s AS STRING) 'print centered on row the string
209.     LOCATE row, 1: PRINT SPACE$(80); 'clear row of text
210.     LOCATE row, (80 - LEN(s)) / 2: PRINT s;
211. END SUB
212.  

Started at 100 chips and always 2 chip bets. Currently: dang! I lost the screen at 60 Rounds I was ahead!

Nuts 2nd Session and I  am down a bits...

[bplus]

Session 3 is hanging in there.

Made a compact version for when watching YouTube.

[bplus]

There is something spooky between running the code in SCREEN 0 (just default) and using tiny graphics screen.

True I have only tested a long run once but the SCREEN 0 code holds it's own for a long time, watching it play I can't tell if if will loose in long run.

Running the code in a small graphics screen and it is easy to see the AI is loser and can't last the night.

And that's what happened.

I am getting superstitious! Today
 

BTW you start with 100 chips, plus or minus from that is how to judge progress in the session.


To all,

I am writing a program to test several AI's together against Dealer, if you'd like to be included I just need your AI$ sub routine:

my first as example:

Code: QB64: [Select]

1. FUNCTION bplusAI$
2.     SELECT CASE Players(Player).Total
3.         CASE IS < 10: bplusAI$ = "h" 'no caps!
4.         CASE 10, 11
5.             IF LEN(Players(Player).Hand) = 2 THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
6.         CASE IS < 15
7.             IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
8.         CASE ELSE: bplusAI$ = "Show me the money!"
9.     END SELECT
10. END FUNCTION

Each player has a name or number in the Players() array to track their cards, total, setbet, current bet... so Players(player).Total is your current total for the hand you hold. Just use Players(Player).Total

You can check the Dealer's first card with something like DealerFirst$ =  LEFT$(Players(Dealer).hand, 1) - not allowed to peak at 2nd card. If you are holding an Ace there is a flag for that and be careful how Total is calculated (it assumes the first ace is 11 unless total goes over 21).

So your AI$ function has to return an "h" to hit, an "d" to double down when you have 2 cards that option is open, anything else is equivalent to Stay.


yep opposite from last night!
 

[bplus]

Here is my compact AI tester with my 2nd AI, a mod of first that decreases probability to hit between 12 and 14 and refusing to Double Down if Dealer shows an Ace:

Code: QB64: [Select]

1. OPTION _EXPLICIT ' No suits shown for cards A is Ace, J, Q, K are Jack, Queen, King, X is for 10
2. DEFINT A-Z '       Player's Blackjack pays double the bet set at the beginning of the game
3. RANDOMIZE TIMER
4. '2020-07-05 fix hit (it wasn't brolen), delete line card$ = inkey$ before loop
5. ' force dealer to hit on 16 stay 17
6. ' ties are push
7. ' bring in double down option
8. ' fix dealer has Blackjack should tell also fix exposing 2nd card
9. ' work this towards converting to multiple AI players, so players stats are all located in PlayerType
10. ' 2020-07-06 Installed AI and mods for it
11. ' 2020-07-06 new Compact Tester with 2nd AI
12.  
13. _TITLE "Blackjack AI Tester" ' started 2019-06-06, revisit and match functions with B+J Balckjack with audio and graphics.
14. CONST rank$ = "A23456789XJQK"
15. CONST Player = 1
16. CONST Dealer = 2
17.  
18. TYPE PlayerType
19.     ID AS STRING
20.     Hand AS STRING
21.     Ace AS INTEGER
22.     Total AS INTEGER
23.     chips AS _INTEGER64
24.     setBet AS _INTEGER64
25.     bet AS _INTEGER64
26. END TYPE
27.  
28. DIM SHARED deck$(1 TO 52), Players(1 TO 2) AS PlayerType, deckIndex, round
29. SCREEN _NEWIMAGE(400, 300, 32)
30. DIM i, r, card$
31. Players(Player).ID = "Player"
32. Players(Dealer).ID = "Dealer"
33. FOR i = 1 TO 52
34.     deck$(i) = MID$(rank$ + rank$ + rank$ + rank$, i, 1)
35. NEXT
36. Players(Dealer).chips = -100
37. Players(Player).chips = 100
38. 'bbbbb"1234567890123456789012345678901234567890
39. cp 4, "*** BJ Compact AI Tester ***"
40. cp 6, "You start with 100 chips."
41. cp 7, "AI sets bet amount to 2."
42. cp 8, "Dealer must hit on 16 or less."
43. cp 9, "Blackjack pays 1.5 X the bet."
44. cp 10, "Double down option available"
45. cp 11, "when you get 2 cards."
46. cp 12, "It Doubles the bet and you get one"
47. cp 13, "more card."
48. cp 17, "press any to continue..."
49. SLEEP
50. Players(Player).setBet = 2
51. 'LOCATE 17, 38: INPUT ""; Players(Player).setBet
52. DO
53.     IF Players(Player).setBet = 0 THEN
54.         CLS
55.         cp 10, "You have" + STR$(Players(Player).chips) + "."
56.         LOCATE 11, 25: INPUT "(0 quits) Enter your bet > ", Players(Player).bet
57.         IF Players(Player).bet = 0 THEN EXIT DO
58.         IF Players(Player).bet >= Players(Player).chips THEN Players(Player).bet = Players(Player).chips
59.     ELSE
60.         IF Players(Player).chips < Players(Player).setBet THEN Players(Player).bet = Players(Player).chips ELSE Players(Player).bet = Players(Player).setBet
61.     END IF
62.     clearPlayers 'clears screen too
63.     cp 4, "Chips:" + STR$(Players(Player).chips) + "   betting:" + STR$(Players(Player).bet) + " chips."
64.     FOR i = 52 TO 2 STEP -1 'shuffle
65.         r = INT(RND * i) + 1
66.         SWAP deck$(r), deck$(i)
67.     NEXT
68.     deckIndex = 0
69.     FOR i = 1 TO 2 'each Player is dealt 2 cards
70.         PlayerAddCard Player
71.         IF i = 1 THEN cp 10, playerShow$(Player)
72.         _DELAY 1
73.         PlayerAddCard Dealer
74.         IF i = 1 THEN cp 7, playerShow$(Dealer)
75.         _DELAY 1
76.     NEXT
77.     cp 10, playerShow$(Player)
78.     _DELAY 1
79.     cp 7, Players(Dealer).ID + ": " + MID$(Players(Dealer).Hand, 1, 1) + " ?  Total = ??"
80.     _DELAY 1
81.     '   BJ  debug players having BJ
82.     'Players(Dealer).Total = 21
83.     'Players(Player).Total = 21
84.     IF Players(Player).Total = 21 AND Players(Dealer).Total = 21 THEN
85.         cp 7, playerShow$(Dealer) + " Blackjack!"
86.         cp 10, playerShow$(Player) + " Blackjack!"
87.         cp 13, "Push"
88.         GOTO BJskip
89.     ELSEIF Players(Player).Total = 21 THEN
90.         cp 10, playerShow$(Player) + " Blackjack!"
91.         Players(Player).chips = Players(Player).chips + 1.5 * Players(Player).bet
92.         Players(Dealer).chips = Players(Dealer).chips - 1.5 * Players(Player).bet
93.         cp 13, "You won" + STR$(2 * Players(Player).bet)
94.         GOTO BJskip
95.     ELSEIF Players(Dealer).Total = 21 THEN
96.         cp 7, playerShow$(Dealer) + " Blackjack!"
97.         Players(Player).chips = Players(Player).chips - Players(Player).bet
98.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
99.         cp 13, "You lost" + STR$(Players(Player).bet)
100.         _DELAY 1
101.         GOTO BJskip
102.     END IF
103.     WHILE Players(Player).Total < 21
104.         IF LEN(Players(Player).Hand) = 2 THEN
105.             cp 15, "Hit Double or Stay"
106.         ELSE
107.             cp 15, "Hit or Stay"
108.         END IF
109.         'card$ = ""
110.         'WHILE LEN(card$) = 0: card$ = INKEY$: _LIMIT 60: WEND   ' bplus calling it in now!
111.         card$ = bplusAI$
112.         IF card$ = "h" THEN cp 17, "Hit"
113.         IF card$ = "d" THEN cp 17, "Double Down"
114.         IF card$ <> "h" AND card$ <> "d" THEN cp 17, "Stay"
115.         cp 15, SPACE$(39) 'erase line
116.         _DELAY 2
117.         cp 17, SPACE$(39)
118.         IF card$ = "h" THEN
119.             PlayerAddCard Player
120.             'cp 11, SPACE$(50)
121.             cp 10, playerShow$(Player)
122.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'busted! skip dealer expose 2nd and play
123.         ELSEIF card$ = "d" AND LEN(Players(Player).Hand) = 2 THEN
124.             Players(Player).bet = 2 * Players(Player).bet
125.             PlayerAddCard Player
126.             'cp 11, SPACE$(50)
127.             cp 10, playerShow$(Player)
128.             IF Players(Player).Total > 21 THEN GOTO finalReckoning 'bustest! skip dealer expose 2nd and play
129.             EXIT WHILE
130.         ELSE 'stayed
131.             ' cp 11, SPACE$(50)
132.             EXIT WHILE
133.         END IF
134.     WEND
135.     cp 7, playerShow$(Dealer)
136.     _DELAY 1
137.     WHILE Players(Player).Total < 22 AND Players(Dealer).Total < 17
138.         cp 8, "Dealer takes a card."
139.         _DELAY 1
140.         PlayerAddCard Dealer
141.         cp 7, playerShow$(Dealer)
142.         cp 8, SPACE$(39)
143.         _DELAY 1
144.     WEND
145.     finalReckoning:
146.     IF Players(Player).Total > 21 OR (Players(Player).Total < Players(Dealer).Total AND Players(Dealer).Total < 22) THEN
147.         cp 13, "You lose" + STR$(Players(Player).bet)
148.         Players(Player).chips = Players(Player).chips - Players(Player).bet
149.         Players(Dealer).chips = Players(Dealer).chips + Players(Player).bet
150.     ELSEIF Players(Player).Total = Players(Dealer).Total THEN
151.         cp 13, "Push"
152.     ELSE
153.         cp 13, "You win!" + STR$(Players(Player).bet)
154.         Players(Player).chips = Players(Player).chips + Players(Player).bet
155.         Players(Dealer).chips = Players(Dealer).chips - Players(Player).bet
156.     END IF
157.  
158.     BJskip:
159.     IF Players(Player).chips = 0 THEN cp 15, "Out of chips!"
160.     _DELAY 2
161. LOOP UNTIL Players(Player).chips = 0
162. cp 17, "Goodbye"
163.  
164. SUB clearPlayers
165.     DIM i
166.     CLS
167.     round = round + 1
168.     cp 2, "Round:" + STR$(round)
169.     FOR i = 1 TO 2
170.         Players(i).Hand = ""
171.         Players(i).Ace = 0
172.         Players(i).Total = 0
173.     NEXT
174. END SUB
175.  
176. 'FUNCTION bplusAI$     ' first try
177. '    SELECT CASE Players(Player).Total
178. '        CASE IS < 10: bplusAI$ = "h" 'no caps!
179. '        CASE 10, 11
180. '            IF LEN(Players(Player).Hand) = 2 THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
181. '        CASE IS < 15
182. '            IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
183. '        CASE ELSE: bplusAI$ = "Show me the money!"
184. '    END SELECT
185. 'END FUNCTION
186.  
187. FUNCTION bplusAI$ 'after trying first want to try this make it more likely to hit on 12 than 13, 14...
188.     SELECT CASE Players(Player).Total
189.         CASE IS < 9: bplusAI$ = "h" 'no caps!
190.         CASE 9, 10, 11 'double down unless dealer showing an Ace which is like insurance for dealer
191.             IF LEN(Players(Player).Hand) = 2 AND LEFT$(Players(Dealer).Hand, 1) <> "A" THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
192.         CASE 12: IF RND < .75 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
193.         CASE 13: IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
194.         CASE 14: IF RND < .25 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
195.         CASE ELSE: bplusAI$ = "Show me the money!"
196.     END SELECT
197. END FUNCTION
198.  
199. SUB PlayerAddCard (receiver) 'updates player's hand and total
200.     DIM i AS INTEGER, cv AS INTEGER
201.     deckIndex = deckIndex + 1
202.     Players(receiver).Hand = Players(receiver).Hand + deck$(deckIndex)
203.     IF deck$(deckIndex) = "A" THEN Players(receiver).Ace = -1
204.     Players(receiver).Total = 0
205.     FOR i = 1 TO LEN(Players(receiver).Hand)
206.         IF INSTR(rank, MID$(Players(receiver).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank, MID$(Players(receiver).Hand, i, 1))
207.         Players(receiver).Total = Players(receiver).Total + cv
208.     NEXT
209.     IF Players(receiver).Total < 12 AND Players(receiver).Ace THEN Players(receiver).Total = Players(receiver).Total + 10
210. END SUB
211.  
212. FUNCTION playerShow$ (shower) 'creates string with player name: hand Total = xx and "Busted!" if so.
213.     DIM i AS INTEGER, S$
214.     S$ = Players(shower).ID + ": "
215.     FOR i = 1 TO LEN(Players(shower).Hand)
216.         S$ = S$ + MID$(Players(shower).Hand, i, 1) + " "
217.     NEXT
218.     S$ = S$ + "Total =" + STR$(Players(shower).Total)
219.     IF Players(shower).Total > 21 THEN S$ = S$ + " Bust"
220.     playerShow$ = S$
221. END FUNCTION
222.  
223. SUB cp (row, s AS STRING) 'print centered on row the string
224.     LOCATE row, 1: PRINT SPACE$(50); 'clear row of text
225.     LOCATE row, (50 - LEN(s)) / 2: PRINT s;
226. END SUB
227.  

Update 250 Rounds one of 4 still winning:


Final Results, Rounds lasted: 327, 410, 649, 899.

[johnno56]

Umm... 252 rounds? Can I assume that one round is equivalent to one hand? If so, 'that' is a lot of card games... With such devotion to a specific task, may I suggest either a pastime of jigsaws or golf ball dimple counting?  I could probably attempt 50 rounds, but unfortunately, I do not have enough coffee stockpiled to get me through it... lol

With your coloured version, may I suggest a background of rgb(31,45,80) (a kind of slate-blue) with either white or light blue text? Pure blue, for me anyway, is quite bright on 'pre-coffee' eyes... lol

I would be happy to help but I'm not that familiar with coding AI. Crumbs, I have enough trouble with my 'I'... lol

[bplus]

Hi @johnno56

Here is my first AI, all I need to know is when to hit = "h", when to double down (after first 2 cards) = "d" else the code assumes you want to stay = CASE ELSE neither "h" or "d"

Players(Player).Total = current card total in your hand
IF LEFT$(Players(Dealer).Cards, 1) = "A" THEN ' Dealer is showing an Ace
IF LEN(Players(Player).Hand) = 2 THEN ' player only has 2 cards so Double Down Option is available

Code: QB64: [Select]

1. 'FUNCTION bplusAI$     ' first try
2. '    SELECT CASE Players(Player).Total
3. '        CASE IS < 10: bplusAI$ = "h" 'no caps!  == If my Total < 10 the hit me!
4. '        CASE 10, 11 '=================== If my Total is 10 or 11 then Double down if I have only 2 cards else hit me!
5. '            IF LEN(Players(Player).Hand) = 2 THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
6. '        CASE IS < 15 ' ================== If my Total < 15 toss a coin to hit or stay
7. '            IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
8. '        CASE ELSE: bplusAI$ = "Show me the money!"   "If my Total > 14 just Stay! maybe the Dealer will Bust
9. '    END SELECT
10. 'END FUNCTION
11.  

[johnno56]

I am no card player, but if it was me and I could see the dealers' card is less than say 6, I would stay on 15 because the odds are good that the dealers' next card would be less than 9. If the dealer's card is closer to 9 then I would probably reconsider staying. eg: If the dealer's first card is 6, then yes, stay. If 7 or 8, may be not stay - toss coin 50/50. If 9 or more, definitely not stay - hit.

But that's me...  I hope that I have explained all that properly?

[bplus]

OK I can code that for you. Do you ever try Double Down?

Also do you know Aces are little insurance agents? That is the first one is taken as 11 until or unless you go over 21 then it's 1 and you get a 2nd chance with another hit.

So Double Down when you have an Ace might be a waste of it and not wise if Dealer shows an Ace.

[SMcNeill]

I'd go with some simple kid style logic for a random AI:  "If the dealer stays at 17, then as long as I stay at 18+, I have a good chance to beat them."

[johnno56]

I think Steve may be right, in respect to keeping it simple. My idea may not be the best to use... lol  I have used DD in the past. Usually if both cards add up to either 10 or 11. That didn't happen all that often, but when it did, DD was the way to go...

[bplus]

Thanks for input on AI guys! For Steve I used the absolutely simplest thing I could think of. Ha! it did pretty good on first round of tests.

AI multi Tester:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. ' No suits shown for cards A is Ace, J, Q, K are Jack, Queen, King, X is for 10
3. '2020-07-05 fix hit (it wasn't broken), delete line card$ = inkey$ before loop
4. ' force dealer to hit on 16 stay 17
5. ' ties are push
6. ' bring in double down option
7. ' fix dealer has Blackjack should tell also fix exposing 2nd card
8. ' work this towards converting to multiple AI players, so players stats are all located in PlayerType
9. ' 2020-07-06 Installed AI and mods for it
10. ' 2020-07-06 new Compact Tester with 2nd AI
11. ' 2020-07-06 start Blackjack Multi AI Tester off of Compact Tester
12. '            add in allot of code worked out in Blackjack with Bots 2019-06-07
13. '            Yes, major overhaul of last year bot code which was/is neat!
14. '            Thanks Johnno and Steve for some interesting AI ideas to try!
15.  
16.  
17. DEFINT A-Z
18. RANDOMIZE TIMER
19.  
20. _TITLE "Blackjack Multi AI Tester" ' started 2019-06-06, revisit and match functions with B+J Balckjack with audio and graphics.
21.  
22. CONST nPlayers = 5 'dealer counts as the last player   this number depends on how many AI's to test
23. CONST xmax = 800, ymax = 500, margin = 4
24. CONST rank$ = "A23456789XJQK" 'for building deck and figuring Totals
25. CONST bH = 14, bW = 20 ' box height and box width in rows and columns
26. CONST white = &HFFFFFFFF, black = &HFF000000, bc = &HFF008822, fc = &HFFCCCCFF
27.  
28. TYPE PlayerType
29.     ID AS STRING '        name of bot including dealer bot
30.     Col AS INTEGER '      left corner column
31.     Row AS INTEGER '      top row
32.     FC AS _UNSIGNED LONG 'player colors are assigned in init FC are alternating Black and White
33.     BC AS _UNSIGNED LONG 'random light and dark opposite print FC
34.     Hand AS STRING '      cards are 1 char strings 10 is X
35.     Ace AS INTEGER '      flag has ace for totalling hand
36.     Bust AS INTEGER '     flag for final reckoning
37.     BJ AS INTEGER '       flag for final reckoning
38.     Total AS INTEGER '    card total of hand
39.     Chips AS _INTEGER64 ' players status
40.     SetBet AS _INTEGER64 'regular bet amount
41.     Bet AS _INTEGER64 '   players bet each round
42. END TYPE
43.  
44. DIM SHARED deck$(1 TO 52), p(1 TO nPlayers) AS PlayerType, deckIndex, round, allOut, player, blockDealer
45. SCREEN _NEWIMAGE(xmax, ymax, 32)
46. DIM i, card$
47. initGame
48. 'FOR i = 1 TO nPlayers
49. '    showPlayer i
50. 'NEXT
51. DO
52.     clearPlayers 'clears screen too and shuffles deck
53.  
54.     FOR i = 1 TO 2
55.         FOR player = 1 TO nPlayers 'each Player is dealt 2 cards
56.             IF player <> nPlayers THEN
57.                 IF p(player).Chips > 0 THEN
58.                     allOut = 0 'signal everyone is out of chips is false
59.                     PlayerAddCard player
60.                     showPlayer player
61.                     _DELAY .5
62.                 END IF
63.             ELSE
64.                 IF allOut THEN
65.                     EXIT DO
66.                 ELSE
67.                     PlayerAddCard player
68.                     showPlayer player
69.                     _DELAY .5
70.                 END IF
71.             END IF
72.         NEXT
73.     NEXT
74.  
75.     IF p(nPlayers).BJ = 0 THEN 'dealer does not have BJ
76.         FOR player = 1 TO nPlayers - 1
77.             showPlayer player
78.             _DELAY 1
79.             WHILE p(player).Total < 21
80.                 SELECT CASE player ' this has to be coded for exactly all nPlayers - 1
81.                     CASE 1: card$ = Johnno$(player)
82.                     CASE 2: card$ = Steve$(player)
83.                     CASE 3: card$ = bplusAI$(player)
84.                     CASE 4: card$ = bplusAI2$(player)
85.                 END SELECT
86.                 IF card$ = "h" THEN cp player, 13, "Hit"
87.                 IF card$ = "d" THEN cp player, 13, "Double Down"
88.                 IF card$ <> "h" AND card$ <> "d" THEN cp player, 13, "Stay"
89.                 _DELAY 2
90.                 IF card$ = "h" THEN
91.                     PlayerAddCard player
92.                     showPlayer player
93.                     _DELAY 1
94.                 ELSEIF card$ = "d" AND LEN(p(player).Hand) = 2 THEN
95.                     p(player).Bet = 2 * p(player).Bet
96.                     PlayerAddCard player
97.                     showPlayer player
98.                     _DELAY 1
99.                     EXIT WHILE
100.                 ELSE 'stayed
101.                     showPlayer player
102.                     _DELAY 1
103.                     EXIT WHILE
104.                 END IF
105.             WEND
106.         NEXT
107.     END IF
108.  
109.     blockDealer = 0
110.     showPlayer nPlayers
111.     _DELAY 1
112.     WHILE p(nPlayers).Total < 17
113.         cp nPlayers, 11, "Dealer takes a card."
114.         _DELAY 1
115.         PlayerAddCard nPlayers
116.         showPlayer nPlayers
117.         _DELAY 1
118.     WEND
119.  
120.     '    final Reckoning
121.     FOR player = 1 TO nPlayers - 1
122.         showPlayer player
123.         IF p(player).Total > 21 OR (p(player).Total < p(nPlayers).Total AND p(nPlayers).Total < 22) THEN
124.             cp player, 13, "Lost" + STR$(p(player).Bet)
125.             p(player).Chips = p(player).Chips - p(player).Bet
126.             p(nPlayers).Chips = p(nPlayers).Chips + p(player).Bet
127.         ELSEIF p(player).Total = p(nPlayers).Total AND p(player).BJ = 0 THEN
128.             cp player, 13, "Push"
129.         ELSE
130.             IF p(player).BJ THEN
131.                 cp player, 13, "Win!" + STR$(p(player).Bet + .5 * p(player).Bet)
132.                 p(player).Chips = p(player).Chips + p(player).Bet + .5 * p(player).Bet
133.                 p(nPlayers).Chips = p(nPlayers).Chips - p(player).Bet - .5 * p(player).Bet
134.             ELSE
135.                 cp player, 13, "Win!" + STR$(p(player).Bet)
136.                 p(player).Chips = p(player).Chips + p(player).Bet
137.                 p(nPlayers).Chips = p(nPlayers).Chips - p(player).Bet
138.             END IF
139.         END IF
140.         IF p(player).Chips = 0 THEN cp player, 14, "Out of chips!"
141.         _DELAY 3
142.     NEXT
143. LOOP UNTIL allOut
144. SLEEP
145.  
146. SUB clearPlayers
147.     DIM i
148.     COLOR fc, bc: CLS
149.     round = round + 1: allOut = -1
150.     FOR i = 1 TO nPlayers
151.         p(i).Hand = ""
152.         p(i).Ace = 0
153.         p(i).Total = 0
154.         p(i).BJ = 0
155.         p(i).Bust = 0
156.         'because of double down option I have to reset bet during play and set it back at each new round
157.         'make sure we aren't betting more than our chips count at least to start
158.         IF p(i).Chips < p(i).SetBet THEN p(i).Bet = p(i).Chips ELSE p(i).Bet = p(i).SetBet
159.     NEXT
160.     FOR i = 52 TO 2 STEP -1 'shuffle
161.         SWAP deck$(INT(RND * i) + 1), deck$(i)
162.     NEXT
163.     'deck$(5) = "A": deck$(10) = "J"  'check immediate show of Blackjack for dealer
164.     deckIndex = 0: blockDealer = -1
165. END SUB
166.  
167. FUNCTION bplusAI$ (pn) ' first try
168.     SELECT CASE p(pn).Total
169.         CASE IS < 10: bplusAI$ = "h" 'no caps!
170.         CASE 10, 11
171.             IF LEN(p(pn).Hand) = 2 THEN bplusAI$ = "d" ELSE bplusAI$ = "h"
172.         CASE IS < 15
173.             IF RND < .5 THEN bplusAI$ = "h" ELSE bplusAI$ = "whatever"
174.         CASE ELSE: bplusAI$ = "Show me the money!"
175.     END SELECT
176. END FUNCTION
177.  
178. FUNCTION bplusAI2$ (pN) 'after trying first want to try this make it more likely to hit on 12 than 13, 14...
179.     SELECT CASE p(pN).Total
180.         CASE IS < 10: bplusAI2$ = "h" 'no caps!
181.         CASE 10, 11 'double down unless dealer showing an Ace which is like insurance for dealer
182.             IF LEN(p(pN).Hand) = 2 AND LEFT$(p(nPlayers).Hand, 1) <> "A" THEN bplusAI2$ = "d" ELSE bplusAI2$ = "h"
183.         CASE 12: IF RND < .75 THEN bplusAI2$ = "h" ELSE bplusAI2$ = "whatever"
184.         CASE 13: IF RND < .5 THEN bplusAI2$ = "h" ELSE bplusAI2$ = "whatever"
185.         CASE 14: IF RND < .25 THEN bplusAI2$ = "h" ELSE bplusAI2$ = "whatever"
186.         CASE ELSE: bplusAI2$ = "Show me the money!"
187.     END SELECT
188. END FUNCTION
189.  
190. FUNCTION Johnno$ (pN)
191.     IF p(pN).Total = 10 OR p(pN).Total = 11 AND LEN(p(pN).Hand) = 2 THEN
192.         Johnno$ = "d"
193.     ELSEIF p(pN).Total = 10 OR p(pN).Total = 11 AND LEN(p(pN).Hand) <> 2 THEN
194.         Johnno$ = "h"
195.     ELSEIF 12 <= p(pN).Total AND p(pN).Total <= 15 THEN
196.         SELECT CASE LEFT$(p(nPlayers).Hand, 1)
197.             CASE "A", "K", "Q", "J", "X", "9": Johnno$ = "h"
198.             CASE "7", "8": IF RND < .5 THEN Johnno$ = "h"
199.             CASE ELSE: Johnno$ = "Hope to Bust em"
200.         END SELECT
201.     ELSEIF p(pN).Total < 12 THEN
202.         Johnno$ = "h"
203.     ELSE
204.         Johnno$ = "Stay"
205.     END IF
206. END FUNCTION
207.  
208. FUNCTION Steve$ (pN) 'how simple is this! never bust make dealer work for it
209.     IF p(pN).Total < 12 THEN Steve$ = "h"
210. END FUNCTION
211.  
212. SUB PlayerAddCard (rec) 'updates player's hand and total
213.     DIM i AS INTEGER, cv AS INTEGER
214.     deckIndex = deckIndex + 1
215.     p(rec).Hand = p(rec).Hand + deck$(deckIndex)
216.     IF deck$(deckIndex) = "A" THEN p(rec).Ace = -1
217.     p(rec).Total = 0
218.     FOR i = 1 TO LEN(p(rec).Hand)
219.         IF INSTR(rank$, MID$(p(rec).Hand, i, 1)) > 10 THEN cv = 10 ELSE cv = INSTR(rank$, MID$(p(rec).Hand, i, 1))
220.         p(rec).Total = p(rec).Total + cv
221.     NEXT
222.     IF p(rec).Total < 12 AND p(rec).Ace THEN p(rec).Total = p(rec).Total + 10
223.     IF LEN(p(rec).Hand) = 2 AND p(rec).Total = 21 THEN p(rec).BJ = -1
224.     IF p(rec).Total > 21 THEN p(rec).Bust = -1
225. END SUB
226.  
227. SUB showPlayer (nPlayer)
228.     DIM i AS INTEGER, S$
229.     COLOR p(nPlayer).FC, p(nPlayer).BC
230.     FOR i = 0 TO bH - 1 'clear our block
231.         'PRINT p(nPlayer).Row + i, p(nPlayer).Col
232.         LOCATE p(nPlayer).Row + i, p(nPlayer).Col: PRINT SPACE$(bW);
233.     NEXT
234.     cp nPlayer, 1, "Round:" + STR$(round)
235.     cp nPlayer, 3, p(nPlayer).ID
236.     cp nPlayer, 5, "Chips:" + STR$(p(nPlayer).Chips)
237.     IF nPlayer <> nPlayers THEN cp nPlayer, 6, "Bet:" + STR$(p(nPlayer).Bet)
238.     FOR i = 1 TO LEN(p(nPlayer).Hand) 'with 12 aces could get very long hands
239.         S$ = S$ + MID$(p(nPlayer).Hand, i, 1) + " "
240.     NEXT
241.     cp nPlayer, 8, "___Hand___"
242.     IF nPlayer = nPlayers AND LEN(p(nPlayer).Hand) = 2 AND p(nPlayer).Total <> 21 AND blockDealer THEN
243.         S$ = LEFT$(S$, 2) + "?"
244.         cp nPlayer, 9, S$
245.         cp nPlayer, 10, "Total: ??"
246.     ELSE
247.         cp nPlayer, 9, S$
248.         cp nPlayer, 10, "Total:" + STR$(p(nPlayer).Total)
249.     END IF
250.  
251.     IF p(nPlayer).Bust THEN cp nPlayer, 11, "Busted"
252.     IF p(nPlayer).BJ THEN cp nPlayer, 11, "Blackjack"
253. END FUNCTION
254.  
255. SUB initGame 'the stuff that never changes
256.     DIM i, spacer
257.     FOR i = 1 TO 52 'get deck ready
258.         deck$(i) = MID$(rank$ + rank$ + rank$ + rank$, i, 1)
259.     NEXT
260.  
261.     'for printing in each players window area of screen = blackjack table
262.     'xmax/8 =  2*margin + bW *(nplayers -1) + spacer *(nplayer-2)
263.     spacer = ((xmax / 8) - margin - bW * (nPlayers - 1)) / (nPlayers - 2)
264.  
265.     FOR i = 1 TO nPlayers
266.         IF i <> nPlayers THEN
267.             SELECT CASE i
268.                 CASE 1: p(i).ID = "Johnno"
269.                 CASE 2: p(i).ID = "Steve"
270.                 CASE 3: p(i).ID = "bplus AI"
271.                 CASE 4: p(i).ID = "bplus AI2"
272.             END SELECT
273.             p(i).Col = margin + (i - 1) * (spacer + bW)
274.             p(i).Row = 18
275.             p(i).Chips = 100
276.             p(i).SetBet = 2
277.             IF i MOD 2 THEN
278.                 p(i).BC = _RGB32(RND * 128, RND * 128, RND * 128)
279.             ELSE
280.                 p(i).BC = _RGB32(RND * 128 + 127, RND * 128 + 127, RND * 128 + 127)
281.             END IF
282.         ELSE
283.             p(i).ID = "Dealer"
284.             p(i).Col = (xmax / 8 - bW) / 2
285.             p(i).Row = 2
286.             p(i).Chips = -100 * (nPlayers - 1)
287.             IF i MOD 2 THEN p(i).BC = &HFF000000 ELSE p(i).BC = &HFFFFFFFF
288.         END IF
289.         IF i MOD 2 THEN p(i).FC = &HFFFFFFFF ELSE p(i).FC = &HFF000000
290.     NEXT
291.  
292.     'ask the user / YOU what e prefers for betting
293.     COLOR fc, bc: CLS
294.     cp 0, 10, "*** Blackjack Multi AI Tester ***"
295.     cp 0, 12, "Each AI bot starts with 100 chips and bets 2 each round."
296.     cp 0, 13, "Dealer must hit on 16 or less."
297.     cp 0, 14, "Blackjack pays 1.5 X the bet."
298.     cp 0, 15, "Double down option available when you get 2 cards."
299.     cp 0, 16, "It Doubles the bet and you get one more card."
300.     cp 0, 20, "press any to continue..."
301.     SLEEP
302. END SUB
303.  
304. SUB cp (nPlayer, row, s AS STRING) 'center print a string on the given row
305.     IF nPlayer THEN
306.         COLOR p(nPlayer).FC, p(nPlayer).BC
307.         LOCATE p(nPlayer).Row + row, p(nPlayer).Col + (bW - LEN(s)) / 2: PRINT s;
308.     ELSE
309.         COLOR fc, bc
310.         LOCATE row, (xmax / 8 - LEN(s)) / 2: PRINT s;
311.     END IF
312. END SUB
313.  
314.  

 

[johnno56]

I know. I know. I'm not a fan of Star Wars but... Darth Vader. Episode IV: A New Hope. "Impressive. Most impressive."

[George McGinn]

Over on my iPad, I have a deck shuffling program which is very simple. I create a random array with numbers from 1 to 52, and these numbers serve as an index to another table that holds the card number and suit. I use graphics (UNICODE or the iPad's expanded ASCII Code) and the suit is the same size as the number.

I can bring it over to QB64 and get it to work if you are interested in it. I can even create options where you can create a shuffled array with 4 to 8 decks if you can use it.