Convert Decimal to Fraction

[bplus]

I was looking over some of the programs in the DOS WORLD QBASIC.zip package:
https://www.qb64.org/forum/index.php?topic=1085.msg102795#msg102795

 and became interested in DEC_FRAC.BAS:

Code: QB64: [Select]

1. '  DEC_FRAC.BAS - Fraction/Decimal conversion functions
2. '                and sample program
3.  
4. '  by Antonio and Alfonso De Pasquale
5. '  Copyright (C) 1993 DOS Resource Guide
6. '  Published in Issue #10, July 1993, page 46
7.  
8. DECLARE FUNCTION DecToFrac$ (decimal)
9. DECLARE FUNCTION FracToDec (fraction$)
10.  
11. MAIN:
12. CLS: LOCATE 1, 25: PRINT "Fraction/Decimal Converter"
13. LOCATE 2, 21: PRINT "by Antonio and Alfonso De Pasquale"
14. LOCATE 3, 1: FOR x = 1 TO 79: PRINT "=";: NEXT x
15. LOCATE 5, 1: PRINT "Please select one of the following choices:"
16. LOCATE 7, 10: PRINT "[D]ecimal to Fraction"
17. LOCATE 8, 10: PRINT "[F]raction to Decimal"
18. LOCATE 9, 10: PRINT "[Q]uit Program"
19.  
20. DO
21.     LOCATE 11, 1: PRINT SPACE$(79)
22.     LOCATE 11, 1: INPUT "Please enter your choice (D/F/Q): ", choice$
23.     choice$ = UCASE$(LEFT$(choice$, 1))
24. LOOP UNTIL choice$ = "D" OR choice$ = "F" OR choice$ = "Q"
25.  
26. CONVERT:
27. SELECT CASE choice$
28.     CASE "Q"
29.         CLS: END
30.  
31.     CASE "D"
32.         LOCATE 13, 1: PRINT SPACE$(79)
33.         LOCATE 13, 1: INPUT "Please enter a decimal value: ", decimal$
34.         decimal = VAL(decimal$)
35.         IF decimal = 0 OR INT(decimal) = decimal THEN GOTO CONVERT
36.         fraction$ = DecToFrac$(decimal)
37.         LOCATE 16, 1: PRINT "The Decimal  "; decimal; "  is equal to the fraction; "; fraction$; ""
38.  
39.     CASE "F"
40.         LOCATE 13, 1: PRINT SPACE$(79)
41.         LOCATE 13, 1: INPUT "Please enter a fractional value: ", fraction$
42.         fl$ = fraction$: fl$ = fl$ + " ": fl = INSTR(1, fl$, "/")
43.         IF VAL(fraction$) = 0 OR fl = 0 THEN GOTO CONVERT
44.         IF (MID$(fl$, fl - 1, 1) = " ") OR (MID$(fl$, fl + 1, 1) = " ") THEN GOTO CONVERT
45.         decimal = FracToDec(fraction$)
46.         LOCATE 16, 1: PRINT "The fraction  "; fraction$; "  is equal to the decimal  "; decimal
47.  
48. END SELECT
49.  
50. LOCATE 19, 1: PRINT "Press Enter to continue";
51. DO: LOOP UNTIL INKEY$ = CHR$(13)
52. GOTO MAIN
53. END
54.  
55. '*********************************************************
56. '
57. '         ACTUAL CONVERSION FUNCTIONS BEGIN HERE
58. '
59. '*********************************************************
60.  
61. FUNCTION DecToFrac$ (decimal)
62.  
63.     decimal$ = STR$(decimal)
64.     index = INSTR(decimal$, ".")
65.    
66.     IF index = 1 THEN
67.         decimal$ = "0" + decimal$
68.         index = index + 1
69.     END IF
70.  
71.     whole$ = LEFT$(decimal$, index - 1)
72.     dec$ = MID$(decimal$, index, 10)
73.  
74.     IF VAL(whole$) = 0 THEN
75.         whole$ = ""
76.     END IF
77.  
78.     dec = VAL(dec$)
79.     dec = INT(dec * 1000 + .5)
80.  
81.     num = dec
82.     den = 1000
83.  
84.     FOR pass = 0 TO 3
85.         FOR index = 10 TO 1 STEP -1
86.             IF (num / index = INT(num / index)) AND (den / index) = INT(den / index) THEN
87.                 num = (num / index)
88.                 den = (den / index)
89.             END IF
90.         NEXT index
91.     NEXT pass
92.  
93.     fraction$ = whole$ + STR$(num) + "/" + MID$(STR$(den), 2)
94.     DecToFrac$ = fraction$
95.  
96. END FUNCTION
97.  
98. FUNCTION FracToDec (fraction$)
99.  
100.     decimal = 0
101.     dp = 0
102.  
103.     index = INSTR(fraction$, CHR$(32))
104.  
105.     IF index = 0 THEN
106.         f$ = fraction$
107.     ELSE
108.         whole$ = LEFT$(fraction$, index)
109.         f$ = MID$(fraction$, index + 1, 10)
110.     END IF
111.  
112.     index = INSTR(f$, "/")
113.     num = VAL(LEFT$(f$, index - 1))
114.     den = VAL(MID$(f$, index + 1))
115.  
116.     dp = num / den
117.     decimal = ABS(VAL(whole$)) + dp
118.     IF LEFT$(fraction$, 1) = "-" THEN decimal = (-decimal)
119.     IF LEFT$(fraction$, 1) = "-" AND decimal > 0 THEN decimal = (-decimal)
120.     FracToDec = decimal
121.  
122. END FUNCTION
123.  

