CIRCLE vs Circle Fill

[TempodiBasic]

Hi guys
again on CIRCLE original graphic function....
it shows many points of weakness...

Why is it yet there?

Why don't substitute it with Circle Fill (by Steve) or with another good implementation (see Bplus, TerryRitchie etc etc sorry to who my memory puts out of the list)?

this is an open letter... not a criticism
what council of developers can do this?

Thanks to read

QB64 rocks

[Qwerkey]

Tempo, I have not found CIRCLE problems.  It does what the wiki says (as far as I know), so what is the problem ("many points of weakness")?

[bplus]

Hi (again) TempodiBasic,

We did investigate adding a Circle Fill routine to QB64 and found it to be a very complex proposition.


Hi Qwerkey,

Circle does have a problem with alpha colors overlapping at the cardinal compass points. Hardly anyone knows or notices.
Circle has another problem when attemping to fill pie shaped borders with PAINT, it tends to leak because start and/or stop angle is a bit off. Again hardly anyone knows but you would notice it if you tried it.

Overlapping alpha at cardinal points:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(400, 400, 32)
2. FOR r = 175 TO 1 STEP -1
3.     CIRCLE (200, 200), r, _RGB32(0, 0, 180, 100)
4. NEXT
5.  

Pie slice leaks:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(400, 400, 32)
2. COLOR _RGB32(0, 0, 255)
3. startR = _PI / 12: stopR = _PI * 5 / 12
4. CIRCLE (200, 200), 100, , startR, stopR
5. LINE (200, 200)-(200 + 100 * COS(startR), 200 - 100 * SIN(startR))
6. LINE (200, 200)-(200 + 100 * COS(stopR), 200 - 100 * SIN(stopR))
7. 'PSET (250, 150) 'check paint point
8. PRINT "Press any to PAINT pie slice"
9. SLEEP
10. PAINT (250, 150), _RGB32(255, 255, 255), _RGB32(0, 0, 255)
11.  

Also while making 2nd example I noticed that startRadians and stopRadians go in the opposite direction around a circle eg to make the lines of the pie slice match the endpoints of the arc drawn with circle. Blah!, not consistent with radian measures starting at 0 Due East and going CLOCKWISE from there like the rest of the graphics work with radian angles.

[TempodiBasic]

@Qwerkey
thanks for reply...

IMHO
try this , it seems that there is a lack of continuity of the line of the ellipse mode that lets go out the color of PAINT

Code: QB64: [Select]

