Circle Filled

[bplus]

I had fun this morning trying to get this going, not quite right but close enough to give idea.

Code: QB64: [Select]

1. _TITLE "*** Circle Filled *** by bplus 2018-02-28"
2. RANDOMIZE TIMER
3. CONST sw = 600
4. CONST sh = 600
5. SCREEN _NEWIMAGE(sw, sh, 32)
6. _SCREENMOVE 100, 20
7.  
8. TYPE circles
9.     x AS INTEGER
10.     y AS INTEGER
11.     r AS INTEGER
12. END TYPE
13. i = 0
14. REDIM cs(i) AS circles
15. r = 150
16. WHILE r >= 2
17.     IF i > 0 THEN
18.         FOR y = r TO sh - r STEP r / 2
19.             FOR x = r TO sw - r STEP r / 2
20.                 ck = 1
21.                 FOR c = 0 TO i - 1
22.                     IF ((x - cs(c).x) ^ 2 + (y - cs(c).y) ^ 2) ^ .5 < r + cs(c).r THEN ck = 0: EXIT FOR
23.                 NEXT
24.                 IF ck THEN 'new circle  draw it
25.                     COLOR _RGB32(155 + r, 155 + r, 155 + r)
26.                     fcirc x, y, r
27.                     CIRCLE (x, y), r, _RGB32(255, 255, 255)
28.                     cs(i).x = x
29.                     cs(i).y = y
30.                     cs(i).r = r
31.                     i = i + 1
32.                     REDIM _PRESERVE cs(i) AS circles
33.                 END IF
34.             NEXT
35.         NEXT
36.         'keep reducing r until smallest r desired
37.         r = r - 1
38.     ELSE
39.         'start this sucker in top left corner of screen
40.         cs(i).x = r
41.         cs(i).y = r
42.         cs(i).r = r
43.         COLOR _RGB32(155 + r, 155 + r, 155 + r)
44.         fcirc cs(i).x, cs(i).y, cs(i).r
45.         CIRCLE (cs(i).x, cs(i).y), cs(i).r, _RGB32(255, 255, 255)
46.         i = i + 1
47.         REDIM _PRESERVE cs(i) AS circles
48.     END IF
49. WEND
50. SLEEP
51.  
52.  
53. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
54. SUB fcirc (CX AS LONG, CY AS LONG, R AS LONG)
55.     DIM subRadius AS LONG, RadiusError AS LONG
56.     DIM X AS LONG, Y AS LONG
57.  
58.     subRadius = ABS(R)
59.     RadiusError = -subRadius
60.     X = subRadius
61.     Y = 0
62.  
63.     IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
64.  
65.     ' Draw the middle span here so we don't draw it twice in the main loop,
66.     ' which would be a problem with blending turned on.
67.     LINE (CX - X, CY)-(CX + X, CY), , BF
68.  
69.     WHILE X > Y
70.         RadiusError = RadiusError + Y * 2 + 1
71.         IF RadiusError >= 0 THEN
72.             IF X <> Y + 1 THEN
73.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
74.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
75.             END IF
76.             X = X - 1
77.             RadiusError = RadiusError - X * 2
78.         END IF
79.         Y = Y + 1
80.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
81.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
82.     WEND
83. END SUB
84.  
85.  

If you know what I am trying to get at, feel free to show me the way. :)