I tried a couple of 6 digit decimals .125125 and .333111 and saw that the method only seemed to handle 3 digits, ie answers back were for .125 and .333. The method used was a little curious too...

I thought I'd challenge folks to see if anyone could come up with better, elegant method, one that could at least come up with better answers for the tests mentioned.

[Pete]

My string math routine does a much better job of converting a fraction to a decimal. I don't have, nor do I want to make a way to convert a decimal to a fraction.

Pete

[Jack002]

The idea of converting any decimal to a fraction is huge.
If you had to do it yourself, you'd be able to see X/10, X/5, X/3, X/9. Some know the pattern of 1/7 and might see that.
I saw a cool youtube vid where they claim any number no matter how long (like 15-20 digits mostly) they could tell you if it was prime or what factors it had. Some tricky little hacks to do it.
If I find that link, I'll post it here.

[edit]

Not the one I saw, but seems similar

[bplus]

Hint: You don't have to find all the factors of a number, though prime sieving is fun too! :)

27 lines of code, .333111 >>> 333111 / 1,000,000  .125125 >>> 1001 / 8000

Bonus .125125125 >>> 1001001 / 8,000,000

[bplus]

Code: QB64: [Select]

1. WHILE 1
2.     PRINT: INPUT "Enter decimal to convert to fraction, 0 quits "; dec$
3.     IF dec$ = "0" THEN END ELSE PRINT convert2Fraction$(dec$)
4. WEND
5.  
6. FUNCTION convert2Fraction$ (decimal$)
7.     dot%% = INSTR(decimal$, ".")
8.     IF dot%% > 0 THEN
9.         whole$ = MID$(decimal$, 1, dot%% - 1)
10.         p%% = LEN(decimal$) - dot%%
11.         n&& = VAL(MID$(decimal$, dot%% + 1))
12.         d&& = 10 ^ p%%
13.         g&& = gcd&&(n&&, d&&): sn&& = n&& / g&&: sd&& = d&& / g&&
14.         convert2Fraction$ = whole$ + " " + _TRIM$(STR$(sn&&)) + "/" + _TRIM$(STR$(sd&&))
15.     ELSE
16.         convert2Fraction$ = decimal$
17.     END IF
18. END FUNCTION
19.  
20. FUNCTION gcd&& (a&&, b&&)
21.     'a and b will be changed unless make copies
22.     c&& = a&&: d&& = b&&
23.     WHILE c&& <> 0 AND d&& <> 0
24.         IF c&& > d&& THEN c&& = c&& MOD d&& ELSE d&& = d&& MOD c&&
25.     WEND
26.     gcd&& = c&& + d&&
27. END FUNCTION
28.  
29.  