1. ' **********************  USO DEI SOTTOPROGRAMMI --SUB-- ********************
2. '************************ FUNZIONI GRAFICHE ECCETTO DRAW ********************
3.  
4. ' Parte delle dichiarazioni
5. ' Dichiaro le SUB cioŠ i sottoprogrammi
6. DECLARE SUB Aspetta (Sec!)
7. DECLARE SUB Inizializza ()
8. DECLARE SUB Linee ()
9. DECLARE SUB Scritte ()
10. DECLARE SUB RettangoliVuoti ()
11. DECLARE SUB RettangoliPieni ()
12. DECLARE SUB CerchiVuoti ()
13. DECLARE SUB CerchiPieni ()
14. DECLARE SUB ArchiVuoti ()
15. DECLARE SUB ArchiPieni ()
16. DECLARE SUB FetteVuote ()
17. DECLARE SUB FettePiene ()
18. DECLARE SUB EllisseOrizzontaleVuota ()
19. DECLARE SUB EllisseOrizzontalePiena ()
20. DECLARE SUB EllisseVerticaleVuota ()
21. DECLARE SUB EllisseVerticalePiena ()
22. DECLARE SUB ArchiEllisseOrizzontale ()
23. DECLARE SUB ArchiEllisseVerticale ()
24. DECLARE SUB FetteVuoteEllisseOrizzontale ()
25. DECLARE SUB FetteVuoteEllisseVerticale ()
26. DECLARE SUB FettePieneEllisseOrizzontale ()
27. DECLARE SUB FettePieneEllisseVerticale ()
28. CONST tot = .1
29.  
30. SCREEN 9 'pongo lo schermo in modalit… grafica
31. WIDTH 80, 25
32.  
33.  
34. ' Qui inizia il programma che chiama le varie SUB
35. REM Inizializza
36. REM Scritte
37. REM Inizializza
38. REM Linee
39. REM Inizializza
40. REM RettangoliVuoti
41. REM Inizializza
42. REM RettangoliPieni
43. Inizializza
44. CerchiVuoti
45. Inizializza
46. CerchiPieni
47. Inizializza
48. ArchiVuoti
49. Inizializza
50. FetteVuote
51. Inizializza
52. FettePiene
53. Inizializza
54. EllisseOrizzontaleVuota
55. Inizializza
56. EllisseOrizzontalePiena
57. Inizializza
58. EllisseVerticaleVuota
59. Inizializza
60. EllisseVerticalePiena
61. Inizializza
62. ArchiEllisseOrizzontale
63. Inizializza
64. FetteVuoteEllisseOrizzontale
65. Inizializza
66. FettePieneEllisseOrizzontale
67. Inizializza
68. ArchiEllisseVerticale
69. Inizializza
70. FetteVuoteEllisseVerticale
71. Inizializza
72. FettePieneEllisseVerticale
73.  
74. ' do il messaggio Finale
75. LOCATE 23, 23: PRINT "Premere un tasto per terminare..."
76. SLEEP
77. CLS 'pulisco lo schermo
78. contatore% = 0 'inizializzo contatore%
79. END
80.  
81. SUB ArchiEllisseOrizzontale
82.     ' ArchiEllisseOrizzontale
83.     FOR contatore% = 1 TO 15
84.         ' creo un cerchio colorato
85.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, tot, contatore% MOD 7, .5
86.         Aspetta tot
87.     NEXT
88.  
89. END SUB
90.  
91. SUB ArchiEllisseVerticale
92.     'Archi di ellisse ad asse maggiore verticale
93.     FOR contatore% = 1 TO 15
94.         ' creo un cerchio colorato
95.         CIRCLE (350, 215), 220 - (10 * contatore%), contatore%, tot, (contatore% MOD 7), -1
96.         Aspetta tot
97.     NEXT
98.  
99. END SUB
100.  
101. SUB ArchiVuoti
102.     'archi vuoti
103.  
104.     FOR contatore% = 1 TO 15
105.         ' creo un cerchio colorato
106.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, tot, contatore% MOD 7
107.         Aspetta tot
108.     NEXT
109.  
110. END SUB
111.  
112. SUB Aspetta (Sec!)
113.     via! = TIMER
114.     WHILE TIMER - via! <= Sec!
115.     WEND
116. END SUB
117.  
118. SUB CerchiPieni
119.  
120.     ' cerchi pieni
121.  
122.     FOR contatore% = 1 TO 15
123.         ' creo un cerchio colorato
124.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%
125.         ' dipingo l'interno del cerchio
126.         PAINT (350, 175), contatore%, contatore%
127.         Aspetta tot
128.     NEXT
129.  
130. END SUB
131.  
132. SUB CerchiVuoti
133.     'cerchi vuoti
134.     FOR contatore% = 1 TO 15
135.         ' creo un cerchio colorato
136.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%
137.         Aspetta tot
138.     NEXT
139.  
140. END SUB
141.  
142. SUB EllisseOrizzontalePiena
143.     'ellissi piene ad asse maggiore orizzontale
144.  
145.     FOR contatore% = 1 TO 15
146.         ' creo un cerchio colorato
147.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, , , .5
148.         ' dipingo l'interno del cerchio
149.         PAINT (350, 175), contatore%, contatore%
150.         Aspetta tot
151.     NEXT
152.  
153. END SUB
154.  
155. SUB EllisseOrizzontaleVuota
156.  
157.     ' ellissi vuote ad asse maggiore orizzontale
158.  
159.     FOR contatore% = 1 TO 15
160.         ' creo un cerchio colorato
161.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, , , .5
162.         Aspetta tot
163.     NEXT
164.  
165. END SUB
166.  
167. SUB EllisseVerticalePiena
168.     ' ellissi  piene ad asse maggiore verticale
169.     FOR contatore% = 1 TO 15
170.         ' creo un cerchio colorato
171.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, , , -4
172.         ' dipingo l'interno del cerchio
173.         PAINT (350, 175), contatore%, contatore%
174.         Aspetta tot
175.     NEXT
176.  
177.  
178. END SUB
179.  
180. SUB EllisseVerticaleVuota
181.     ' ellissi vuote ad asse maggiore verticale
182.  
183.     FOR contatore% = 1 TO 15
184.         ' creo un cerchio colorato
185.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, , , -4
186.         Aspetta tot
187.     NEXT
188.  
189. END SUB
190.  
191. SUB FettePiene
192.  
193.     ' aree di cerchio o fette di torta piene
194.  
195.     FOR contatore% = 1 TO 15
196.         ' creo un cerchio colorato
197.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, -.3, -(contatore% MOD 5) - tot
198.         ' coloro l'area
199.         PAINT (370, 155), contatore%, contatore%
200.         Aspetta tot
201.     NEXT
202.  
203. END SUB
204.  
205. SUB FettePieneEllisseOrizzontale
206.     ' Fette di torta di ellisse orizzontale piene
207.     FOR contatore% = 1 TO 15
208.         ' creo un cerchio colorato
209.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, -tot, -(contatore% MOD 2) + -2.5, .5
210.         ' coloro l'interno della fetta
211.         PAINT (360, 170), contatore%, contatore%
212.         Aspetta tot
213.     NEXT
214.  
215. END SUB
216.  
217. SUB FettePieneEllisseVerticale
218.     ' Fette di torta di ellisse orizzontale piene
219.     FOR contatore% = 1 TO 15
220.         ' creo un cerchio colorato
221.         CIRCLE (350, 215), 220 - (10 * contatore%), contatore%, -tot, -(contatore% MOD 2) + -2.5, -1
222.         ' coloro l'interno della fetta
223.         PAINT (360, 210), contatore%, contatore%
224.     NEXT
225.  
226. END SUB
227.  
228. SUB FetteVuote
229.  
230.     ' aree di cerchio o fette di torta vuote
231.  
232.  
233.     FOR contatore% = 1 TO 15
234.         ' creo un cerchio colorato
235.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, -.3, -(contatore% MOD 5) - tot
236.         Aspetta tot
237.     NEXT
238.  
239. END SUB
240.  
241. SUB FetteVuoteEllisseOrizzontale
242.     ' Fette di torta di ellisse vuote
243.     FOR contatore% = 1 TO 15
244.         ' creo un cerchio colorato
245.         CIRCLE (350, 175), 220 - (10 * contatore%), contatore%, -tot, -(contatore% MOD 7) - tot, .5
246.         Aspetta tot
247.     NEXT
248.  
249. END SUB
250.  
251. SUB FetteVuoteEllisseVerticale
252.     ' Fette di torta di ellisse orizzontale vuote
253.     FOR contatore% = 1 TO 15
254.         ' creo un cerchio colorato
255.         CIRCLE (350, 215), 220 - (10 * contatore%), contatore%, -tot, -(contatore% MOD 2) + -2.5, -1
256.         Aspetta tot
257.     NEXT
258.  
259. END SUB
260.  
261. SUB Inizializza
262.     ' do il messaggio
263.     LOCATE 23: PRINT "Premere un tasto per continuare..."
264.     SLEEP 1
265.     CLS 'pulisco lo schermo
266.     contatore% = 0 'inizializzo contatore%
267.  
268. END SUB
269.  
270. SUB Linee
271.                                
272.     FOR contatore% = 1 TO 15
273.         ' creo una linea dall'angolo in alto a sinistra a quello in basso a destra
274.         LINE (1 + 10 * contatore%, 1)-(640 + contatore%, 350), contatore%
275.         Aspetta tot
276.     NEXT 'contatore%       'qui finisce il ciclo FOR...NEXT
277.  
278. END SUB
279.  
280. SUB RettangoliPieni
281.  
282.     ' rettangoli pieni
283.  
284.     FOR contatore% = 1 TO 15
285.         ' creo un rettangolo pieno rosso
286.         LINE (20 + 10 * contatore%, 20 + 5 * contatore%)-(200 + 10 * contatore%, 200 + 10 * contatore%), contatore%, BF
287.         Aspetta tot
288.     NEXT ' qui finisce il ciclo FOR...NEXT
289.  
290. END SUB
291.  
292. SUB RettangoliVuoti
293.                          
294.     'rettangoli vuoti
295.     FOR contatore% = 1 TO 15
296.         ' creo un rettangolo vuoto in fucsia
297.         LINE (10 + 10 * contatore%, 10 + 5 * contatore%)-(100 + 20 * contatore%, 100 + 10 * contatore%), contatore%, B
298.         Aspetta tot
299.     NEXT 'qui finisce il ciclo FOR ... NEXT
300.  
301. END SUB
302.  
303. SUB Scritte
304.                                
305.     'scritte  colorate
306.     FOR contatore% = 1 TO 15
307.         ' pongo il cursore alla riga 1 e colonna 1, uso il colore  e scrivo Ciao
308.         LOCATE contatore%, contatore%: COLOR contatore%
309.         PRINT "Ciao"
310.         Aspetta tot
311.     NEXT
312. END SUB
313.  