[Pete]

If you enter too many digits, it just returns 1/1. Large decimals like 1 / 97 cannot be properly evaluated. Because it can't round, it would just give a giant numerator and denominator, anyway. It works great for common fractions.

Pete

[bplus]

If you enter too many digits, it just returns 1/1. Large decimals like 1 / 97 cannot be properly evaluated. Because it can't round, it would just give a giant numerator and denominator, anyway. It works great for common fractions.

Pete

Works for up to 18 digits, a little better than 3 don't ya think?

Because it can't reduce (not round) it will give giant denominators. I only promised a fraction not convenience nor practicality. :D

[Pete]

"I never promised you a rose garden..."

Pete :D

[Jack002]

If you enter too many digits, it just returns 1/1. Large decimals like 1 / 97 cannot be properly evaluated. Because it can't round, it would just give a giant numerator and denominator, anyway. It works great for common fractions.

Pete

Oh but if you ever get a chance, look at the recip of 97, its pretty cool. I did it in LISP once.

[Pete]

Works for up to 18 digits, a little better than 3 don't ya think?

Because it can't reduce (not round) it will give giant denominators. I only promised a fraction not convenience nor practicality. :D

It has to round to some degree to reduce properly. To try and get that for all possible decimal to fraction conversion would be a real... challenge.

Pete

[Qwerkey]

Works for up to 18 digits, a little better than 3 don't ya think?

bplus, another brilliancy.  But what does WHILE 1 mean?  My brain doesn't like that statement at all.  Clearly it's not 0 and therefore NOT False and therefore the condition is True, but it just looks horrible (to me).  I think that I'd be happier with WHILE -1 (which is the BASIC convention for True), but even that I don't like.  I'd have to write: Condition%% = -1, WHILE Condition%%.  Good thing that I never got a job requiring programming.

[bplus]

Hi Qwerky,

How about: WHILE 1 = 1 ?

Actually with QB64 you can do infinite loops (or loops with escape or end coded inside) with DO... LOOP so:

Code: QB64: [Select]

1. DO
2.     PRINT: INPUT "Enter decimal to convert to fraction, 0 quits "; dec$
3.     IF dec$ = "0" THEN END ELSE PRINT convert2Fraction$(dec$)
4. LOOP
5.  

might satisfy your QB senses. :)

[Jack002]

What about this?

For i = 1 to 2 step 0
    REM Now you're stuck here
next i

;)

[bplus]

Oh but if you ever get a chance, look at the recip of 97, its pretty cool. I did it in LISP once.

It has to round to some degree to reduce properly. To try and get that for all possible decimal to fraction conversion would be a real... challenge.

Pete

Hi Jack002,

Yes, I know what you are talking about and I have some code floating about that calculates precisely the decimal and the repeating digits part of the decimal like we learned in school for 1/7 = .142857 with a bar over the digits that repeat forever.


Hi Pete,

Yes, I think it is possible to do any fraction BUT first you must express the decimal with a special notation to handle the repeating part. I like 1/3 = .R3 = .33333...   1/6 = .1R6 = .16666...

I will try to dig up the code I had that did that and then I will try to reverse it back from the special decimal notation eg, .1R6 back to 1/6. There will likely be a limit on digits again until/unless you convert the code to employ your string math.

[bplus]

OK I have the special decimal notation working (I think):

Code: QB64: [Select]

1. _TITLE "n divided by d using R notation" '2019-04-24 R stands for Repeat section not Remainder
2. ' from:"Decimal Expansion of Division without Dividing  by bplus 2017-12-03"
3. ' dove tailing Adrians and my recent dividing programs
4.  
5. ' 2019-04-24
6. ' I want to isolate the repeated section immdeiately not write the fraction out and then repeat the repeated section
7. ' not 1/6 = .16R6 >>> but .1R6
8.  
9. 'hmm... look like have to cycle through twice to get the length of the repeat section
10. ' but before returning backup to start of repeat section insert the R where it starts the first time
11. ' and end it where " repeat " starts.
12.  
13.  
14. RANDOMIZE TIMER
15. DEFLNG A-Z
16. WHILE 1
17.     PRINT: PRINT "Enter 2 integers < 3200, numerator / denominator, 0's quit, don't forget / "
18.     INPUT nd$
19.     slash = INSTR(nd$, "/")
20.     IF slash THEN
21.         dvsr = VAL(MID$(nd$, slash + 1))
22.         IF dvsr = 0 THEN PRINT "Divisor is 0, bye.": END
23.         numerator = VAL(MID$(nd$, 1, slash - 1))
24.         IF numerator = 0 THEN PRINT "Numerator is 0, bye.": END
25.     ELSE
26.         PRINT "No slash found, bye.": END
27.     END IF
28.     PRINT numerator; " / "; dvsr; " = "; divide$(numerator, dvsr)
29. WEND
30.  
31. FUNCTION divide$ (n, d)
32.     'n = original product or numerator (preserve value of n)
33.     'd = divisor  (also preserve value)
34.     c = n 'copy of n to be reduced until <= d, c will be the remainder part of division
35.     a = 0 'a is for answer or accumulate, the integer part of the division result
36.  
37.     'find lowest power of 10 such that: d * 10^p > n
38.     p = 0 'power of 10
39.     WHILE d * (10 ^ p) < n
40.         p = p + 1
41.     WEND
42.     WHILE c >= d
43.         IF c = d THEN a = a + 1: c = 0: EXIT WHILE
44.         p = p - 1
45.         IF p >= 0 THEN
46.             m = 0
47.             WHILE d * m * 10 ^ p < c
48.                 m = m + 1
49.             WEND
50.             m = m - 1
51.             c = c - d * m * 10 ^ p
52.             a = a + m * 10 ^ p
53.         END IF
54.     WEND
55.  
56.     'Now for the decimal expansion isolating the repeating part if one
57.     IF c <> 0 THEN
58.         DIM b(d)
59.         b$ = "."
60.         WHILE c <> 0
61.  
62.             'emergency bug out!
63.             loopct = loopct + 1 'loop count should not exceed 1000 for numbers I am testing
64.             IF loopct > 1000 THEN PRINT "Error: loop too long, bugging out! ": GOTO skip
65.  
66.             'track repeats  b() tracks been here once, b2() tracks been here twice
67.             IF b(c) = 1 THEN 'been here!
68.                 IF rFlag = 1 THEN 'been here twice!
69.                     IF b2(c) = 1 THEN EXIT WHILE 'strike 3, we're out of here
70.                     b2(c) = 1
71.                 ELSE
72.                     rFlag = 1
73.                     DIM b2(d)
74.                     b$ = b$ + " repeat "
75.                     b2(c) = 1
76.                 END IF
77.             ELSE
78.                 b(c) = 1
79.             END IF
80.  
81.             'c was last remainder, mult by 10 and see if some m * d > can reduce it
82.             tc = 10 * c
83.             flag = 0
84.             FOR m = 0 TO 9
85.                 IF ((tc - m * d) >= 0) AND ((tc - (m + 1) * d) < 0) THEN
86.                     flag = 1: b$ = b$ + LTRIM$(STR$(m))
87.                     EXIT FOR
88.                 END IF
89.             NEXT
90.             IF flag = 0 THEN b$ = b$ + "0": m = 0
91.             c = tc - d * m
92.         WEND
93.     END IF
94.  
95.     'OK either d divided n eventually or there is a repeated pattern recorded in b$
96.     skip: '< needed for debugging
97.     r$ = STR$(a)
98.     IF b$ <> "" THEN r$ = r$ + b$
99.     PRINT "Check string before chopping redundant section:"
100.     PRINT r$
101.     pete$ = " repeat "
102.     rpos = INSTR(r$, pete$)
103.     IF rpos > 0 THEN 'cut string down
104.         tail$ = MID$(r$, rpos)
105.         backup = LEN(tail$) - LEN(pete$)
106.         r$ = MID$(r$, 1, rpos - 1 - backup) + "R" + MID$(r$, rpos - backup, backup)
107.     END IF
108.     divide$ = r$
109. END FUNCTION
110.  
111.  

Yeah, 1/97 is looking like it would need string math to process. :D yikes! that's long!