(this is an old code written in Qbasic)

and try this

Code: QB64: [Select]

1. ' a porting to QB64 of Mitosis simulation as showed in this video
2. '[youtube]https://www.youtube.com/watch?v=jxGS3fKPKJA[/youtube]
3. TYPE Cell
4.     x AS INTEGER
5.     y AS INTEGER
6.     Radius AS INTEGER
7.     Colors AS _UNSIGNED LONG
8. END TYPE
9.  
10. CONST Hscreen = 700, Wscreen = 800, StartRadius = 60, MaxCells = 1000
11. CONST True = -1, False = NOT True, MinRadius = 3
12. 'CONST Blu = _RGB32(0, 0, 255): CONST Black = _RGB32(0, 0, 0)
13. 'CONST Red = _RGB32(255, 0, 0): CONST Green = _RGB32(0, 255, 0)
14. 'CONST White = _RGB(255, 255, 255)
15. DIM SHARED A AS LONG, Cells(1 TO MaxCells) AS Cell, NumActiveCell AS INTEGER
16. DIM SHARED FNameOn AS INTEGER, KeyS AS INTEGER
17. RANDOMIZE TIMER
18.  
19. IF NOT Setup THEN PRINT "Error in Setup"
20. DO
21.     IF NOT Draws THEN PRINT "Error in Draws"
22.     IF NOT MoveCell THEN PRINT "Error in movecell"
23.     IF MousePressed THEN
24.         F = CellClicked
25.         'clear buffer of mouse input
26.         WHILE _MOUSEBUTTON(1)
27.             IF _MOUSEINPUT THEN REM
28.         WEND
29.  
30.         IF F <> False THEN
31.             PRINT "LeftClick on cell "; F
32.             IF NumActiveCell < MaxCells AND (NOT DuplicateCell(F)) THEN PRINT "Error in Duplicatecell"
33.         ELSE
34.             PRINT "LeftClick out of cells"
35.         END IF
36.     END IF
37.     KeyS = _KEYHIT
38.     IF KeyS = 78 OR KeyS = 110 THEN FNameOn = NOT FNameOn
39.     _DISPLAY '<<<<<<<<<<<< prevent flicker
40.     _LIMIT 10
41. LOOP UNTIL KeyS = 32
42. END
43.  
44.  
45. FUNCTION Setup
46.     'Setup = False
47.     DIM b AS INTEGER
48.     A = _NEWIMAGE(Wscreen, Hscreen, 32)
49.     IF A < -1 THEN SCREEN A ELSE PRINT "Image handle for Screen not valid"
50.     _TITLE "Mitosis Simulation"
51.     _SCREENMOVE _MIDDLE
52.     NumActiveCell = 10
53.     FNameOn = False
54.     FOR b = 1 TO NumActiveCell
55.         IF b < 11 THEN
56.             Cells(b).x = MinMax(5, Wscreen - 5)
57.             Cells(b).y = MinMax(5, Hscreen - 5)
58.             Cells(b).Radius = StartRadius
59.             Cells(b).Colors = NewColor
60.             'ELSE
61.             '    Cells(b).x = 0
62.             '    Cells(b).y = 0
63.             '    Cells(b).Radius = 0
64.             '    Cells(b).Colors = 0
65.         END IF
66.     NEXT b
67.     Setup = True
68. END FUNCTION
69.  
70. FUNCTION DuplicateCell (Index AS INTEGER)
71.     'DuplicateCell = False
72.     IF INT(Cells(Index).Radius / 2) > MinRadius THEN
73.         NumActiveCell = NumActiveCell + 1
74.         Cells(NumActiveCell).y = Cells(Index).y
75.         Cells(NumActiveCell).Colors = Cells(Index).Colors
76.         Cells(NumActiveCell).Radius = INT(Cells(Index).Radius / 2)
77.         Cells(Index).Radius = Cells(NumActiveCell).Radius
78.         Cells(NumActiveCell).x = Cells(Index).x + MinMax(-Cells(Index).Radius, Cells(Index).Radius)
79.         Cells(Index).x = Cells(Index).x + MinMax(-Cells(Index).Radius, Cells(Index).Radius)
80.     END IF
81.     DuplicateCell = True
82. END FUNCTION
83.  
84. FUNCTION MousePressed
85.     'MousePressed = False
86.     WHILE _MOUSEINPUT
87.         IF _MOUSEBUTTON(1) = True THEN MousePressed = True
88.     WEND
89. END FUNCTION
90.  
91. FUNCTION IsInTheRange (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
92.     'IsInTheRange = False
93.     IF What > Min AND What < Max THEN IsInTheRange = True
94. END FUNCTION
95.  
96. FUNCTION CellClicked
97.     'CellClicked = False
98.     DIM b AS INTEGER
99.     FOR b = 1 TO NumActiveCell STEP 1
100.         'IF IsInTheRange(_MOUSEX, Cells(b).x - Cells(b).Radius, Cells(b).x + Cells(b).Radius) THEN
101.         '    IF IsInTheRange(_MOUSEY, Cells(b).y - Cells(b).Radius, Cells(b).y + Cells(b).Radius) THEN
102.         '        CellClicked = b
103.         '        EXIT FUNCTION
104.         '    END IF
105.         'END IF
106.         IF ((_MOUSEX - Cells(b).x) ^ 2 + (_MOUSEY - Cells(b).y) ^ 2) ^ .5 <= Cells(b).Radius THEN CellClicked = b: EXIT FUNCTION
107.     NEXT b
108. END FUNCTION
109.  
110. FUNCTION InTheRange (What AS INTEGER, Min AS INTEGER, Max AS INTEGER)
111.     'InTheRange = False
112.     IF What < Min THEN What = Min
113.     IF What > Max THEN What = Max
114.     IF What >= Min AND What <= Max THEN InTheRange = True
115. END FUNCTION
116.  
117. FUNCTION MinMax (Min AS INTEGER, Max AS INTEGER)
118.     'MinMax = False
119.     IF Min > Max THEN SWAP Min, Max
120.     MinMax = INT(RND * (Max - Min + 1)) + Min
121. END FUNCTION
122.  
123. FUNCTION Draws
124.     'Draws = False
125.     DIM b AS INTEGER
126.     CLS , Black
127.     FOR b = 1 TO NumActiveCell
128.         IF NOT ShowCell THEN PRINT "Error in Showcell with value "; Cells(b).x; " "; Cells(b).y
129.     NEXT b
130.     Draws = True
131. END FUNCTION
132.  
133. FUNCTION MoveCell
134.     'MoveCell = False
135.     DIM b AS INTEGER
136.     FOR b = 1 TO NumActiveCell STEP 1
137.         Cells(b).x = Cells(b).x + MinMax(-3, 3)
138.         Cells(b).y = Cells(b).y + MinMax(-3, 3)
139.         IF NOT InTheRange(Cells(b).x, 5, Wscreen - 5) THEN PRINT "Error IntheRange X"
140.         IF NOT InTheRange(Cells(b).y, 5, Hscreen - 5) THEN PRINT "Error IntheRange Y"
141.     NEXT b
142.     MoveCell = True
143. END FUNCTION
144.  
145. FUNCTION NewColor~&
146.     'NewColor~& = False
147.     DIM c AS _UNSIGNED LONG
148.     c = _RGB32(MinMax(100, 255), MinMax(100, 255), MinMax(100, 255), 20)
149.     IF c < 0 THEN
150.         PRINT "Error in NewColor "; c: EXIT FUNCTION
151.     ELSE
152.         NewColor~& = c
153.     END IF
154. END FUNCTION
155.  
156. FUNCTION ShowCell
157.     'ShowCell = False
158.     DIM b AS INTEGER
159.     FOR b = 1 TO NumActiveCell STEP 1
160.         'fcirc
161.         CIRCLE (Cells(b).x, Cells(b).y), Cells(b).Radius, Cells(b).Colors
162.         PAINT STEP(0, 0), Cells(b).Colors, Cells(b).Colors
163.         IF FNameOn THEN _PRINTSTRING (Cells(b).x, Cells(b).y), LTRIM$(STR$(b))
164.     NEXT b
165.     ShowCell = True
166. END FUNCTION
167.  
168.  
169. 'from Steve Gold standard, >>> add for Circle Fills
170. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
171.     DIM Radius AS INTEGER, RadiusError AS INTEGER
172.     DIM X AS INTEGER, Y AS INTEGER
173.  
174.     Radius = ABS(R)
175.     RadiusError = -Radius
176.     X = Radius
177.     Y = 0
178.  
179.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
180.  
181.     ' Draw the middle span here so we don't draw it twice in the main loop,
182.     ' which would be a problem with blending turned on.
183.     LINE (CX - X, CY)-(CX + X, CY), C, BF
184.  
185.     WHILE X > Y
186.         RadiusError = RadiusError + Y * 2 + 1
187.         IF RadiusError >= 0 THEN
188.             IF X <> Y + 1 THEN
189.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
190.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
191.             END IF
192.             X = X - 1
193.             RadiusError = RadiusError - X * 2
194.         END IF
195.         Y = Y + 1
196.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
197.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
198.     WEND
199. END SUB
200.  

taken from here https://www.qb64.org/forum/index.php?topic=1345.msg105440#msg105440
what do you think about it?

Thanks to reply

[TempodiBasic]

Hi Bplus
thanks for your time
I am very glad to get informations about QB64

I'm sorry for my  heavy curiosity, but is the problem  in the underlaying C++ function or in the algorythm coded building QB64?

[Qwerkey]

Guys, thanks.  I had imagined that Tempo's (well everybody's) problem had something to do with leakiness or such.  But having recently used (for my Pascal's Triangle graphical program) CIRCLE and PAINT with complete success, I'd assumed that there was nothing wrong.  I've never used segments nor tried alpha with CIRCLE.  I have always been wondrous at PAINT actually working: what brilliant piece of programming is required to determine uniquely one side and the other of a drawn line? does the (c#) programming look pixel-by-pixel or what?

[bplus]

Hi Bplus
thanks for your time
I am very glad to get informations about QB64

I'm sorry for my  heavy curiosity, but is the problem  in the underlaying C++ function or in the algorythm coded building QB64?

There was some discussion of Circle in the QB64 code here:
https://www.qb64.org/forum/index.php?topic=1044.135

Steve gave instructions of how to find it in source in reply #136
I checked it out and it was discussed a little more in replies 140++

This was when I stumbled into the alpha colors problem.

The pie slice filling problem was discovered earlier by others and solutions explored at Walter's forum. I still have code and Steve has solutions too I think. I see the PAINT leaks shows up in running old Qbasic code in QB64 that TempodiBasic brought today.

[bplus]

Guys, thanks.  I had imagined that Tempo's (well everybody's) problem had something to do with leakiness or such.  But having recently used (for my Pascal's Triangle graphical program) CIRCLE and PAINT with complete success, I'd assumed that there was nothing wrong.  I've never used segments not tried alpha with CIRCLE.  I have always been wondrous at PAINT actually working: what brilliant piece of programming is required to determine uniquely one side and the other of a drawn line? does the (c#) programming look pixel-by-pixel or what?

PAINT is an interesting recursive algorithm similar to making fire or growing kelp. Steve and I played around with a PAINT like method for filling a space with balls. It also comes up with labeling cells in FreeCell or MineSweeper and the Pathfinding thing we played with here for possible games.

Code: QB64: [Select]

1. _TITLE "Circle Paint by Steve mod B+" '2019-02-06
2. SCREEN _NEWIMAGE(640, 480, 32)
3.  
4. CONST Red = &HFFFF0000
5.  
6. LINE (200, 200)-(400, 400), Red, B
7. CircleFiller 300, 300, 10, Red
8. PRINT "Hit any key for real fun!"
9. SLEEP
10. CLS , 0
11. WHILE _KEYDOWN(27) = 0
12.     CLS
13.     LINE (1, 1)-(639, 479), Red, B
14.     LINE (0, 0)-(640, 480), Red, B
15.     FOR i = 1 TO 5
16.         CIRCLE (RND * 640, RND * 480), RND * 30 + 20, Red
17.     NEXT
18.     CircleFiller 320, 240, 10, Red
19.     _DISPLAY
20.     _LIMIT .5
21. WEND
22.  
23. SUB CircleFiller (x, y, r, k AS _UNSIGNED LONG)
24.     IF CircleFillValid(x, y, r, k) THEN
25.         CircleFill x, y, r, k
26.         CircleFiller x - r - r - 1, y, r, k
27.         CircleFiller x + r + r + 1, y, r, k
28.         CircleFiller x, y - r - r - 1, r, k
29.         CircleFiller x, y + r + r + 1, r, k
30.     END IF
31. END SUB
32.  
33.  
34. SUB CircleFill (cx AS INTEGER, cy AS INTEGER, r AS INTEGER, c AS _UNSIGNED LONG)
35.     DIM a AS LONG, b AS LONG
36.     DIM x AS LONG, y AS LONG
37.     DIM xx AS LONG, yy AS LONG
38.     DIM sx AS LONG, sy AS LONG
39.     DIM e AS LONG
40.     DIM rx AS INTEGER, ry AS INTEGER
41.     rx = r: ry = r
42.  
43.     a = 2 * rx * rx
44.     b = 2 * ry * ry
45.     x = rx
46.     xx = ry * ry * (1 - rx - rx)
47.     yy = rx * rx
48.     sx = b * rx
49.  
50.     DO WHILE sx >= sy
51.         LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
52.         IF y <> 0 THEN LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
53.  
54.         y = y + 1
55.         sy = sy + a
56.         e = e + yy
57.         yy = yy + a
58.  
59.         IF (e + e + xx) > 0 THEN
60.             x = x - 1
61.             sx = sx - b
62.             e = e + xx
63.             xx = xx + b
64.         END IF
65.     LOOP
66.  
67.     x = 0
68.     y = ry
69.     xx = rx * ry
70.     yy = rx * rx * (1 - ry - ry)
71.     e = 0
72.     sx = 0
73.     sy = a * ry
74.  
75.     DO WHILE sx <= sy
76.         LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
77.         LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
78.  
79.         DO
80.             x = x + 1
81.             sx = sx + b
82.             e = e + xx
83.             xx = xx + b
84.         LOOP UNTIL (e + e + yy) > 0
85.  
86.         y = y - 1
87.         sy = sy - a
88.         e = e + yy
89.         yy = yy + a
90.  
91.     LOOP
92.  
93. END SUB
94.  
95.  
96. FUNCTION CircleFillValid (cx AS INTEGER, cy AS INTEGER, r AS INTEGER, c AS _UNSIGNED LONG)
97.     DIM a AS LONG, b AS LONG
98.     DIM x AS LONG, y AS LONG
99.     DIM xx AS LONG, yy AS LONG
100.     DIM sx AS LONG, sy AS LONG
101.     DIM e AS LONG
102.     DIM rx AS INTEGER, ry AS INTEGER
103.     rx = r: ry = r
104.  
105.     a = 2 * rx * rx
106.     b = 2 * ry * ry
107.     x = rx
108.     xx = ry * ry * (1 - rx - rx)
109.     yy = rx * rx
110.     sx = b * rx
111.  
112.     DO WHILE sx >= sy
113.         FOR i = cx - x TO cx + x
114.             IF POINT(i, cy - y) = c THEN EXIT FUNCTION
115.         NEXT
116.         'LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
117.         IF y <> 0 THEN
118.             'LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
119.             FOR i = cx - x TO cx + x
120.                 IF POINT(i, cy + y) = c THEN EXIT FUNCTION
121.             NEXT
122.         END IF
123.  
124.         y = y + 1
125.         sy = sy + a
126.         e = e + yy
127.         yy = yy + a
128.  
129.         IF (e + e + xx) > 0 THEN
130.             x = x - 1
131.             sx = sx - b
132.             e = e + xx
133.             xx = xx + b
134.         END IF
135.     LOOP
136.  
137.     x = 0
138.     y = ry
139.     xx = rx * ry
140.     yy = rx * rx * (1 - ry - ry)
141.     e = 0
142.     sx = 0
143.     sy = a * ry
144.  
145.     DO WHILE sx <= sy
146.         'LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
147.         'LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
148.         FOR i = cx - x TO cx + x
149.             IF POINT(i, cy - y) = c THEN EXIT FUNCTION
150.             IF POINT(i, cy + y) = c THEN EXIT FUNCTION
151.         NEXT
152.  
153.         DO
154.             x = x + 1
155.             sx = sx + b
156.             e = e + xx
157.             xx = xx + b
158.         LOOP UNTIL (e + e + yy) > 0
159.  
160.         y = y - 1
161.         sy = sy - a
162.         e = e + yy
163.         yy = yy + a
164.  
165.     LOOP
166.     CircleFillValid = -1
167. END SUB
168.  
169.  

Hey Pete!

Code: QB64: [Select]

1. _TITLE "Circle Filled by Steve mod B+" '2019-02-06
2. CONST xmax = 800
3. CONST ymax = 600
4.  
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE _MIDDLE
7. DIM SHARED black AS _UNSIGNED LONG
8. black = _RGB32(0, 0, 0)
9.  
10. LINE (0, 0)-(800, 600), black, BF
11. LINE (200, 200)-(400, 400), &HFFFFFFFF, B
12. PaintWithBalls 300, 300, 10, _RGB32(255, 128, 0)
13. INPUT "To see a show, press enter,  and other + enter ends program... "; wate$
14.  
15. WHILE _KEYDOWN(27) = 0
16.     LINE (0, 0)-(800, 600), &HFF000000, BF
17.     LINE (0, 0)-(800, 600), _RGB32(255, 255, 255), B
18.     LINE (1, 1)-(799, 599), _RGB32(255, 255, 255), B
19.     FOR i = 1 TO 5
20.         LINE (RND * 800, RND * 600)-STEP(RND * 50 + 50, RND * 50 + 50), _RGB32(RND * 255, RND * 255, RND * 255), B
21.     NEXT
22.     PaintWithBalls 200, 200, INT(RND * 45 + 5), _RGB32(255, 100, 0)
23.     _LIMIT 1
24. WEND
25.  
26. SUB PaintWithBalls (X, Y, ballRadius, ballColr AS _UNSIGNED LONG)
27.     ra = _PI(2 / 6)
28.     br = 2 * ballRadius + 1
29.     IF circClear(X, Y, ballRadius) THEN
30.         ball X, Y, ballRadius, ballColr
31.         PaintWithBalls X + br * COS(0), Y + br * SIN(0), ballRadius, ballColr
32.         PaintWithBalls X + br * COS(ra), Y + br * SIN(ra), ballRadius, ballColr
33.         PaintWithBalls X + br * COS(ra * 2), Y + br * SIN(ra * 2), ballRadius, ballColr
34.         PaintWithBalls X + br * COS(ra * 3), Y + br * SIN(ra * 3), ballRadius, ballColr
35.         PaintWithBalls X + br * COS(ra * 4), Y + br * SIN(ra * 4), ballRadius, ballColr
36.         PaintWithBalls X + br * COS(ra * 5), Y + br * SIN(ra * 5), ballRadius, ballColr
37.     END IF
38. END SUB
39.  
40. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
41. FUNCTION circClear (CX AS LONG, CY AS LONG, R AS LONG)
42.     DIM subRadius AS LONG, RadiusError AS LONG
43.     DIM X AS LONG, Y AS LONG
44.  
45.     subRadius = ABS(R)
46.     RadiusError = -subRadius
47.     X = subRadius
48.     Y = 0
49.  
50.     'IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
51.  
52.     ' Draw the middle span here so we don't draw it twice in the main loop,
53.     ' which would be a problem with blending turned on.
54.     FOR i = CX - X TO CX + X
55.         IF POINT(i, CY) <> black THEN EXIT FUNCTION
56.     NEXT
57.     WHILE X > Y
58.         RadiusError = RadiusError + Y * 2 + 1
59.         IF RadiusError >= 0 THEN
60.             IF X <> Y + 1 THEN
61.                 FOR i = CX - Y TO CX + Y
62.                     IF POINT(i, CY - X) <> black THEN EXIT FUNCTION
63.                 NEXT
64.                 'LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
65.                 FOR i = CX - Y TO CX + Y
66.                     IF POINT(i, CY + X) <> black THEN EXIT FUNCTION
67.                 NEXT
68.                 'LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
69.             END IF
70.             X = X - 1
71.             RadiusError = RadiusError - X * 2
72.         END IF
73.         Y = Y + 1
74.         FOR i = CX - X TO CX + X
75.             IF POINT(i, CY - Y) <> black THEN EXIT FUNCTION
76.         NEXT
77.         'LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
78.  
79.         FOR i = CX - X TO CX + X
80.             IF POINT(i, CY + Y) <> black THEN EXIT FUNCTION
81.         NEXT
82.         'LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
83.  
84.     WEND
85.     circClear = -1
86. END FUNCTION
87.  
88. SUB ball (x AS INTEGER, y AS INTEGER, r AS INTEGER, K AS _UNSIGNED LONG)
89.     DIM rd AS _UNSIGNED LONG, g AS _UNSIGNED LONG, b AS LONG, kr AS _UNSIGNED LONG
90.     rd = _RED32(K): g = _GREEN32(K): b = _BLUE32(K)
91.     FOR rad = r TO 1 STEP -1
92.         kr = _RGB32((r - rad) / r * rd, (r - rad) / r * g, (r - rad) / r * b)
93.         fel x, y, rad, rad, kr
94.     NEXT
95. END SUB
96.  
97. 'FillEllipse is too much typing so aballRadiuseviated to fel
98. ' with Steve's EllipseFill, who needs CircleFill? fix for 0 radii 2019-02-05
99. ' Is this fast enough for general circle fill (June 2018):  https://www.qb64.org/forum/index.php?topic=298.msg1942#msg1942
100. '  EllipseFill SMcNeill (Nov 3, 2018) https://www.qb64.org/forum/index.php?topic=755.msg6506#msg6506
101. SUB fel (cx AS INTEGER, cy AS INTEGER, rx AS INTEGER, ry AS INTEGER, c AS _UNSIGNED LONG)
102.     DIM a AS LONG, b AS LONG
103.     DIM x AS LONG, y AS LONG
104.     DIM xx AS LONG, yy AS LONG
105.     DIM sx AS LONG, sy AS LONG
106.     DIM e AS LONG
107.  
108.     IF rx = 0 OR ry = 0 THEN EXIT SUB 'nothing to draw
109.  
110.     a = 2 * rx * rx
111.     b = 2 * ry * ry
112.     x = rx
113.     xx = ry * ry * (1 - rx - rx)
114.     yy = rx * rx
115.     sx = b * rx
116.  
117.     DO WHILE sx >= sy
118.         LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
119.         IF y <> 0 THEN LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
120.  
121.         y = y + 1
122.         sy = sy + a
123.         e = e + yy
124.         yy = yy + a
125.  
126.         IF (e + e + xx) > 0 THEN
127.             x = x - 1
128.             sx = sx - b
129.             e = e + xx
130.             xx = xx + b
131.         END IF
132.     LOOP
133.  
134.     x = 0
135.     y = ry
136.     xx = rx * ry
137.     yy = rx * rx * (1 - ry - ry)
138.     e = 0
139.     sx = 0
140.     sy = a * ry
141.  
142.     DO WHILE sx <= sy
143.         LINE (cx - x, cy - y)-(cx + x, cy - y), c, BF
144.         LINE (cx - x, cy + y)-(cx + x, cy + y), c, BF
145.  
146.         DO
147.             x = x + 1
148.             sx = sx + b
149.             e = e + xx
150.             xx = xx + b
151.         LOOP UNTIL (e + e + yy) > 0
152.  
153.         y = y - 1
154.         sy = sy - a
155.         e = e + yy
156.         yy = yy + a
157.  
158.     LOOP
159.  
160. END SUB
161.  
162. FUNCTION rand% (lo%, hi%)
163.     rand% = INT(RND * (hi% - lo% + 1)) + lo%
164. END FUNCTION
165.  
166.  
167.